[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / ResultSource / RowParser.pm

package # hide from the pauses
  DBIx::Class::ResultSource::RowParser;

use strict;
use warnings;

use base 'DBIx::Class';

use Try::Tiny;
use List::Util qw(first max);

use DBIx::Class::ResultSource::RowParser::Util qw(
  assemble_simple_parser
  assemble_collapsing_parser
);

use namespace::clean;

# Accepts one or more relationships for the current source and returns an
# array of column names for each of those relationships. Column names are
# prefixed relative to the current source, in accordance with where they appear
# in the supplied relationships.
sub _resolve_prefetch {
  my ($self, $pre, $alias, $alias_map, $order, $pref_path) = @_;
  $pref_path ||= [];

  if (not defined $pre or not length $pre) {
    return ();
  }
  elsif( ref $pre eq 'ARRAY' ) {
    return
      map { $self->_resolve_prefetch( $_, $alias, $alias_map, $order, [ @$pref_path ] ) }
        @$pre;
  }
  elsif( ref $pre eq 'HASH' ) {
    my @ret =
    map {
      $self->_resolve_prefetch($_, $alias, $alias_map, $order, [ @$pref_path ] ),
      $self->related_source($_)->_resolve_prefetch(
         $pre->{$_}, "${alias}.$_", $alias_map, $order, [ @$pref_path, $_] )
    } keys %$pre;
    return @ret;
  }
  elsif( ref $pre ) {
    $self->throw_exception(
      "don't know how to resolve prefetch reftype ".ref($pre));
  }
  else {
    my $p = $alias_map;
    $p = $p->{$_} for (@$pref_path, $pre);

    $self->throw_exception (
      "Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
      . join (' -> ', @$pref_path, $pre)
    ) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );

    my $as = shift @{$p->{-join_aliases}};

    my $rel_info = $self->relationship_info( $pre );
    $self->throw_exception( $self->source_name . " has no such relationship '$pre'" )
      unless $rel_info;

    my $as_prefix = ($alias =~ /^.*?\.(.+)$/ ? $1.'.' : '');

    return map { [ "${as}.$_", "${as_prefix}${pre}.$_", ] }
      $self->related_source($pre)->columns;
  }
}

