[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / _Util.pm

package # hide from PAUSE
  DBIx::Class::_Util;

use warnings;
use strict;

use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);

BEGIN {
  package # hide from pause
    DBIx::Class::_ENV_;

  use Config;

  use constant {

    # but of course
    BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,

    BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,

    HAS_ITHREADS => $Config{useithreads} ? 1 : 0,

    DBICTEST => $INC{"DBICTest/Util.pm"} ? 1 : 0,

    # During 5.13 dev cycle HELEMs started to leak on copy
    # add an escape for these perls ON SMOKERS - a user will still get death
    PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ( "$]" >= 5.013005 and "$]" <= 5.013006) ),

    SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,

    ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,

    ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,

    STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,

    STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE => $ENV{DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE} ? 1 : 0,

    IV_SIZE => $Config{ivsize},

    OS_NAME => $^O,
  };

  if ( "$]" < 5.009_005) {
    require MRO::Compat;
    constant->import( OLD_MRO => 1 );
  }
  else {
    require mro;
    constant->import( OLD_MRO => 0 );
  }
}

# FIXME - this is not supposed to be here
# Carp::Skip to the rescue soon
use DBIx::Class::Carp '^DBIx::Class|^DBICTest';

use B ();
use Carp 'croak';
use Storable 'nfreeze';
use Scalar::Util qw(weaken blessed reftype refaddr);
use List::Util qw(first);
use Sub::Quote qw(qsub quote_sub);

# Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
BEGIN { *deep_clone = \&Storable::dclone }

use base 'Exporter';
our @EXPORT_OK = qw(
  sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  fail_on_internal_wantarray fail_on_internal_call
  refdesc refcount hrefaddr is_exception detected_reinvoked_destructor
  quote_sub qsub perlstring serialize deep_clone
  UNRESOLVABLE_CONDITION
);

use constant UNRESOLVABLE_CONDITION => \ '1 = 0';

sub sigwarn_silencer ($) {
  my $pattern = shift;

  croak "Expecting a regexp" if ref $pattern ne 'Regexp';

  my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };

  return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
}

sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };

sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }

sub refdesc ($) {
  croak "Expecting a reference" if ! length ref $_[0];

  # be careful not to trigger stringification,
  # reuse @_ as a scratch-pad
  sprintf '%s%s(0x%x)',
    ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
    reftype $_[0],
    refaddr($_[0]),
  ;
}

sub refcount ($) {
  croak "Expecting a reference" if ! length ref $_[0];

  # No tempvars - must operate on $_[0], otherwise the pad
  # will count as an extra ref
  B::svref_2object($_[0])->REFCNT;
}

sub serialize ($) {
  local $Storable::canonical = 1;
  nfreeze($_[0]);
}

sub is_exception ($) {
  my $e = $_[0];

  # this is not strictly correct - an eval setting $@ to undef
  # is *not* the same as an eval setting $@ to ''
  # but for the sake of simplicity assume the following for
  # the time being
  return 0 unless defined $e;

  my ($not_blank, $suberror);
  {
    local $@;
    eval {
      $not_blank = ($e ne '') ? 1 : 0;
      1;
    } or $suberror = $@;
  }

  if (defined $suberror) {
    if (length (my $class = blessed($e) )) {
      carp_unique( sprintf(
        'External exception class %s implements partial (broken) overloading '
      . 'preventing its instances from being used in simple ($x eq $y) '
      . 'comparisons. Given Perl\'s "globally cooperative" exception '
      . 'handling this type of brokenness is extremely dangerous on '
      . 'exception objects, as it may (and often does) result in silent '
      . '"exception substitution". DBIx::Class tries to work around this '
      . 'as much as possible, but other parts of your software stack may '
      . 'not be even aware of this. Please submit a bugreport against the '
      . 'distribution containing %s and in the meantime apply a fix similar '
      . 'to the one shown at %s, in order to ensure your exception handling '
      . 'is saner application-wide. What follows is the actual error text '
      . "as generated by Perl itself:\n\n%s\n ",
        $class,
        $class,
        'http://v.gd/DBIC_overload_tempfix/',
        $suberror,
      ));

      # workaround, keeps spice flowing
      $not_blank = ("$e" ne '') ? 1 : 0;
    }
    else {
      # not blessed yet failed the 'ne'... this makes 0 sense...
      # just throw further
      die $suberror
    }
  }
  elsif (
    # a ref evaluating to '' is definitively a "null object"
    ( not $not_blank )
      and
    length( my $class = ref $e )
  ) {
    carp_unique( sprintf(
      "Objects of external exception class '%s' stringify to '' (the "
    . 'empty string), implementing the so called null-object-pattern. '
    . 'Given Perl\'s "globally cooperative" exception handling using this '
    . 'class of exceptions is extremely dangerous, as it may (and often '
    . 'does) result in silent discarding of errors. DBIx::Class tries to '
    . 'work around this as much as possible, but other parts of your '
    . 'software stack may not be even aware of the problem. Please submit '
    . 'a bugreport against the distribution containing %s.',

      ($class) x 2,
    ));

    $not_blank = 1;
  }

  return $not_blank;
}

