[catagits/Catalyst-Runtime.git] / lib / Catalyst / Engine / HTTP.pm

package Catalyst::Engine::HTTP;

use strict;
use base 'Catalyst::Engine::CGI';
use Errno 'EWOULDBLOCK';
use HTTP::Status;
use NEXT;
use Socket;
use IO::Socket::INET ();
use IO::Select       ();

# For PAR
require Catalyst::Engine::HTTP::Restarter;
require Catalyst::Engine::HTTP::Restarter::Watcher;

=head1 NAME

Catalyst::Engine::HTTP - Catalyst HTTP Engine

=head1 SYNOPSIS

A script using the Catalyst::Engine::HTTP module might look like:

    #!/usr/bin/perl -w

    BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }

    use strict;
    use lib '/path/to/MyApp/lib';
    use MyApp;

    MyApp->run;

=head1 DESCRIPTION

This is the Catalyst engine specialized for development and testing.

=head1 METHODS

=head2 $self->finalize_headers($c)

=cut

sub finalize_headers {
    my ( $self, $c ) = @_;
    my $protocol = $c->request->protocol;
    my $status   = $c->response->status;
    my $message  = status_message($status);
    print "$protocol $status $message\015\012";
    $c->response->headers->date(time);
    $c->response->headers->header(
        Connection => $self->_keep_alive ? 'keep-alive' : 'close' );
        
    $c->response->header( Status => $c->response->status );
        
    # Avoid 'print() on closed filehandle Remote' warnings when using IE
    print $c->response->headers->as_string("\015\012") if *STDOUT->opened();
    print "\015\012" if *STDOUT->opened();
}

=head2 $self->finalize_read($c)

=cut

sub finalize_read {
    my ( $self, $c ) = @_;

    # Never ever remove this, it would result in random length output
    # streams if STDIN eq STDOUT (like in the HTTP engine)
    *STDIN->blocking(1);

    return $self->NEXT::finalize_read($c);
}

=head2 $self->prepare_read($c)

=cut

sub prepare_read {
    my ( $self, $c ) = @_;

    # Set the input handle to non-blocking
    *STDIN->blocking(0);

    return $self->NEXT::prepare_read($c);
}

=head2 $self->read_chunk($c, $buffer, $length)

=cut

sub read_chunk {
    my $self = shift;
    my $c    = shift;

    # support for non-blocking IO
    my $rin = '';
    vec( $rin, *STDIN->fileno, 1 ) = 1;

  READ:
    {
        select( $rin, undef, undef, undef );
        my $rc = *STDIN->sysread(@_);
        if ( defined $rc ) {
            return $rc;
        }
        else {
            next READ if $! == EWOULDBLOCK;
            return;
        }
    }
}

=head2 $self->write($c, $buffer)

Writes the buffer to the client. Can only be called once for a request.

=cut

sub write {
	# Avoid 'print() on closed filehandle Remote' warnings when using IE
	return unless *STDOUT->opened();
	
	shift->NEXT::write( @_ );
}

=head2 run

=cut

