[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / ResultSource / RowParser.pm

package # hide from the pauses
  DBIx::Class::ResultSource::RowParser;

use strict;
use warnings;

use base 'DBIx::Class';

use Try::Tiny;
use List::Util qw(first max);
use B 'perlstring';

use DBIx::Class::ResultSource::RowParser::Util qw(
  assemble_simple_parser
  assemble_collapsing_parser
);

use namespace::clean;

# Accepts one or more relationships for the current source and returns an
# array of column names for each of those relationships. Column names are
# prefixed relative to the current source, in accordance with where they appear
# in the supplied relationships.
sub _resolve_prefetch {
  my ($self, $pre, $alias, $alias_map, $order, $pref_path) = @_;
  $pref_path ||= [];

  if (not defined $pre or not length $pre) {
    return ();
  }
  elsif( ref $pre eq 'ARRAY' ) {
    return
      map { $self->_resolve_prefetch( $_, $alias, $alias_map, $order, [ @$pref_path ] ) }
        @$pre;
  }
  elsif( ref $pre eq 'HASH' ) {
    my @ret =
    map {
      $self->_resolve_prefetch($_, $alias, $alias_map, $order, [ @$pref_path ] ),
      $self->related_source($_)->_resolve_prefetch(
         $pre->{$_}, "${alias}.$_", $alias_map, $order, [ @$pref_path, $_] )
    } keys %$pre;
    return @ret;
  }
  elsif( ref $pre ) {
    $self->throw_exception(
      "don't know how to resolve prefetch reftype ".ref($pre));
  }
  else {
    my $p = $alias_map;
    $p = $p->{$_} for (@$pref_path, $pre);

    $self->throw_exception (
      "Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
      . join (' -> ', @$pref_path, $pre)
    ) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );

    my $as = shift @{$p->{-join_aliases}};

    my $rel_info = $self->relationship_info( $pre );
    $self->throw_exception( $self->source_name . " has no such relationship '$pre'" )
      unless $rel_info;

    my $as_prefix = ($alias =~ /^.*?\.(.+)$/ ? $1.'.' : '');

    return map { [ "${as}.$_", "${as_prefix}${pre}.$_", ] }
      $self->related_source($pre)->columns;
  }
}