{
  my $destruction_registry = {};

  sub CLONE {
    $destruction_registry = { map
      { defined $_ ? ( refaddr($_) => $_ ) : () }
      values %$destruction_registry
    };
  }

  # This is almost invariably invoked from within DESTROY
  # throwing exceptions won't work
  sub detected_reinvoked_destructor {

    # quick "garbage collection" pass - prevents the registry
    # from slowly growing with a bunch of undef-valued keys
    defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
      for keys %$destruction_registry;

    if (! length ref $_[0]) {
      printf STDERR '%s() expects a blessed reference %s',
        (caller(0))[3],
        Carp::longmess,
      ;
      return undef; # don't know wtf to do
    }
    elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
      weaken( $destruction_registry->{$addr} = $_[0] );
      return 0;
    }
    else {
      carp_unique ( sprintf (
        'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
      . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
      . 'application, affecting *ALL* classes without active protection against '
      . 'this. Diagnose and fix the root cause ASAP!!!%s',
      refdesc $_[0],
        ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
          ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
          : ''
        )
      ));

      return 1;
    }
  }
}

sub modver_gt_or_eq ($$) {
  my ($mod, $ver) = @_;

  croak "Nonsensical module name supplied"
    if ! defined $mod or ! length $mod;

  croak "Nonsensical minimum version supplied"
    if ! defined $ver or $ver =~ /[^0-9\.\_]/;

  local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
    if SPURIOUS_VERSION_CHECK_WARNINGS;

  croak "$mod does not seem to provide a version (perhaps it never loaded)"
    unless $mod->VERSION;

  local $@;
  eval { $mod->VERSION($ver) } ? 1 : 0;
}

sub modver_gt_or_eq_and_lt ($$$) {
  my ($mod, $v_ge, $v_lt) = @_;

  croak "Nonsensical maximum version supplied"
    if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;

  return (
    modver_gt_or_eq($mod, $v_ge)
      and
    ! modver_gt_or_eq($mod, $v_lt)
  ) ? 1 : 0;
}

{
  my $list_ctx_ok_stack_marker;

  sub fail_on_internal_wantarray () {
    return if $list_ctx_ok_stack_marker;

    if (! defined wantarray) {
      croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
    }

    my $cf = 1;
    while ( ( (CORE::caller($cf+1))[3] || '' ) =~ / :: (?:

      # these are public API parts that alter behavior on wantarray
      search | search_related | slice | search_literal

        |

      # these are explicitly prefixed, since we only recognize them as valid
      # escapes when they come from the guts of CDBICompat
      CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )

    ) $/x ) {
      $cf++;
    }

    my ($fr, $want, $argdesc);
    {
      package DB;
      $fr = [ CORE::caller($cf) ];
      $want = ( CORE::caller($cf-1) )[5];
      $argdesc = ref $DB::args[0]
        ? DBIx::Class::_Util::refdesc($DB::args[0])
        : 'non '
      ;
    };

    if (
      $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
    ) {
      DBIx::Class::Exception->throw( sprintf (
        "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
        $argdesc, @{$fr}[1,2]
      ), 'with_stacktrace');
    }

    my $mark = [];
    weaken ( $list_ctx_ok_stack_marker = $mark );
    $mark;
  }
}

sub fail_on_internal_call {
  my ($fr, $argdesc);
  {
    package DB;
    $fr = [ CORE::caller(1) ];
    $argdesc = ref $DB::args[0]
      ? DBIx::Class::_Util::refdesc($DB::args[0])
      : undef
    ;
  };

  if (
    $argdesc
      and
    $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
      and
    $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
  ) {
    DBIx::Class::Exception->throw( sprintf (
      "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
      $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
        require B::Deparse;
        no strict 'refs';
        B::Deparse->new->coderef2text(\&{$fr->[3]})
      }),
    ), 'with_stacktrace');
  }
}

