Commit | Line | Data |
b1dbf716 |
1 | package # hide from PAUSE |
2 | DBIx::Class::_Util; |
3 | |
4 | use warnings; |
5 | use strict; |
6 | |
750a4ad2 |
7 | use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0); |
b1dbf716 |
8 | |
37873f78 |
9 | BEGIN { |
10 | package # hide from pause |
11 | DBIx::Class::_ENV_; |
12 | |
13 | use Config; |
14 | |
15 | use constant { |
16 | |
17 | # but of course |
18 | BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0, |
19 | |
750a4ad2 |
20 | BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0, |
8d73fcd4 |
21 | |
37873f78 |
22 | HAS_ITHREADS => $Config{useithreads} ? 1 : 0, |
23 | |
bbf6a9a5 |
24 | UNSTABLE_DOLLARAT => ( "$]" < 5.013002 ) ? 1 : 0, |
25 | |
db83437e |
26 | ( map |
27 | # |
28 | # the "DBIC_" prefix below is crucial - this is what makes CI pick up |
29 | # all envvars without further adjusting its scripts |
30 | # DO NOT CHANGE to the more logical { $_ => !!( $ENV{"DBIC_$_"} ) } |
31 | # |
32 | { substr($_, 5) => !!( $ENV{$_} ) } |
33 | qw( |
34 | DBIC_SHUFFLE_UNORDERED_RESULTSETS |
35 | DBIC_ASSERT_NO_INTERNAL_WANTARRAY |
36 | DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS |
37 | DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE |
38 | DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE |
39 | ) |
40 | ), |
f45dc928 |
41 | |
37873f78 |
42 | IV_SIZE => $Config{ivsize}, |
00882d2c |
43 | |
44 | OS_NAME => $^O, |
37873f78 |
45 | }; |
46 | |
750a4ad2 |
47 | if ( "$]" < 5.009_005) { |
37873f78 |
48 | require MRO::Compat; |
49 | constant->import( OLD_MRO => 1 ); |
50 | } |
51 | else { |
52 | require mro; |
53 | constant->import( OLD_MRO => 0 ); |
54 | } |
55 | } |
56 | |
841efcb3 |
57 | # FIXME - this is not supposed to be here |
58 | # Carp::Skip to the rescue soon |
59 | use DBIx::Class::Carp '^DBIx::Class|^DBICTest'; |
60 | |
d7d45bdc |
61 | use B (); |
841efcb3 |
62 | use Carp 'croak'; |
d7d45bdc |
63 | use Storable 'nfreeze'; |
3d56e026 |
64 | use Scalar::Util qw(weaken blessed reftype refaddr); |
3705e3b2 |
65 | use List::Util qw(first); |
0020e364 |
66 | use Sub::Quote qw(qsub quote_sub); |
7f9a3f70 |
67 | |
1c30a2e4 |
68 | # Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone' |
69 | BEGIN { *deep_clone = \&Storable::dclone } |
70 | |
b1dbf716 |
71 | use base 'Exporter'; |
3705e3b2 |
72 | our @EXPORT_OK = qw( |
d634850b |
73 | sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt |
77c3a5dc |
74 | fail_on_internal_wantarray fail_on_internal_call |
bbf6a9a5 |
75 | refdesc refcount hrefaddr |
ddcc02d1 |
76 | scope_guard detected_reinvoked_destructor |
77 | is_exception dbic_internal_try |
1c30a2e4 |
78 | quote_sub qsub perlstring serialize deep_clone |
439a7283 |
79 | parent_dir mkdir_p |
facd0e8e |
80 | UNRESOLVABLE_CONDITION |
3705e3b2 |
81 | ); |
052a832c |
82 | |
facd0e8e |
83 | use constant UNRESOLVABLE_CONDITION => \ '1 = 0'; |
84 | |
bf302897 |
85 | sub sigwarn_silencer ($) { |
052a832c |
86 | my $pattern = shift; |
87 | |
88 | croak "Expecting a regexp" if ref $pattern ne 'Regexp'; |
89 | |
90 | my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) }; |
91 | |
92 | return sub { &$orig_sig_warn unless $_[0] =~ $pattern }; |
93 | } |
b1dbf716 |
94 | |
01b25f12 |
95 | sub perlstring ($) { q{"}. quotemeta( shift ). q{"} }; |
96 | |
3d56e026 |
97 | sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 } |
8433421f |
98 | |
99 | sub refdesc ($) { |
100 | croak "Expecting a reference" if ! length ref $_[0]; |
101 | |
102 | # be careful not to trigger stringification, |
103 | # reuse @_ as a scratch-pad |
104 | sprintf '%s%s(0x%x)', |
105 | ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ), |
106 | reftype $_[0], |
3d56e026 |
107 | refaddr($_[0]), |
8433421f |
108 | ; |
109 | } |
bf302897 |
110 | |
111 | sub refcount ($) { |
dac7972a |
112 | croak "Expecting a reference" if ! length ref $_[0]; |
113 | |
dac7972a |
114 | # No tempvars - must operate on $_[0], otherwise the pad |
115 | # will count as an extra ref |
116 | B::svref_2object($_[0])->REFCNT; |
117 | } |
118 | |
b34d9331 |
119 | sub serialize ($) { |
b34d9331 |
120 | local $Storable::canonical = 1; |
d7d45bdc |
121 | nfreeze($_[0]); |
b34d9331 |
122 | } |
123 | |
bbf6a9a5 |
124 | sub scope_guard (&) { |
125 | croak 'Calling scope_guard() in void context makes no sense' |
126 | if ! defined wantarray; |
127 | |
128 | # no direct blessing of coderefs - DESTROY is buggy on those |
129 | bless [ $_[0] ], 'DBIx::Class::_Util::ScopeGuard'; |
130 | } |
131 | { |
132 | package # |
133 | DBIx::Class::_Util::ScopeGuard; |
134 | |
135 | sub DESTROY { |
136 | &DBIx::Class::_Util::detected_reinvoked_destructor; |
137 | |
138 | local $@ if DBIx::Class::_ENV_::UNSTABLE_DOLLARAT; |
139 | |
140 | eval { |
141 | $_[0]->[0]->(); |
142 | 1; |
118b2c36 |
143 | } |
144 | or |
145 | Carp::cluck( |
146 | "Execution of scope guard $_[0] resulted in the non-trappable exception:\n\n$@" |
147 | ); |
bbf6a9a5 |
148 | } |
149 | } |
150 | |
151 | |
841efcb3 |
152 | sub is_exception ($) { |
153 | my $e = $_[0]; |
154 | |
35cf7d1a |
155 | # FIXME |
a0414138 |
156 | # this is not strictly correct - an eval setting $@ to undef |
157 | # is *not* the same as an eval setting $@ to '' |
158 | # but for the sake of simplicity assume the following for |
159 | # the time being |
160 | return 0 unless defined $e; |
161 | |
841efcb3 |
162 | my ($not_blank, $suberror); |
163 | { |
164 | local $@; |
165 | eval { |
d52c4a75 |
166 | # The ne() here is deliberate - a plain length($e), or worse "$e" ne |
167 | # will entirely obviate the need for the encolsing eval{}, as the |
168 | # condition we guard against is a missing fallback overload |
169 | $not_blank = ( $e ne '' ); |
841efcb3 |
170 | 1; |
171 | } or $suberror = $@; |
172 | } |
173 | |
174 | if (defined $suberror) { |
175 | if (length (my $class = blessed($e) )) { |
176 | carp_unique( sprintf( |
9bea2000 |
177 | 'External exception class %s implements partial (broken) overloading ' |
178 | . 'preventing its instances from being used in simple ($x eq $y) ' |
841efcb3 |
179 | . 'comparisons. Given Perl\'s "globally cooperative" exception ' |
180 | . 'handling this type of brokenness is extremely dangerous on ' |
181 | . 'exception objects, as it may (and often does) result in silent ' |
182 | . '"exception substitution". DBIx::Class tries to work around this ' |
183 | . 'as much as possible, but other parts of your software stack may ' |
184 | . 'not be even aware of this. Please submit a bugreport against the ' |
185 | . 'distribution containing %s and in the meantime apply a fix similar ' |
186 | . 'to the one shown at %s, in order to ensure your exception handling ' |
187 | . 'is saner application-wide. What follows is the actual error text ' |
188 | . "as generated by Perl itself:\n\n%s\n ", |
9bea2000 |
189 | $class, |
841efcb3 |
190 | $class, |
191 | 'http://v.gd/DBIC_overload_tempfix/', |
192 | $suberror, |
193 | )); |
194 | |
195 | # workaround, keeps spice flowing |
d52c4a75 |
196 | $not_blank = !!( length $e ); |
841efcb3 |
197 | } |
198 | else { |
199 | # not blessed yet failed the 'ne'... this makes 0 sense... |
200 | # just throw further |
201 | die $suberror |
202 | } |
203 | } |
84e4e006 |
204 | elsif ( |
205 | # a ref evaluating to '' is definitively a "null object" |
206 | ( not $not_blank ) |
207 | and |
208 | length( my $class = ref $e ) |
209 | ) { |
210 | carp_unique( sprintf( |
211 | "Objects of external exception class '%s' stringify to '' (the " |
212 | . 'empty string), implementing the so called null-object-pattern. ' |
213 | . 'Given Perl\'s "globally cooperative" exception handling using this ' |
214 | . 'class of exceptions is extremely dangerous, as it may (and often ' |
215 | . 'does) result in silent discarding of errors. DBIx::Class tries to ' |
216 | . 'work around this as much as possible, but other parts of your ' |
217 | . 'software stack may not be even aware of the problem. Please submit ' |
35cf7d1a |
218 | . 'a bugreport against the distribution containing %s', |
84e4e006 |
219 | |
220 | ($class) x 2, |
221 | )); |
222 | |
223 | $not_blank = 1; |
224 | } |
841efcb3 |
225 | |
226 | return $not_blank; |
227 | } |
228 | |
3d56e026 |
229 | { |
ddcc02d1 |
230 | my $callstack_state; |
231 | |
232 | # Recreate the logic of try(), while reusing the catch()/finally() as-is |
233 | # |
234 | # FIXME: We need to move away from Try::Tiny entirely (way too heavy and |
235 | # yes, shows up ON TOP of profiles) but this is a batle for another maint |
236 | sub dbic_internal_try (&;@) { |
237 | |
238 | my $try_cref = shift; |
239 | my $catch_cref = undef; # apparently this is a thing... https://rt.perl.org/Public/Bug/Display.html?id=119311 |
240 | |
241 | for my $arg (@_) { |
242 | |
243 | if( ref($arg) eq 'Try::Tiny::Catch' ) { |
244 | |
245 | croak 'dbic_internal_try() may not be followed by multiple catch() blocks' |
246 | if $catch_cref; |
247 | |
248 | $catch_cref = $$arg; |
249 | } |
250 | elsif ( ref($arg) eq 'Try::Tiny::Finally' ) { |
251 | croak 'dbic_internal_try() does not support finally{}'; |
252 | } |
253 | else { |
254 | croak( |
255 | 'dbic_internal_try() encountered an unexpected argument ' |
256 | . "'@{[ defined $arg ? $arg : 'UNDEF' ]}' - perhaps " |
257 | . 'a missing semi-colon before or ' # trailing space important |
258 | ); |
259 | } |
260 | } |
261 | |
262 | my $wantarray = wantarray; |
263 | my $preexisting_exception = $@; |
264 | |
265 | my @ret; |
266 | my $all_good = eval { |
267 | $@ = $preexisting_exception; |
268 | |
269 | local $callstack_state->{in_internal_try} = 1 |
270 | unless $callstack_state->{in_internal_try}; |
271 | |
272 | # always unset - someone may have snuck it in |
273 | local $SIG{__DIE__} |
274 | if $SIG{__DIE__}; |
275 | |
276 | |
277 | if( $wantarray ) { |
278 | @ret = $try_cref->(); |
279 | } |
280 | elsif( defined $wantarray ) { |
281 | $ret[0] = $try_cref->(); |
282 | } |
283 | else { |
284 | $try_cref->(); |
285 | } |
286 | |
287 | 1; |
288 | }; |
289 | |
290 | my $exception = $@; |
291 | $@ = $preexisting_exception; |
292 | |
293 | if ( $all_good ) { |
294 | return $wantarray ? @ret : $ret[0] |
295 | } |
296 | elsif ( $catch_cref ) { |
297 | for ( $exception ) { |
298 | return $catch_cref->($exception); |
299 | } |
300 | } |
301 | |
302 | return; |
303 | } |
304 | |
305 | sub in_internal_try { !! $callstack_state->{in_internal_try} } |
306 | } |
307 | |
308 | { |
3d56e026 |
309 | my $destruction_registry = {}; |
310 | |
311 | sub CLONE { |
312 | $destruction_registry = { map |
313 | { defined $_ ? ( refaddr($_) => $_ ) : () } |
314 | values %$destruction_registry |
315 | }; |
d52fc26d |
316 | |
317 | # Dummy NEXTSTATE ensuring the all temporaries on the stack are garbage |
318 | # collected before leaving this scope. Depending on the code above, this |
319 | # may very well be just a preventive measure guarding future modifications |
320 | undef; |
3d56e026 |
321 | } |
322 | |
323 | # This is almost invariably invoked from within DESTROY |
324 | # throwing exceptions won't work |
e1d9e578 |
325 | sub detected_reinvoked_destructor { |
3d56e026 |
326 | |
327 | # quick "garbage collection" pass - prevents the registry |
328 | # from slowly growing with a bunch of undef-valued keys |
329 | defined $destruction_registry->{$_} or delete $destruction_registry->{$_} |
330 | for keys %$destruction_registry; |
331 | |
e1d9e578 |
332 | if (! length ref $_[0]) { |
333 | printf STDERR '%s() expects a blessed reference %s', |
3d56e026 |
334 | (caller(0))[3], |
335 | Carp::longmess, |
336 | ; |
337 | return undef; # don't know wtf to do |
338 | } |
e1d9e578 |
339 | elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) { |
3d56e026 |
340 | weaken( $destruction_registry->{$addr} = $_[0] ); |
341 | return 0; |
342 | } |
343 | else { |
344 | carp_unique ( sprintf ( |
345 | 'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY ' |
346 | . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your ' |
347 | . 'application, affecting *ALL* classes without active protection against ' |
348 | . 'this. Diagnose and fix the root cause ASAP!!!%s', |
349 | refdesc $_[0], |
350 | ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } ) |
351 | ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)" |
352 | : '' |
353 | ) |
354 | )); |
355 | |
356 | return 1; |
357 | } |
358 | } |
359 | } |
360 | |
7302b3e0 |
361 | my $module_name_rx = qr/ \A [A-Z_a-z] [0-9A-Z_a-z]* (?: :: [0-9A-Z_a-z]+ )* \z /x; |
362 | my $ver_rx = qr/ \A [0-9]+ (?: \. [0-9]+ )* (?: \_ [0-9]+ )* \z /x; |
363 | |
bf302897 |
364 | sub modver_gt_or_eq ($$) { |
b1dbf716 |
365 | my ($mod, $ver) = @_; |
366 | |
367 | croak "Nonsensical module name supplied" |
7302b3e0 |
368 | if ! defined $mod or $mod !~ $module_name_rx; |
b1dbf716 |
369 | |
370 | croak "Nonsensical minimum version supplied" |
7302b3e0 |
371 | if ! defined $ver or $ver !~ $ver_rx; |
372 | |
373 | no strict 'refs'; |
374 | my $ver_cache = ${"${mod}::__DBIC_MODULE_VERSION_CHECKS__"} ||= ( $mod->VERSION |
375 | ? {} |
376 | : croak "$mod does not seem to provide a version (perhaps it never loaded)" |
377 | ); |
378 | |
379 | ! defined $ver_cache->{$ver} |
380 | and |
381 | $ver_cache->{$ver} = do { |
b1dbf716 |
382 | |
7302b3e0 |
383 | local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ ) |
384 | if SPURIOUS_VERSION_CHECK_WARNINGS; |
b1dbf716 |
385 | |
7302b3e0 |
386 | local $@; |
387 | local $SIG{__DIE__}; |
388 | eval { $mod->VERSION($ver) } ? 1 : 0; |
389 | }; |
56270bba |
390 | |
7302b3e0 |
391 | $ver_cache->{$ver}; |
b1dbf716 |
392 | } |
393 | |
d634850b |
394 | sub modver_gt_or_eq_and_lt ($$$) { |
395 | my ($mod, $v_ge, $v_lt) = @_; |
396 | |
397 | croak "Nonsensical maximum version supplied" |
7302b3e0 |
398 | if ! defined $v_lt or $v_lt !~ $ver_rx; |
d634850b |
399 | |
400 | return ( |
401 | modver_gt_or_eq($mod, $v_ge) |
402 | and |
403 | ! modver_gt_or_eq($mod, $v_lt) |
404 | ) ? 1 : 0; |
405 | } |
406 | |
e3be2b6f |
407 | |
408 | # |
409 | # Why not just use some higher-level module or at least File::Spec here? |
410 | # Because: |
411 | # 1) This is a *very* rarely used function, and the deptree is large |
412 | # enough already as it is |
413 | # |
414 | # 2) (more importantly) Our tooling is utter shit in this area. There |
415 | # is no comprehensive support for UNC paths in PathTools and there |
416 | # are also various small bugs in representation across different |
417 | # path-manipulation CPAN offerings. |
418 | # |
419 | # Since this routine is strictly used for logical path processing (it |
420 | # *must* be able to work with not-yet-existing paths), use this seemingly |
421 | # simple but I *think* complete implementation to feed to other consumers |
422 | # |
423 | # If bugs are ever uncovered in this routine, *YOU ARE URGED TO RESIST* |
424 | # the impulse to bring in an external dependency. During runtime there |
425 | # is exactly one spot that could potentially maybe once in a blue moon |
426 | # use this function. Keep it lean. |
427 | # |
428 | sub parent_dir ($) { |
429 | ( $_[0] =~ m{ [\/\\] ( \.{0,2} ) ( [\/\\]* ) \z }x ) |
430 | ? ( |
431 | $_[0] |
432 | . |
433 | ( ( length($1) and ! length($2) ) ? '/' : '' ) |
434 | . |
435 | '../' |
436 | ) |
437 | : ( |
438 | require File::Spec |
439 | and |
440 | File::Spec->catpath ( |
441 | ( File::Spec->splitpath( "$_[0]" ) )[0,1], |
442 | '/', |
443 | ) |
444 | ) |
445 | ; |
446 | } |
447 | |
439a7283 |
448 | sub mkdir_p ($) { |
449 | require File::Path; |
450 | # do not ask for a recent version, use 1.x API calls |
451 | File::Path::mkpath([ "$_[0]" ]); # File::Path does not like objects |
452 | } |
453 | |
e3be2b6f |
454 | |
a9da9b6a |
455 | { |
456 | my $list_ctx_ok_stack_marker; |
457 | |
e89c7968 |
458 | sub fail_on_internal_wantarray () { |
a9da9b6a |
459 | return if $list_ctx_ok_stack_marker; |
460 | |
461 | if (! defined wantarray) { |
462 | croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard'); |
463 | } |
464 | |
465 | my $cf = 1; |
821edc09 |
466 | while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?: |
a9da9b6a |
467 | |
468 | # these are public API parts that alter behavior on wantarray |
469 | search | search_related | slice | search_literal |
470 | |
471 | | |
472 | |
473 | # these are explicitly prefixed, since we only recognize them as valid |
474 | # escapes when they come from the guts of CDBICompat |
475 | CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all ) |
476 | |
477 | ) $/x ) { |
478 | $cf++; |
479 | } |
480 | |
e89c7968 |
481 | my ($fr, $want, $argdesc); |
482 | { |
483 | package DB; |
821edc09 |
484 | $fr = [ CORE::caller($cf) ]; |
485 | $want = ( CORE::caller($cf-1) )[5]; |
e89c7968 |
486 | $argdesc = ref $DB::args[0] |
487 | ? DBIx::Class::_Util::refdesc($DB::args[0]) |
488 | : 'non ' |
489 | ; |
490 | }; |
491 | |
a9da9b6a |
492 | if ( |
e89c7968 |
493 | $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/ |
a9da9b6a |
494 | ) { |
a9da9b6a |
495 | DBIx::Class::Exception->throw( sprintf ( |
e89c7968 |
496 | "Improper use of %s instance in list context at %s line %d\n\n Stacktrace starts", |
497 | $argdesc, @{$fr}[1,2] |
a9da9b6a |
498 | ), 'with_stacktrace'); |
499 | } |
500 | |
501 | my $mark = []; |
502 | weaken ( $list_ctx_ok_stack_marker = $mark ); |
503 | $mark; |
504 | } |
505 | } |
506 | |
77c3a5dc |
507 | sub fail_on_internal_call { |
508 | my ($fr, $argdesc); |
509 | { |
510 | package DB; |
821edc09 |
511 | $fr = [ CORE::caller(1) ]; |
77c3a5dc |
512 | $argdesc = ref $DB::args[0] |
513 | ? DBIx::Class::_Util::refdesc($DB::args[0]) |
514 | : undef |
515 | ; |
516 | }; |
517 | |
518 | if ( |
519 | $argdesc |
520 | and |
521 | $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/ |
522 | and |
523 | $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/ # no point touching there |
524 | ) { |
525 | DBIx::Class::Exception->throw( sprintf ( |
526 | "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n Stacktrace starts", |
527 | $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do { |
528 | require B::Deparse; |
529 | no strict 'refs'; |
530 | B::Deparse->new->coderef2text(\&{$fr->[3]}) |
531 | }), |
532 | ), 'with_stacktrace'); |
533 | } |
534 | } |
535 | |
b1dbf716 |
536 | 1; |