[catagits/Catalyst-Runtime.git] / lib / Catalyst / Engine / HTTP.pm

package Catalyst::Engine::HTTP;

use strict;
use base 'Catalyst::Engine::CGI';
use Errno 'EWOULDBLOCK';
use FindBin;
use File::Find;
use File::Spec;
use HTTP::Status;
use NEXT;
use Socket;

=head1 NAME

Catalyst::Engine::HTTP - Catalyst HTTP Engine

=head1 SYNOPSIS

A script using the Catalyst::Engine::HTTP module might look like:

    #!/usr/bin/perl -w

    BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }

    use strict;
    use lib '/path/to/MyApp/lib';
    use MyApp;

    MyApp->run;

=head1 DESCRIPTION

This is the Catalyst engine specialized for development and testing.

=head1 METHODS

=over 4

=item $self->finalize_headers($c)

=cut

sub finalize_headers {
    my ( $self, $c ) = @_;
    my $protocol = $c->request->protocol;
    my $status   = $c->response->status;
    my $message  = status_message($status);
    print "$protocol $status $message\015\012";
    $c->response->headers->date(time);
    $self->NEXT::finalize_headers($c);
}

=item $self->finalize_read($c)

=cut

sub finalize_read {
    my ( $self, $c ) = @_;

    # Never ever remove this, it would result in random length output
    # streams if STDIN eq STDOUT (like in the HTTP engine)
    *STDIN->blocking(1);

    return $self->NEXT::finalize_read($c);
}

=item $self->prepare_read($c)

=cut

sub prepare_read {
    my ( $self, $c ) = @_;

    # Set the input handle to non-blocking
    *STDIN->blocking(0);

    return $self->NEXT::prepare_read($c);
}

=item $self->read_chunk($c, $buffer, $length)

=cut

sub read_chunk {
    my $self = shift;
    my $c    = shift;

    # support for non-blocking IO
    my $rin = '';
    vec( $rin, *STDIN->fileno, 1 ) = 1;

  READ:
    {
        select( $rin, undef, undef, undef );
        my $rc = *STDIN->sysread(@_);
        if ( defined $rc ) {
            return $rc;
        }
        else {
            next READ if $! == EWOULDBLOCK;
            return;
        }
    }
}

=item run

=cut

