[catagits/Catalyst-Runtime.git] / lib / Catalyst / Engine / HTTP.pm

package Catalyst::Engine::HTTP;

use strict;
use base 'Catalyst::Engine::CGI';
use Errno 'EWOULDBLOCK';
use FindBin;
use File::Find;
use File::Spec;
use HTTP::Status;
use NEXT;
use Socket;

=head1 NAME

Catalyst::Engine::HTTP - Catalyst HTTP Engine

=head1 SYNOPSIS

A script using the Catalyst::Engine::HTTP module might look like:

    #!/usr/bin/perl -w

    BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }

    use strict;
    use lib '/path/to/MyApp/lib';
    use MyApp;

    MyApp->run;

=head1 DESCRIPTION

This is the Catalyst engine specialized for development and testing.

=head1 METHODS

=over 4

=item $self->finalize_headers($c)

=cut

sub finalize_headers {
    my ( $self, $c ) = @_;
    my $protocol = $c->request->protocol;
    my $status   = $c->response->status;
    my $message  = status_message($status);
    print "$protocol $status $message\015\012";
    $c->response->headers->date(time);
    $self->NEXT::finalize_headers($c);
}

=item $self->finalize_read($c)

=cut

sub finalize_read {
    my ( $self, $c ) = @_;

    # Never ever remove this, it would result in random length output
    # streams if STDIN eq STDOUT (like in the HTTP engine)
    *STDIN->blocking(1);

    return $self->NEXT::finalize_read($c);
}

=item $self->prepare_read($c)

=cut

sub prepare_read {
    my ( $self, $c ) = @_;

    # Set the input handle to non-blocking
    *STDIN->blocking(0);

    return $self->NEXT::prepare_read($c);
}

=item $self->read_chunk($c, $buffer, $length)

=cut

sub read_chunk {
    my $self = shift;
    my $c    = shift;

    # support for non-blocking IO
    my $rin = '';
    vec( $rin, *STDIN->fileno, 1 ) = 1;

  READ:
    {
        select( $rin, undef, undef, undef );
        my $rc = *STDIN->sysread(@_);
        if ( defined $rc ) {
            return $rc;
        }
        else {
            next READ if $! == EWOULDBLOCK;
            return;
        }
    }
}

=item run

=cut

