[catagits/Catalyst-Runtime.git] / lib / Catalyst / Engine / HTTP.pm

package Catalyst::Engine::HTTP;

use strict;
use base 'Catalyst::Engine::CGI';
use Data::Dump qw(dump);
use Errno 'EWOULDBLOCK';
use HTTP::Date ();
use HTTP::Headers;
use HTTP::Status;
use NEXT;
use Socket;
use IO::Socket::INET ();
use IO::Select       ();

# For PAR
require Catalyst::Engine::HTTP::Restarter;
require Catalyst::Engine::HTTP::Restarter::Watcher;

use constant CHUNKSIZE => 64 * 1024;
use constant DEBUG     => $ENV{CATALYST_HTTP_DEBUG} || 0;

=head1 NAME

Catalyst::Engine::HTTP - Catalyst HTTP Engine

=head1 SYNOPSIS

A script using the Catalyst::Engine::HTTP module might look like:

    #!/usr/bin/perl -w

    BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }

    use strict;
    use lib '/path/to/MyApp/lib';
    use MyApp;

    MyApp->run;

=head1 DESCRIPTION

This is the Catalyst engine specialized for development and testing.

=head1 METHODS

=head2 $self->finalize_headers($c)

=cut

sub finalize_headers {
    my ( $self, $c ) = @_;
    my $protocol = $c->request->protocol;
    my $status   = $c->response->status;
    my $message  = status_message($status);
    
    my @headers;
    push @headers, "$protocol $status $message";
    
    $c->response->headers->header( Date => HTTP::Date::time2str(time) );
    $c->response->headers->header( Status => $status );
    
    # Should we keep the connection open?
    my $connection = $c->request->header('Connection');
    if (   $self->{options}->{keepalive} 
        && $connection 
        && $connection =~ /^keep-alive$/i
    ) {
        $c->response->headers->header( Connection => 'keep-alive' );
        $self->{_keepalive} = 1;
    }
    else {
        $c->response->headers->header( Connection => 'close' );
    }
    
    push @headers, $c->response->headers->as_string("\x0D\x0A");
    
    # Buffer the headers so they are sent with the first write() call
    # This reduces the number of TCP packets we are sending
    $self->{_header_buf} = join("\x0D\x0A", @headers, '');
}

=head2 $self->finalize_read($c)

=cut

sub finalize_read {
    my ( $self, $c ) = @_;

    # Never ever remove this, it would result in random length output
    # streams if STDIN eq STDOUT (like in the HTTP engine)
    *STDIN->blocking(1);

    return $self->NEXT::finalize_read($c);
}

=head2 $self->prepare_read($c)

=cut

sub prepare_read {
    my ( $self, $c ) = @_;

    # Set the input handle to non-blocking
    *STDIN->blocking(0);

    return $self->NEXT::prepare_read($c);
}

=head2 $self->read_chunk($c, $buffer, $length)

=cut

sub read_chunk {
    my $self = shift;
    my $c    = shift;
    
    # If we have any remaining data in the input buffer, send it back first
    if ( $_[0] = delete $self->{inputbuf} ) {
        my $read = length( $_[0] );
        DEBUG && warn "read_chunk: Read $read bytes from previous input buffer\n";
        return $read;
    }

    # support for non-blocking IO
    my $rin = '';
    vec( $rin, *STDIN->fileno, 1 ) = 1;

  READ:
    {
        select( $rin, undef, undef, undef );
        my $rc = *STDIN->sysread(@_);
        if ( defined $rc ) {
            DEBUG && warn "read_chunk: Read $rc bytes from socket\n";
            return $rc;
        }
        else {
            next READ if $! == EWOULDBLOCK;
            return;
        }
    }
}

=head2 $self->write($c, $buffer)

Writes the buffer to the client. Can only be called once for a request.

=cut

sub write {
    my ( $self, $c, $buffer ) = @_;
    
	# Avoid 'print() on closed filehandle Remote' warnings when using IE
	return unless *STDOUT->opened();
	
	my $ret;
	
	# Prepend the headers if they have not yet been sent
	if ( my $headers = delete $self->{_header_buf} ) {
	    DEBUG && warn "write: Wrote headers and first chunk (" . length($headers . $buffer) . " bytes)\n";
	    $ret = $self->NEXT::write( $c, $headers . $buffer );
    }
    else {
        DEBUG && warn "write: Wrote chunk (" . length($buffer) . " bytes)\n";
        $ret = $self->NEXT::write( $c, $buffer );
    }
    
    if ( !$ret ) {
        $self->{_write_error} = $!;
    }
    
    return $ret;
}