# Takes an arrayref of {as} dbic column aliases and the collapse and select
# attributes from the same $rs (the selector requirement is a temporary
# workaround... I hope), and returns a coderef capable of:
# my $me_pref_clps = $coderef->([$rs->cursor->next/all])
# Where the $me_pref_clps arrayref is the future argument to inflate_result()
#
# For an example of this coderef in action (and to see its guts) look at
# t/resultset/rowparser_internals.t
#
# This is a huge performance win, as we call the same code for every row
# returned from the db, thus avoiding repeated method lookups when traversing
# relationships
#
# Also since the coderef is completely stateless (the returned structure is
# always fresh on every new invocation) this is a very good opportunity for
# memoization if further speed improvements are needed
#
# The way we construct this coderef is somewhat fugly, although the result is
# really worth it. The final coderef does not perform any kind of recursion -
# the entire nested structure constructor is rolled out into a single scope.
#
# In any case - the output of this thing is meticulously micro-tested, so
# any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
#
sub _mk_row_parser {
  # $args and $attrs are separated to delineate what is core collapser stuff and
  # what is dbic $rs specific
  my ($self, $args, $attrs) = @_;

  die "HRI without pruning makes zero sense"
  if ( $args->{hri_style} && ! $args->{prune_null_branches} );

  my %common = (
    hri_style => $args->{hri_style},
    prune_null_branches => $args->{prune_null_branches},
    val_index => { map
      { $args->{inflate_map}[$_] => $_ }
      ( 0 .. $#{$args->{inflate_map}} )
    },
  );

  my $check_null_columns;

  my $src = (! $args->{collapse} ) ? assemble_simple_parser(\%common) : do {
    my $collapse_map = $self->_resolve_collapse ({
      # FIXME
      # only consider real columns (not functions) during collapse resolution
      # this check shouldn't really be here, as fucktards are not supposed to
      # alias random crap to existing column names anyway, but still - just in
      # case
      # FIXME !!!! - this does not yet deal with unbalanced selectors correctly
      # (it is now trivial as the attrs specify where things go out of sync
      # needs MOAR tests)
      as => { map
        { ref $attrs->{select}[$common{val_index}{$_}] ? () : ( $_ => $common{val_index}{$_} ) }
        keys %{$common{val_index}}
      },
      premultiplied => $args->{premultiplied},
    });

    $check_null_columns = $collapse_map->{-identifying_columns}
      if @{$collapse_map->{-identifying_columns}};

    assemble_collapsing_parser({
      %common,
      collapse_map => $collapse_map,
    });
  };

  return (
    $args->{eval} ? ( eval "sub $src" || die $@ ) : $src,
    $check_null_columns,
  );
}


# Takes an arrayref selection list and generates a collapse-map representing
# row-object fold-points. Every relationship is assigned a set of unique,
# non-nullable columns (which may *not even be* from the same resultset)
# and the collapser will use this information to correctly distinguish
# data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
# for extensive RV examples
sub _resolve_collapse {
  my ($self, $args, $common_args) = @_;

  # for comprehensible error messages put ourselves at the head of the relationship chain
  $args->{_rel_chain} ||= [ $self->source_name ];

  # record top-level fully-qualified column index, signify toplevelness
  unless ($common_args->{_as_fq_idx}) {
    $common_args->{_as_fq_idx} = { %{$args->{as}} };
    $args->{_is_top_level} = 1;
  };

  my ($my_cols, $rel_cols);
  for (keys %{$args->{as}}) {
    if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
      $rel_cols->{$1}{$2} = 1;
    }
    else {
      $my_cols->{$_} = {};  # important for ||='s below
    }
  }

  my $relinfo;
  # run through relationships, collect metadata
  for my $rel (keys %$rel_cols) {
    my $inf = $self->relationship_info ($rel);

    $relinfo->{$rel} = {
      is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
      is_inner => ( ( $inf->{attrs}{join_type} || '' ) !~ /^left/i),
      rsrc => $self->related_source($rel),
    };

    # FIME - need to use _resolve_cond here instead
    my $cond = $inf->{cond};

    if (
      ref $cond eq 'HASH'
        and
      keys %$cond
        and
      ! defined first { $_ !~ /^foreign\./ } (keys %$cond)
        and
      ! defined first { $_ !~ /^self\./ } (values %$cond)
    ) {
      for my $f (keys %$cond) {
        my $s = $cond->{$f};
        $_ =~ s/^ (?: foreign | self ) \.//x for ($f, $s);
        $relinfo->{$rel}{fk_map}{$s} = $f;
      }
    }
  }

  # inject non-left fk-bridges from *INNER-JOINED* children (if any)
  for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
    my $ri = $relinfo->{$rel};
    for (keys %{$ri->{fk_map}} ) {
      # need to know source from *our* pov, hence $rel.col
      $my_cols->{$_} ||= { via_fk => "$rel.$ri->{fk_map}{$_}" }
        if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
    }
  }

  # if the parent is already defined *AND* we have an inner reverse relationship
  # (i.e. do not exist without it) , assume all of its related FKs are selected
  # (even if they in fact are NOT in the select list). Keep a record of what we
  # assumed, and if any such phantom-column becomes part of our own collapser,
  # throw everything assumed-from-parent away and replace with the collapser of
  # the parent (whatever it may be)
  my $assumed_from_parent;
  if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
    for my $col ( values %{$args->{_parent_info}{rel_condition} || {}} ) {
      next if exists $my_cols->{$col};
      $my_cols->{$col} = { via_collapse => $args->{_parent_info}{collapse_on_idcols} };
      $assumed_from_parent->{columns}{$col}++;
    }
  }

  # get colinfo for everything
  if ($my_cols) {
    my $ci = $self->columns_info;
    $my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
  }

  my $collapse_map;

  # first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
  # (makes for a leaner coderef later)
  unless ($collapse_map->{-identifying_columns}) {
    $collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
      if $args->{_parent_info}{collapser_reusable};
  }

  # Still don't know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
  if (
    ! $collapse_map->{-identifying_columns}
      and
    $my_cols
      and
    my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
  ) {
    # see if the resulting collapser relies on any implied columns,
    # and fix stuff up if this is the case
    my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;

    $collapse_map->{-identifying_columns} = [ __unique_numlist(
      @{ $args->{_parent_info}{collapse_on_idcols}||[] },

      (map
        {
          my $fqc = join ('.',
            @{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
            ( $my_cols->{$_}{via_fk} || $_ ),
          );

          $common_args->{_as_fq_idx}->{$fqc};
        }
        @reduced_set
      ),
    )];
  }

  # Stil don't know how to collapse - keep descending down 1:1 chains - if
  # a related non-LEFT 1:1 is resolvable - its condition will collapse us
  # too
  unless ($collapse_map->{-identifying_columns}) {
    my @candidates;

    for my $rel (keys %$relinfo) {
      next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});

      if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
        as => $rel_cols->{$rel},
        _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
        _parent_info => { underdefined => 1 },
      }, $common_args)) {
        push @candidates, $rel_collapse->{-identifying_columns};
      }
    }

    # get the set with least amount of columns
    # FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
    # to a single varchar)
    if (@candidates) {
      ($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
    }
  }

  # Stil don't know how to collapse, and we are the root node. Last ditch
  # effort in case we are *NOT* premultiplied.
  # Run through *each multi* all the way down, left or not, and all
  # *left* singles (a single may become a multi underneath) . When everything
  # gets back see if all the rels link to us definitively. If this is the
  # case we are good - either one of them will define us, or if all are NULLs
  # we know we are "unique" due to the "non-premultiplied" check
  if (
    ! $collapse_map->{-identifying_columns}
      and
    ! $args->{premultiplied}
      and
    $args->{_is_top_level}
  ) {
    my (@collapse_sets, $uncollapsible_chain);

    for my $rel (keys %$relinfo) {

      # we already looked at these higher up
      next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});

      if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
        as => $rel_cols->{$rel},
        _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
        _parent_info => { underdefined => 1 },
      }, $common_args) ) {

        # for singles use the idcols wholesale (either there or not)
        if ($relinfo->{$rel}{is_single}) {
          push @collapse_sets, $clps->{-identifying_columns};
        }
        elsif (! $relinfo->{$rel}{fk_map}) {
          $uncollapsible_chain = 1;
          last;
        }
        else {
          my $defined_cols_parent_side;

          for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
            my ($col) = $fq_col =~ /([^\.]+)$/;

            $defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
              { $relinfo->{$rel}{fk_map}{$_} eq $col }
              keys %{$relinfo->{$rel}{fk_map}}
            ;
          }

          if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
            push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
          }
          else {
            $uncollapsible_chain = 1;
            last;
          }
        }
      }
      else {
        $uncollapsible_chain = 1;
        last;
      }
    }

    unless ($uncollapsible_chain) {
      # if we got here - we are good to go, but the construction is tricky
      # since our children will want to include our collapse criteria - we
      # don't give them anything (safe, since they are all collapsible on their own)
      # in addition we record the individual collapse possibilities
      # of all left children node collapsers, and merge them in the rowparser
      # coderef later
      $collapse_map->{-identifying_columns} = [];
      $collapse_map->{-identifying_columns_variants} = [ sort {
        (scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
      } @collapse_sets ];
    }
  }

  # stop descending into children if we were called by a parent for first-pass
  # and don't despair if nothing was found (there may be other parallel branches
  # to dive into)
  if ($args->{_parent_info}{underdefined}) {
    return $collapse_map->{-identifying_columns} ? $collapse_map : undef
  }
  # nothing down the chain resolved - can't calculate a collapse-map
  elsif (! $collapse_map->{-identifying_columns}) {
    $self->throw_exception ( sprintf
      "Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
      $self->source_name,
      @{$args->{_rel_chain}} > 1
        ? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
        : ''
      ,
    );
  }

  # If we got that far - we are collapsable - GREAT! Now go down all children
  # a second time, and fill in the rest

  $collapse_map->{-identifying_columns} = [ __unique_numlist(
    @{ $args->{_parent_info}{collapse_on_idcols}||[] },
    @{ $collapse_map->{-identifying_columns} },
  )];

  my @id_sets;
  for my $rel (sort keys %$relinfo) {

    $collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
      as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
      _rel_chain => [ @{$args->{_rel_chain}}, $rel],
      _parent_info => {
        # shallow copy
        collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],

        rel_condition => $relinfo->{$rel}{fk_map},

        is_optional => ! $relinfo->{$rel}{is_inner},

        # if there is at least one *inner* reverse relationship which is HASH-based (equality only)
        # we can safely assume that the child can not exist without us
        rev_rel_is_optional => ( first
          { ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}||'') !~ /^left/i }
          values %{ $self->reverse_relationship_info($rel) },
        ) ? 0 : 1,

        # if this is a 1:1 our own collapser can be used as a collapse-map
        # (regardless of left or not)
        collapser_reusable => (
          $relinfo->{$rel}{is_single}
            &&
          $relinfo->{$rel}{is_inner}
            &&
          @{$collapse_map->{-identifying_columns}}
        ) ? 1 : 0,
      },
    }, $common_args );

    $collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
    $collapse_map->{$rel}{-is_optional} ||= 1 unless $relinfo->{$rel}{is_inner};
  }

  return $collapse_map;
}