# A very very simple HTTP server that initializes a CGI environment
sub run {
    my ( $self, $class, $port, $host, $options ) = @_;

    $options ||= {};

    our $GOT_HUP;
    local $GOT_HUP = 0;

    local $SIG{HUP} = sub { $GOT_HUP = 1; };
    local $SIG{CHLD} = 'IGNORE';

    # Setup restarter
    my $restarter;
    if ( $options->{restart} ) {
        my $parent = $$;
        unless ( $restarter = fork ) {

            # Prepare
            close STDIN;
            close STDOUT;

            # Index parent directory
            my $dir = File::Spec->catdir( $FindBin::Bin, '..' );

            my $regex = $options->{restart_regex};
            my $one   = _index( $dir, $regex );
          RESTART: while (1) {
                sleep $options->{restart_delay};
                my $two     = _index( $dir,         $regex );
                my $changes = _compare_index( $one, $two );
                if (@$changes) {
                    $one = $two;

                    # Test modified pm's
                    for my $file (@$changes) {
                        next unless $file =~ /\.pm$/;
                        if ( my $error = _test($file) ) {
                            print STDERR
                              qq/File "$file" modified, not restarting\n\n/;
                            print STDERR '*' x 80, "\n";
                            print STDERR $error;
                            print STDERR '*' x 80, "\n";
                            next RESTART;
                        }
                    }

                    # Restart
                    my $files = join ', ', @$changes;
                    print STDERR qq/File(s) "$files" modified, restarting\n\n/;
                    kill( 1, $parent );
                    exit;
                }
            }
        }
    }

    # Handle requests

    # Setup socket
    $host = $host ? inet_aton($host) : INADDR_ANY;
    socket( HTTPDaemon, PF_INET, SOCK_STREAM, getprotobyname('tcp') )
        || die "Couldn't assign TCP socket: $!";
    setsockopt( HTTPDaemon, SOL_SOCKET, SO_REUSEADDR, pack( "l", 1 ) )
        || die "Couldn't set TCP socket options: $!";
    bind( HTTPDaemon, sockaddr_in( $port, $host ) )
        || die "Couldn't bind socket to $port on $host: $!";
    listen( HTTPDaemon, SOMAXCONN )
	|| die "Couldn't listen to socket on $port on $host: $!";
    my $url = 'http://';
    if ( $host eq INADDR_ANY ) {
        require Sys::Hostname;
        $url .= lc Sys::Hostname::hostname();
    }
    else {
        $url .= gethostbyaddr( $host, AF_INET ) || inet_ntoa($host);
    }
    $url .= ":$port";
    print "You can connect to your server at $url\n";
    my $pid = undef;
    while ( accept( Remote, HTTPDaemon ) ) {

        # Fork
        if ( $options->{fork} ) { next if $pid = fork }

        close HTTPDaemon if defined $pid;

        # Ignore broken pipes as an HTTP server should
        local $SIG{PIPE} = sub { close Remote };
        local $SIG{HUP} = ( defined $pid ? 'IGNORE' : $SIG{HUP} );

        local *STDIN  = \*Remote;
        local *STDOUT = \*Remote;
        select STDOUT;

        # Request data
        my $remote_sockaddr = getpeername( \*Remote );
        my ( undef, $iaddr ) = sockaddr_in($remote_sockaddr);
        my $peername = gethostbyaddr( $iaddr, AF_INET ) || "localhost";
        my $peeraddr = inet_ntoa($iaddr) || "127.0.0.1";
        my $local_sockaddr = getsockname( \*Remote );
        my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
        my $localname = gethostbyaddr( $localiaddr, AF_INET )
          || "localhost";
        my $localaddr = inet_ntoa($localiaddr) || "127.0.0.1";

        STDIN->blocking(1);

        # Parse request line
        my $line = $self->_get_line( \*STDIN );
        next
          unless my ( $method, $uri, $protocol ) =
          $line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;

        # We better be careful and just use 1.0
        $protocol = '1.0';

        my ( $path, $query_string ) = split /\?/, $uri, 2;

        # Initialize CGI environment
        local %ENV = (
            PATH_INFO      => $path         || '',
            QUERY_STRING   => $query_string || '',
            REMOTE_ADDR    => $peeraddr,
            REMOTE_HOST    => $peername,
            REQUEST_METHOD => $method       || '',
            SERVER_NAME    => $localname,
            SERVER_PORT    => $port,
            SERVER_PROTOCOL => "HTTP/$protocol",
            %ENV,
        );

        # Parse headers
        if ( $protocol >= 1 ) {
            while (1) {
                my $line = $self->_get_line( \*STDIN );
                last if $line eq '';
                next
                  unless my ( $name, $value ) =
                  $line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;

                $name = uc $name;
                $name = 'COOKIE' if $name eq 'COOKIES';
                $name =~ tr/-/_/;
                $name = 'HTTP_' . $name
                  unless $name =~ m/\A(?:CONTENT_(?:LENGTH|TYPE)|COOKIE)\z/;
                if ( exists $ENV{$name} ) {
                    $ENV{$name} .= "; $value";
                }
                else {
                    $ENV{$name} = $value;
                }
            }
        }

        # Pass flow control to Catalyst
        $class->handle_request;
        exit if defined $pid;
    }
    continue {
        close Remote;
    }
    close HTTPDaemon;

    if ($GOT_HUP) {
        $SIG{CHLD} = 'DEFAULT';
        wait;
        exec {$0}( ( ( -x $0 ) ? () : ($^X) ), $0, @{ $options->{argv} } );
    }
}

sub _compare_index {
    my ( $one, $two ) = @_;
    my %clone = %$two;
    my @changes;
    while ( my ( $key, $val ) = each %$one ) {
        if ( !$clone{$key} || ( $clone{$key} ne $val ) ) {
            push @changes, $key;
        }
        delete $clone{$key};
    }
    for my $key ( keys %clone ) { push @changes, $key }
    return \@changes;
}

sub _get_line {
    my ( $self, $handle ) = @_;

    my $line = '';

    while ( sysread( $handle, my $byte, 1 ) ) {
        last if $byte eq "\012";    # eol
        $line .= $byte;
    }

    1 while $line =~ s/\s\z//;

    return $line;
}

sub _index {
    my ( $dir, $regex ) = @_;
    my %index;
    finddepth(
        {
            wanted => sub {
                my $file = File::Spec->rel2abs($File::Find::name);
                return unless $file =~ /$regex/;
                return unless -f $file;
                my $time = ( stat $file )[9];
                $index{$file} = $time;
            },
            no_chdir => 1
        },
        $dir
    );
    return \%index;
}