=head2 run

=cut

# A very very simple HTTP server that initializes a CGI environment
sub run {
    my ( $self, $class, $port, $host, $options ) = @_;

    $options ||= {};
    
    $self->{options} = $options;

    if ($options->{background}) {
        my $child = fork;
        die "Can't fork: $!" unless defined($child);
        exit if $child;
    }

    my $restart = 0;
    local $SIG{CHLD} = 'IGNORE';

    my $allowed = $options->{allowed} || { '127.0.0.1' => '255.255.255.255' };
    my $addr = $host ? inet_aton($host) : INADDR_ANY;
    if ( $addr eq INADDR_ANY ) {
        require Sys::Hostname;
        $host = lc Sys::Hostname::hostname();
    }
    else {
        $host = gethostbyaddr( $addr, AF_INET ) || inet_ntoa($addr);
    }

    # Handle requests

    # Setup socket
    my $daemon = IO::Socket::INET->new(
        Listen    => SOMAXCONN,
        LocalAddr => inet_ntoa($addr),
        LocalPort => $port,
        Proto     => 'tcp',
        ReuseAddr => 1,
        Type      => SOCK_STREAM,
      )
      or die "Couldn't create daemon: $!";

    my $url = "http://$host";
    $url .= ":$port" unless $port == 80;

    print "You can connect to your server at $url\n";

    if ($options->{background}) {
        open STDIN,  "+</dev/null" or die $!;
        open STDOUT, ">&STDIN"     or die $!;
        open STDERR, ">&STDIN"     or die $!;
        if ( $^O !~ /MSWin32/ ) {
             require POSIX;
             POSIX::setsid()
                 or die "Can't start a new session: $!";
        }
    }

    if (my $pidfile = $options->{pidfile}) {
        if (! open PIDFILE, "> $pidfile") {
            warn("Cannot open: $pidfile: $!");
        }
        print PIDFILE "$$\n";
        close PIDFILE;
    }

    my $pid = undef;
    
    # Ignore broken pipes as an HTTP server should
    local $SIG{PIPE} = 'IGNORE';
    
    # Restart on HUP
    local $SIG{HUP} = sub { 
        $restart = 1;
        warn "Restarting server on SIGHUP...\n";
    };
    
    LISTEN:
    while ( !$restart ) {
        while ( accept( Remote, $daemon ) ) {        
            DEBUG && warn "New connection\n";

            select Remote;

            Remote->blocking(1);
        
            # Read until we see all headers
            $self->{inputbuf} = '';
            
            if ( !$self->_read_headers ) {
                # Error reading, give up
                next LISTEN;
            }

            my ( $method, $uri, $protocol ) = $self->_parse_request_line;
        
            DEBUG && warn "Parsed request: $method $uri $protocol\n";
        
            next unless $method;

            unless ( uc($method) eq 'RESTART' ) {

                # Fork
                if ( $options->{fork} ) { 
                    if ( $pid = fork ) {
                        DEBUG && warn "Forked child $pid\n";
                        next;
                    }
                }

                $self->_handler( $class, $port, $method, $uri, $protocol );
            
                if ( my $error = delete $self->{_write_error} ) {
                    DEBUG && warn "Write error: $error\n";
                    close Remote;
                    
                    if ( !defined $pid ) {
                        next LISTEN;
                    }
                }

                if ( defined $pid ) {
                    # Child process, close connection and exit
                    DEBUG && warn "Child process exiting\n";
                    $daemon->close;
                    exit;
                }
            }
            else {
                my $sockdata = $self->_socket_data( \*Remote );
                my $ipaddr   = _inet_addr( $sockdata->{peeraddr} );
                my $ready    = 0;
                foreach my $ip ( keys %$allowed ) {
                    my $mask = $allowed->{$ip};
                    $ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
                    last if $ready;
                }
                if ($ready) {
                    $restart = 1;
                    last;
                }
            }
        }
        continue {
            close Remote;
        }
    }
    
    $daemon->close;
    
    DEBUG && warn "Shutting down\n";

    if ($restart) {
        $SIG{CHLD} = 'DEFAULT';
        wait;

        ### if the standalone server was invoked with perl -I .. we will loose
        ### those include dirs upon re-exec. So add them to PERL5LIB, so they
        ### are available again for the exec'ed process --kane
        use Config;
        $ENV{PERL5LIB} .= join $Config{path_sep}, @INC; 
        
        exec $^X . ' "' . $0 . '" ' . join( ' ', @{ $options->{argv} } );
    }

    exit;
}

