[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / ResultSource / RowParser.pm

package # hide from the pauses
  DBIx::Class::ResultSource::RowParser;

use strict;
use warnings;

use base 'DBIx::Class';

use Try::Tiny;
use List::Util qw(first max);

use DBIx::Class::ResultSource::RowParser::Util qw(
  assemble_simple_parser
  assemble_collapsing_parser
);

use DBIx::Class::Carp;

use namespace::clean;

# Accepts a prefetch map (one or more relationships for the current source),
# returns a set of select/as pairs for each of those relationships. Columns
# are fully qualified inflation_slot names
sub _resolve_selection_from_prefetch {
  my ($self, $pre, $alias_map, $pref_path) = @_;

  # internal recursion marker
  $pref_path ||= [];

  if (not defined $pre or not length $pre) {
    return ();
  }
  elsif( ref $pre eq 'ARRAY' ) {
    map { $self->_resolve_selection_from_prefetch( $_, $alias_map, [ @$pref_path ] ) }
      @$pre;
  }
  elsif( ref $pre eq 'HASH' ) {
    map {
      $self->_resolve_selection_from_prefetch($_, $alias_map, [ @$pref_path ] ),
      $self->related_source($_)->_resolve_selection_from_prefetch(
         $pre->{$_}, $alias_map, [ @$pref_path, $_] )
    } keys %$pre;
  }
  elsif( ref $pre ) {
    $self->throw_exception(
      "don't know how to resolve prefetch reftype ".ref($pre));
  }
  else {
    my $p = $alias_map;
    $p = $p->{$_} for @$pref_path, $pre;

    $self->throw_exception (
      "Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
      . join (' -> ', @$pref_path, $pre)
    ) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );

    # this shift() is critical - it is what allows prefetch => [ (foo) x 2 ] to work
    my $src_alias = shift @{$p->{-join_aliases}};

    # ordered [select => as] pairs
    map { [
      "${src_alias}.$_" => join ( '.',
        @$pref_path,
        $pre,
        $_,
      )
    ] } $self->related_source($pre)->columns;
  }
}

sub _resolve_prefetch {
  carp_unique(
    'There is no good reason to call this internal deprecated method - '
  . 'please open a ticket detailing your usage, so that a better plan can '
  . 'be devised for your case. In either case _resolve_prefetch() is '
  . 'deprecated in favor of _resolve_selection_from_prefetch(), which has '
  . 'a greatly simplified arglist.'
  );

  $_[0]->_resolve_selection_from_prefetch( $_[1], $_[3] );
}