# Takes an arrayref of {as} dbic column aliases and the collapse and select
# attributes from the same $rs (the selector requirement is a temporary
# workaround... I hope), and returns a coderef capable of:
# my $me_pref_clps = $coderef->([$rs->cursor->next/all])
# Where the $me_pref_clps arrayref is the future argument to inflate_result()
#
# For an example of this coderef in action (and to see its guts) look at
# t/resultset/rowparser_internals.t
#
# This is a huge performance win, as we call the same code for every row
# returned from the db, thus avoiding repeated method lookups when traversing
# relationships
#
# Also since the coderef is completely stateless (the returned structure is
# always fresh on every new invocation) this is a very good opportunity for
# memoization if further speed improvements are needed
#
# The way we construct this coderef is somewhat fugly, although the result is
# really worth it. The final coderef does not perform any kind of recursion -
# the entire nested structure constructor is rolled out into a single scope.
#
# In any case - the output of this thing is meticulously micro-tested, so
# any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
#
sub _mk_row_parser {
  my ($self, $args) = @_;

  my $val_index = { map
    { $args->{inflate_map}[$_] => $_ }
    ( 0 .. $#{$args->{inflate_map}} )
  };

  my $src;

  if (! $args->{collapse} ) {
    $src = assemble_simple_parser({
      val_index => $val_index,
      hri_style => $args->{hri_style},
    });
  }
  else {
    my $collapse_map = $self->_resolve_collapse ({
      premultiplied => $args->{premultiplied},
      # FIXME
      # only consider real columns (not functions) during collapse resolution
      # this check shouldn't really be here, as fucktards are not supposed to
      # alias random crap to existing column names anyway, but still - just in
      # case
      # FIXME !!!! - this does not yet deal with unbalanced selectors correctly
      # (it is now trivial as the attrs specify where things go out of sync
      # needs MOAR tests)
      as => { map
        { ref $args->{selection}[$val_index->{$_}] ? () : ( $_ => $val_index->{$_} ) }
        keys %$val_index
      }
    });

    $src = assemble_collapsing_parser({
      val_index => $val_index,
      collapse_map => $collapse_map,
      hri_style => $args->{hri_style},
    });
  }

  return $args->{eval}
    ? ( eval "sub $src" || die $@ )
    : $src
  ;
}


# Takes an arrayref selection list and generates a collapse-map representing
# row-object fold-points. Every relationship is assigned a set of unique,
# non-nullable columns (which may *not even be* from the same resultset)
# and the collapser will use this information to correctly distinguish
# data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
# for extensive RV examples
sub _resolve_collapse {
  my ($self, $args, $common_args) = @_;

  # for comprehensible error messages put ourselves at the head of the relationship chain
  $args->{_rel_chain} ||= [ $self->source_name ];

  # record top-level fully-qualified column index, signify toplevelness
  unless ($common_args->{_as_fq_idx}) {
    $common_args->{_as_fq_idx} = { %{$args->{as}} };
    $args->{_is_top_level} = 1;
  };

  my ($my_cols, $rel_cols);
  for (keys %{$args->{as}}) {
    if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
      $rel_cols->{$1}{$2} = 1;
    }
    else {
      $my_cols->{$_} = {};  # important for ||='s below
    }
  }

  my $relinfo;
  # run through relationships, collect metadata
  for my $rel (keys %$rel_cols) {
    my $inf = $self->relationship_info ($rel);

    $relinfo->{$rel} = {
      is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
      is_inner => ( ( $inf->{attrs}{join_type} || '' ) !~ /^left/i),
      rsrc => $self->related_source($rel),
    };

    # FIME - need to use _resolve_cond here instead
    my $cond = $inf->{cond};

    if (
      ref $cond eq 'HASH'
        and
      keys %$cond
        and
      ! defined first { $_ !~ /^foreign\./ } (keys %$cond)
        and
      ! defined first { $_ !~ /^self\./ } (values %$cond)
    ) {
      for my $f (keys %$cond) {
        my $s = $cond->{$f};
        $_ =~ s/^ (?: foreign | self ) \.//x for ($f, $s);
        $relinfo->{$rel}{fk_map}{$s} = $f;
      }
    }
  }

  # inject non-left fk-bridges from *INNER-JOINED* children (if any)
  for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
    my $ri = $relinfo->{$rel};
    for (keys %{$ri->{fk_map}} ) {
      # need to know source from *our* pov, hence $rel.col
      $my_cols->{$_} ||= { via_fk => "$rel.$ri->{fk_map}{$_}" }
        if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
    }
  }

  # if the parent is already defined *AND* we have an inner reverse relationship
  # (i.e. do not exist without it) , assume all of its related FKs are selected
  # (even if they in fact are NOT in the select list). Keep a record of what we
  # assumed, and if any such phantom-column becomes part of our own collapser,
  # throw everything assumed-from-parent away and replace with the collapser of
  # the parent (whatever it may be)
  my $assumed_from_parent;
  if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
    for my $col ( values %{$args->{_parent_info}{rel_condition} || {}} ) {
      next if exists $my_cols->{$col};
      $my_cols->{$col} = { via_collapse => $args->{_parent_info}{collapse_on_idcols} };
      $assumed_from_parent->{columns}{$col}++;
    }
  }

  # get colinfo for everything
  if ($my_cols) {
    my $ci = $self->columns_info;
    $my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
  }

  my $collapse_map;

  # first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
  # (makes for a leaner coderef later)
  unless ($collapse_map->{-identifying_columns}) {
    $collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
      if $args->{_parent_info}{collapser_reusable};
  }

  # Still dont know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
  if (
    ! $collapse_map->{-identifying_columns}
      and
    $my_cols
      and
    my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
  ) {
    # see if the resulting collapser relies on any implied columns,
    # and fix stuff up if this is the case
    my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;

    $collapse_map->{-identifying_columns} = [ __unique_numlist(
      @{ $args->{_parent_info}{collapse_on_idcols}||[] },

      (map
        {
          my $fqc = join ('.',
            @{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
            ( $my_cols->{$_}{via_fk} || $_ ),
          );

          $common_args->{_as_fq_idx}->{$fqc};
        }
        @reduced_set
      ),
    )];
  }

  # Stil don't know how to collapse - keep descending down 1:1 chains - if
  # a related non-LEFT 1:1 is resolvable - its condition will collapse us
  # too
  unless ($collapse_map->{-identifying_columns}) {
    my @candidates;

    for my $rel (keys %$relinfo) {
      next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});

      if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
        as => $rel_cols->{$rel},
        _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
        _parent_info => { underdefined => 1 },
      }, $common_args)) {
        push @candidates, $rel_collapse->{-identifying_columns};
      }
    }

    # get the set with least amount of columns
    # FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
    # to a single varchar)
    if (@candidates) {
      ($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
    }
  }

  # Stil don't know how to collapse, and we are the root node. Last ditch
  # effort in case we are *NOT* premultiplied.
  # Run through *each multi* all the way down, left or not, and all
  # *left* singles (a single may become a multi underneath) . When everything
  # gets back see if all the rels link to us definitively. If this is the
  # case we are good - either one of them will define us, or if all are NULLs
  # we know we are "unique" due to the "non-premultiplied" check
  if (
    ! $collapse_map->{-identifying_columns}
      and
    ! $args->{premultiplied}
      and
    $args->{_is_top_level}
  ) {
    my (@collapse_sets, $uncollapsible_chain);

    for my $rel (keys %$relinfo) {

      # we already looked at these higher up
      next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});

      if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
        as => $rel_cols->{$rel},
        _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
        _parent_info => { underdefined => 1 },
      }, $common_args) ) {

        # for singles use the idcols wholesale (either there or not)
        if ($relinfo->{$rel}{is_single}) {
          push @collapse_sets, $clps->{-identifying_columns};
        }
        elsif (! $relinfo->{$rel}{fk_map}) {
          $uncollapsible_chain = 1;
          last;
        }
        else {
          my $defined_cols_parent_side;

          for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
            my ($col) = $fq_col =~ /([^\.]+)$/;

            $defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
              { $relinfo->{$rel}{fk_map}{$_} eq $col }
              keys %{$relinfo->{$rel}{fk_map}}
            ;
          }

          if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
            push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
          }
          else {
            $uncollapsible_chain = 1;
            last;
          }
        }
      }
      else {
        $uncollapsible_chain = 1;
        last;
      }
    }

    unless ($uncollapsible_chain) {
      # if we got here - we are good to go, but the construction is tricky
      # since our children will want to include our collapse criteria - we
      # don't give them anything (safe, since they are all collapsible on their own)
      # in addition we record the individual collapse posibilities
      # of all left children node collapsers, and merge them in the rowparser
      # coderef later
      $collapse_map->{-identifying_columns} = [];
      $collapse_map->{-identifying_columns_variants} = [ sort {
        (scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
      } @collapse_sets ];
    }
  }

  # stop descending into children if we were called by a parent for first-pass
  # and don't despair if nothing was found (there may be other parallel branches
  # to dive into)
  if ($args->{_parent_info}{underdefined}) {
    return $collapse_map->{-identifying_columns} ? $collapse_map : undef
  }
  # nothing down the chain resolved - can't calculate a collapse-map
  elsif (! $collapse_map->{-identifying_columns}) {
    $self->throw_exception ( sprintf
      "Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
      $self->source_name,
      @{$args->{_rel_chain}} > 1
        ? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
        : ''
      ,
    );
  }

  # If we got that far - we are collapsable - GREAT! Now go down all children
  # a second time, and fill in the rest

  $collapse_map->{-identifying_columns} = [ __unique_numlist(
    @{ $args->{_parent_info}{collapse_on_idcols}||[] },
    @{ $collapse_map->{-identifying_columns} },
  )];

  my @id_sets;
  for my $rel (sort keys %$relinfo) {

    $collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
      as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
      _rel_chain => [ @{$args->{_rel_chain}}, $rel],
      _parent_info => {
        # shallow copy
        collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],

        rel_condition => $relinfo->{$rel}{fk_map},

        is_optional => ! $relinfo->{$rel}{is_inner},

        # if there is at least one *inner* reverse relationship which is HASH-based (equality only)
        # we can safely assume that the child can not exist without us
        rev_rel_is_optional => ( first
          { ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}||'') !~ /^left/i }
          values %{ $self->reverse_relationship_info($rel) },
        ) ? 0 : 1,

        # if this is a 1:1 our own collapser can be used as a collapse-map
        # (regardless of left or not)
        collapser_reusable => (
          $relinfo->{$rel}{is_single}
            &&
          $relinfo->{$rel}{is_inner}
            &&
          @{$collapse_map->{-identifying_columns}}
        ) ? 1 : 0,
      },
    }, $common_args );

    $collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
    $collapse_map->{$rel}{-is_optional} ||= 1 unless $relinfo->{$rel}{is_inner};
  }

  return $collapse_map;
}