sub _test {
    my $file = shift;
    delete $INC{$file};
    local $SIG{__WARN__} = sub { };
    open my $olderr, '>&STDERR';
    open STDERR, '>', File::Spec->devnull;
    eval "require '$file'";
    open STDERR, '>&', $olderr;
    return $@ if $@;
    return 0;
}

=back

=head1 SEE ALSO

L<Catalyst>, L<Catalyst::Engine>.

=head1 AUTHORS

Sebastian Riedel, <sri@cpan.org>

Dan Kubb, <dan.kubb-cpan@onautopilot.com>

=head1 THANKS

Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.

=head1 COPYRIGHT

This program is free software, you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
Commit	Line	Data
ca61af20	1	package Catalyst::Engine::HTTP;
45374ac6	2
45374ac6	3	use strict;
fbcc39ad	4	use base 'Catalyst::Engine::CGI';
fbcc39ad	5	use Errno 'EWOULDBLOCK';
37553dc8	6	use FindBin;
	7	use File::Find;
	8	use File::Spec;
fbcc39ad	9	use HTTP::Status;
	10	use NEXT;
	11	use Socket;
45374ac6	12
	13	=head1 NAME
	14
ca61af20	15	Catalyst::Engine::HTTP - Catalyst HTTP Engine
45374ac6	16
	17	=head1 SYNOPSIS
	18
ca61af20	19	A script using the Catalyst::Engine::HTTP module might look like:
45374ac6	20
	21	#!/usr/bin/perl -w
	22
ca61af20	23	BEGIN { $ENV{CATALYST_ENGINE} = 'HTTP' }
45374ac6	24
	25	use strict;
	26	use lib '/path/to/MyApp/lib';
	27	use MyApp;
	28
	29	MyApp->run;
	30
	31	=head1 DESCRIPTION
	32
	33	This is the Catalyst engine specialized for development and testing.
	34