# Takes an arrayref of {as} dbic column aliases and the collapse and select
# attributes from the same $rs (the selector requirement is a temporary
# workaround... I hope), and returns a coderef capable of:
# my $me_pref_clps = $coderef->([$rs->cursor->next/all])
# Where the $me_pref_clps arrayref is the future argument to inflate_result()
#
# For an example of this coderef in action (and to see its guts) look at
# t/resultset/rowparser_internals.t
#
# This is a huge performance win, as we call the same code for every row
# returned from the db, thus avoiding repeated method lookups when traversing
# relationships
#
# Also since the coderef is completely stateless (the returned structure is
# always fresh on every new invocation) this is a very good opportunity for
# memoization if further speed improvements are needed
#
# The way we construct this coderef is somewhat fugly, although the result is
# really worth it. The final coderef does not perform any kind of recursion -
# the entire nested structure constructor is rolled out into a single scope.
#
# In any case - the output of this thing is meticulously micro-tested, so
# any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
#
sub _mk_row_parser {
  # $args and $attrs are separated to delineate what is core collapser stuff and
  # what is dbic $rs specific
  my ($self, $args, $attrs) = @_;

  die "HRI without pruning makes zero sense"
  if ( $args->{hri_style} && ! $args->{prune_null_branches} );

  my %common = (
    hri_style => $args->{hri_style},
    prune_null_branches => $args->{prune_null_branches},
    val_index => { map
      { $args->{inflate_map}[$_] => $_ }
      ( 0 .. $#{$args->{inflate_map}} )
    },
  );

  my $check_null_columns;

  my $src = (! $args->{collapse} ) ? assemble_simple_parser(\%common) : do {
    my $collapse_map = $self->_resolve_collapse ({
      # FIXME
      # only consider real columns (not functions) during collapse resolution
      # this check shouldn't really be here, as fucktards are not supposed to
      # alias random crap to existing column names anyway, but still - just in
      # case
      # FIXME !!!! - this does not yet deal with unbalanced selectors correctly
      # (it is now trivial as the attrs specify where things go out of sync
      # needs MOAR tests)
      as => { map
        { ref $attrs->{select}[$common{val_index}{$_}] ? () : ( $_ => $common{val_index}{$_} ) }
        keys %{$common{val_index}}
      },
      premultiplied => $args->{premultiplied},
    });

    $check_null_columns = $collapse_map->{-identifying_columns}
      if @{$collapse_map->{-identifying_columns}};

    assemble_collapsing_parser({
      %common,
      collapse_map => $collapse_map,
    });
  };

  utf8::upgrade($src)
    if DBIx::Class::_ENV_::STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE;

  return (
    $args->{eval} ? ( eval "sub $src" || die $@ ) : $src,
    $check_null_columns,
  );
}


# Takes an arrayref selection list and generates a collapse-map representing
# row-object fold-points. Every relationship is assigned a set of unique,
# non-nullable columns (which may *not even be* from the same resultset)
# and the collapser will use this information to correctly distinguish
# data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
# for extensive RV examples
sub _resolve_collapse {
  my ($self, $args, $common_args) = @_;

  # for comprehensible error messages put ourselves at the head of the relationship chain
  $args->{_rel_chain} ||= [ $self->source_name ];

  # record top-level fully-qualified column index, signify toplevelness
  unless ($common_args->{_as_fq_idx}) {
    $common_args->{_as_fq_idx} = { %{$args->{as}} };
    $args->{_is_top_level} = 1;
  };

  my ($my_cols, $rel_cols);
  for (keys %{$args->{as}}) {
    if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
      $rel_cols->{$1}{$2} = 1;
    }
    else {
      $my_cols->{$_} = {};  # important for ||='s below
    }
  }

  my $relinfo;
  # run through relationships, collect metadata
  for my $rel (keys %$rel_cols) {
    my $inf = $self->relationship_info ($rel);

    $relinfo->{$rel} = {
      is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
      is_inner => ( ( $inf->{attrs}{join_type} || '' ) !~ /^left/i),
      rsrc => $self->related_source($rel),
      fk_map => $self->_resolve_relationship_condition(
        rel_name => $rel,
        self_alias => "\xFE", # irrelevant
        foreign_alias => "\xFF", # irrelevant
      )->{identity_map},
    };
  }

  # inject non-left fk-bridges from *INNER-JOINED* children (if any)
  for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
    my $ri = $relinfo->{$rel};
    for (keys %{$ri->{fk_map}} ) {
      # need to know source from *our* pov, hence $rel.col
      $my_cols->{$_} ||= { via_fk => "$rel.$ri->{fk_map}{$_}" }
        if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
    }
  }

  # if the parent is already defined *AND* we have an inner reverse relationship
  # (i.e. do not exist without it) , assume all of its related FKs are selected
  # (even if they in fact are NOT in the select list). Keep a record of what we
  # assumed, and if any such phantom-column becomes part of our own collapser,
  # throw everything assumed-from-parent away and replace with the collapser of
  # the parent (whatever it may be)
  my $assumed_from_parent;
  if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
    for my $col ( values %{$args->{_parent_info}{rel_condition} || {}} ) {
      next if exists $my_cols->{$col};
      $my_cols->{$col} = {};
      $assumed_from_parent->{columns}{$col}++;
    }
  }

  # get colinfo for everything
  if ($my_cols) {
    my $ci = $self->columns_info;
    $my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
  }

  my $collapse_map;

  # first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
  # (makes for a leaner coderef later)
  unless ($collapse_map->{-identifying_columns}) {
    $collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
      if $args->{_parent_info}{collapser_reusable};
  }

  # Still don't know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
  if (
    ! $collapse_map->{-identifying_columns}
      and
    $my_cols
      and
    my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
  ) {
    # see if the resulting collapser relies on any implied columns,
    # and fix stuff up if this is the case
    my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;

    $collapse_map->{-identifying_columns} = [ __unique_numlist(
      @{ $args->{_parent_info}{collapse_on_idcols}||[] },

      (map
        {
          my $fqc = join ('.',
            @{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
            ( $my_cols->{$_}{via_fk} || $_ ),
          );

          $common_args->{_as_fq_idx}->{$fqc};
        }
        @reduced_set
      ),
    )];
  }

  # Stil don't know how to collapse - keep descending down 1:1 chains - if
  # a related non-LEFT 1:1 is resolvable - its condition will collapse us
  # too
  unless ($collapse_map->{-identifying_columns}) {
    my @candidates;

    for my $rel (keys %$relinfo) {
      next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});

      if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
        as => $rel_cols->{$rel},
        _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
        _parent_info => { underdefined => 1 },
      }, $common_args)) {
        push @candidates, $rel_collapse->{-identifying_columns};
      }
    }

    # get the set with least amount of columns
    # FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
    # to a single varchar)
    if (@candidates) {
      ($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
    }
  }

  # Stil don't know how to collapse, and we are the root node. Last ditch
  # effort in case we are *NOT* premultiplied.
  # Run through *each multi* all the way down, left or not, and all
  # *left* singles (a single may become a multi underneath) . When everything
  # gets back see if all the rels link to us definitively. If this is the
  # case we are good - either one of them will define us, or if all are NULLs
  # we know we are "unique" due to the "non-premultiplied" check
  if (
    ! $collapse_map->{-identifying_columns}
      and
    ! $args->{premultiplied}
      and
    $args->{_is_top_level}
  ) {
    my (@collapse_sets, $uncollapsible_chain);

    for my $rel (keys %$relinfo) {

      # we already looked at these higher up
      next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});

      if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
        as => $rel_cols->{$rel},
        _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
        _parent_info => { underdefined => 1 },
      }, $common_args) ) {

        # for singles use the idcols wholesale (either there or not)
        if ($relinfo->{$rel}{is_single}) {
          push @collapse_sets, $clps->{-identifying_columns};
        }
        elsif (! $relinfo->{$rel}{fk_map}) {
          $uncollapsible_chain = 1;
          last;
        }
        else {
          my $defined_cols_parent_side;

          for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
            my ($col) = $fq_col =~ /([^\.]+)$/;

            $defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
              { $relinfo->{$rel}{fk_map}{$_} eq $col }
              keys %{$relinfo->{$rel}{fk_map}}
            ;
          }

          if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
            push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
          }
          else {
            $uncollapsible_chain = 1;
            last;
          }
        }
      }
      else {
        $uncollapsible_chain = 1;
        last;
      }
    }

    unless ($uncollapsible_chain) {
      # if we got here - we are good to go, but the construction is tricky
      # since our children will want to include our collapse criteria - we
      # don't give them anything (safe, since they are all collapsible on their own)
      # in addition we record the individual collapse possibilities
      # of all left children node collapsers, and merge them in the rowparser
      # coderef later
      $collapse_map->{-identifying_columns} = [];
      $collapse_map->{-identifying_columns_variants} = [ sort {
        (scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
      } @collapse_sets ];
    }
  }

  # stop descending into children if we were called by a parent for first-pass
  # and don't despair if nothing was found (there may be other parallel branches
  # to dive into)
  if ($args->{_parent_info}{underdefined}) {
    return $collapse_map->{-identifying_columns} ? $collapse_map : undef
  }
  # nothing down the chain resolved - can't calculate a collapse-map
  elsif (! $collapse_map->{-identifying_columns}) {
    $self->throw_exception ( sprintf
      "Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
      $self->source_name,
      @{$args->{_rel_chain}} > 1
        ? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
        : ''
      ,
    );
  }

  # If we got that far - we are collapsable - GREAT! Now go down all children
  # a second time, and fill in the rest

  $collapse_map->{-identifying_columns} = [ __unique_numlist(
    @{ $args->{_parent_info}{collapse_on_idcols}||[] },
    @{ $collapse_map->{-identifying_columns} },
  )];

  for my $rel (sort keys %$relinfo) {

    $collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
      as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
      _rel_chain => [ @{$args->{_rel_chain}}, $rel],
      _parent_info => {
        # shallow copy
        collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],

        rel_condition => $relinfo->{$rel}{fk_map},

        is_optional => ! $relinfo->{$rel}{is_inner},

        # if there is at least one *inner* reverse relationship which is HASH-based (equality only)
        # we can safely assume that the child can not exist without us
        rev_rel_is_optional => ( first
          { ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}||'') !~ /^left/i }
          values %{ $self->reverse_relationship_info($rel) },
        ) ? 0 : 1,

        # if this is a 1:1 our own collapser can be used as a collapse-map
        # (regardless of left or not)
        collapser_reusable => (
          $relinfo->{$rel}{is_single}
            &&
          $relinfo->{$rel}{is_inner}
            &&
          @{$collapse_map->{-identifying_columns}}
        ) ? 1 : 0,
      },
    }, $common_args );

    $collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
    $collapse_map->{$rel}{-is_optional} ||= 1 unless $relinfo->{$rel}{is_inner};
  }

  return $collapse_map;
}