# adding a dep on MoreUtils *just* for this is retarded
sub __unique_numlist {
  sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
}

1;
Commit	Line	Data
4e9fc3f3	1	package # hide from the pauses
4e9fc3f3	2	DBIx::Class::ResultSource::RowParser;
76031e14	3
	4	use strict;
	5	use warnings;
	6
9f98c4b2	7	use base 'DBIx::Class';
9f98c4b2	8
76031e14	9	use Try::Tiny;
fcf32d04	10	use List::Util qw(first max);
76031e14	11
9f98c4b2	12	use DBIx::Class::ResultSource::RowParser::Util qw(
	13	assemble_simple_parser
	14	assemble_collapsing_parser
	15	);
76031e14	16
9f98c4b2	17	use namespace::clean;
76031e14	18
	19	# Accepts one or more relationships for the current source and returns an
	20	# array of column names for each of those relationships. Column names are
	21	# prefixed relative to the current source, in accordance with where they appear
	22	# in the supplied relationships.
	23	sub _resolve_prefetch {
	24	my ($self, $pre, $alias, $alias_map, $order, $pref_path) = @_;
	25	$pref_path \|\|= [];
	26
	27	if (not defined $pre or not length $pre) {
	28	return ();
	29	}
	30	elsif( ref $pre eq 'ARRAY' ) {
	31	return
	32	map { $self->_resolve_prefetch( $_, $alias, $alias_map, $order, [ @$pref_path ] ) }
	33	@$pre;
	34	}
	35	elsif( ref $pre eq 'HASH' ) {
	36	my @ret =
	37	map {
	38	$self->_resolve_prefetch($_, $alias, $alias_map, $order, [ @$pref_path ] ),
	39	$self->related_source($_)->_resolve_prefetch(
4e9fc3f3	40	$pre->{$_}, "${alias}.$_", $alias_map, $order, [ @$pref_path, $_] )
76031e14	41	} keys %$pre;
	42	return @ret;
	43	}
	44	elsif( ref $pre ) {
	45	$self->throw_exception(
	46	"don't know how to resolve prefetch reftype ".ref($pre));
	47	}
	48	else {
	49	my $p = $alias_map;
	50	$p = $p->{$_} for (@$pref_path, $pre);
	51
	52	$self->throw_exception (
	53	"Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
	54	. join (' -> ', @$pref_path, $pre)
	55	) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );
	56
	57	my $as = shift @{$p->{-join_aliases}};
	58
	59	my $rel_info = $self->relationship_info( $pre );
	60	$self->throw_exception( $self->source_name . " has no such relationship '$pre'" )
	61	unless $rel_info;
	62
	63	my $as_prefix = ($alias =~ /^.*?\.(.+)$/ ? $1.'.' : '');
76031e14	64
76031e14	65	return map { [ "${as}.$_", "${as_prefix}${pre}.$_", ] }
4e9fc3f3	66	$self->related_source($pre)->columns;
76031e14	67	}
	68	}
	69