# A very very simple HTTP server that initializes a CGI environment
sub run {
    my ( $self, $class, $port, $host, $options ) = @_;

    our $GOT_HUP;
    local $GOT_HUP = 0;

    local $SIG{HUP} = sub { $GOT_HUP = 1; };
    local $SIG{CHLD} = 'IGNORE';

    # Setup restarter
    my $restarter;
    if ( $options->{restart} ) {
        my $parent = $$;
        unless ( $restarter = fork ) {

            # Prepare
            close STDIN;
            close STDOUT;

            # Index parent directory
            my $dir = File::Spec->catdir( $FindBin::Bin, '..' );

            my $regex = $options->{restart_regex};
            my $one   = _index( $dir, $regex );
          RESTART: while (1) {
                sleep $options->{restart_delay};
                my $two     = _index( $dir,         $regex );
                my $changes = _compare_index( $one, $two );
                if (@$changes) {
                    $one = $two;

                    # Test modified pm's
                    for my $file (@$changes) {
                        next unless $file =~ /\.pm$/;
                        if ( my $error = _test($file) ) {
                            print STDERR
                              qq/File "$file" modified, not restarting\n\n/;
                            print STDERR '*' x 80, "\n";
                            print STDERR $error;
                            print STDERR '*' x 80, "\n";
                            next RESTART;
                        }
                    }

                    # Restart
                    my $files = join ', ', @$changes;
                    print STDERR qq/File(s) "$files" modified, restarting\n\n/;
                    kill( 1, $parent );
                    exit;
                }
            }
        }
    }

    # Handle requests

    # Setup socket
    $host = $host ? inet_aton($host) : INADDR_ANY;
    socket( HTTPDaemon, PF_INET, SOCK_STREAM, getprotobyname('tcp') );
    setsockopt( HTTPDaemon, SOL_SOCKET, SO_REUSEADDR, pack( "l", 1 ) );
    bind( HTTPDaemon, sockaddr_in( $port, $host ) );
    listen( HTTPDaemon, SOMAXCONN );
    my $url = 'http://';
    if ( $host eq INADDR_ANY ) {
        require Sys::Hostname;
        $url .= lc Sys::Hostname::hostname();
    }
    else {
        $url .= gethostbyaddr( $host, AF_INET ) || inet_ntoa($host);
    }
    $url .= ":$port";
    print "You can connect to your server at $url\n";
    my $pid = undef;
    while ( accept( Remote, HTTPDaemon ) ) {

        # Fork
        if ( $options->{fork} ) { next if $pid = fork }

        close HTTPDaemon if defined $pid;

        # Ignore broken pipes as an HTTP server should
        local $SIG{PIPE} = sub { close Remote };
        local $SIG{HUP} = ( defined $pid ? 'IGNORE' : $SIG{HUP} );

        local *STDIN  = \*Remote;
        local *STDOUT = \*Remote;
        select STDOUT;

        # Request data
        my $remote_sockaddr = getpeername( \*Remote );
        my ( undef, $iaddr ) = sockaddr_in($remote_sockaddr);
        my $peername = gethostbyaddr( $iaddr, AF_INET ) || "localhost";
        my $peeraddr = inet_ntoa($iaddr) || "127.0.0.1";
        my $local_sockaddr = getsockname( \*Remote );
        my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
        my $localname = gethostbyaddr( $localiaddr, AF_INET )
          || "localhost";
        my $localaddr = inet_ntoa($localiaddr) || "127.0.0.1";

        STDIN->blocking(1);

        # Parse request line
        my $line = $self->_get_line( \*STDIN );
        next
          unless my ( $method, $uri, $protocol ) =
          $line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;

        # We better be careful and just use 1.0
        $protocol = '1.0';

        my ( $path, $query_string ) = split /\?/, $uri, 2;

        # Initialize CGI environment
        local %ENV = (
            PATH_INFO      => $path         || '',
            QUERY_STRING   => $query_string || '',
            REMOTE_ADDR    => $peeraddr,
            REMOTE_HOST    => $peername,
            REQUEST_METHOD => $method       || '',
            SERVER_NAME    => $localname,
            SERVER_PORT    => $port,
            SERVER_PROTOCOL => "HTTP/$protocol",
            %ENV,
        );

        # Parse headers
        if ( $protocol >= 1 ) {
            while (1) {
                my $line = $self->_get_line( \*STDIN );
                last if $line eq '';
                next
                  unless my ( $name, $value ) =
                  $line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;

                $name = uc $name;
                $name = 'COOKIE' if $name eq 'COOKIES';
                $name =~ tr/-/_/;
                $name = 'HTTP_' . $name
                  unless $name =~ m/\A(?:CONTENT_(?:LENGTH|TYPE)|COOKIE)\z/;
                if ( exists $ENV{$name} ) {
                    $ENV{$name} .= "; $value";
                }
                else {
                    $ENV{$name} = $value;
                }
            }
        }

        # Pass flow control to Catalyst
        $class->handle_request;
        exit if defined $pid;
    }
    continue {
        close Remote;
    }
    close HTTPDaemon;

    if ($GOT_HUP) {
        $SIG{CHLD} = 'DEFAULT';
        wait;
        exec {$0}( ( ( -x $0 ) ? () : ($^X) ), $0, @{ $options->{argv} } );
    }
}

sub _compare_index {
    my ( $one, $two ) = @_;
    my %clone = %$two;
    my @changes;
    while ( my ( $key, $val ) = each %$one ) {
        if ( !$clone{$key} || ( $clone{$key} ne $val ) ) {
            push @changes, $key;
        }
        delete $clone{$key};
    }
    for my $key ( keys %clone ) { push @changes, $key }
    return \@changes;
}

sub _get_line {
    my ( $self, $handle ) = @_;

    my $line = '';

    while ( sysread( $handle, my $byte, 1 ) ) {
        last if $byte eq "\012";    # eol
        $line .= $byte;
    }

    1 while $line =~ s/\s\z//;

    return $line;
}

sub _index {
    my ( $dir, $regex ) = @_;
    my %index;
    finddepth(
        {
            wanted => sub {
                my $file = File::Spec->rel2abs($File::Find::name);
                return unless $file =~ /$regex/;
                return unless -f $file;
                my $time = ( stat $file )[9];
                $index{$file} = $time;
            },
            no_chdir => 1
        },
        $dir
    );
    return \%index;
}