# adding a dep on MoreUtils *just* for this is retarded
sub __unique_numlist {
  sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
}

1;
Commit	Line	Data
4e9fc3f3	1	package # hide from the pauses
4e9fc3f3	2	DBIx::Class::ResultSource::RowParser;
76031e14	3
	4	use strict;
	5	use warnings;
	6
9f98c4b2	7	use base 'DBIx::Class';
9f98c4b2	8
76031e14	9	use Try::Tiny;
fcf32d04	10	use List::Util qw(first max);
76031e14	11
9f98c4b2	12	use DBIx::Class::ResultSource::RowParser::Util qw(
	13	assemble_simple_parser
	14	assemble_collapsing_parser
	15	);
76031e14	16
47dba3e3	17	use DBIx::Class::Carp;
47dba3e3	18
9f98c4b2	19	use namespace::clean;
76031e14	20
47dba3e3	21	# Accepts a prefetch map (one or more relationships for the current source),
	22	# returns a set of select/as pairs for each of those relationships. Columns
	23	# are fully qualified inflation_slot names
	24	sub _resolve_selection_from_prefetch {
	25	my ($self, $pre, $alias_map, $pref_path) = @_;
	26
	27	# internal recursion marker
76031e14	28	$pref_path \|\|= [];
	29
	30	if (not defined $pre or not length $pre) {
	31	return ();
	32	}
	33	elsif( ref $pre eq 'ARRAY' ) {
47dba3e3	34	map { $self->_resolve_selection_from_prefetch( $_, $alias_map, [ @$pref_path ] ) }
47dba3e3	35	@$pre;
76031e14	36	}
76031e14	37	elsif( ref $pre eq 'HASH' ) {
76031e14	38	map {
47dba3e3	39	$self->_resolve_selection_from_prefetch($_, $alias_map, [ @$pref_path ] ),
	40	$self->related_source($_)->_resolve_selection_from_prefetch(
	41	$pre->{$_}, $alias_map, [ @$pref_path, $_] )
76031e14	42	} keys %$pre;
76031e14	43	}
	44	elsif( ref $pre ) {
	45	$self->throw_exception(
	46	"don't know how to resolve prefetch reftype ".ref($pre));
	47	}
	48	else {
	49	my $p = $alias_map;
47dba3e3	50	$p = $p->{$_} for @$pref_path, $pre;
76031e14	51
	52	$self->throw_exception (
	53	"Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
	54	. join (' -> ', @$pref_path, $pre)
	55	) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );
	56
47dba3e3	57	# this shift() is critical - it is what allows prefetch => [ (foo) x 2 ] to work
47dba3e3	58	my $src_alias = shift @{$p->{-join_aliases}};
76031e14	59
47dba3e3	60	# ordered [select => as] pairs
	61	map { [
	62	"${src_alias}.$_" => join ( '.',
	63	@$pref_path,
	64	$pre,
	65	$_,
	66	)
	67	] } $self->related_source($pre)->columns;
	68	}
	69	}