fbcc39ad	35	=head1 METHODS
	36
	37	=over 4
	38
	39	=item $self->finalize_headers($c)
	40
	41	=cut
	42
	43	sub finalize_headers {
	44	my ( $self, $c ) = @_;
	45	my $protocol = $c->request->protocol;
	46	my $status = $c->response->status;
	47	my $message = status_message($status);
	48	print "$protocol $status $message\015\012";
	49	$c->response->headers->date(time);
	50	$self->NEXT::finalize_headers($c);
	51	}
	52
	53	=item $self->finalize_read($c)
	54
	55	=cut
	56
	57	sub finalize_read {
	58	my ( $self, $c ) = @_;
	59
	60	# Never ever remove this, it would result in random length output
	61	# streams if STDIN eq STDOUT (like in the HTTP engine)
4f5ebacd	62	*STDIN->blocking(1);
fbcc39ad	63
	64	return $self->NEXT::finalize_read($c);
	65	}
	66
	67	=item $self->prepare_read($c)
	68
	69	=cut
	70
	71	sub prepare_read {
	72	my ( $self, $c ) = @_;
	73
	74	# Set the input handle to non-blocking
4f5ebacd	75	*STDIN->blocking(0);
fbcc39ad	76
	77	return $self->NEXT::prepare_read($c);
	78	}
	79
	80	=item $self->read_chunk($c, $buffer, $length)
	81
	82	=cut
	83
	84	sub read_chunk {
	85	my $self = shift;
	86	my $c = shift;
	87
	88	# support for non-blocking IO
4f5ebacd	89	my $rin = '';
4f5ebacd	90	vec( $rin, *STDIN->fileno, 1 ) = 1;
fbcc39ad	91
	92	READ:
	93	{
	94	select( $rin, undef, undef, undef );
4f5ebacd	95	my $rc = *STDIN->sysread(@_);
fbcc39ad	96	if ( defined $rc ) {
	97	return $rc;
	98	}
	99	else {
	100	next READ if $! == EWOULDBLOCK;
	101	return;
	102	}
	103	}
	104	}
	105
	106	=item run
	107
	108	=cut
	109
	110	# A very very simple HTTP server that initializes a CGI environment
	111	sub run {
37553dc8	112	my ( $self, $class, $port, $host, $options ) = @_;
fbcc39ad	113
4eeca0f2	114	$options \|\|= {};
4eeca0f2	115
fbcc39ad	116	our $GOT_HUP;
	117	local $GOT_HUP = 0;
	118
	119	local $SIG{HUP} = sub { $GOT_HUP = 1; };
60c38e3e	120	local $SIG{CHLD} = 'IGNORE';
fbcc39ad	121
37553dc8	122	# Setup restarter
	123	my $restarter;
	124	if ( $options->{restart} ) {
	125	my $parent = $$;
	126	unless ( $restarter = fork ) {
	127
7a1df403	128	# Prepare
	129	close STDIN;
	130	close STDOUT;
	131
37553dc8	132	# Index parent directory
	133	my $dir = File::Spec->catdir( $FindBin::Bin, '..' );
	134
	135	my $regex = $options->{restart_regex};
7a1df403	136	my $one = _index( $dir, $regex );
7a1df403	137	RESTART: while (1) {
37553dc8	138	sleep $options->{restart_delay};
7a1df403	139	my $two = _index( $dir, $regex );
	140	my $changes = _compare_index( $one, $two );
	141	if (@$changes) {
37553dc8	142	$one = $two;
7a1df403	143
	144	# Test modified pm's
	145	for my $file (@$changes) {
	146	next unless $file =~ /\.pm$/;
	147	if ( my $error = _test($file) ) {
	148	print STDERR
6844bc1c	149	qq/File "$file" modified, not restarting\n\n/;
7a1df403	150	print STDERR '*' x 80, "\n";
	151	print STDERR $error;
	152	print STDERR '*' x 80, "\n";
	153	next RESTART;
	154	}
	155	}
	156
	157	# Restart
	158	my $files = join ', ', @$changes;
6844bc1c	159	print STDERR qq/File(s) "$files" modified, restarting\n\n/;
7a1df403	160	kill( 1, $parent );
7a1df403	161	exit;
37553dc8	162	}
	163	}
	164	}
	165	}
fbcc39ad	166
	167	# Handle requests
	168
	169	# Setup socket
	170	$host = $host ? inet_aton($host) : INADDR_ANY;
bd357f39	171	socket( HTTPDaemon, PF_INET, SOCK_STREAM, getprotobyname('tcp') )
	172	\|\| die "Couldn't assign TCP socket: $!";
	173	setsockopt( HTTPDaemon, SOL_SOCKET, SO_REUSEADDR, pack( "l", 1 ) )
	174	\|\| die "Couldn't set TCP socket options: $!";
	175	bind( HTTPDaemon, sockaddr_in( $port, $host ) )
	176	\|\| die "Couldn't bind socket to $port on $host: $!";
	177	listen( HTTPDaemon, SOMAXCONN )
	178	\|\| die "Couldn't listen to socket on $port on $host: $!";
fbcc39ad	179	my $url = 'http://';
	180	if ( $host eq INADDR_ANY ) {
	181	require Sys::Hostname;
	182	$url .= lc Sys::Hostname::hostname();
	183	}
	184	else {
	185	$url .= gethostbyaddr( $host, AF_INET ) \|\| inet_ntoa($host);
	186	}
	187	$url .= ":$port";
	188	print "You can connect to your server at $url\n";
	189	my $pid = undef;
	190	while ( accept( Remote, HTTPDaemon ) ) {
	191
	192	# Fork
37553dc8	193	if ( $options->{fork} ) { next if $pid = fork }
fbcc39ad	194
	195	close HTTPDaemon if defined $pid;
	196
	197	# Ignore broken pipes as an HTTP server should
	198	local $SIG{PIPE} = sub { close Remote };
4f5ebacd	199	local $SIG{HUP} = ( defined $pid ? 'IGNORE' : $SIG{HUP} );
fbcc39ad	200
	201	local STDIN = \Remote;
	202	local STDOUT = \Remote;
	203	select STDOUT;
	204
	205	# Request data
	206	my $remote_sockaddr = getpeername( \*Remote );
	207	my ( undef, $iaddr ) = sockaddr_in($remote_sockaddr);
	208	my $peername = gethostbyaddr( $iaddr, AF_INET ) \|\| "localhost";
	209	my $peeraddr = inet_ntoa($iaddr) \|\| "127.0.0.1";
	210	my $local_sockaddr = getsockname( \*Remote );
	211	my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
	212	my $localname = gethostbyaddr( $localiaddr, AF_INET )
	213	\|\| "localhost";
	214	my $localaddr = inet_ntoa($localiaddr) \|\| "127.0.0.1";
	215
	216	STDIN->blocking(1);
	217
	218	# Parse request line
	219	my $line = $self->_get_line( \*STDIN );
	220	next
	221	unless my ( $method, $uri, $protocol ) =
	222	$line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;
	223
	224	# We better be careful and just use 1.0
	225	$protocol = '1.0';
	226
	227	my ( $path, $query_string ) = split /\?/, $uri, 2;
	228
	229	# Initialize CGI environment
	230	local %ENV = (
	231	PATH_INFO => $path \|\| '',
	232	QUERY_STRING => $query_string \|\| '',
	233	REMOTE_ADDR => $peeraddr,
	234	REMOTE_HOST => $peername,
	235	REQUEST_METHOD => $method \|\| '',
	236	SERVER_NAME => $localname,
	237	SERVER_PORT => $port,
	238	SERVER_PROTOCOL => "HTTP/$protocol",
	239	%ENV,
	240	);
	241
	242	# Parse headers
	243	if ( $protocol >= 1 ) {
	244	while (1) {
	245	my $line = $self->_get_line( \*STDIN );
	246	last if $line eq '';
	247	next
	248	unless my ( $name, $value ) =
	249	$line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;
	250
	251	$name = uc $name;
	252	$name = 'COOKIE' if $name eq 'COOKIES';
	253	$name =~ tr/-/_/;
	254	$name = 'HTTP_' . $name
	255	unless $name =~ m/\A(?:CONTENT_(?:LENGTH\|TYPE)\|COOKIE)\z/;
	256	if ( exists $ENV{$name} ) {
	257	$ENV{$name} .= "; $value";
	258	}
	259	else {
	260	$ENV{$name} = $value;
	261	}
	262	}
	263	}
264
265	# Pass flow control to Catalyst
266	$class->handle_request;
267	exit if defined $pid;
268	}
269	continue {
270	close Remote;
271	}
272	close HTTPDaemon;
37553dc8	273
60c38e3e	274	if ($GOT_HUP) {
60c38e3e	275	$SIG{CHLD} = 'DEFAULT';
6844bc1c	276	wait;
6844bc1c	277	exec {$0}( ( ( -x $0 ) ? () : ($^X) ), $0, @{ $options->{argv} } );
60c38e3e	278	}
fbcc39ad	279	}
fbcc39ad	280
37553dc8	281	sub _compare_index {
	282	my ( $one, $two ) = @_;
	283	my %clone = %$two;
7a1df403	284	my @changes;
37553dc8	285	while ( my ( $key, $val ) = each %$one ) {
7a1df403	286	if ( !$clone{$key} \|\| ( $clone{$key} ne $val ) ) {
	287	push @changes, $key;
	288	}
37553dc8	289	delete $clone{$key};
37553dc8	290	}
7a1df403	291	for my $key ( keys %clone ) { push @changes, $key }
7a1df403	292	return \@changes;
37553dc8	293	}
37553dc8	294
fbcc39ad	295	sub _get_line {
	296	my ( $self, $handle ) = @_;
	297
	298	my $line = '';
	299
	300	while ( sysread( $handle, my $byte, 1 ) ) {
	301	last if $byte eq "\012"; # eol
	302	$line .= $byte;
	303	}
	304
	305	1 while $line =~ s/\s\z//;
	306
	307	return $line;
	308	}
	309
