[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / _Util.pm

package # hide from PAUSE
  DBIx::Class::_Util;

use warnings;
use strict;

# Temporary - tempextlib
use namespace::clean;
BEGIN {
  require Module::Runtime;
  require File::Spec;

  # There can be only one of these, make sure we get the bundled part and
  # *not* something off the site lib
  for (qw(
    DBIx::Class::SQLMaker
    SQL::Abstract
    SQL::Abstract::Test
  )) {
    if ($INC{Module::Runtime::module_notional_filename($_)}) {
      die "\nUnable to continue - a part of the bundled templib contents "
        . "was already loaded (likely an older version from CPAN). "
        . "Make sure that @{[ __PACKAGE__ ]} is loaded before $_\n\n"
      ;
    }
  }

  our ($HERE) = File::Spec->rel2abs(
    File::Spec->catdir( (File::Spec->splitpath(__FILE__))[1], '_TempExtlib' )
  ) =~ /^(.*)$/; # screw you, taint mode

  die "TempExtlib $HERE does not seem to exist - perhaps you need to run `perl Makefile.PL` in the DBIC checkout?\n"
    unless -d $HERE;

  unshift @INC, $HERE;
}

use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);

BEGIN {
  package # hide from pause
    DBIx::Class::_ENV_;

  use Config;

  use constant {

    # but of course
    BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,

    BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,

    HAS_ITHREADS => $Config{useithreads} ? 1 : 0,

    # ::Runmode would only be loaded by DBICTest, which in turn implies t/
    DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,

    # During 5.13 dev cycle HELEMs started to leak on copy
    # add an escape for these perls ON SMOKERS - a user will still get death
    PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),

    SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,

    ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,

    ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,

    IV_SIZE => $Config{ivsize},

    OS_NAME => $^O,
  };

  if ($] < 5.009_005) {
    require MRO::Compat;
    constant->import( OLD_MRO => 1 );
  }
  else {
    require mro;
    constant->import( OLD_MRO => 0 );
  }
}

# FIXME - this is not supposed to be here
# Carp::Skip to the rescue soon
use DBIx::Class::Carp '^DBIx::Class|^DBICTest';

use Carp 'croak';
use Scalar::Util qw(weaken blessed reftype);
use List::Util qw(first);

# DO NOT edit away without talking to riba first, he will just put it back
# BEGIN pre-Moo2 import block
BEGIN {
  my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};
  local $ENV{PERL_STRICTURES_EXTRA} = 0;
  require Sub::Quote; Sub::Quote->import('quote_sub');
  ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
}
sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
# END pre-Moo2 import block

use base 'Exporter';
our @EXPORT_OK = qw(
  sigwarn_silencer modver_gt_or_eq
  fail_on_internal_wantarray fail_on_internal_call
  refdesc refcount hrefaddr is_exception
  quote_sub qsub perlstring
  UNRESOLVABLE_CONDITION
);

use constant UNRESOLVABLE_CONDITION => \ '1 = 0';

sub sigwarn_silencer ($) {
  my $pattern = shift;

  croak "Expecting a regexp" if ref $pattern ne 'Regexp';

  my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };

  return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
}

sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };

sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }

sub refdesc ($) {
  croak "Expecting a reference" if ! length ref $_[0];

  # be careful not to trigger stringification,
  # reuse @_ as a scratch-pad
  sprintf '%s%s(0x%x)',
    ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
    reftype $_[0],
    Scalar::Util::refaddr($_[0]),
  ;
}

sub refcount ($) {
  croak "Expecting a reference" if ! length ref $_[0];

  require B;
  # No tempvars - must operate on $_[0], otherwise the pad
  # will count as an extra ref
  B::svref_2object($_[0])->REFCNT;
}

sub is_exception ($) {
  my $e = $_[0];

  # this is not strictly correct - an eval setting $@ to undef
  # is *not* the same as an eval setting $@ to ''
  # but for the sake of simplicity assume the following for
  # the time being
  return 0 unless defined $e;

  my ($not_blank, $suberror);
  {
    local $@;
    eval {
      $not_blank = ($e ne '') ? 1 : 0;
      1;
    } or $suberror = $@;
  }

  if (defined $suberror) {
    if (length (my $class = blessed($e) )) {
      carp_unique( sprintf(
        'External exception class %s implements partial (broken) overloading '
      . 'preventing its instances from being used in simple ($x eq $y) '
      . 'comparisons. Given Perl\'s "globally cooperative" exception '
      . 'handling this type of brokenness is extremely dangerous on '
      . 'exception objects, as it may (and often does) result in silent '
      . '"exception substitution". DBIx::Class tries to work around this '
      . 'as much as possible, but other parts of your software stack may '
      . 'not be even aware of this. Please submit a bugreport against the '
      . 'distribution containing %s and in the meantime apply a fix similar '
      . 'to the one shown at %s, in order to ensure your exception handling '
      . 'is saner application-wide. What follows is the actual error text '
      . "as generated by Perl itself:\n\n%s\n ",
        $class,
        $class,
        'http://v.gd/DBIC_overload_tempfix/',
        $suberror,
      ));

      # workaround, keeps spice flowing
      $not_blank = ("$e" ne '') ? 1 : 0;
    }
    else {
      # not blessed yet failed the 'ne'... this makes 0 sense...
      # just throw further
      die $suberror
    }
  }

  return $not_blank;
}