9f98c4b2	70	# Takes an arrayref of {as} dbic column aliases and the collapse and select
	71	# attributes from the same $rs (the selector requirement is a temporary
	72	# workaround... I hope), and returns a coderef capable of:
	73	# my $me_pref_clps = $coderef->([$rs->cursor->next/all])
	74	# Where the $me_pref_clps arrayref is the future argument to inflate_result()
	75	#
	76	# For an example of this coderef in action (and to see its guts) look at
	77	# t/resultset/rowparser_internals.t
	78	#
	79	# This is a huge performance win, as we call the same code for every row
	80	# returned from the db, thus avoiding repeated method lookups when traversing
	81	# relationships
	82	#
	83	# Also since the coderef is completely stateless (the returned structure is
	84	# always fresh on every new invocation) this is a very good opportunity for
	85	# memoization if further speed improvements are needed
	86	#
	87	# The way we construct this coderef is somewhat fugly, although the result is
	88	# really worth it. The final coderef does not perform any kind of recursion -
	89	# the entire nested structure constructor is rolled out into a single scope.
	90	#
	91	# In any case - the output of this thing is meticulously micro-tested, so
	92	# any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
	93	#
	94	sub _mk_row_parser {
4a0eed52	95	# $args and $attrs are separated to delineate what is core collapser stuff and
5b309063	96	# what is dbic $rs specific
5b309063	97	my ($self, $args, $attrs) = @_;
9f98c4b2	98
79adc44f	99	die "HRI without pruning makes zero sense"
	100	if ( $args->{hri_style} && ! $args->{prune_null_branches} );
	101
	102	my %common = (
	103	hri_style => $args->{hri_style},
	104	prune_null_branches => $args->{prune_null_branches},
	105	val_index => { map
	106	{ $args->{inflate_map}[$_] => $_ }
	107	( 0 .. $#{$args->{inflate_map}} )
	108	},
	109	);
	110
02a73c96	111	my $check_null_columns;
	112
	113	my $src = (! $args->{collapse} ) ? assemble_simple_parser(\%common) : do {
	114	my $collapse_map = $self->_resolve_collapse ({
	115	# FIXME
	116	# only consider real columns (not functions) during collapse resolution
	117	# this check shouldn't really be here, as fucktards are not supposed to
	118	# alias random crap to existing column names anyway, but still - just in
	119	# case
	120	# FIXME !!!! - this does not yet deal with unbalanced selectors correctly
	121	# (it is now trivial as the attrs specify where things go out of sync
	122	# needs MOAR tests)
	123	as => { map
	124	{ ref $attrs->{select}[$common{val_index}{$_}] ? () : ( $_ => $common{val_index}{$_} ) }
	125	keys %{$common{val_index}}
	126	},
	127	premultiplied => $args->{premultiplied},
	128	});
	129
	130	$check_null_columns = $collapse_map->{-identifying_columns}
	131	if @{$collapse_map->{-identifying_columns}};
	132
	133	assemble_collapsing_parser({
79adc44f	134	%common,
02a73c96	135	collapse_map => $collapse_map,
	136	});
	137	};
	138
	139	return (
	140	$args->{eval} ? ( eval "sub $src" \|\| die $@ ) : $src,
	141	$check_null_columns,
	142	);
9f98c4b2	143	}
	144
	145
2d0b795a	146	# Takes an arrayref selection list and generates a collapse-map representing
76031e14	147	# row-object fold-points. Every relationship is assigned a set of unique,
	148	# non-nullable columns (which may not even be from the same resultset)
	149	# and the collapser will use this information to correctly distinguish
2d0b795a	150	# data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
2d0b795a	151	# for extensive RV examples
76031e14	152	sub _resolve_collapse {
82f0e0aa	153	my ($self, $args, $common_args) = @_;
76031e14	154
76031e14	155	# for comprehensible error messages put ourselves at the head of the relationship chain
82f0e0aa	156	$args->{_rel_chain} \|\|= [ $self->source_name ];
76031e14	157
9f98c4b2	158	# record top-level fully-qualified column index, signify toplevelness
	159	unless ($common_args->{_as_fq_idx}) {
	160	$common_args->{_as_fq_idx} = { %{$args->{as}} };
	161	$args->{_is_top_level} = 1;
82f0e0aa	162	};
76031e14	163
76031e14	164	my ($my_cols, $rel_cols);
82f0e0aa	165	for (keys %{$args->{as}}) {
76031e14	166	if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
	167	$rel_cols->{$1}{$2} = 1;
	168	}
	169	else {
fcf32d04	170	$my_cols->{$_} = {}; # important for \|\|='s below
76031e14	171	}
	172	}
	173
	174	my $relinfo;
fcf32d04	175	# run through relationships, collect metadata
76031e14	176	for my $rel (keys %$rel_cols) {
76031e14	177	my $inf = $self->relationship_info ($rel);
76031e14	178
95e41036	179	$relinfo->{$rel} = {
	180	is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
	181	is_inner => ( ( $inf->{attrs}{join_type} \|\| '' ) !~ /^left/i),
	182	rsrc => $self->related_source($rel),
	183	};
76031e14	184
fcf32d04	185	# FIME - need to use _resolve_cond here instead
76031e14	186	my $cond = $inf->{cond};
	187
	188	if (
	189	ref $cond eq 'HASH'
	190	and
	191	keys %$cond
	192	and
fcf32d04	193	! defined first { $_ !~ /^foreign\./ } (keys %$cond)
76031e14	194	and
fcf32d04	195	! defined first { $_ !~ /^self\./ } (values %$cond)
76031e14	196	) {
	197	for my $f (keys %$cond) {
	198	my $s = $cond->{$f};
	199	$_ =~ s/^ (?: foreign \| self ) \.//x for ($f, $s);
	200	$relinfo->{$rel}{fk_map}{$s} = $f;
76031e14	201	}
	202	}
	203	}
	204
fcf32d04	205	# inject non-left fk-bridges from INNER-JOINED children (if any)
	206	for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
	207	my $ri = $relinfo->{$rel};
	208	for (keys %{$ri->{fk_map}} ) {
	209	# need to know source from our pov, hence $rel.col
	210	$my_cols->{$_} \|\|= { via_fk => "$rel.$ri->{fk_map}{$_}" }
	211	if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
	212	}
	213	}
	214