sub _handler {
    my ( $self, $class, $port, $method, $uri, $protocol ) = @_;

    local *STDIN  = \*Remote;
    local *STDOUT = \*Remote;

    # We better be careful and just use 1.0
    $protocol = '1.0';

    my $sockdata    = $self->_socket_data( \*Remote );
    my %copy_of_env = %ENV;

    my $sel = IO::Select->new;
    $sel->add( \*STDIN );
    
    REQUEST:
    while (1) {
        my ( $path, $query_string ) = split /\?/, $uri, 2;
        
        # Initialize CGI environment
        local %ENV = (
            PATH_INFO       => $path         || '',
            QUERY_STRING    => $query_string || '',
            REMOTE_ADDR     => $sockdata->{peeraddr},
            REMOTE_HOST     => $sockdata->{peername},
            REQUEST_METHOD  => $method || '',
            SERVER_NAME     => $sockdata->{localname},
            SERVER_PORT     => $port,
            SERVER_PROTOCOL => "HTTP/$protocol",
            %copy_of_env,
        );

        # Parse headers
        if ( $protocol >= 1 ) {
            $self->_parse_headers;
        }

        # Pass flow control to Catalyst
        $class->handle_request;
    
        DEBUG && warn "Request done\n";
    
        # Allow keepalive requests, this is a hack but we'll support it until
        # the next major release.
        if ( delete $self->{_keepalive} ) {
            
            DEBUG && warn "Reusing previous connection for keep-alive request\n";
            
            if ( $sel->can_read(1) ) {            
                if ( !$self->_read_headers ) {
                    # Error reading, give up
                    last REQUEST;
                }

                ( $method, $uri, $protocol ) = $self->_parse_request_line;
                
                DEBUG && warn "Parsed request: $method $uri $protocol\n";
                
                # Force HTTP/1.0
                $protocol = '1.0';
                
                next REQUEST;
            }
            
            DEBUG && warn "No keep-alive request within 1 second\n";
        }
        
        last REQUEST;
    }
    
    DEBUG && warn "Closing connection\n";

    close Remote;
}

sub _read_headers {
    my $self = shift;
    
    while (1) {
        my $read = sysread Remote, my $buf, CHUNKSIZE;
    
        if ( !$read ) {
            DEBUG && warn "EOF or error: $!\n";
            return;
        }
    
        DEBUG && warn "Read $read bytes\n";
        $self->{inputbuf} .= $buf;
        last if $self->{inputbuf} =~ /(\x0D\x0A?\x0D\x0A?|\x0A\x0D?\x0A\x0D?)/s;
    }
    
    return 1;
}

sub _parse_request_line {
    my $self = shift;

    # Parse request line    
    if ( $self->{inputbuf} !~ s/^(\w+)[ \t]+(\S+)(?:[ \t]+(HTTP\/\d+\.\d+))?[^\012]*\012// ) {
        return ();
    }
    
    my $method = $1;
    my $uri    = $2;
    my $proto  = $3 || 'HTTP/0.9';
    
    return ( $method, $uri, $proto );
}

sub _parse_headers {
    my $self = shift;
    
    # Copy the buffer for header parsing, and remove the header block
    # from the content buffer.
    my $buf = $self->{inputbuf};
    $self->{inputbuf} =~ s/.*?(\x0D\x0A?\x0D\x0A?|\x0A\x0D?\x0A\x0D?)//s;
    
    # Parse headers
    my $headers = HTTP::Headers->new;
    my ($key, $val);
    HEADER:
    while ( $buf =~ s/^([^\012]*)\012// ) {
        $_ = $1;
        s/\015$//;
        if ( /^([\w\-~]+)\s*:\s*(.*)/ ) {
            $headers->push_header( $key, $val ) if $key;
            ($key, $val) = ($1, $2);
        }
        elsif ( /^\s+(.*)/ ) {
            $val .= " $1";
        }
        else {
            last HEADER;
        }
    }
    $headers->push_header( $key, $val ) if $key;
    
    DEBUG && warn "Parsed headers: " . dump($headers) . "\n";

    # Convert headers into ENV vars
    $headers->scan( sub {
        my ( $key, $val ) = @_;
        
        $key = uc $key;
        $key = 'COOKIE' if $key eq 'COOKIES';
        $key =~ tr/-/_/;
        $key = 'HTTP_' . $key
            unless $key =~ m/\A(?:CONTENT_(?:LENGTH|TYPE)|COOKIE)\z/;
            
        if ( exists $ENV{$key} ) {
            $ENV{$key} .= ", $val";
        }
        else {
            $ENV{$key} = $val;
        }
    } );
}