# adding a dep on MoreUtils *just* for this is retarded
sub __unique_numlist {
  sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
}

1;
Commit	Line	Data
4e9fc3f3	1	package # hide from the pauses
4e9fc3f3	2	DBIx::Class::ResultSource::RowParser;
76031e14	3
	4	use strict;
	5	use warnings;
	6
9f98c4b2	7	use base 'DBIx::Class';
9f98c4b2	8
76031e14	9	use Try::Tiny;
fcf32d04	10	use List::Util qw(first max);
76031e14	11	use B 'perlstring';
76031e14	12
9f98c4b2	13	use DBIx::Class::ResultSource::RowParser::Util qw(
	14	assemble_simple_parser
	15	assemble_collapsing_parser
	16	);
76031e14	17
9f98c4b2	18	use namespace::clean;
76031e14	19
	20	# Accepts one or more relationships for the current source and returns an
	21	# array of column names for each of those relationships. Column names are
	22	# prefixed relative to the current source, in accordance with where they appear
	23	# in the supplied relationships.
	24	sub _resolve_prefetch {
	25	my ($self, $pre, $alias, $alias_map, $order, $pref_path) = @_;
	26	$pref_path \|\|= [];
	27
	28	if (not defined $pre or not length $pre) {
	29	return ();
	30	}
	31	elsif( ref $pre eq 'ARRAY' ) {
	32	return
	33	map { $self->_resolve_prefetch( $_, $alias, $alias_map, $order, [ @$pref_path ] ) }
	34	@$pre;
	35	}
	36	elsif( ref $pre eq 'HASH' ) {
	37	my @ret =
	38	map {
	39	$self->_resolve_prefetch($_, $alias, $alias_map, $order, [ @$pref_path ] ),
	40	$self->related_source($_)->_resolve_prefetch(
4e9fc3f3	41	$pre->{$_}, "${alias}.$_", $alias_map, $order, [ @$pref_path, $_] )
76031e14	42	} keys %$pre;
	43	return @ret;
	44	}
	45	elsif( ref $pre ) {
	46	$self->throw_exception(
	47	"don't know how to resolve prefetch reftype ".ref($pre));
	48	}
	49	else {
	50	my $p = $alias_map;
	51	$p = $p->{$_} for (@$pref_path, $pre);
	52
	53	$self->throw_exception (
	54	"Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
	55	. join (' -> ', @$pref_path, $pre)
	56	) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );
	57
	58	my $as = shift @{$p->{-join_aliases}};
	59
	60	my $rel_info = $self->relationship_info( $pre );
	61	$self->throw_exception( $self->source_name . " has no such relationship '$pre'" )
	62	unless $rel_info;
	63
	64	my $as_prefix = ($alias =~ /^.*?\.(.+)$/ ? $1.'.' : '');
76031e14	65
76031e14	66	return map { [ "${as}.$_", "${as_prefix}${pre}.$_", ] }
4e9fc3f3	67	$self->related_source($pre)->columns;
76031e14	68	}
	69	}
	70