76031e14	70
47dba3e3	71	sub _resolve_prefetch {
	72	carp_unique(
	73	'There is no good reason to call this internal deprecated method - '
	74	. 'please open a ticket detailing your usage, so that a better plan can '
	75	. 'be devised for your case. In either case _resolve_prefetch() is '
	76	. 'deprecated in favor of _resolve_selection_from_prefetch(), which has '
	77	. 'a greatly simplified arglist.'
	78	);
76031e14	79
47dba3e3	80	$_[0]->_resolve_selection_from_prefetch( $_[1], $_[3] );
76031e14	81	}
76031e14	82
47dba3e3	83
9f98c4b2	84	# Takes an arrayref of {as} dbic column aliases and the collapse and select
	85	# attributes from the same $rs (the selector requirement is a temporary
	86	# workaround... I hope), and returns a coderef capable of:
	87	# my $me_pref_clps = $coderef->([$rs->cursor->next/all])
	88	# Where the $me_pref_clps arrayref is the future argument to inflate_result()
	89	#
	90	# For an example of this coderef in action (and to see its guts) look at
	91	# t/resultset/rowparser_internals.t
	92	#
	93	# This is a huge performance win, as we call the same code for every row
	94	# returned from the db, thus avoiding repeated method lookups when traversing
	95	# relationships
	96	#
	97	# Also since the coderef is completely stateless (the returned structure is
	98	# always fresh on every new invocation) this is a very good opportunity for
	99	# memoization if further speed improvements are needed
	100	#
	101	# The way we construct this coderef is somewhat fugly, although the result is
	102	# really worth it. The final coderef does not perform any kind of recursion -
	103	# the entire nested structure constructor is rolled out into a single scope.
	104	#
	105	# In any case - the output of this thing is meticulously micro-tested, so
	106	# any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
	107	#
	108	sub _mk_row_parser {
4a0eed52	109	# $args and $attrs are separated to delineate what is core collapser stuff and
5b309063	110	# what is dbic $rs specific
5b309063	111	my ($self, $args, $attrs) = @_;
9f98c4b2	112
79adc44f	113	die "HRI without pruning makes zero sense"
	114	if ( $args->{hri_style} && ! $args->{prune_null_branches} );
	115
	116	my %common = (
	117	hri_style => $args->{hri_style},
	118	prune_null_branches => $args->{prune_null_branches},
	119	val_index => { map
	120	{ $args->{inflate_map}[$_] => $_ }
	121	( 0 .. $#{$args->{inflate_map}} )
	122	},
	123	);
	124
02a73c96	125	my $check_null_columns;
	126
	127	my $src = (! $args->{collapse} ) ? assemble_simple_parser(\%common) : do {
	128	my $collapse_map = $self->_resolve_collapse ({
	129	# FIXME
	130	# only consider real columns (not functions) during collapse resolution
	131	# this check shouldn't really be here, as fucktards are not supposed to
	132	# alias random crap to existing column names anyway, but still - just in
	133	# case
	134	# FIXME !!!! - this does not yet deal with unbalanced selectors correctly
	135	# (it is now trivial as the attrs specify where things go out of sync
	136	# needs MOAR tests)
	137	as => { map
	138	{ ref $attrs->{select}[$common{val_index}{$_}] ? () : ( $_ => $common{val_index}{$_} ) }
	139	keys %{$common{val_index}}
	140	},
	141	premultiplied => $args->{premultiplied},
	142	});
	143
	144	$check_null_columns = $collapse_map->{-identifying_columns}
	145	if @{$collapse_map->{-identifying_columns}};
	146
	147	assemble_collapsing_parser({
79adc44f	148	%common,
02a73c96	149	collapse_map => $collapse_map,
	150	});
	151	};
	152
2fdeef65	153	utf8::upgrade($src)
	154	if DBIx::Class::_ENV_::STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE;
	155
02a73c96	156	return (
	157	$args->{eval} ? ( eval "sub $src" \|\| die $@ ) : $src,
	158	$check_null_columns,
	159	);
9f98c4b2	160	}
	161
	162
2d0b795a	163	# Takes an arrayref selection list and generates a collapse-map representing
76031e14	164	# row-object fold-points. Every relationship is assigned a set of unique,
	165	# non-nullable columns (which may not even be from the same resultset)
	166	# and the collapser will use this information to correctly distinguish
2d0b795a	167	# data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
2d0b795a	168	# for extensive RV examples
76031e14	169	sub _resolve_collapse {
82f0e0aa	170	my ($self, $args, $common_args) = @_;
76031e14	171
76031e14	172	# for comprehensible error messages put ourselves at the head of the relationship chain
82f0e0aa	173	$args->{_rel_chain} \|\|= [ $self->source_name ];
76031e14	174
9f98c4b2	175	# record top-level fully-qualified column index, signify toplevelness
	176	unless ($common_args->{_as_fq_idx}) {
	177	$common_args->{_as_fq_idx} = { %{$args->{as}} };
	178	$args->{_is_top_level} = 1;
82f0e0aa	179	};
76031e14	180
76031e14	181	my ($my_cols, $rel_cols);
82f0e0aa	182	for (keys %{$args->{as}}) {
76031e14	183	if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
	184	$rel_cols->{$1}{$2} = 1;
	185	}
	186	else {
fcf32d04	187	$my_cols->{$_} = {}; # important for \|\|='s below
76031e14	188	}
	189	}
	190
	191	my $relinfo;
fcf32d04	192	# run through relationships, collect metadata
76031e14	193	for my $rel (keys %$rel_cols) {
76031e14	194	my $inf = $self->relationship_info ($rel);
76031e14	195
95e41036	196	$relinfo->{$rel} = {
	197	is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
	198	is_inner => ( ( $inf->{attrs}{join_type} \|\| '' ) !~ /^left/i),
	199	rsrc => $self->related_source($rel),
a4e58b18	200	fk_map => $self->_resolve_relationship_condition(
	201	rel_name => $rel,
	202	self_alias => "\xFE", # irrelevant
	203	foreign_alias => "\xFF", # irrelevant
	204	)->{identity_map},
95e41036	205	};
76031e14	206	}
76031e14	207
fcf32d04	208	# inject non-left fk-bridges from INNER-JOINED children (if any)
	209	for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
	210	my $ri = $relinfo->{$rel};
	211	for (keys %{$ri->{fk_map}} ) {
	212	# need to know source from our pov, hence $rel.col
	213	$my_cols->{$_} \|\|= { via_fk => "$rel.$ri->{fk_map}{$_}" }
	214	if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
	215	}
	216	}
	217