sub _socket_data {
    my ( $self, $handle ) = @_;

    my $remote_sockaddr       = getpeername($handle);
    my ( undef, $iaddr )      = $remote_sockaddr 
        ? sockaddr_in($remote_sockaddr) 
        : (undef, undef);
        
    my $local_sockaddr        = getsockname($handle);
    my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);

    # This mess is necessary to keep IE from crashing the server
    my $data = {
        peername  => $iaddr 
            ? ( gethostbyaddr( $iaddr, AF_INET ) || 'localhost' )
            : 'localhost',
        peeraddr  => $iaddr 
            ? ( inet_ntoa($iaddr) || '127.0.0.1' )
            : '127.0.0.1',
        localname => gethostbyaddr( $localiaddr, AF_INET ) || 'localhost',
        localaddr => inet_ntoa($localiaddr) || '127.0.0.1',
    };

    return $data;
}

sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }

=head1 SEE ALSO

L<Catalyst>, L<Catalyst::Engine>.

=head1 AUTHORS

Sebastian Riedel, <sri@cpan.org>

Dan Kubb, <dan.kubb-cpan@onautopilot.com>

Sascha Kiefer, <esskar@cpan.org>

Andy Grundman, <andy@hybridized.org>

=head1 THANKS

Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.

=head1 COPYRIGHT

This program is free software, you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
Commit	Line	Data
ca61af20	1	package Catalyst::Engine::HTTP;
45374ac6	2
45374ac6	3	use strict;
fbcc39ad	4	use base 'Catalyst::Engine::CGI';
4bb8bd62	5	use Data::Dump qw(dump);
fbcc39ad	6	use Errno 'EWOULDBLOCK';
055ff026	7	use HTTP::Date ();
06744540	8	use HTTP::Headers;
fbcc39ad	9	use HTTP::Status;
	10	use NEXT;
	11	use Socket;
6c7a1d2f	12	use IO::Socket::INET ();
b5ecfcf0	13	use IO::Select ();
45374ac6	14
71fd2e0f	15	# For PAR
	16	require Catalyst::Engine::HTTP::Restarter;
	17	require Catalyst::Engine::HTTP::Restarter::Watcher;
	18
333123ef	19	use constant CHUNKSIZE => 64 * 1024;
333123ef	20	use constant DEBUG => $ENV{CATALYST_HTTP_DEBUG} \|\| 0;
4bb8bd62	21
45374ac6	22	=head1 NAME
45374ac6	23
ca61af20	24	Catalyst::Engine::HTTP - Catalyst HTTP Engine
45374ac6	25
	26	=head1 SYNOPSIS
	27
ca61af20	28	A script using the Catalyst::Engine::HTTP module might look like:
45374ac6	29
	30	#!/usr/bin/perl -w
	31
ca61af20	32	BEGIN { $ENV{CATALYST_ENGINE} = 'HTTP' }
45374ac6	33
	34	use strict;
	35	use lib '/path/to/MyApp/lib';
	36	use MyApp;
	37
	38	MyApp->run;
	39
	40	=head1 DESCRIPTION
	41
	42	This is the Catalyst engine specialized for development and testing.
	43
fbcc39ad	44	=head1 METHODS
fbcc39ad	45
b5ecfcf0	46	=head2 $self->finalize_headers($c)
fbcc39ad	47
	48	=cut
	49
	50	sub finalize_headers {
	51	my ( $self, $c ) = @_;
	52	my $protocol = $c->request->protocol;
	53	my $status = $c->response->status;
	54	my $message = status_message($status);
055ff026	55
06744540	56	my @headers;
06744540	57	push @headers, "$protocol $status $message";
055ff026	58
055ff026	59	$c->response->headers->header( Date => HTTP::Date::time2str(time) );
055ff026	60	$c->response->headers->header( Status => $status );
06744540	61
7f3c5736	62	# Should we keep the connection open?
	63	my $connection = $c->request->header('Connection');
	64	if ( $self->{options}->{keepalive}
	65	&& $connection
	66	&& $connection =~ /^keep-alive$/i
	67	) {
	68	$c->response->headers->header( Connection => 'keep-alive' );
	69	$self->{_keepalive} = 1;
	70	}
	71	else {
	72	$c->response->headers->header( Connection => 'close' );
	73	}
	74
06744540	75	push @headers, $c->response->headers->as_string("\x0D\x0A");
	76
	77	# Buffer the headers so they are sent with the first write() call
	78	# This reduces the number of TCP packets we are sending
	79	$self->{_header_buf} = join("\x0D\x0A", @headers, '');
fbcc39ad	80	}
fbcc39ad	81
b5ecfcf0	82	=head2 $self->finalize_read($c)
fbcc39ad	83
	84	=cut
	85
	86	sub finalize_read {
	87	my ( $self, $c ) = @_;
	88
	89	# Never ever remove this, it would result in random length output
	90	# streams if STDIN eq STDOUT (like in the HTTP engine)
4f5ebacd	91	*STDIN->blocking(1);
fbcc39ad	92
	93	return $self->NEXT::finalize_read($c);
	94	}
	95