9f98c4b2	71	# Takes an arrayref of {as} dbic column aliases and the collapse and select
	72	# attributes from the same $rs (the selector requirement is a temporary
	73	# workaround... I hope), and returns a coderef capable of:
	74	# my $me_pref_clps = $coderef->([$rs->cursor->next/all])
	75	# Where the $me_pref_clps arrayref is the future argument to inflate_result()
	76	#
	77	# For an example of this coderef in action (and to see its guts) look at
	78	# t/resultset/rowparser_internals.t
	79	#
	80	# This is a huge performance win, as we call the same code for every row
	81	# returned from the db, thus avoiding repeated method lookups when traversing
	82	# relationships
	83	#
	84	# Also since the coderef is completely stateless (the returned structure is
	85	# always fresh on every new invocation) this is a very good opportunity for
	86	# memoization if further speed improvements are needed
	87	#
	88	# The way we construct this coderef is somewhat fugly, although the result is
	89	# really worth it. The final coderef does not perform any kind of recursion -
	90	# the entire nested structure constructor is rolled out into a single scope.
	91	#
	92	# In any case - the output of this thing is meticulously micro-tested, so
	93	# any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
	94	#
	95	sub _mk_row_parser {
	96	my ($self, $args) = @_;
	97
	98	my $val_index = { map
	99	{ $args->{inflate_map}[$_] => $_ }
	100	( 0 .. $#{$args->{inflate_map}} )
	101	};
	102
ce556881	103	my $src;
ce556881	104
9f98c4b2	105	if (! $args->{collapse} ) {
ce556881	106	$src = assemble_simple_parser({
9f98c4b2	107	val_index => $val_index,
ce556881	108	hri_style => $args->{hri_style},
9f98c4b2	109	});
	110	}
	111	else {
	112	my $collapse_map = $self->_resolve_collapse ({
	113	premultiplied => $args->{premultiplied},
	114	# FIXME
	115	# only consider real columns (not functions) during collapse resolution
	116	# this check shouldn't really be here, as fucktards are not supposed to
	117	# alias random crap to existing column names anyway, but still - just in
	118	# case
	119	# FIXME !!!! - this does not yet deal with unbalanced selectors correctly
	120	# (it is now trivial as the attrs specify where things go out of sync
	121	# needs MOAR tests)
	122	as => { map
	123	{ ref $args->{selection}[$val_index->{$_}] ? () : ( $_ => $val_index->{$_} ) }
	124	keys %$val_index
	125	}
	126	});
	127
ce556881	128	$src = assemble_collapsing_parser({
9f98c4b2	129	val_index => $val_index,
9f98c4b2	130	collapse_map => $collapse_map,
ce556881	131	hri_style => $args->{hri_style},
9f98c4b2	132	});
9f98c4b2	133	}
ce556881	134
52864fbd	135	return $args->{eval}
bdbd2ae8	136	? ( eval "sub $src" \|\| die $@ )
52864fbd	137	: $src
ce556881	138	;
9f98c4b2	139	}
	140
	141
2d0b795a	142	# Takes an arrayref selection list and generates a collapse-map representing
76031e14	143	# row-object fold-points. Every relationship is assigned a set of unique,
	144	# non-nullable columns (which may not even be from the same resultset)
	145	# and the collapser will use this information to correctly distinguish
2d0b795a	146	# data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
2d0b795a	147	# for extensive RV examples
76031e14	148	sub _resolve_collapse {
82f0e0aa	149	my ($self, $args, $common_args) = @_;
76031e14	150
76031e14	151	# for comprehensible error messages put ourselves at the head of the relationship chain
82f0e0aa	152	$args->{_rel_chain} \|\|= [ $self->source_name ];
76031e14	153
9f98c4b2	154	# record top-level fully-qualified column index, signify toplevelness
	155	unless ($common_args->{_as_fq_idx}) {
	156	$common_args->{_as_fq_idx} = { %{$args->{as}} };
	157	$args->{_is_top_level} = 1;
82f0e0aa	158	};
76031e14	159
76031e14	160	my ($my_cols, $rel_cols);
82f0e0aa	161	for (keys %{$args->{as}}) {
76031e14	162	if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
	163	$rel_cols->{$1}{$2} = 1;
	164	}
	165	else {
fcf32d04	166	$my_cols->{$_} = {}; # important for \|\|='s below
76031e14	167	}
	168	}
	169
	170	my $relinfo;
fcf32d04	171	# run through relationships, collect metadata
76031e14	172	for my $rel (keys %$rel_cols) {
76031e14	173	my $inf = $self->relationship_info ($rel);
76031e14	174
95e41036	175	$relinfo->{$rel} = {
	176	is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
	177	is_inner => ( ( $inf->{attrs}{join_type} \|\| '' ) !~ /^left/i),
	178	rsrc => $self->related_source($rel),
	179	};
76031e14	180
fcf32d04	181	# FIME - need to use _resolve_cond here instead
76031e14	182	my $cond = $inf->{cond};
	183
	184	if (
	185	ref $cond eq 'HASH'
	186	and
	187	keys %$cond
	188	and
fcf32d04	189	! defined first { $_ !~ /^foreign\./ } (keys %$cond)
76031e14	190	and
fcf32d04	191	! defined first { $_ !~ /^self\./ } (values %$cond)
76031e14	192	) {
	193	for my $f (keys %$cond) {
	194	my $s = $cond->{$f};
	195	$_ =~ s/^ (?: foreign \| self ) \.//x for ($f, $s);
	196	$relinfo->{$rel}{fk_map}{$s} = $f;
76031e14	197	}
	198	}
	199	}
	200
fcf32d04	201	# inject non-left fk-bridges from INNER-JOINED children (if any)
	202	for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
	203	my $ri = $relinfo->{$rel};
	204	for (keys %{$ri->{fk_map}} ) {
	205	# need to know source from our pov, hence $rel.col
	206	$my_cols->{$_} \|\|= { via_fk => "$rel.$ri->{fk_map}{$_}" }
	207	if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
	208	}
	209	}
	210