# A very very simple HTTP server that initializes a CGI environment
sub run {
    my ( $self, $class, $port, $host, $options ) = @_;

    $options ||= {};

    if ($options->{background}) {
        my $child = fork;
        die "Can't fork: $!" unless defined($child);
        exit if $child;
    }

    my $restart = 0;
    local $SIG{CHLD} = 'IGNORE';

    my $allowed = $options->{allowed} || { '127.0.0.1' => '255.255.255.255' };
    my $addr = $host ? inet_aton($host) : INADDR_ANY;
    if ( $addr eq INADDR_ANY ) {
        require Sys::Hostname;
        $host = lc Sys::Hostname::hostname();
    }
    else {
        $host = gethostbyaddr( $addr, AF_INET ) || inet_ntoa($addr);
    }

    # Handle requests

    # Setup socket
    my $daemon = IO::Socket::INET->new(
        Listen    => SOMAXCONN,
        LocalAddr => inet_ntoa($addr),
        LocalPort => $port,
        Proto     => 'tcp',
        ReuseAddr => 1,
        Type      => SOCK_STREAM,
      )
      or die "Couldn't create daemon: $!";

    my $url = "http://$host";
    $url .= ":$port" unless $port == 80;

    print "You can connect to your server at $url\n";

    if ($options->{background}) {
        open STDIN,  "+</dev/null" or die $!;
        open STDOUT, ">&STDIN"     or die $!;
        open STDERR, ">&STDIN"     or die $!;
        if ( $^O !~ /MSWin32/ ) {
             require POSIX;
             POSIX::setsid()
                 or die "Can't start a new session: $!";
        }
    }

    if (my $pidfile = $options->{pidfile}) {
        if (! open PIDFILE, "> $pidfile") {
            warn("Cannot open: $pidfile: $!");
        }
        print PIDFILE "$$\n";
        close PIDFILE;
    }

    $self->_keep_alive( $options->{keepalive} || 0 );

    my $pid    = undef;
    while ( accept( Remote, $daemon ) )
    {    # TODO: get while ( my $remote = $daemon->accept ) to work

        select Remote;

        # Request data

        Remote->blocking(1);

        next
          unless my ( $method, $uri, $protocol ) =
          $self->_parse_request_line( \*Remote );

        unless ( uc($method) eq 'RESTART' ) {

            # Fork
            if ( $options->{fork} ) { next if $pid = fork }

            $self->_handler( $class, $port, $method, $uri, $protocol );

            $daemon->close if defined $pid;

        }
        else {
            my $sockdata = $self->_socket_data( \*Remote );
            my $ipaddr   = _inet_addr( $sockdata->{peeraddr} );
            my $ready    = 0;
            foreach my $ip ( keys %$allowed ) {
                my $mask = $allowed->{$ip};
                $ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
                last if $ready;
            }
            if ($ready) {
                $restart = 1;
                last;
            }
        }

        exit if defined $pid;
    }
    continue {
        close Remote;
    }
    $daemon->close;

    if ($restart) {
        $SIG{CHLD} = 'DEFAULT';
        wait;

        ### if the standalone server was invoked with perl -I .. we will loose
        ### those include dirs upon re-exec. So add them to PERL5LIB, so they
        ### are available again for the exec'ed process --kane
        use Config;
        $ENV{PERL5LIB} .= join $Config{path_sep}, @INC; 
        
        exec $^X . ' "' . $0 . '" ' . join( ' ', @{ $options->{argv} } );
    }

    exit;
}

sub _handler {
    my ( $self, $class, $port, $method, $uri, $protocol ) = @_;

    # Ignore broken pipes as an HTTP server should
    local $SIG{PIPE} = sub { close Remote };

    local *STDIN  = \*Remote;
    local *STDOUT = \*Remote;

    # We better be careful and just use 1.0
    $protocol = '1.0';

    my $sockdata    = $self->_socket_data( \*Remote );
    my %copy_of_env = %ENV;

    my $sel = IO::Select->new;
    $sel->add( \*STDIN );

    while (1) {
        my ( $path, $query_string ) = split /\?/, $uri, 2;

        # Initialize CGI environment
        local %ENV = (
            PATH_INFO    => $path         || '',
            QUERY_STRING => $query_string || '',
            REMOTE_ADDR     => $sockdata->{peeraddr},
            REMOTE_HOST     => $sockdata->{peername},
            REQUEST_METHOD  => $method || '',
            SERVER_NAME     => $sockdata->{localname},
            SERVER_PORT     => $port,
            SERVER_PROTOCOL => "HTTP/$protocol",
            %copy_of_env,
        );

        # Parse headers
        if ( $protocol >= 1 ) {
            while (1) {
                my $line = $self->_get_line( \*STDIN );
                last if $line eq '';
                next
                  unless my ( $name, $value ) =
                  $line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;

                $name = uc $name;
                $name = 'COOKIE' if $name eq 'COOKIES';
                $name =~ tr/-/_/;
                $name = 'HTTP_' . $name
                  unless $name =~ m/\A(?:CONTENT_(?:LENGTH|TYPE)|COOKIE)\z/;
                if ( exists $ENV{$name} ) {
                    $ENV{$name} .= ", $value";
                }
                else {
                    $ENV{$name} = $value;
                }
            }
        }

        # Pass flow control to Catalyst
        $class->handle_request;

        my $connection = lc $ENV{HTTP_CONNECTION};
        last
          unless $self->_keep_alive()
          && index( $connection, 'keep-alive' ) > -1
          && index( $connection, 'te' ) == -1          # opera stuff
          && $sel->can_read(5);

        last
          unless ( $method, $uri, $protocol ) =
          $self->_parse_request_line( \*STDIN );
    }

    close Remote;
}