b5ecfcf0	96	=head2 $self->prepare_read($c)
fbcc39ad	97
	98	=cut
	99
	100	sub prepare_read {
	101	my ( $self, $c ) = @_;
	102
	103	# Set the input handle to non-blocking
4f5ebacd	104	*STDIN->blocking(0);
fbcc39ad	105
	106	return $self->NEXT::prepare_read($c);
	107	}
	108
b5ecfcf0	109	=head2 $self->read_chunk($c, $buffer, $length)
fbcc39ad	110
	111	=cut
	112
	113	sub read_chunk {
	114	my $self = shift;
	115	my $c = shift;
4bb8bd62	116
	117	# If we have any remaining data in the input buffer, send it back first
	118	if ( $_[0] = delete $self->{inputbuf} ) {
	119	my $read = length( $_[0] );
	120	DEBUG && warn "read_chunk: Read $read bytes from previous input buffer\n";
	121	return $read;
	122	}
fbcc39ad	123
fbcc39ad	124	# support for non-blocking IO
4f5ebacd	125	my $rin = '';
4f5ebacd	126	vec( $rin, *STDIN->fileno, 1 ) = 1;
fbcc39ad	127
	128	READ:
	129	{
	130	select( $rin, undef, undef, undef );
4f5ebacd	131	my $rc = *STDIN->sysread(@_);
fbcc39ad	132	if ( defined $rc ) {
4bb8bd62	133	DEBUG && warn "read_chunk: Read $rc bytes from socket\n";
fbcc39ad	134	return $rc;
	135	}
	136	else {
	137	next READ if $! == EWOULDBLOCK;
	138	return;
	139	}
	140	}
	141	}
	142