a0726a33	215	# if the parent is already defined AND we have an inner reverse relationship
a0726a33	216	# (i.e. do not exist without it) , assume all of its related FKs are selected
76031e14	217	# (even if they in fact are NOT in the select list). Keep a record of what we
	218	# assumed, and if any such phantom-column becomes part of our own collapser,
	219	# throw everything assumed-from-parent away and replace with the collapser of
	220	# the parent (whatever it may be)
	221	my $assumed_from_parent;
a0726a33	222	if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
fcf32d04	223	for my $col ( values %{$args->{_parent_info}{rel_condition} \|\| {}} ) {
	224	next if exists $my_cols->{$col};
	225	$my_cols->{$col} = { via_collapse => $args->{_parent_info}{collapse_on_idcols} };
	226	$assumed_from_parent->{columns}{$col}++;
	227	}
76031e14	228	}
	229
	230	# get colinfo for everything
	231	if ($my_cols) {
	232	my $ci = $self->columns_info;
	233	$my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
	234	}
	235
	236	my $collapse_map;
	237
3faac878	238	# first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
3faac878	239	# (makes for a leaner coderef later)
9f98c4b2	240	unless ($collapse_map->{-identifying_columns}) {
9f98c4b2	241	$collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
3faac878	242	if $args->{_parent_info}{collapser_reusable};
	243	}
	244