a0726a33	211	# if the parent is already defined AND we have an inner reverse relationship
a0726a33	212	# (i.e. do not exist without it) , assume all of its related FKs are selected
76031e14	213	# (even if they in fact are NOT in the select list). Keep a record of what we
	214	# assumed, and if any such phantom-column becomes part of our own collapser,
	215	# throw everything assumed-from-parent away and replace with the collapser of
	216	# the parent (whatever it may be)
	217	my $assumed_from_parent;
a0726a33	218	if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
fcf32d04	219	for my $col ( values %{$args->{_parent_info}{rel_condition} \|\| {}} ) {
	220	next if exists $my_cols->{$col};
	221	$my_cols->{$col} = { via_collapse => $args->{_parent_info}{collapse_on_idcols} };
	222	$assumed_from_parent->{columns}{$col}++;
	223	}
76031e14	224	}
	225
	226	# get colinfo for everything
	227	if ($my_cols) {
	228	my $ci = $self->columns_info;
	229	$my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
	230	}
	231
	232	my $collapse_map;
	233
3faac878	234	# first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
3faac878	235	# (makes for a leaner coderef later)
9f98c4b2	236	unless ($collapse_map->{-identifying_columns}) {
9f98c4b2	237	$collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
3faac878	238	if $args->{_parent_info}{collapser_reusable};
	239	}
	240