00c99324	143	=head2 $self->write($c, $buffer)
	144
	145	Writes the buffer to the client. Can only be called once for a request.
	146
	147	=cut
	148
	149	sub write {
4bb8bd62	150	my ( $self, $c, $buffer ) = @_;
4bb8bd62	151
00c99324	152	# Avoid 'print() on closed filehandle Remote' warnings when using IE
	153	return unless *STDOUT->opened();
	154
4bb8bd62	155	my $ret;
	156
	157	# Prepend the headers if they have not yet been sent
	158	if ( my $headers = delete $self->{_header_buf} ) {
	159	DEBUG && warn "write: Wrote headers and first chunk (" . length($headers . $buffer) . " bytes)\n";
	160	$ret = $self->NEXT::write( $c, $headers . $buffer );
	161	}
	162	else {
	163	DEBUG && warn "write: Wrote chunk (" . length($buffer) . " bytes)\n";
	164	$ret = $self->NEXT::write( $c, $buffer );
	165	}
	166
	167	if ( !$ret ) {
	168	$self->{_write_error} = $!;
	169	}
	170
	171	return $ret;
00c99324	172	}
00c99324	173
b5ecfcf0	174	=head2 run
fbcc39ad	175
	176	=cut
	177
	178	# A very very simple HTTP server that initializes a CGI environment
	179	sub run {
37553dc8	180	my ( $self, $class, $port, $host, $options ) = @_;
fbcc39ad	181
4eeca0f2	182	$options \|\|= {};
3bcb3aae	183
3bcb3aae	184	$self->{options} = $options;
1cf1c56a	185
e1576f62	186	if ($options->{background}) {
	187	my $child = fork;
	188	die "Can't fork: $!" unless defined($child);
	189	exit if $child;
	190	}
	191
57a87bb3	192	my $restart = 0;
31b426c0	193	local $SIG{CHLD} = 'IGNORE';
fbcc39ad	194
1cf1c56a	195	my $allowed = $options->{allowed} \|\| { '127.0.0.1' => '255.255.255.255' };
6c7a1d2f	196	my $addr = $host ? inet_aton($host) : INADDR_ANY;
6c7a1d2f	197	if ( $addr eq INADDR_ANY ) {
fbcc39ad	198	require Sys::Hostname;
6c7a1d2f	199	$host = lc Sys::Hostname::hostname();
fbcc39ad	200	}
fbcc39ad	201	else {
6c7a1d2f	202	$host = gethostbyaddr( $addr, AF_INET ) \|\| inet_ntoa($addr);
fbcc39ad	203	}
6c7a1d2f	204
	205	# Handle requests
	206
	207	# Setup socket
	208	my $daemon = IO::Socket::INET->new(
	209	Listen => SOMAXCONN,
	210	LocalAddr => inet_ntoa($addr),
	211	LocalPort => $port,
	212	Proto => 'tcp',
	213	ReuseAddr => 1,
	214	Type => SOCK_STREAM,
	215	)
	216	or die "Couldn't create daemon: $!";
	217
	218	my $url = "http://$host";
	219	$url .= ":$port" unless $port == 80;
	220
fbcc39ad	221	print "You can connect to your server at $url\n";
fbcc39ad	222
e1576f62	223	if ($options->{background}) {
	224	open STDIN, "+</dev/null" or die $!;
	225	open STDOUT, ">&STDIN" or die $!;
	226	open STDERR, ">&STDIN" or die $!;
	227	if ( $^O !~ /MSWin32/ ) {
	228	require POSIX;
	229	POSIX::setsid()
	230	or die "Can't start a new session: $!";
	231	}
	232	}
	233
	234	if (my $pidfile = $options->{pidfile}) {
	235	if (! open PIDFILE, "> $pidfile") {
	236	warn("Cannot open: $pidfile: $!");
	237	}
	238	print PIDFILE "$$\n";
	239	close PIDFILE;
	240	}
	241
4bb8bd62	242	my $pid = undef;
	243
	244	# Ignore broken pipes as an HTTP server should
	245	local $SIG{PIPE} = 'IGNORE';
	246
b095458a	247	# Restart on HUP
	248	local $SIG{HUP} = sub {
	249	$restart = 1;
	250	warn "Restarting server on SIGHUP...\n";
	251	};
	252
4bb8bd62	253	LISTEN:
	254	while ( !$restart ) {
	255	while ( accept( Remote, $daemon ) ) {
	256	DEBUG && warn "New connection\n";
fbcc39ad	257
4bb8bd62	258	select Remote;
fbcc39ad	259
4bb8bd62	260	Remote->blocking(1);
4bb8bd62	261
7f3c5736	262	# Read until we see all headers
4bb8bd62	263	$self->{inputbuf} = '';
4bb8bd62	264
7f3c5736	265	if ( !$self->_read_headers ) {
	266	# Error reading, give up
	267	next LISTEN;
4bb8bd62	268	}
fbcc39ad	269
4bb8bd62	270	my ( $method, $uri, $protocol ) = $self->_parse_request_line;
	271
	272	DEBUG && warn "Parsed request: $method $uri $protocol\n";
	273
	274	next unless $method;
57a87bb3	275
4bb8bd62	276	unless ( uc($method) eq 'RESTART' ) {
57a87bb3	277
4bb8bd62	278	# Fork
1b45d7e5	279	if ( $options->{fork} ) {
	280	if ( $pid = fork ) {
	281	DEBUG && warn "Forked child $pid\n";
	282	next;
	283	}
	284	}
6c7a1d2f	285
4bb8bd62	286	$self->_handler( $class, $port, $method, $uri, $protocol );
	287
	288	if ( my $error = delete $self->{_write_error} ) {
	289	DEBUG && warn "Write error: $error\n";
	290	close Remote;
1b45d7e5	291
	292	if ( !defined $pid ) {
	293	next LISTEN;
	294	}
4bb8bd62	295	}
fbcc39ad	296
1b45d7e5	297	if ( defined $pid ) {
	298	# Child process, close connection and exit
	299	DEBUG && warn "Child process exiting\n";
	300	$daemon->close;
	301	exit;
	302	}
1cf1c56a	303	}
4bb8bd62	304	else {
	305	my $sockdata = $self->_socket_data( \*Remote );
	306	my $ipaddr = _inet_addr( $sockdata->{peeraddr} );
	307	my $ready = 0;
	308	foreach my $ip ( keys %$allowed ) {
	309	my $mask = $allowed->{$ip};
	310	$ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
	311	last if $ready;
	312	}
	313	if ($ready) {
	314	$restart = 1;
	315	last;
	316	}
1cf1c56a	317	}
4bb8bd62	318	}
	319	continue {
	320	close Remote;
	321	}
fbcc39ad	322	}
4bb8bd62	323
6c7a1d2f	324	$daemon->close;
4bb8bd62	325
4bb8bd62	326	DEBUG && warn "Shutting down\n";
37553dc8	327
57a87bb3	328	if ($restart) {
60c38e3e	329	$SIG{CHLD} = 'DEFAULT';
6844bc1c	330	wait;
e37e3977	331
	332	### if the standalone server was invoked with perl -I .. we will loose
	333	### those include dirs upon re-exec. So add them to PERL5LIB, so they
	334	### are available again for the exec'ed process --kane
	335	use Config;
	336	$ENV{PERL5LIB} .= join $Config{path_sep}, @INC;
	337
1cf1c56a	338	exec $^X . ' "' . $0 . '" ' . join( ' ', @{ $options->{argv} } );
60c38e3e	339	}
57a87bb3	340
57a87bb3	341	exit;
fbcc39ad	342	}
fbcc39ad	343
6c7a1d2f	344	sub _handler {
	345	my ( $self, $class, $port, $method, $uri, $protocol ) = @_;
	346
6c7a1d2f	347	local STDIN = \Remote;
	348	local STDOUT = \Remote;
	349
	350	# We better be careful and just use 1.0
	351	$protocol = '1.0';
	352
	353	my $sockdata = $self->_socket_data( \*Remote );
	354	my %copy_of_env = %ENV;
	355
	356	my $sel = IO::Select->new;
	357	$sel->add( \*STDIN );
3bcb3aae	358
3bcb3aae	359	REQUEST:
683762ca	360	while (1) {
	361	my ( $path, $query_string ) = split /\?/, $uri, 2;
	362
7f3c5736	363	# Initialize CGI environment
	364	local %ENV = (
	365	PATH_INFO => $path \|\| '',
	366	QUERY_STRING => $query_string \|\| '',
	367	REMOTE_ADDR => $sockdata->{peeraddr},
	368	REMOTE_HOST => $sockdata->{peername},
	369	REQUEST_METHOD => $method \|\| '',
	370	SERVER_NAME => $sockdata->{localname},
	371	SERVER_PORT => $port,
	372	SERVER_PROTOCOL => "HTTP/$protocol",
	373	%copy_of_env,
	374	);
cf26c39c	375
7f3c5736	376	# Parse headers
	377	if ( $protocol >= 1 ) {
	378	$self->_parse_headers;
	379	}
6c7a1d2f	380
7f3c5736	381	# Pass flow control to Catalyst
	382	$class->handle_request;
	383
	384	DEBUG && warn "Request done\n";
cf26c39c	385
7f3c5736	386	# Allow keepalive requests, this is a hack but we'll support it until
	387	# the next major release.
	388	if ( delete $self->{_keepalive} ) {
	389
	390	DEBUG && warn "Reusing previous connection for keep-alive request\n";
	391
	392	if ( $sel->can_read(1) ) {
	393	if ( !$self->_read_headers ) {
	394	# Error reading, give up
	395	last REQUEST;
	396	}
	397
	398	( $method, $uri, $protocol ) = $self->_parse_request_line;
	399
	400	DEBUG && warn "Parsed request: $method $uri $protocol\n";
	401
	402	# Force HTTP/1.0
	403	$protocol = '1.0';
	404
	405	next REQUEST;
	406	}
	407
	408	DEBUG && warn "No keep-alive request within 1 second\n";
	409	}
	410
	411	last REQUEST;
	412	}
3bcb3aae	413
7f3c5736	414	DEBUG && warn "Closing connection\n";
06744540	415
06744540	416	close Remote;
3bcb3aae	417	}
3bcb3aae	418
7f3c5736	419	sub _read_headers {
	420	my $self = shift;
	421
	422	while (1) {
	423	my $read = sysread Remote, my $buf, CHUNKSIZE;
	424
	425	if ( !$read ) {
	426	DEBUG && warn "EOF or error: $!\n";
	427	return;
	428	}
	429
	430	DEBUG && warn "Read $read bytes\n";
	431	$self->{inputbuf} .= $buf;
	432	last if $self->{inputbuf} =~ /(\x0D\x0A?\x0D\x0A?\|\x0A\x0D?\x0A\x0D?)/s;
	433	}
	434
	435	return 1;
	436	}
	437