4a0eed52	245	# Still don't know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
76031e14	246	if (
9f98c4b2	247	! $collapse_map->{-identifying_columns}
3faac878	248	and
76031e14	249	$my_cols
76031e14	250	and
4e9fc3f3	251	my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
76031e14	252	) {
	253	# see if the resulting collapser relies on any implied columns,
	254	# and fix stuff up if this is the case
4e9fc3f3	255	my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;
76031e14	256
9f98c4b2	257	$collapse_map->{-identifying_columns} = [ __unique_numlist(
3faac878	258	@{ $args->{_parent_info}{collapse_on_idcols}\|\|[] },
3faac878	259
76031e14	260	(map
	261	{
	262	my $fqc = join ('.',
82f0e0aa	263	@{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
76031e14	264	( $my_cols->{$_}{via_fk} \|\| $_ ),
	265	);
	266
82f0e0aa	267	$common_args->{_as_fq_idx}->{$fqc};
76031e14	268	}
4e9fc3f3	269	@reduced_set
76031e14	270	),
3faac878	271	)];
76031e14	272	}
	273
	274	# Stil don't know how to collapse - keep descending down 1:1 chains - if
	275	# a related non-LEFT 1:1 is resolvable - its condition will collapse us
	276	# too
9f98c4b2	277	unless ($collapse_map->{-identifying_columns}) {
76031e14	278	my @candidates;
	279
	280	for my $rel (keys %$relinfo) {
	281	next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
	282
82f0e0aa	283	if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	284	as => $rel_cols->{$rel},
	285	_rel_chain => [ @{$args->{_rel_chain}}, $rel ],
	286	_parent_info => { underdefined => 1 },
	287	}, $common_args)) {
9f98c4b2	288	push @candidates, $rel_collapse->{-identifying_columns};
76031e14	289	}
	290	}
	291
	292	# get the set with least amount of columns
	293	# FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
	294	# to a single varchar)
	295	if (@candidates) {
9f98c4b2	296	($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
76031e14	297	}
	298	}
	299