a0726a33	218	# if the parent is already defined AND we have an inner reverse relationship
a0726a33	219	# (i.e. do not exist without it) , assume all of its related FKs are selected
76031e14	220	# (even if they in fact are NOT in the select list). Keep a record of what we
	221	# assumed, and if any such phantom-column becomes part of our own collapser,
	222	# throw everything assumed-from-parent away and replace with the collapser of
	223	# the parent (whatever it may be)
	224	my $assumed_from_parent;
a0726a33	225	if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
fcf32d04	226	for my $col ( values %{$args->{_parent_info}{rel_condition} \|\| {}} ) {
fcf32d04	227	next if exists $my_cols->{$col};
27f3e97d	228	$my_cols->{$col} = {};
fcf32d04	229	$assumed_from_parent->{columns}{$col}++;
fcf32d04	230	}
76031e14	231	}
	232
	233	# get colinfo for everything
	234	if ($my_cols) {
	235	my $ci = $self->columns_info;
	236	$my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
	237	}
	238
	239	my $collapse_map;
	240
3faac878	241	# first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
3faac878	242	# (makes for a leaner coderef later)
9f98c4b2	243	unless ($collapse_map->{-identifying_columns}) {
9f98c4b2	244	$collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
3faac878	245	if $args->{_parent_info}{collapser_reusable};
	246	}
	247