3faac878	241	# Still dont know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
76031e14	242	if (
9f98c4b2	243	! $collapse_map->{-identifying_columns}
3faac878	244	and
76031e14	245	$my_cols
76031e14	246	and
4e9fc3f3	247	my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
76031e14	248	) {
	249	# see if the resulting collapser relies on any implied columns,
	250	# and fix stuff up if this is the case
4e9fc3f3	251	my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;
76031e14	252
9f98c4b2	253	$collapse_map->{-identifying_columns} = [ __unique_numlist(
3faac878	254	@{ $args->{_parent_info}{collapse_on_idcols}\|\|[] },
3faac878	255
76031e14	256	(map
	257	{
	258	my $fqc = join ('.',
82f0e0aa	259	@{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
76031e14	260	( $my_cols->{$_}{via_fk} \|\| $_ ),
	261	);
	262
82f0e0aa	263	$common_args->{_as_fq_idx}->{$fqc};
76031e14	264	}
4e9fc3f3	265	@reduced_set
76031e14	266	),
3faac878	267	)];
76031e14	268	}
	269
	270	# Stil don't know how to collapse - keep descending down 1:1 chains - if
	271	# a related non-LEFT 1:1 is resolvable - its condition will collapse us
	272	# too
9f98c4b2	273	unless ($collapse_map->{-identifying_columns}) {
76031e14	274	my @candidates;
	275
	276	for my $rel (keys %$relinfo) {
	277	next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
	278
82f0e0aa	279	if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	280	as => $rel_cols->{$rel},
	281	_rel_chain => [ @{$args->{_rel_chain}}, $rel ],
	282	_parent_info => { underdefined => 1 },
	283	}, $common_args)) {
9f98c4b2	284	push @candidates, $rel_collapse->{-identifying_columns};
76031e14	285	}
	286	}
	287
	288	# get the set with least amount of columns
	289	# FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
	290	# to a single varchar)
	291	if (@candidates) {
9f98c4b2	292	($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
76031e14	293	}
	294	}
	295