fcf32d04	300	# Stil don't know how to collapse, and we are the root node. Last ditch
	301	# effort in case we are NOT premultiplied.
	302	# Run through each multi all the way down, left or not, and all
	303	# left singles (a single may become a multi underneath) . When everything
	304	# gets back see if all the rels link to us definitively. If this is the
	305	# case we are good - either one of them will define us, or if all are NULLs
	306	# we know we are "unique" due to the "non-premultiplied" check
	307	if (
9f98c4b2	308	! $collapse_map->{-identifying_columns}
fcf32d04	309	and
	310	! $args->{premultiplied}
	311	and
9f98c4b2	312	$args->{_is_top_level}
fcf32d04	313	) {
	314	my (@collapse_sets, $uncollapsible_chain);
	315
	316	for my $rel (keys %$relinfo) {
	317
	318	# we already looked at these higher up
	319	next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
	320
	321	if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	322	as => $rel_cols->{$rel},
	323	_rel_chain => [ @{$args->{_rel_chain}}, $rel ],
	324	_parent_info => { underdefined => 1 },
	325	}, $common_args) ) {
	326
	327	# for singles use the idcols wholesale (either there or not)
	328	if ($relinfo->{$rel}{is_single}) {
9f98c4b2	329	push @collapse_sets, $clps->{-identifying_columns};
fcf32d04	330	}
	331	elsif (! $relinfo->{$rel}{fk_map}) {
	332	$uncollapsible_chain = 1;
	333	last;
	334	}
	335	else {
	336	my $defined_cols_parent_side;
	337
	338	for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
	339	my ($col) = $fq_col =~ /([^\.]+)$/;
	340
	341	$defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
	342	{ $relinfo->{$rel}{fk_map}{$_} eq $col }
	343	keys %{$relinfo->{$rel}{fk_map}}
	344	;
	345	}
	346
	347	if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
	348	push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
	349	}
	350	else {
	351	$uncollapsible_chain = 1;
	352	last;
	353	}
	354	}
	355	}
	356	else {
	357	$uncollapsible_chain = 1;
	358	last;
	359	}
	360	}
	361
	362	unless ($uncollapsible_chain) {
	363	# if we got here - we are good to go, but the construction is tricky
	364	# since our children will want to include our collapse criteria - we
	365	# don't give them anything (safe, since they are all collapsible on their own)
4a0eed52	366	# in addition we record the individual collapse possibilities
fcf32d04	367	# of all left children node collapsers, and merge them in the rowparser
fcf32d04	368	# coderef later
9f98c4b2	369	$collapse_map->{-identifying_columns} = [];
9f98c4b2	370	$collapse_map->{-identifying_columns_variants} = [ sort {
fcf32d04	371	(scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
	372	} @collapse_sets ];
	373	}
	374	}
	375