sub _test {
    my $file = shift;
    delete $INC{$file};
    local $SIG{__WARN__} = sub { };
    open my $olderr, '>&STDERR';
    open STDERR, '>', File::Spec->devnull;
    eval "require '$file'";
    open STDERR, '>&', $olderr;
    return $@ if $@;
    return 0;
}

=back

=head1 SEE ALSO

L<Catalyst>, L<Catalyst::Engine>.

=head1 AUTHORS

Sebastian Riedel, <sri@cpan.org>

Dan Kubb, <dan.kubb-cpan@onautopilot.com>

=head1 THANKS

Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.

=head1 COPYRIGHT

This program is free software, you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
Commit	Line	Data
ca61af20	1	package Catalyst::Engine::HTTP;
45374ac6	2
45374ac6	3	use strict;
fbcc39ad	4	use base 'Catalyst::Engine::CGI';
fbcc39ad	5	use Errno 'EWOULDBLOCK';
37553dc8	6	use FindBin;
	7	use File::Find;
	8	use File::Spec;
fbcc39ad	9	use HTTP::Status;
	10	use NEXT;
	11	use Socket;
45374ac6	12
	13	=head1 NAME
	14
ca61af20	15	Catalyst::Engine::HTTP - Catalyst HTTP Engine
45374ac6	16
	17	=head1 SYNOPSIS
	18
ca61af20	19	A script using the Catalyst::Engine::HTTP module might look like:
45374ac6	20
	21	#!/usr/bin/perl -w
	22
ca61af20	23	BEGIN { $ENV{CATALYST_ENGINE} = 'HTTP' }
45374ac6	24
	25	use strict;
	26	use lib '/path/to/MyApp/lib';
	27	use MyApp;
	28
	29	MyApp->run;
	30
	31	=head1 DESCRIPTION
	32
	33	This is the Catalyst engine specialized for development and testing.
	34