sub modver_gt_or_eq ($$) {
  my ($mod, $ver) = @_;

  croak "Nonsensical module name supplied"
    if ! defined $mod or ! length $mod;

  croak "Nonsensical minimum version supplied"
    if ! defined $ver or $ver =~ /[^0-9\.\_]/;

  local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
    if SPURIOUS_VERSION_CHECK_WARNINGS;

  croak "$mod does not seem to provide a version (perhaps it never loaded)"
    unless $mod->VERSION;

  local $@;
  eval { $mod->VERSION($ver) } ? 1 : 0;
}

{
  my $list_ctx_ok_stack_marker;

  sub fail_on_internal_wantarray () {
    return if $list_ctx_ok_stack_marker;

    if (! defined wantarray) {
      croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
    }

    my $cf = 1;
    while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:

      # these are public API parts that alter behavior on wantarray
      search | search_related | slice | search_literal

        |

      # these are explicitly prefixed, since we only recognize them as valid
      # escapes when they come from the guts of CDBICompat
      CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )

    ) $/x ) {
      $cf++;
    }

    my ($fr, $want, $argdesc);
    {
      package DB;
      $fr = [ caller($cf) ];
      $want = ( caller($cf-1) )[5];
      $argdesc = ref $DB::args[0]
        ? DBIx::Class::_Util::refdesc($DB::args[0])
        : 'non '
      ;
    };

    if (
      $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
    ) {
      DBIx::Class::Exception->throw( sprintf (
        "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
        $argdesc, @{$fr}[1,2]
      ), 'with_stacktrace');
    }

    my $mark = [];
    weaken ( $list_ctx_ok_stack_marker = $mark );
    $mark;
  }
}

sub fail_on_internal_call {
  my ($fr, $argdesc);
  {
    package DB;
    $fr = [ caller(1) ];
    $argdesc = ref $DB::args[0]
      ? DBIx::Class::_Util::refdesc($DB::args[0])
      : undef
    ;
  };

  if (
    $argdesc
      and
    $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
      and
    $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
  ) {
    DBIx::Class::Exception->throw( sprintf (
      "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
      $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
        require B::Deparse;
        no strict 'refs';
        B::Deparse->new->coderef2text(\&{$fr->[3]})
      }),
    ), 'with_stacktrace');
  }
}

1;
Commit	Line	Data
b1dbf716	1	package # hide from PAUSE
	2	DBIx::Class::_Util;
	3
	4	use warnings;
	5	use strict;
	6
d0435d75	7	# Temporary - tempextlib
	8	use namespace::clean;
	9	BEGIN {
	10	require Module::Runtime;
	11	require File::Spec;
	12
	13	# There can be only one of these, make sure we get the bundled part and
	14	# not something off the site lib
	15	for (qw(
	16	DBIx::Class::SQLMaker
	17	SQL::Abstract
	18	SQL::Abstract::Test
	19	)) {
	20	if ($INC{Module::Runtime::module_notional_filename($_)}) {
	21	die "\nUnable to continue - a part of the bundled templib contents "
	22	. "was already loaded (likely an older version from CPAN). "
	23	. "Make sure that @{[ __PACKAGE__ ]} is loaded before $_\n\n"
	24	;
	25	}
	26	}
	27
	28	our ($HERE) = File::Spec->rel2abs(
	29	File::Spec->catdir( (File::Spec->splitpath(__FILE__))[1], '_TempExtlib' )
	30	) =~ /^(.*)$/; # screw you, taint mode
	31
c1ce337f	32	die "TempExtlib $HERE does not seem to exist - perhaps you need to run `perl Makefile.PL` in the DBIC checkout?\n"
	33	unless -d $HERE;
	34
d0435d75	35	unshift @INC, $HERE;
	36	}
	37