76031e14	376	# stop descending into children if we were called by a parent for first-pass
	377	# and don't despair if nothing was found (there may be other parallel branches
	378	# to dive into)
82f0e0aa	379	if ($args->{_parent_info}{underdefined}) {
9f98c4b2	380	return $collapse_map->{-identifying_columns} ? $collapse_map : undef
76031e14	381	}
76031e14	382	# nothing down the chain resolved - can't calculate a collapse-map
9f98c4b2	383	elsif (! $collapse_map->{-identifying_columns}) {
76031e14	384	$self->throw_exception ( sprintf
	385	"Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
	386	$self->source_name,
82f0e0aa	387	@{$args->{_rel_chain}} > 1
82f0e0aa	388	? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
76031e14	389	: ''
	390	,
	391	);
	392	}
	393
	394	# If we got that far - we are collapsable - GREAT! Now go down all children
	395	# a second time, and fill in the rest
	396
a0726a33	397	$collapse_map->{-identifying_columns} = [ __unique_numlist(
	398	@{ $args->{_parent_info}{collapse_on_idcols}\|\|[] },
	399	@{ $collapse_map->{-identifying_columns} },
	400	)];
3faac878	401
3faac878	402	my @id_sets;
76031e14	403	for my $rel (sort keys %$relinfo) {
76031e14	404
82f0e0aa	405	$collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	406	as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
	407	_rel_chain => [ @{$args->{_rel_chain}}, $rel],
	408	_parent_info => {
3faac878	409	# shallow copy
9f98c4b2	410	collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],
76031e14	411
	412	rel_condition => $relinfo->{$rel}{fk_map},
	413
a0726a33	414	is_optional => ! $relinfo->{$rel}{is_inner},
	415
	416	# if there is at least one inner reverse relationship which is HASH-based (equality only)
	417	# we can safely assume that the child can not exist without us
	418	rev_rel_is_optional => ( first
	419	{ ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}\|\|'') !~ /^left/i }
	420	values %{ $self->reverse_relationship_info($rel) },
	421	) ? 0 : 1,
76031e14	422
	423	# if this is a 1:1 our own collapser can be used as a collapse-map
	424	# (regardless of left or not)
3d8caf63	425	collapser_reusable => (
	426	$relinfo->{$rel}{is_single}
	427	&&
	428	$relinfo->{$rel}{is_inner}
	429	&&
	430	@{$collapse_map->{-identifying_columns}}
	431	) ? 1 : 0,
76031e14	432	},
82f0e0aa	433	}, $common_args );
76031e14	434
	435	$collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
	436	$collapse_map->{$rel}{-is_optional} \|\|= 1 unless $relinfo->{$rel}{is_inner};
3faac878	437	}
76031e14	438
	439	return $collapse_map;
	440	}
	441
76031e14	442	# adding a dep on MoreUtils just for this is retarded
76031e14	443	sub __unique_numlist {
3faac878	444	sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
76031e14	445	}
76031e14	446
76031e14	447	1;