4bb8bd62	438	sub _parse_request_line {
4bb8bd62	439	my $self = shift;
6c7a1d2f	440
4bb8bd62	441	# Parse request line
	442	if ( $self->{inputbuf} !~ s/^(\w+)[ \t]+(\S+)(?:[ \t]+(HTTP\/\d+\.\d+))?[^\012]*\012// ) {
	443	return ();
	444	}
	445
	446	my $method = $1;
	447	my $uri = $2;
	448	my $proto = $3 \|\| 'HTTP/0.9';
	449
	450	return ( $method, $uri, $proto );
6c7a1d2f	451	}
6c7a1d2f	452
4bb8bd62	453	sub _parse_headers {
	454	my $self = shift;
	455
	456	# Copy the buffer for header parsing, and remove the header block
	457	# from the content buffer.
	458	my $buf = $self->{inputbuf};
	459	$self->{inputbuf} =~ s/.*?(\x0D\x0A?\x0D\x0A?\|\x0A\x0D?\x0A\x0D?)//s;
	460
	461	# Parse headers
	462	my $headers = HTTP::Headers->new;
	463	my ($key, $val);
	464	HEADER:
	465	while ( $buf =~ s/^([^\012]*)\012// ) {
	466	$_ = $1;
	467	s/\015$//;
	468	if ( /^([\w\-~]+)\s:\s(.*)/ ) {
	469	$headers->push_header( $key, $val ) if $key;
	470	($key, $val) = ($1, $2);
	471	}
	472	elsif ( /^\s+(.*)/ ) {
	473	$val .= " $1";
	474	}
	475	else {
	476	last HEADER;
	477	}
	478	}
	479	$headers->push_header( $key, $val ) if $key;
	480
	481	DEBUG && warn "Parsed headers: " . dump($headers) . "\n";
6c7a1d2f	482
4bb8bd62	483	# Convert headers into ENV vars
	484	$headers->scan( sub {
	485	my ( $key, $val ) = @_;
	486
	487	$key = uc $key;
	488	$key = 'COOKIE' if $key eq 'COOKIES';
	489	$key =~ tr/-/_/;
	490	$key = 'HTTP_' . $key
	491	unless $key =~ m/\A(?:CONTENT_(?:LENGTH\|TYPE)\|COOKIE)\z/;
	492
	493	if ( exists $ENV{$key} ) {
	494	$ENV{$key} .= ", $val";
	495	}
	496	else {
	497	$ENV{$key} = $val;
	498	}
	499	} );
6c7a1d2f	500	}
	501
	502	sub _socket_data {
	503	my ( $self, $handle ) = @_;
	504
8b9d0298	505	my $remote_sockaddr = getpeername($handle);
3150d774	506	my ( undef, $iaddr ) = $remote_sockaddr
	507	? sockaddr_in($remote_sockaddr)
	508	: (undef, undef);
	509
8b9d0298	510	my $local_sockaddr = getsockname($handle);
6c7a1d2f	511	my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
6c7a1d2f	512
8b9d0298	513	# This mess is necessary to keep IE from crashing the server
6c7a1d2f	514	my $data = {
8b9d0298	515	peername => $iaddr
	516	? ( gethostbyaddr( $iaddr, AF_INET ) \|\| 'localhost' )
	517	: 'localhost',
	518	peeraddr => $iaddr
	519	? ( inet_ntoa($iaddr) \|\| '127.0.0.1' )
	520	: '127.0.0.1',
	521	localname => gethostbyaddr( $localiaddr, AF_INET ) \|\| 'localhost',
	522	localaddr => inet_ntoa($localiaddr) \|\| '127.0.0.1',
6c7a1d2f	523	};
	524
	525	return $data;
	526	}
	527
1cf1c56a	528	sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }
1cf1c56a	529
45374ac6	530	=head1 SEE ALSO
45374ac6	531
fbcc39ad	532	L<Catalyst>, L<Catalyst::Engine>.
	533
	534	=head1 AUTHORS
	535
	536	Sebastian Riedel, <sri@cpan.org>
	537
	538	Dan Kubb, <dan.kubb-cpan@onautopilot.com>
45374ac6	539
6c7a1d2f	540	Sascha Kiefer, <esskar@cpan.org>
6c7a1d2f	541
4bb8bd62	542	Andy Grundman, <andy@hybridized.org>
4bb8bd62	543
fbcc39ad	544	=head1 THANKS
45374ac6	545
fbcc39ad	546	Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.
45374ac6	547
	548	=head1 COPYRIGHT
	549
	550	This program is free software, you can redistribute it and/or modify it under
	551	the same terms as Perl itself.
	552
	553	=cut
	554
45374ac6	555	1;