4a0eed52	248	# Still don't know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
76031e14	249	if (
9f98c4b2	250	! $collapse_map->{-identifying_columns}
3faac878	251	and
76031e14	252	$my_cols
76031e14	253	and
4e9fc3f3	254	my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
76031e14	255	) {
	256	# see if the resulting collapser relies on any implied columns,
	257	# and fix stuff up if this is the case
4e9fc3f3	258	my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;
76031e14	259
9f98c4b2	260	$collapse_map->{-identifying_columns} = [ __unique_numlist(
3faac878	261	@{ $args->{_parent_info}{collapse_on_idcols}\|\|[] },
3faac878	262
76031e14	263	(map
	264	{
	265	my $fqc = join ('.',
82f0e0aa	266	@{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
76031e14	267	( $my_cols->{$_}{via_fk} \|\| $_ ),
	268	);
	269
82f0e0aa	270	$common_args->{_as_fq_idx}->{$fqc};
76031e14	271	}
4e9fc3f3	272	@reduced_set
76031e14	273	),
3faac878	274	)];
76031e14	275	}
	276
	277	# Stil don't know how to collapse - keep descending down 1:1 chains - if
	278	# a related non-LEFT 1:1 is resolvable - its condition will collapse us
	279	# too
9f98c4b2	280	unless ($collapse_map->{-identifying_columns}) {
76031e14	281	my @candidates;
	282
	283	for my $rel (keys %$relinfo) {
	284	next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
	285
82f0e0aa	286	if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	287	as => $rel_cols->{$rel},
	288	_rel_chain => [ @{$args->{_rel_chain}}, $rel ],
	289	_parent_info => { underdefined => 1 },
	290	}, $common_args)) {
9f98c4b2	291	push @candidates, $rel_collapse->{-identifying_columns};
76031e14	292	}
	293	}
	294
	295	# get the set with least amount of columns
	296	# FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
	297	# to a single varchar)
	298	if (@candidates) {
9f98c4b2	299	($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
76031e14	300	}
	301	}
	302