37553dc8	310	sub _index {
	311	my ( $dir, $regex ) = @_;
	312	my %index;
	313	finddepth(
	314	{
	315	wanted => sub {
	316	my $file = File::Spec->rel2abs($File::Find::name);
	317	return unless $file =~ /$regex/;
	318	return unless -f $file;
	319	my $time = ( stat $file )[9];
	320	$index{$file} = $time;
	321	},
	322	no_chdir => 1
	323	},
	324	$dir
	325	);
	326	return \%index;
	327	}
	328
7a1df403	329	sub _test {
7a1df403	330	my $file = shift;
6844bc1c	331	delete $INC{$file};
7a1df403	332	local $SIG{__WARN__} = sub { };
	333	open my $olderr, '>&STDERR';
	334	open STDERR, '>', File::Spec->devnull;
	335	eval "require '$file'";
	336	open STDERR, '>&', $olderr;
	337	return $@ if $@;
	338	return 0;
	339	}
	340
fbcc39ad	341	=back
fbcc39ad	342
45374ac6	343	=head1 SEE ALSO
45374ac6	344
fbcc39ad	345	L<Catalyst>, L<Catalyst::Engine>.
	346
	347	=head1 AUTHORS
	348
	349	Sebastian Riedel, <sri@cpan.org>
	350
	351	Dan Kubb, <dan.kubb-cpan@onautopilot.com>
45374ac6	352
fbcc39ad	353	=head1 THANKS
45374ac6	354
fbcc39ad	355	Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.
45374ac6	356
	357	=head1 COPYRIGHT
	358
	359	This program is free software, you can redistribute it and/or modify it under
	360	the same terms as Perl itself.
	361
	362	=cut
	363
45374ac6	364	1;