sub _keep_alive {
    my ( $self, $keepalive ) = @_;

    my $r = $self->{_keepalive} || 0;
    $self->{_keepalive} = $keepalive if defined $keepalive;

    return $r;

}

sub _parse_request_line {
    my ( $self, $handle ) = @_;

    # Parse request line
    my $line = $self->_get_line($handle);
    return ()
      unless my ( $method, $uri, $protocol ) =
      $line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;
    return ( $method, $uri, $protocol );
}

sub _socket_data {
    my ( $self, $handle ) = @_;

    my $remote_sockaddr       = getpeername($handle);
    my ( undef, $iaddr )      = $remote_sockaddr 
        ? sockaddr_in($remote_sockaddr) 
        : (undef, undef);
        
    my $local_sockaddr        = getsockname($handle);
    my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);

    # This mess is necessary to keep IE from crashing the server
    my $data = {
        peername  => $iaddr 
            ? ( gethostbyaddr( $iaddr, AF_INET ) || 'localhost' )
            : 'localhost',
        peeraddr  => $iaddr 
            ? ( inet_ntoa($iaddr) || '127.0.0.1' )
            : '127.0.0.1',
        localname => gethostbyaddr( $localiaddr, AF_INET ) || 'localhost',
        localaddr => inet_ntoa($localiaddr) || '127.0.0.1',
    };

    return $data;
}

sub _get_line {
    my ( $self, $handle ) = @_;

    my $line = '';

    while ( sysread( $handle, my $byte, 1 ) ) {
        last if $byte eq "\012";    # eol
        $line .= $byte;
    }

    1 while $line =~ s/\s\z//;

    return $line;
}

sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }

=head1 SEE ALSO

L<Catalyst>, L<Catalyst::Engine>.

=head1 AUTHORS

Sebastian Riedel, <sri@cpan.org>

Dan Kubb, <dan.kubb-cpan@onautopilot.com>

Sascha Kiefer, <esskar@cpan.org>

=head1 THANKS

Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.

=head1 COPYRIGHT

This program is free software, you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
Commit	Line	Data
ca61af20	1	package Catalyst::Engine::HTTP;
45374ac6	2
45374ac6	3	use strict;
fbcc39ad	4	use base 'Catalyst::Engine::CGI';
	5	use Errno 'EWOULDBLOCK';
	6	use HTTP::Status;
	7	use NEXT;
	8	use Socket;
6c7a1d2f	9	use IO::Socket::INET ();
b5ecfcf0	10	use IO::Select ();
45374ac6	11
71fd2e0f	12	# For PAR
	13	require Catalyst::Engine::HTTP::Restarter;
	14	require Catalyst::Engine::HTTP::Restarter::Watcher;
	15
45374ac6	16	=head1 NAME
45374ac6	17
ca61af20	18	Catalyst::Engine::HTTP - Catalyst HTTP Engine
45374ac6	19
	20	=head1 SYNOPSIS
	21
ca61af20	22	A script using the Catalyst::Engine::HTTP module might look like:
45374ac6	23
	24	#!/usr/bin/perl -w
	25
ca61af20	26	BEGIN { $ENV{CATALYST_ENGINE} = 'HTTP' }
45374ac6	27
	28	use strict;
	29	use lib '/path/to/MyApp/lib';
	30	use MyApp;
	31
	32	MyApp->run;
	33
	34	=head1 DESCRIPTION
	35
	36	This is the Catalyst engine specialized for development and testing.
	37
fbcc39ad	38	=head1 METHODS
fbcc39ad	39
b5ecfcf0	40	=head2 $self->finalize_headers($c)
fbcc39ad	41
	42	=cut
	43
	44	sub finalize_headers {
	45	my ( $self, $c ) = @_;
	46	my $protocol = $c->request->protocol;
	47	my $status = $c->response->status;
	48	my $message = status_message($status);
	49	print "$protocol $status $message\015\012";
	50	$c->response->headers->date(time);
6c7a1d2f	51	$c->response->headers->header(
6c7a1d2f	52	Connection => $self->_keep_alive ? 'keep-alive' : 'close' );
00c99324	53
	54	$c->response->header( Status => $c->response->status );
	55
	56	# Avoid 'print() on closed filehandle Remote' warnings when using IE
	57	print $c->response->headers->as_string("\015\012") if *STDOUT->opened();
	58	print "\015\012" if *STDOUT->opened();
fbcc39ad	59	}
fbcc39ad	60
b5ecfcf0	61	=head2 $self->finalize_read($c)
fbcc39ad	62
	63	=cut
	64
	65	sub finalize_read {
	66	my ( $self, $c ) = @_;
	67
	68	# Never ever remove this, it would result in random length output
	69	# streams if STDIN eq STDOUT (like in the HTTP engine)
4f5ebacd	70	*STDIN->blocking(1);
fbcc39ad	71
	72	return $self->NEXT::finalize_read($c);
	73	}
	74