fcf32d04	303	# Stil don't know how to collapse, and we are the root node. Last ditch
	304	# effort in case we are NOT premultiplied.
	305	# Run through each multi all the way down, left or not, and all
	306	# left singles (a single may become a multi underneath) . When everything
	307	# gets back see if all the rels link to us definitively. If this is the
	308	# case we are good - either one of them will define us, or if all are NULLs
	309	# we know we are "unique" due to the "non-premultiplied" check
	310	if (
9f98c4b2	311	! $collapse_map->{-identifying_columns}
fcf32d04	312	and
	313	! $args->{premultiplied}
	314	and
9f98c4b2	315	$args->{_is_top_level}
fcf32d04	316	) {
	317	my (@collapse_sets, $uncollapsible_chain);
	318
	319	for my $rel (keys %$relinfo) {
	320
	321	# we already looked at these higher up
	322	next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
	323
	324	if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	325	as => $rel_cols->{$rel},
	326	_rel_chain => [ @{$args->{_rel_chain}}, $rel ],
	327	_parent_info => { underdefined => 1 },
	328	}, $common_args) ) {
	329
	330	# for singles use the idcols wholesale (either there or not)
	331	if ($relinfo->{$rel}{is_single}) {
9f98c4b2	332	push @collapse_sets, $clps->{-identifying_columns};
fcf32d04	333	}
	334	elsif (! $relinfo->{$rel}{fk_map}) {
	335	$uncollapsible_chain = 1;
	336	last;
	337	}
	338	else {
	339	my $defined_cols_parent_side;
	340
	341	for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
	342	my ($col) = $fq_col =~ /([^\.]+)$/;
	343
	344	$defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
	345	{ $relinfo->{$rel}{fk_map}{$_} eq $col }
	346	keys %{$relinfo->{$rel}{fk_map}}
	347	;
	348	}
	349
	350	if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
	351	push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
	352	}
	353	else {
	354	$uncollapsible_chain = 1;
	355	last;
	356	}
	357	}
	358	}
	359	else {
	360	$uncollapsible_chain = 1;
	361	last;
	362	}
	363	}
	364
	365	unless ($uncollapsible_chain) {
	366	# if we got here - we are good to go, but the construction is tricky
	367	# since our children will want to include our collapse criteria - we
	368	# don't give them anything (safe, since they are all collapsible on their own)
4a0eed52	369	# in addition we record the individual collapse possibilities
fcf32d04	370	# of all left children node collapsers, and merge them in the rowparser
fcf32d04	371	# coderef later
9f98c4b2	372	$collapse_map->{-identifying_columns} = [];
9f98c4b2	373	$collapse_map->{-identifying_columns_variants} = [ sort {
fcf32d04	374	(scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
	375	} @collapse_sets ];
	376	}
	377	}
	378