fbcc39ad	35	=head1 METHODS
	36
	37	=over 4
	38
	39	=item $self->finalize_headers($c)
	40
	41	=cut
	42
	43	sub finalize_headers {
	44	my ( $self, $c ) = @_;
	45	my $protocol = $c->request->protocol;
	46	my $status = $c->response->status;
	47	my $message = status_message($status);
	48	print "$protocol $status $message\015\012";
	49	$c->response->headers->date(time);
	50	$self->NEXT::finalize_headers($c);
	51	}
	52
	53	=item $self->finalize_read($c)
	54
	55	=cut
	56
	57	sub finalize_read {
	58	my ( $self, $c ) = @_;
	59
	60	# Never ever remove this, it would result in random length output
	61	# streams if STDIN eq STDOUT (like in the HTTP engine)
4f5ebacd	62	*STDIN->blocking(1);
fbcc39ad	63
	64	return $self->NEXT::finalize_read($c);
	65	}
	66
	67	=item $self->prepare_read($c)
	68
	69	=cut
	70
	71	sub prepare_read {
	72	my ( $self, $c ) = @_;
	73
	74	# Set the input handle to non-blocking
4f5ebacd	75	*STDIN->blocking(0);
fbcc39ad	76
	77	return $self->NEXT::prepare_read($c);
	78	}
	79
	80	=item $self->read_chunk($c, $buffer, $length)
	81
	82	=cut
	83
	84	sub read_chunk {
	85	my $self = shift;
	86	my $c = shift;
	87
	88	# support for non-blocking IO
4f5ebacd	89	my $rin = '';
4f5ebacd	90	vec( $rin, *STDIN->fileno, 1 ) = 1;
fbcc39ad	91
	92	READ:
	93	{
	94	select( $rin, undef, undef, undef );
4f5ebacd	95	my $rc = *STDIN->sysread(@_);
fbcc39ad	96	if ( defined $rc ) {
	97	return $rc;
	98	}
	99	else {
	100	next READ if $! == EWOULDBLOCK;
	101	return;
	102	}
	103	}
	104	}
	105
	106	=item run
	107
	108	=cut
	109
	110	# A very very simple HTTP server that initializes a CGI environment
	111	sub run {
37553dc8	112	my ( $self, $class, $port, $host, $options ) = @_;
fbcc39ad	113
	114	our $GOT_HUP;
	115	local $GOT_HUP = 0;
	116
	117	local $SIG{HUP} = sub { $GOT_HUP = 1; };
60c38e3e	118	local $SIG{CHLD} = 'IGNORE';
fbcc39ad	119
37553dc8	120	# Setup restarter
	121	my $restarter;
	122	if ( $options->{restart} ) {
	123	my $parent = $$;
	124	unless ( $restarter = fork ) {
	125
7a1df403	126	# Prepare
	127	close STDIN;
	128	close STDOUT;
	129
37553dc8	130	# Index parent directory
	131	my $dir = File::Spec->catdir( $FindBin::Bin, '..' );
	132
	133	my $regex = $options->{restart_regex};
7a1df403	134	my $one = _index( $dir, $regex );
7a1df403	135	RESTART: while (1) {
37553dc8	136	sleep $options->{restart_delay};
7a1df403	137	my $two = _index( $dir, $regex );
	138	my $changes = _compare_index( $one, $two );
	139	if (@$changes) {
37553dc8	140	$one = $two;
7a1df403	141
	142	# Test modified pm's
	143	for my $file (@$changes) {
	144	next unless $file =~ /\.pm$/;
	145	if ( my $error = _test($file) ) {
	146	print STDERR
6844bc1c	147	qq/File "$file" modified, not restarting\n\n/;
7a1df403	148	print STDERR '*' x 80, "\n";
	149	print STDERR $error;
	150	print STDERR '*' x 80, "\n";
	151	next RESTART;
	152	}
	153	}
	154
	155	# Restart
	156	my $files = join ', ', @$changes;
6844bc1c	157	print STDERR qq/File(s) "$files" modified, restarting\n\n/;
7a1df403	158	kill( 1, $parent );
7a1df403	159	exit;
37553dc8	160	}
	161	}
	162	}
	163	}
fbcc39ad	164
	165	# Handle requests
	166
	167	# Setup socket
	168	$host = $host ? inet_aton($host) : INADDR_ANY;
	169	socket( HTTPDaemon, PF_INET, SOCK_STREAM, getprotobyname('tcp') );
	170	setsockopt( HTTPDaemon, SOL_SOCKET, SO_REUSEADDR, pack( "l", 1 ) );
	171	bind( HTTPDaemon, sockaddr_in( $port, $host ) );
	172	listen( HTTPDaemon, SOMAXCONN );
	173	my $url = 'http://';
	174	if ( $host eq INADDR_ANY ) {
	175	require Sys::Hostname;
	176	$url .= lc Sys::Hostname::hostname();
	177	}
	178	else {
	179	$url .= gethostbyaddr( $host, AF_INET ) \|\| inet_ntoa($host);
	180	}
	181	$url .= ":$port";
	182	print "You can connect to your server at $url\n";
	183	my $pid = undef;
	184	while ( accept( Remote, HTTPDaemon ) ) {
	185
	186	# Fork
37553dc8	187	if ( $options->{fork} ) { next if $pid = fork }
fbcc39ad	188
	189	close HTTPDaemon if defined $pid;
	190
	191	# Ignore broken pipes as an HTTP server should
	192	local $SIG{PIPE} = sub { close Remote };
4f5ebacd	193	local $SIG{HUP} = ( defined $pid ? 'IGNORE' : $SIG{HUP} );
fbcc39ad	194
	195	local STDIN = \Remote;
	196	local STDOUT = \Remote;
	197	select STDOUT;
	198
	199	# Request data
	200	my $remote_sockaddr = getpeername( \*Remote );
	201	my ( undef, $iaddr ) = sockaddr_in($remote_sockaddr);
	202	my $peername = gethostbyaddr( $iaddr, AF_INET ) \|\| "localhost";
	203	my $peeraddr = inet_ntoa($iaddr) \|\| "127.0.0.1";
	204	my $local_sockaddr = getsockname( \*Remote );
	205	my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
	206	my $localname = gethostbyaddr( $localiaddr, AF_INET )
	207	\|\| "localhost";
	208	my $localaddr = inet_ntoa($localiaddr) \|\| "127.0.0.1";
	209
	210	STDIN->blocking(1);
	211
	212	# Parse request line
	213	my $line = $self->_get_line( \*STDIN );
	214	next
	215	unless my ( $method, $uri, $protocol ) =
	216	$line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;
	217
	218	# We better be careful and just use 1.0
	219	$protocol = '1.0';
	220
	221	my ( $path, $query_string ) = split /\?/, $uri, 2;
	222
	223	# Initialize CGI environment
	224	local %ENV = (
	225	PATH_INFO => $path \|\| '',
	226	QUERY_STRING => $query_string \|\| '',
	227	REMOTE_ADDR => $peeraddr,
	228	REMOTE_HOST => $peername,
	229	REQUEST_METHOD => $method \|\| '',
	230	SERVER_NAME => $localname,
	231	SERVER_PORT => $port,
	232	SERVER_PROTOCOL => "HTTP/$protocol",
	233	%ENV,
	234	);
	235
	236	# Parse headers
	237	if ( $protocol >= 1 ) {
	238	while (1) {
	239	my $line = $self->_get_line( \*STDIN );
	240	last if $line eq '';
	241	next
	242	unless my ( $name, $value ) =
	243	$line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;
	244
	245	$name = uc $name;
	246	$name = 'COOKIE' if $name eq 'COOKIES';
	247	$name =~ tr/-/_/;
	248	$name = 'HTTP_' . $name
	249	unless $name =~ m/\A(?:CONTENT_(?:LENGTH\|TYPE)\|COOKIE)\z/;
	250	if ( exists $ENV{$name} ) {
	251	$ENV{$name} .= "; $value";
	252	}
	253	else {
	254	$ENV{$name} = $value;
	255	}
	256	}
	257	}
258
259	# Pass flow control to Catalyst
260	$class->handle_request;
261	exit if defined $pid;
262	}
263	continue {
264	close Remote;
265	}
266	close HTTPDaemon;
37553dc8	267
60c38e3e	268	if ($GOT_HUP) {
60c38e3e	269	$SIG{CHLD} = 'DEFAULT';
6844bc1c	270	wait;
6844bc1c	271	exec {$0}( ( ( -x $0 ) ? () : ($^X) ), $0, @{ $options->{argv} } );
60c38e3e	272	}
fbcc39ad	273	}
fbcc39ad	274
37553dc8	275	sub _compare_index {
	276	my ( $one, $two ) = @_;
	277	my %clone = %$two;
7a1df403	278	my @changes;
37553dc8	279	while ( my ( $key, $val ) = each %$one ) {
7a1df403	280	if ( !$clone{$key} \|\| ( $clone{$key} ne $val ) ) {
	281	push @changes, $key;
	282	}
37553dc8	283	delete $clone{$key};
37553dc8	284	}
7a1df403	285	for my $key ( keys %clone ) { push @changes, $key }
7a1df403	286	return \@changes;
37553dc8	287	}
37553dc8	288
fbcc39ad	289	sub _get_line {
	290	my ( $self, $handle ) = @_;
	291
	292	my $line = '';
	293
	294	while ( sysread( $handle, my $byte, 1 ) ) {
	295	last if $byte eq "\012"; # eol
	296	$line .= $byte;
	297	}
	298
	299	1 while $line =~ s/\s\z//;
	300
	301	return $line;
	302	}
	303