fcf32d04	296	# Stil don't know how to collapse, and we are the root node. Last ditch
	297	# effort in case we are NOT premultiplied.
	298	# Run through each multi all the way down, left or not, and all
	299	# left singles (a single may become a multi underneath) . When everything
	300	# gets back see if all the rels link to us definitively. If this is the
	301	# case we are good - either one of them will define us, or if all are NULLs
	302	# we know we are "unique" due to the "non-premultiplied" check
	303	if (
9f98c4b2	304	! $collapse_map->{-identifying_columns}
fcf32d04	305	and
	306	! $args->{premultiplied}
	307	and
9f98c4b2	308	$args->{_is_top_level}
fcf32d04	309	) {
	310	my (@collapse_sets, $uncollapsible_chain);
	311
	312	for my $rel (keys %$relinfo) {
	313
	314	# we already looked at these higher up
	315	next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
	316
	317	if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	318	as => $rel_cols->{$rel},
	319	_rel_chain => [ @{$args->{_rel_chain}}, $rel ],
	320	_parent_info => { underdefined => 1 },
	321	}, $common_args) ) {
	322
	323	# for singles use the idcols wholesale (either there or not)
	324	if ($relinfo->{$rel}{is_single}) {
9f98c4b2	325	push @collapse_sets, $clps->{-identifying_columns};
fcf32d04	326	}
	327	elsif (! $relinfo->{$rel}{fk_map}) {
	328	$uncollapsible_chain = 1;
	329	last;
	330	}
	331	else {
	332	my $defined_cols_parent_side;
	333
	334	for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
	335	my ($col) = $fq_col =~ /([^\.]+)$/;
	336
	337	$defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
	338	{ $relinfo->{$rel}{fk_map}{$_} eq $col }
	339	keys %{$relinfo->{$rel}{fk_map}}
	340	;
	341	}
	342
	343	if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
	344	push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
	345	}
	346	else {
	347	$uncollapsible_chain = 1;
	348	last;
	349	}
	350	}
	351	}
	352	else {
	353	$uncollapsible_chain = 1;
	354	last;
	355	}
	356	}
	357
	358	unless ($uncollapsible_chain) {
	359	# if we got here - we are good to go, but the construction is tricky
	360	# since our children will want to include our collapse criteria - we
	361	# don't give them anything (safe, since they are all collapsible on their own)
	362	# in addition we record the individual collapse posibilities
	363	# of all left children node collapsers, and merge them in the rowparser
	364	# coderef later
9f98c4b2	365	$collapse_map->{-identifying_columns} = [];
9f98c4b2	366	$collapse_map->{-identifying_columns_variants} = [ sort {
fcf32d04	367	(scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
	368	} @collapse_sets ];
	369	}
	370	}
	371