76031e14	379	# stop descending into children if we were called by a parent for first-pass
	380	# and don't despair if nothing was found (there may be other parallel branches
	381	# to dive into)
82f0e0aa	382	if ($args->{_parent_info}{underdefined}) {
9f98c4b2	383	return $collapse_map->{-identifying_columns} ? $collapse_map : undef
76031e14	384	}
76031e14	385	# nothing down the chain resolved - can't calculate a collapse-map
9f98c4b2	386	elsif (! $collapse_map->{-identifying_columns}) {
76031e14	387	$self->throw_exception ( sprintf
	388	"Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
	389	$self->source_name,
82f0e0aa	390	@{$args->{_rel_chain}} > 1
82f0e0aa	391	? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
76031e14	392	: ''
	393	,
	394	);
	395	}
	396
	397	# If we got that far - we are collapsable - GREAT! Now go down all children
	398	# a second time, and fill in the rest
	399
a0726a33	400	$collapse_map->{-identifying_columns} = [ __unique_numlist(
	401	@{ $args->{_parent_info}{collapse_on_idcols}\|\|[] },
	402	@{ $collapse_map->{-identifying_columns} },
	403	)];
3faac878	404
76031e14	405	for my $rel (sort keys %$relinfo) {
76031e14	406
82f0e0aa	407	$collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	408	as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
	409	_rel_chain => [ @{$args->{_rel_chain}}, $rel],
	410	_parent_info => {
3faac878	411	# shallow copy
9f98c4b2	412	collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],
76031e14	413
	414	rel_condition => $relinfo->{$rel}{fk_map},
	415
a0726a33	416	is_optional => ! $relinfo->{$rel}{is_inner},
	417
	418	# if there is at least one inner reverse relationship which is HASH-based (equality only)
	419	# we can safely assume that the child can not exist without us
	420	rev_rel_is_optional => ( first
	421	{ ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}\|\|'') !~ /^left/i }
	422	values %{ $self->reverse_relationship_info($rel) },
	423	) ? 0 : 1,
76031e14	424
	425	# if this is a 1:1 our own collapser can be used as a collapse-map
	426	# (regardless of left or not)
3d8caf63	427	collapser_reusable => (
	428	$relinfo->{$rel}{is_single}
	429	&&
	430	$relinfo->{$rel}{is_inner}
	431	&&
	432	@{$collapse_map->{-identifying_columns}}
	433	) ? 1 : 0,
76031e14	434	},
82f0e0aa	435	}, $common_args );
76031e14	436
	437	$collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
	438	$collapse_map->{$rel}{-is_optional} \|\|= 1 unless $relinfo->{$rel}{is_inner};
3faac878	439	}
76031e14	440
	441	return $collapse_map;
	442	}
	443
76031e14	444	# adding a dep on MoreUtils just for this is retarded
76031e14	445	sub __unique_numlist {
3faac878	446	sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
76031e14	447	}
76031e14	448
76031e14	449	1;