b1dbf716	38	use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
b1dbf716	39
37873f78	40	BEGIN {
	41	package # hide from pause
	42	DBIx::Class::_ENV_;
	43
	44	use Config;
	45
	46	use constant {
	47
	48	# but of course
	49	BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
	50
8d73fcd4	51	BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
8d73fcd4	52
37873f78	53	HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
	54
	55	# ::Runmode would only be loaded by DBICTest, which in turn implies t/
	56	DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
	57
	58	# During 5.13 dev cycle HELEMs started to leak on copy
6cfb1d2f	59	# add an escape for these perls ON SMOKERS - a user will still get death
6cfb1d2f	60	PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
37873f78	61
1b658919	62	SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
1b658919	63
37873f78	64	ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
37873f78	65
77c3a5dc	66	ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
77c3a5dc	67
37873f78	68	IV_SIZE => $Config{ivsize},
00882d2c	69
00882d2c	70	OS_NAME => $^O,
37873f78	71	};
	72
	73	if ($] < 5.009_005) {
	74	require MRO::Compat;
	75	constant->import( OLD_MRO => 1 );
	76	}
	77	else {
	78	require mro;
	79	constant->import( OLD_MRO => 0 );
	80	}
	81	}
	82
841efcb3	83	# FIXME - this is not supposed to be here
	84	# Carp::Skip to the rescue soon
	85	use DBIx::Class::Carp '^DBIx::Class\|^DBICTest';
	86
	87	use Carp 'croak';
bf302897	88	use Scalar::Util qw(weaken blessed reftype);
3705e3b2	89	use List::Util qw(first);
b1dbf716	90
7f9a3f70	91	# DO NOT edit away without talking to riba first, he will just put it back
	92	# BEGIN pre-Moo2 import block
	93	BEGIN {
	94	my $initial_fatal_bits = (${^WARNING_BITS}\|\|'') & $warnings::DeadBits{all};
	95	local $ENV{PERL_STRICTURES_EXTRA} = 0;
	96	require Sub::Quote; Sub::Quote->import('quote_sub');
	97	${^WARNING_BITS} &= ( $initial_fatal_bits \| ~ $warnings::DeadBits{all} );
	98	}
	99	sub qsub ($) { goto &quote_sub } # no point depping on new Moo just for this
	100	# END pre-Moo2 import block
	101
b1dbf716	102	use base 'Exporter';
3705e3b2	103	our @EXPORT_OK = qw(
77c3a5dc	104	sigwarn_silencer modver_gt_or_eq
77c3a5dc	105	fail_on_internal_wantarray fail_on_internal_call
8433421f	106	refdesc refcount hrefaddr is_exception
7f9a3f70	107	quote_sub qsub perlstring
facd0e8e	108	UNRESOLVABLE_CONDITION
3705e3b2	109	);
052a832c	110
facd0e8e	111	use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
facd0e8e	112
bf302897	113	sub sigwarn_silencer ($) {
052a832c	114	my $pattern = shift;
	115
	116	croak "Expecting a regexp" if ref $pattern ne 'Regexp';
	117
	118	my $orig_sig_warn = $SIG{__WARN__} \|\| sub { CORE::warn(@_) };
	119
	120	return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
	121	}