37553dc8	304	sub _index {
	305	my ( $dir, $regex ) = @_;
	306	my %index;
	307	finddepth(
	308	{
	309	wanted => sub {
	310	my $file = File::Spec->rel2abs($File::Find::name);
	311	return unless $file =~ /$regex/;
	312	return unless -f $file;
	313	my $time = ( stat $file )[9];
	314	$index{$file} = $time;
	315	},
	316	no_chdir => 1
	317	},
	318	$dir
	319	);
	320	return \%index;
	321	}
	322
7a1df403	323	sub _test {
7a1df403	324	my $file = shift;
6844bc1c	325	delete $INC{$file};
7a1df403	326	local $SIG{__WARN__} = sub { };
	327	open my $olderr, '>&STDERR';
	328	open STDERR, '>', File::Spec->devnull;
	329	eval "require '$file'";
	330	open STDERR, '>&', $olderr;
	331	return $@ if $@;
	332	return 0;
	333	}
	334
fbcc39ad	335	=back
fbcc39ad	336
45374ac6	337	=head1 SEE ALSO
45374ac6	338
fbcc39ad	339	L<Catalyst>, L<Catalyst::Engine>.
	340
	341	=head1 AUTHORS
	342
	343	Sebastian Riedel, <sri@cpan.org>
	344
	345	Dan Kubb, <dan.kubb-cpan@onautopilot.com>
45374ac6	346
fbcc39ad	347	=head1 THANKS
45374ac6	348
fbcc39ad	349	Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.
45374ac6	350
	351	=head1 COPYRIGHT
	352
	353	This program is free software, you can redistribute it and/or modify it under
	354	the same terms as Perl itself.
	355
	356	=cut
	357
45374ac6	358	1;