b5ecfcf0	75	=head2 $self->prepare_read($c)
fbcc39ad	76
	77	=cut
	78
	79	sub prepare_read {
	80	my ( $self, $c ) = @_;
	81
	82	# Set the input handle to non-blocking
4f5ebacd	83	*STDIN->blocking(0);
fbcc39ad	84
	85	return $self->NEXT::prepare_read($c);
	86	}
	87
b5ecfcf0	88	=head2 $self->read_chunk($c, $buffer, $length)
fbcc39ad	89
	90	=cut
	91
	92	sub read_chunk {
	93	my $self = shift;
	94	my $c = shift;
	95
	96	# support for non-blocking IO
4f5ebacd	97	my $rin = '';
4f5ebacd	98	vec( $rin, *STDIN->fileno, 1 ) = 1;
fbcc39ad	99
	100	READ:
	101	{
	102	select( $rin, undef, undef, undef );
4f5ebacd	103	my $rc = *STDIN->sysread(@_);
fbcc39ad	104	if ( defined $rc ) {
	105	return $rc;
	106	}
	107	else {
	108	next READ if $! == EWOULDBLOCK;
	109	return;
	110	}
	111	}
	112	}
	113
00c99324	114	=head2 $self->write($c, $buffer)
	115
	116	Writes the buffer to the client. Can only be called once for a request.
	117
	118	=cut
	119
	120	sub write {
	121	# Avoid 'print() on closed filehandle Remote' warnings when using IE
	122	return unless *STDOUT->opened();
	123
	124	shift->NEXT::write( @_ );
	125	}
	126