1;
Commit	Line	Data
b1dbf716	1	package # hide from PAUSE
	2	DBIx::Class::_Util;
	3
	4	use warnings;
	5	use strict;
	6
750a4ad2	7	use constant SPURIOUS_VERSION_CHECK_WARNINGS => ( "$]" < 5.010 ? 1 : 0);
b1dbf716	8
37873f78	9	BEGIN {
	10	package # hide from pause
	11	DBIx::Class::_ENV_;
	12
	13	use Config;
	14
	15	use constant {
	16
	17	# but of course
	18	BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
	19
750a4ad2	20	BROKEN_GOTO => ( "$]" < 5.008003 ) ? 1 : 0,
8d73fcd4	21
37873f78	22	HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
37873f78	23
69016f65	24	DBICTEST => $INC{"DBICTest/Util.pm"} ? 1 : 0,
37873f78	25
37873f78	26	# During 5.13 dev cycle HELEMs started to leak on copy
6cfb1d2f	27	# add an escape for these perls ON SMOKERS - a user will still get death
750a4ad2	28	PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ( "$]" >= 5.013005 and "$]" <= 5.013006) ),
37873f78	29
1b658919	30	SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
1b658919	31
37873f78	32	ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
37873f78	33
77c3a5dc	34	ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
77c3a5dc	35
2fdeef65	36	STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
2fdeef65	37
f45dc928	38	STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE => $ENV{DBIC_STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE} ? 1 : 0,
f45dc928	39
37873f78	40	IV_SIZE => $Config{ivsize},
00882d2c	41
00882d2c	42	OS_NAME => $^O,
37873f78	43	};
37873f78	44
750a4ad2	45	if ( "$]" < 5.009_005) {
37873f78	46	require MRO::Compat;
	47	constant->import( OLD_MRO => 1 );
	48	}
	49	else {
	50	require mro;
	51	constant->import( OLD_MRO => 0 );
	52	}
	53	}
	54
841efcb3	55	# FIXME - this is not supposed to be here
	56	# Carp::Skip to the rescue soon
	57	use DBIx::Class::Carp '^DBIx::Class\|^DBICTest';
	58
d7d45bdc	59	use B ();
841efcb3	60	use Carp 'croak';
d7d45bdc	61	use Storable 'nfreeze';
3d56e026	62	use Scalar::Util qw(weaken blessed reftype refaddr);
3705e3b2	63	use List::Util qw(first);
0020e364	64	use Sub::Quote qw(qsub quote_sub);
7f9a3f70	65
1c30a2e4	66	# Already correctly prototyped: perlbrew exec perl -MStorable -e 'warn prototype \&Storable::dclone'
	67	BEGIN { *deep_clone = \&Storable::dclone }
	68
b1dbf716	69	use base 'Exporter';
3705e3b2	70	our @EXPORT_OK = qw(
d634850b	71	sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
77c3a5dc	72	fail_on_internal_wantarray fail_on_internal_call
e1d9e578	73	refdesc refcount hrefaddr is_exception detected_reinvoked_destructor
1c30a2e4	74	quote_sub qsub perlstring serialize deep_clone
facd0e8e	75	UNRESOLVABLE_CONDITION
3705e3b2	76	);
052a832c	77
facd0e8e	78	use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
facd0e8e	79
bf302897	80	sub sigwarn_silencer ($) {
052a832c	81	my $pattern = shift;
	82
	83	croak "Expecting a regexp" if ref $pattern ne 'Regexp';
	84
	85	my $orig_sig_warn = $SIG{__WARN__} \|\| sub { CORE::warn(@_) };
	86
	87	return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
	88	}