76031e14	372	# stop descending into children if we were called by a parent for first-pass
	373	# and don't despair if nothing was found (there may be other parallel branches
	374	# to dive into)
82f0e0aa	375	if ($args->{_parent_info}{underdefined}) {
9f98c4b2	376	return $collapse_map->{-identifying_columns} ? $collapse_map : undef
76031e14	377	}
76031e14	378	# nothing down the chain resolved - can't calculate a collapse-map
9f98c4b2	379	elsif (! $collapse_map->{-identifying_columns}) {
76031e14	380	$self->throw_exception ( sprintf
	381	"Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
	382	$self->source_name,
82f0e0aa	383	@{$args->{_rel_chain}} > 1
82f0e0aa	384	? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
76031e14	385	: ''
	386	,
	387	);
	388	}
	389
	390	# If we got that far - we are collapsable - GREAT! Now go down all children
	391	# a second time, and fill in the rest
	392
a0726a33	393	$collapse_map->{-identifying_columns} = [ __unique_numlist(
	394	@{ $args->{_parent_info}{collapse_on_idcols}\|\|[] },
	395	@{ $collapse_map->{-identifying_columns} },
	396	)];
3faac878	397
3faac878	398	my @id_sets;
76031e14	399	for my $rel (sort keys %$relinfo) {
76031e14	400
82f0e0aa	401	$collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	402	as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
	403	_rel_chain => [ @{$args->{_rel_chain}}, $rel],
	404	_parent_info => {
3faac878	405	# shallow copy
9f98c4b2	406	collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],
76031e14	407
	408	rel_condition => $relinfo->{$rel}{fk_map},
	409
a0726a33	410	is_optional => ! $relinfo->{$rel}{is_inner},
	411
	412	# if there is at least one inner reverse relationship which is HASH-based (equality only)
	413	# we can safely assume that the child can not exist without us
	414	rev_rel_is_optional => ( first
	415	{ ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}\|\|'') !~ /^left/i }
	416	values %{ $self->reverse_relationship_info($rel) },
	417	) ? 0 : 1,
76031e14	418
	419	# if this is a 1:1 our own collapser can be used as a collapse-map
	420	# (regardless of left or not)
3d8caf63	421	collapser_reusable => (
	422	$relinfo->{$rel}{is_single}
	423	&&
	424	$relinfo->{$rel}{is_inner}
	425	&&
	426	@{$collapse_map->{-identifying_columns}}
	427	) ? 1 : 0,
76031e14	428	},
82f0e0aa	429	}, $common_args );
76031e14	430
	431	$collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
	432	$collapse_map->{$rel}{-is_optional} \|\|= 1 unless $relinfo->{$rel}{is_inner};
3faac878	433	}
76031e14	434
	435	return $collapse_map;
	436	}
	437
76031e14	438	# adding a dep on MoreUtils just for this is retarded
76031e14	439	sub __unique_numlist {
3faac878	440	sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
76031e14	441	}
76031e14	442
76031e14	443	1;