b5ecfcf0	127	=head2 run
fbcc39ad	128
	129	=cut
	130
	131	# A very very simple HTTP server that initializes a CGI environment
	132	sub run {
37553dc8	133	my ( $self, $class, $port, $host, $options ) = @_;
fbcc39ad	134
4eeca0f2	135	$options \|\|= {};
1cf1c56a	136
e1576f62	137	if ($options->{background}) {
	138	my $child = fork;
	139	die "Can't fork: $!" unless defined($child);
	140	exit if $child;
	141	}
	142
57a87bb3	143	my $restart = 0;
31b426c0	144	local $SIG{CHLD} = 'IGNORE';
fbcc39ad	145
1cf1c56a	146	my $allowed = $options->{allowed} \|\| { '127.0.0.1' => '255.255.255.255' };
6c7a1d2f	147	my $addr = $host ? inet_aton($host) : INADDR_ANY;
6c7a1d2f	148	if ( $addr eq INADDR_ANY ) {
fbcc39ad	149	require Sys::Hostname;
6c7a1d2f	150	$host = lc Sys::Hostname::hostname();
fbcc39ad	151	}
fbcc39ad	152	else {
6c7a1d2f	153	$host = gethostbyaddr( $addr, AF_INET ) \|\| inet_ntoa($addr);
fbcc39ad	154	}
6c7a1d2f	155
	156	# Handle requests
	157
	158	# Setup socket
	159	my $daemon = IO::Socket::INET->new(
	160	Listen => SOMAXCONN,
	161	LocalAddr => inet_ntoa($addr),
	162	LocalPort => $port,
	163	Proto => 'tcp',
	164	ReuseAddr => 1,
	165	Type => SOCK_STREAM,
	166	)
	167	or die "Couldn't create daemon: $!";
	168
	169	my $url = "http://$host";
	170	$url .= ":$port" unless $port == 80;
	171
fbcc39ad	172	print "You can connect to your server at $url\n";
fbcc39ad	173
e1576f62	174	if ($options->{background}) {
	175	open STDIN, "+</dev/null" or die $!;
	176	open STDOUT, ">&STDIN" or die $!;
	177	open STDERR, ">&STDIN" or die $!;
	178	if ( $^O !~ /MSWin32/ ) {
	179	require POSIX;
	180	POSIX::setsid()
	181	or die "Can't start a new session: $!";
	182	}
	183	}
	184
	185	if (my $pidfile = $options->{pidfile}) {
	186	if (! open PIDFILE, "> $pidfile") {
	187	warn("Cannot open: $pidfile: $!");
	188	}
	189	print PIDFILE "$$\n";
	190	close PIDFILE;
	191	}
	192
6c7a1d2f	193	$self->_keep_alive( $options->{keepalive} \|\| 0 );
6c7a1d2f	194
57a87bb3	195	my $pid = undef;
6c7a1d2f	196	while ( accept( Remote, $daemon ) )
6c7a1d2f	197	{ # TODO: get while ( my $remote = $daemon->accept ) to work
fbcc39ad	198
57a87bb3	199	select Remote;
fbcc39ad	200
fbcc39ad	201	# Request data
fbcc39ad	202
57a87bb3	203	Remote->blocking(1);
fbcc39ad	204
fbcc39ad	205	next
fbcc39ad	206	unless my ( $method, $uri, $protocol ) =
6c7a1d2f	207	$self->_parse_request_line( \*Remote );
fbcc39ad	208
57a87bb3	209	unless ( uc($method) eq 'RESTART' ) {
	210
	211	# Fork
	212	if ( $options->{fork} ) { next if $pid = fork }
	213
6c7a1d2f	214	$self->_handler( $class, $port, $method, $uri, $protocol );
	215
	216	$daemon->close if defined $pid;
fbcc39ad	217
1cf1c56a	218	}
1cf1c56a	219	else {
6c7a1d2f	220	my $sockdata = $self->_socket_data( \*Remote );
	221	my $ipaddr = _inet_addr( $sockdata->{peeraddr} );
	222	my $ready = 0;
c82ed742	223	foreach my $ip ( keys %$allowed ) {
c82ed742	224	my $mask = $allowed->{$ip};
1cf1c56a	225	$ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
c82ed742	226	last if $ready;
1cf1c56a	227	}
1cf1c56a	228	if ($ready) {
57a87bb3	229	$restart = 1;
1cf1c56a	230	last;
	231	}
	232	}
57a87bb3	233
fbcc39ad	234	exit if defined $pid;
	235	}
	236	continue {
	237	close Remote;
	238	}
6c7a1d2f	239	$daemon->close;
37553dc8	240
57a87bb3	241	if ($restart) {
60c38e3e	242	$SIG{CHLD} = 'DEFAULT';
6844bc1c	243	wait;
e37e3977	244
	245	### if the standalone server was invoked with perl -I .. we will loose
	246	### those include dirs upon re-exec. So add them to PERL5LIB, so they
	247	### are available again for the exec'ed process --kane
	248	use Config;
	249	$ENV{PERL5LIB} .= join $Config{path_sep}, @INC;
	250
1cf1c56a	251	exec $^X . ' "' . $0 . '" ' . join( ' ', @{ $options->{argv} } );
60c38e3e	252	}
57a87bb3	253
57a87bb3	254	exit;
fbcc39ad	255	}
fbcc39ad	256
6c7a1d2f	257	sub _handler {
	258	my ( $self, $class, $port, $method, $uri, $protocol ) = @_;
	259
	260	# Ignore broken pipes as an HTTP server should
	261	local $SIG{PIPE} = sub { close Remote };
	262
	263	local STDIN = \Remote;
	264	local STDOUT = \Remote;
	265
	266	# We better be careful and just use 1.0
	267	$protocol = '1.0';
	268
	269	my $sockdata = $self->_socket_data( \*Remote );
	270	my %copy_of_env = %ENV;
	271
	272	my $sel = IO::Select->new;
	273	$sel->add( \*STDIN );
	274
	275	while (1) {
	276	my ( $path, $query_string ) = split /\?/, $uri, 2;
	277
	278	# Initialize CGI environment
	279	local %ENV = (
b5ecfcf0	280	PATH_INFO => $path \|\| '',
b5ecfcf0	281	QUERY_STRING => $query_string \|\| '',
6c7a1d2f	282	REMOTE_ADDR => $sockdata->{peeraddr},
	283	REMOTE_HOST => $sockdata->{peername},
	284	REQUEST_METHOD => $method \|\| '',
	285	SERVER_NAME => $sockdata->{localname},
	286	SERVER_PORT => $port,
	287	SERVER_PROTOCOL => "HTTP/$protocol",
	288	%copy_of_env,
	289	);
	290
	291	# Parse headers
	292	if ( $protocol >= 1 ) {
	293	while (1) {
	294	my $line = $self->_get_line( \*STDIN );
	295	last if $line eq '';
	296	next
	297	unless my ( $name, $value ) =
	298	$line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;
	299
	300	$name = uc $name;
	301	$name = 'COOKIE' if $name eq 'COOKIES';
	302	$name =~ tr/-/_/;
	303	$name = 'HTTP_' . $name
	304	unless $name =~ m/\A(?:CONTENT_(?:LENGTH\|TYPE)\|COOKIE)\z/;
	305	if ( exists $ENV{$name} ) {
ace55b07	306	$ENV{$name} .= ", $value";
6c7a1d2f	307	}
	308	else {
	309	$ENV{$name} = $value;
	310	}
	311	}
	312	}
	313
	314	# Pass flow control to Catalyst
	315	$class->handle_request;
	316
	317	my $connection = lc $ENV{HTTP_CONNECTION};
	318	last
	319	unless $self->_keep_alive()
	320	&& index( $connection, 'keep-alive' ) > -1
	321	&& index( $connection, 'te' ) == -1 # opera stuff
	322	&& $sel->can_read(5);
	323
	324	last
	325	unless ( $method, $uri, $protocol ) =
	326	$self->_parse_request_line( \*STDIN );
	327	}
	328
	329	close Remote;
	330	}
	331
	332	sub _keep_alive {
	333	my ( $self, $keepalive ) = @_;
	334
	335	my $r = $self->{_keepalive} \|\| 0;
	336	$self->{_keepalive} = $keepalive if defined $keepalive;
	337
	338	return $r;
	339
	340	}
	341
	342	sub _parse_request_line {
	343	my ( $self, $handle ) = @_;
	344
	345	# Parse request line
	346	my $line = $self->_get_line($handle);
	347	return ()
	348	unless my ( $method, $uri, $protocol ) =
	349	$line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;
	350	return ( $method, $uri, $protocol );
	351	}
	352
	353	sub _socket_data {
	354	my ( $self, $handle ) = @_;
	355
8b9d0298	356	my $remote_sockaddr = getpeername($handle);
3150d774	357	my ( undef, $iaddr ) = $remote_sockaddr
	358	? sockaddr_in($remote_sockaddr)
	359	: (undef, undef);
	360
8b9d0298	361	my $local_sockaddr = getsockname($handle);
6c7a1d2f	362	my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
6c7a1d2f	363
8b9d0298	364	# This mess is necessary to keep IE from crashing the server
6c7a1d2f	365	my $data = {
8b9d0298	366	peername => $iaddr
	367	? ( gethostbyaddr( $iaddr, AF_INET ) \|\| 'localhost' )
	368	: 'localhost',
	369	peeraddr => $iaddr
	370	? ( inet_ntoa($iaddr) \|\| '127.0.0.1' )
	371	: '127.0.0.1',
	372	localname => gethostbyaddr( $localiaddr, AF_INET ) \|\| 'localhost',
	373	localaddr => inet_ntoa($localiaddr) \|\| '127.0.0.1',
6c7a1d2f	374	};
	375
	376	return $data;
	377	}
	378
fbcc39ad	379	sub _get_line {
	380	my ( $self, $handle ) = @_;
	381
	382	my $line = '';
	383
	384	while ( sysread( $handle, my $byte, 1 ) ) {
	385	last if $byte eq "\012"; # eol
	386	$line .= $byte;
	387	}
	388
	389	1 while $line =~ s/\s\z//;
	390
	391	return $line;
	392	}
	393
1cf1c56a	394	sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }
1cf1c56a	395
45374ac6	396	=head1 SEE ALSO
45374ac6	397
fbcc39ad	398	L<Catalyst>, L<Catalyst::Engine>.
	399
	400	=head1 AUTHORS
	401
	402	Sebastian Riedel, <sri@cpan.org>
	403
	404	Dan Kubb, <dan.kubb-cpan@onautopilot.com>
45374ac6	405
6c7a1d2f	406	Sascha Kiefer, <esskar@cpan.org>
6c7a1d2f	407
fbcc39ad	408	=head1 THANKS
45374ac6	409
fbcc39ad	410	Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.
45374ac6	411
	412	=head1 COPYRIGHT
	413
	414	This program is free software, you can redistribute it and/or modify it under
	415	the same terms as Perl itself.
	416
	417	=cut
	418
45374ac6	419	1;