b1dbf716	89
01b25f12	90	sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
01b25f12	91
3d56e026	92	sub hrefaddr ($) { sprintf '0x%x', &refaddr\|\|0 }
8433421f	93
	94	sub refdesc ($) {
	95	croak "Expecting a reference" if ! length ref $_[0];
	96
	97	# be careful not to trigger stringification,
	98	# reuse @_ as a scratch-pad
	99	sprintf '%s%s(0x%x)',
	100	( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
	101	reftype $_[0],
3d56e026	102	refaddr($_[0]),
8433421f	103	;
8433421f	104	}
bf302897	105
bf302897	106	sub refcount ($) {
dac7972a	107	croak "Expecting a reference" if ! length ref $_[0];
dac7972a	108
dac7972a	109	# No tempvars - must operate on $_[0], otherwise the pad
	110	# will count as an extra ref
	111	B::svref_2object($_[0])->REFCNT;
	112	}
	113
b34d9331	114	sub serialize ($) {
b34d9331	115	local $Storable::canonical = 1;
d7d45bdc	116	nfreeze($_[0]);
b34d9331	117	}
b34d9331	118
841efcb3	119	sub is_exception ($) {
	120	my $e = $_[0];
	121
a0414138	122	# this is not strictly correct - an eval setting $@ to undef
	123	# is not the same as an eval setting $@ to ''
	124	# but for the sake of simplicity assume the following for
	125	# the time being
	126	return 0 unless defined $e;
	127
841efcb3	128	my ($not_blank, $suberror);
	129	{
	130	local $@;
	131	eval {
	132	$not_blank = ($e ne '') ? 1 : 0;
	133	1;
	134	} or $suberror = $@;
	135	}
	136
	137	if (defined $suberror) {
	138	if (length (my $class = blessed($e) )) {
	139	carp_unique( sprintf(
9bea2000	140	'External exception class %s implements partial (broken) overloading '
9bea2000	141	. 'preventing its instances from being used in simple ($x eq $y) '
841efcb3	142	. 'comparisons. Given Perl\'s "globally cooperative" exception '
	143	. 'handling this type of brokenness is extremely dangerous on '
	144	. 'exception objects, as it may (and often does) result in silent '
	145	. '"exception substitution". DBIx::Class tries to work around this '
	146	. 'as much as possible, but other parts of your software stack may '
	147	. 'not be even aware of this. Please submit a bugreport against the '
	148	. 'distribution containing %s and in the meantime apply a fix similar '
	149	. 'to the one shown at %s, in order to ensure your exception handling '
	150	. 'is saner application-wide. What follows is the actual error text '
	151	. "as generated by Perl itself:\n\n%s\n ",
9bea2000	152	$class,
841efcb3	153	$class,
	154	'http://v.gd/DBIC_overload_tempfix/',
	155	$suberror,
	156	));
	157
	158	# workaround, keeps spice flowing
	159	$not_blank = ("$e" ne '') ? 1 : 0;
	160	}
	161	else {
	162	# not blessed yet failed the 'ne'... this makes 0 sense...
	163	# just throw further
	164	die $suberror
	165	}
	166	}
84e4e006	167	elsif (
	168	# a ref evaluating to '' is definitively a "null object"
	169	( not $not_blank )
	170	and
	171	length( my $class = ref $e )
	172	) {
	173	carp_unique( sprintf(
	174	"Objects of external exception class '%s' stringify to '' (the "
	175	. 'empty string), implementing the so called null-object-pattern. '
	176	. 'Given Perl\'s "globally cooperative" exception handling using this '
	177	. 'class of exceptions is extremely dangerous, as it may (and often '
	178	. 'does) result in silent discarding of errors. DBIx::Class tries to '
	179	. 'work around this as much as possible, but other parts of your '
	180	. 'software stack may not be even aware of the problem. Please submit '
	181	. 'a bugreport against the distribution containing %s.',
	182
	183	($class) x 2,
	184	));
	185
	186	$not_blank = 1;
	187	}
841efcb3	188
	189	return $not_blank;
	190	}
	191
3d56e026	192	{
	193	my $destruction_registry = {};
	194
	195	sub CLONE {
	196	$destruction_registry = { map
	197	{ defined $_ ? ( refaddr($_) => $_ ) : () }
	198	values %$destruction_registry
	199	};
	200	}
	201
	202	# This is almost invariably invoked from within DESTROY
	203	# throwing exceptions won't work
e1d9e578	204	sub detected_reinvoked_destructor {
3d56e026	205
	206	# quick "garbage collection" pass - prevents the registry
	207	# from slowly growing with a bunch of undef-valued keys
	208	defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
	209	for keys %$destruction_registry;
	210
e1d9e578	211	if (! length ref $_[0]) {
e1d9e578	212	printf STDERR '%s() expects a blessed reference %s',
3d56e026	213	(caller(0))[3],
	214	Carp::longmess,
	215	;
	216	return undef; # don't know wtf to do
	217	}
e1d9e578	218	elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
3d56e026	219	weaken( $destruction_registry->{$addr} = $_[0] );
	220	return 0;
	221	}
	222	else {
	223	carp_unique ( sprintf (
	224	'Preventing MULTIPLE DESTROY() invocations on %s - an *EXTREMELY '
	225	. 'DANGEROUS* condition which is ALMOST CERTAINLY GLOBAL within your '
	226	. 'application, affecting ALL classes without active protection against '
	227	. 'this. Diagnose and fix the root cause ASAP!!!%s',
	228	refdesc $_[0],
	229	( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
	230	? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
	231	: ''
	232	)
	233	));
	234
	235	return 1;
	236	}
	237	}
	238	}
	239