b1dbf716	122
01b25f12	123	sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
01b25f12	124
8433421f	125	sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr\|\|0 }
	126
	127	sub refdesc ($) {
	128	croak "Expecting a reference" if ! length ref $_[0];
	129
	130	# be careful not to trigger stringification,
	131	# reuse @_ as a scratch-pad
	132	sprintf '%s%s(0x%x)',
	133	( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
	134	reftype $_[0],
	135	Scalar::Util::refaddr($_[0]),
	136	;
	137	}
bf302897	138
bf302897	139	sub refcount ($) {
dac7972a	140	croak "Expecting a reference" if ! length ref $_[0];
	141
	142	require B;
	143	# No tempvars - must operate on $_[0], otherwise the pad
	144	# will count as an extra ref
	145	B::svref_2object($_[0])->REFCNT;
	146	}
	147
841efcb3	148	sub is_exception ($) {
	149	my $e = $_[0];
	150
a0414138	151	# this is not strictly correct - an eval setting $@ to undef
	152	# is not the same as an eval setting $@ to ''
	153	# but for the sake of simplicity assume the following for
	154	# the time being
	155	return 0 unless defined $e;
	156
841efcb3	157	my ($not_blank, $suberror);
	158	{
	159	local $@;
	160	eval {
	161	$not_blank = ($e ne '') ? 1 : 0;
	162	1;
	163	} or $suberror = $@;
	164	}
	165
	166	if (defined $suberror) {
	167	if (length (my $class = blessed($e) )) {
	168	carp_unique( sprintf(
9bea2000	169	'External exception class %s implements partial (broken) overloading '
9bea2000	170	. 'preventing its instances from being used in simple ($x eq $y) '
841efcb3	171	. 'comparisons. Given Perl\'s "globally cooperative" exception '
	172	. 'handling this type of brokenness is extremely dangerous on '
	173	. 'exception objects, as it may (and often does) result in silent '
	174	. '"exception substitution". DBIx::Class tries to work around this '
	175	. 'as much as possible, but other parts of your software stack may '
	176	. 'not be even aware of this. Please submit a bugreport against the '
	177	. 'distribution containing %s and in the meantime apply a fix similar '
	178	. 'to the one shown at %s, in order to ensure your exception handling '
	179	. 'is saner application-wide. What follows is the actual error text '
	180	. "as generated by Perl itself:\n\n%s\n ",
9bea2000	181	$class,
841efcb3	182	$class,
	183	'http://v.gd/DBIC_overload_tempfix/',
	184	$suberror,
	185	));
	186
	187	# workaround, keeps spice flowing
	188	$not_blank = ("$e" ne '') ? 1 : 0;
	189	}
	190	else {
	191	# not blessed yet failed the 'ne'... this makes 0 sense...
	192	# just throw further
	193	die $suberror
	194	}
	195	}
	196
	197	return $not_blank;
	198	}
	199
bf302897	200	sub modver_gt_or_eq ($$) {
b1dbf716	201	my ($mod, $ver) = @_;
	202
	203	croak "Nonsensical module name supplied"
	204	if ! defined $mod or ! length $mod;
	205
	206	croak "Nonsensical minimum version supplied"
	207	if ! defined $ver or $ver =~ /[^0-9\.\_]/;
	208
052a832c	209	local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
052a832c	210	if SPURIOUS_VERSION_CHECK_WARNINGS;
b1dbf716	211
56270bba	212	croak "$mod does not seem to provide a version (perhaps it never loaded)"
	213	unless $mod->VERSION;
	214
b1dbf716	215	local $@;
	216	eval { $mod->VERSION($ver) } ? 1 : 0;
	217	}
	218
a9da9b6a	219	{
	220	my $list_ctx_ok_stack_marker;
	221
e89c7968	222	sub fail_on_internal_wantarray () {
a9da9b6a	223	return if $list_ctx_ok_stack_marker;
	224
	225	if (! defined wantarray) {
	226	croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
	227	}
	228
	229	my $cf = 1;
	230	while ( ( (caller($cf+1))[3] \|\| '' ) =~ / :: (?:
	231
	232	# these are public API parts that alter behavior on wantarray
	233	search \| search_related \| slice \| search_literal
	234
	235	\|
	236
	237	# these are explicitly prefixed, since we only recognize them as valid
	238	# escapes when they come from the guts of CDBICompat
	239	CDBICompat .*? :: (?: search_where \| retrieve_from_sql \| retrieve_all )
	240
	241	) $/x ) {
	242	$cf++;
	243	}
	244
e89c7968	245	my ($fr, $want, $argdesc);
	246	{
	247	package DB;
	248	$fr = [ caller($cf) ];
	249	$want = ( caller($cf-1) )[5];
	250	$argdesc = ref $DB::args[0]
	251	? DBIx::Class::_Util::refdesc($DB::args[0])
	252	: 'non '
	253	;
	254	};
	255
a9da9b6a	256	if (
e89c7968	257	$want and $fr->[0] =~ /^(?:DBIx::Class\|DBICx::)/
a9da9b6a	258	) {
a9da9b6a	259	DBIx::Class::Exception->throw( sprintf (
e89c7968	260	"Improper use of %s instance in list context at %s line %d\n\n Stacktrace starts",
e89c7968	261	$argdesc, @{$fr}[1,2]
a9da9b6a	262	), 'with_stacktrace');
	263	}
	264
	265	my $mark = [];
	266	weaken ( $list_ctx_ok_stack_marker = $mark );
	267	$mark;
	268	}
	269	}
	270
77c3a5dc	271	sub fail_on_internal_call {
	272	my ($fr, $argdesc);
	273	{
	274	package DB;
	275	$fr = [ caller(1) ];
	276	$argdesc = ref $DB::args[0]
	277	? DBIx::Class::_Util::refdesc($DB::args[0])
	278	: undef
	279	;
	280	};
	281
	282	if (
	283	$argdesc
	284	and
	285	$fr->[0] =~ /^(?:DBIx::Class\|DBICx::)/
	286	and
	287	$fr->[1] !~ /\b(?:CDBICompat\|ResultSetProxy)\b/ # no point touching there
	288	) {
	289	DBIx::Class::Exception->throw( sprintf (
	290	"Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n Stacktrace starts",
	291	$fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] \|\| do {
	292	require B::Deparse;
	293	no strict 'refs';
	294	B::Deparse->new->coderef2text(\&{$fr->[3]})
	295	}),
	296	), 'with_stacktrace');
	297	}
	298	}
	299
b1dbf716	300	1;