bf302897	240	sub modver_gt_or_eq ($$) {
b1dbf716	241	my ($mod, $ver) = @_;
	242
	243	croak "Nonsensical module name supplied"
	244	if ! defined $mod or ! length $mod;
	245
	246	croak "Nonsensical minimum version supplied"
	247	if ! defined $ver or $ver =~ /[^0-9\.\_]/;
	248
052a832c	249	local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
052a832c	250	if SPURIOUS_VERSION_CHECK_WARNINGS;
b1dbf716	251
56270bba	252	croak "$mod does not seem to provide a version (perhaps it never loaded)"
	253	unless $mod->VERSION;
	254
b1dbf716	255	local $@;
	256	eval { $mod->VERSION($ver) } ? 1 : 0;
	257	}
	258
d634850b	259	sub modver_gt_or_eq_and_lt ($$$) {
	260	my ($mod, $v_ge, $v_lt) = @_;
	261
	262	croak "Nonsensical maximum version supplied"
	263	if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
	264
	265	return (
	266	modver_gt_or_eq($mod, $v_ge)
	267	and
	268	! modver_gt_or_eq($mod, $v_lt)
	269	) ? 1 : 0;
	270	}
	271
a9da9b6a	272	{
	273	my $list_ctx_ok_stack_marker;
	274
e89c7968	275	sub fail_on_internal_wantarray () {
a9da9b6a	276	return if $list_ctx_ok_stack_marker;
	277
	278	if (! defined wantarray) {
	279	croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
	280	}
	281
	282	my $cf = 1;
821edc09	283	while ( ( (CORE::caller($cf+1))[3] \|\| '' ) =~ / :: (?:
a9da9b6a	284
	285	# these are public API parts that alter behavior on wantarray
	286	search \| search_related \| slice \| search_literal
	287
	288	\|
	289
	290	# these are explicitly prefixed, since we only recognize them as valid
	291	# escapes when they come from the guts of CDBICompat
	292	CDBICompat .*? :: (?: search_where \| retrieve_from_sql \| retrieve_all )
	293
	294	) $/x ) {
	295	$cf++;
	296	}
	297
e89c7968	298	my ($fr, $want, $argdesc);
	299	{
	300	package DB;
821edc09	301	$fr = [ CORE::caller($cf) ];
821edc09	302	$want = ( CORE::caller($cf-1) )[5];
e89c7968	303	$argdesc = ref $DB::args[0]
	304	? DBIx::Class::_Util::refdesc($DB::args[0])
	305	: 'non '
	306	;
	307	};
	308
a9da9b6a	309	if (
e89c7968	310	$want and $fr->[0] =~ /^(?:DBIx::Class\|DBICx::)/
a9da9b6a	311	) {
a9da9b6a	312	DBIx::Class::Exception->throw( sprintf (
e89c7968	313	"Improper use of %s instance in list context at %s line %d\n\n Stacktrace starts",
e89c7968	314	$argdesc, @{$fr}[1,2]
a9da9b6a	315	), 'with_stacktrace');
	316	}
	317
	318	my $mark = [];
	319	weaken ( $list_ctx_ok_stack_marker = $mark );
	320	$mark;
	321	}
	322	}
	323
77c3a5dc	324	sub fail_on_internal_call {
	325	my ($fr, $argdesc);
	326	{
	327	package DB;
821edc09	328	$fr = [ CORE::caller(1) ];
77c3a5dc	329	$argdesc = ref $DB::args[0]
	330	? DBIx::Class::_Util::refdesc($DB::args[0])
	331	: undef
	332	;
	333	};
	334
	335	if (
	336	$argdesc
	337	and
	338	$fr->[0] =~ /^(?:DBIx::Class\|DBICx::)/
	339	and
	340	$fr->[1] !~ /\b(?:CDBICompat\|ResultSetProxy)\b/ # no point touching there
	341	) {
	342	DBIx::Class::Exception->throw( sprintf (
	343	"Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n Stacktrace starts",
	344	$fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] \|\| do {
	345	require B::Deparse;
	346	no strict 'refs';
	347	B::Deparse->new->coderef2text(\&{$fr->[3]})
	348	}),
	349	), 'with_stacktrace');
	350	}
	351	}
	352
b1dbf716	353	1;