[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / ResultSource / RowParser.pm

package # hide from the pauses
  DBIx::Class::ResultSource::RowParser;

use strict;
use warnings;

use base 'DBIx::Class';

use Try::Tiny;
use List::Util qw(first max);
use Scalar::Util qw(blessed);

use DBIx::Class::ResultSource::RowParser::Util qw(
  assemble_simple_parser
  assemble_collapsing_parser
);

use namespace::clean;

# Accepts one or more relationships for the current source and returns an
# array of column names for each of those relationships. Column names are
# prefixed relative to the current source, in accordance with where they appear
# in the supplied relationships.
sub _resolve_prefetch {
  my ($self, $pre, $alias, $alias_map, $order, $pref_path) = @_;
  $pref_path ||= [];

  if (not defined $pre or not length $pre) {
    return ();
  }
  elsif( ref $pre eq 'ARRAY' ) {
    return
      map { $self->_resolve_prefetch( $_, $alias, $alias_map, $order, [ @$pref_path ] ) }
        @$pre;
  }
  elsif( ref $pre eq 'HASH' ) {
    my @ret =
    map {
      $self->_resolve_prefetch($_, $alias, $alias_map, $order, [ @$pref_path ] ),
      $self->related_source($_)->_resolve_prefetch(
         $pre->{$_}, "${alias}.$_", $alias_map, $order, [ @$pref_path, $_] )
    } keys %$pre;
    return @ret;
  }
  elsif( ref $pre ) {
    $self->throw_exception(
      "don't know how to resolve prefetch reftype ".ref($pre));
  }
  else {
    my $p = $alias_map;
    $p = $p->{$_} for (@$pref_path, $pre);

    $self->throw_exception (
      "Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
      . join (' -> ', @$pref_path, $pre)
    ) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );

    my $as = shift @{$p->{-join_aliases}};

    my $rel_info = $self->relationship_info( $pre );
    $self->throw_exception( $self->source_name . " has no such relationship '$pre'" )
      unless $rel_info;

    my $as_prefix = ($alias =~ /^.*?\.(.+)$/ ? $1.'.' : '');

    return map { [ "${as}.$_", "${as_prefix}${pre}.$_", ] }
      $self->related_source($pre)->columns;
  }
}

# Takes an arrayref of {as} dbic column aliases and the collapse and select
# attributes from the same $rs (the selector requirement is a temporary
# workaround... I hope), and returns a coderef capable of:
# my $me_pref_clps = $coderef->([$rs->cursor->next/all])
# Where the $me_pref_clps arrayref is the future argument to inflate_result()
#
# For an example of this coderef in action (and to see its guts) look at
# t/resultset/rowparser_internals.t
#
# This is a huge performance win, as we call the same code for every row
# returned from the db, thus avoiding repeated method lookups when traversing
# relationships
#
# Also since the coderef is completely stateless (the returned structure is
# always fresh on every new invocation) this is a very good opportunity for
# memoization if further speed improvements are needed
#
# The way we construct this coderef is somewhat fugly, although the result is
# really worth it. The final coderef does not perform any kind of recursion -
# the entire nested structure constructor is rolled out into a single scope.
#
# In any case - the output of this thing is meticulously micro-tested, so
# any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
#
sub _mk_row_parser {
  # $args and $attrs are separated to delineate what is core collapser stuff and
  # what is dbic $rs specific
  my ($self, $args, $attrs) = @_;

  die "HRI without pruning makes zero sense"
  if ( $args->{hri_style} && ! $args->{prune_null_branches} );

  my %common = (
    hri_style => $args->{hri_style},
    prune_null_branches => $args->{prune_null_branches},
    val_index => { map
      { $args->{inflate_map}[$_] => $_ }
      ( 0 .. $#{$args->{inflate_map}} )
    },
  );

  my $check_null_columns;

  my $src = (! $args->{collapse} ) ? assemble_simple_parser(\%common) : do {
    my $collapse_map = $self->_resolve_collapse ({
      # FIXME
      # only consider real columns (not functions) during collapse resolution
      # this check shouldn't really be here, as fucktards are not supposed to
      # alias random crap to existing column names anyway, but still - just in
      # case
      # FIXME !!!! - this does not yet deal with unbalanced selectors correctly
      # (it is now trivial as the attrs specify where things go out of sync
      # needs MOAR tests)
      as => { map
        { ref $attrs->{select}[$common{val_index}{$_}] ? () : ( $_ => $common{val_index}{$_} ) }
        keys %{$common{val_index}}
      },
      premultiplied => $args->{premultiplied},
    });

    $check_null_columns = $collapse_map->{-identifying_columns}
      if @{$collapse_map->{-identifying_columns}};

    assemble_collapsing_parser({
      %common,
      collapse_map => $collapse_map,
    });
  };

  return (
    $args->{eval} ? ( eval "sub $src" || die $@ ) : $src,
    $check_null_columns,
  );
}


# Takes an arrayref selection list and generates a collapse-map representing
# row-object fold-points. Every relationship is assigned a set of unique,
# non-nullable columns (which may *not even be* from the same resultset)
# and the collapser will use this information to correctly distinguish
# data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
# for extensive RV examples
sub _resolve_collapse {
  my ($self, $args, $common_args) = @_;

  # for comprehensible error messages put ourselves at the head of the relationship chain
  $args->{_rel_chain} ||= [ $self->source_name ];

  # record top-level fully-qualified column index, signify toplevelness
  unless ($common_args->{_as_fq_idx}) {
    $common_args->{_as_fq_idx} = { %{$args->{as}} };
    $args->{_is_top_level} = 1;
  };

  my ($my_cols, $rel_cols);
  for (keys %{$args->{as}}) {
    if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
      $rel_cols->{$1}{$2} = 1;
    }
    else {
      $my_cols->{$_} = {};  # important for ||='s below
    }
  }

  my $relinfo;
  # run through relationships, collect metadata
  for my $rel (keys %$rel_cols) {
    my $inf = $self->relationship_info ($rel);

    $relinfo->{$rel} = {
      is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
      is_inner => ( ( $inf->{attrs}{join_type} || '' ) !~ /^left/i),
      rsrc => $self->related_source($rel),
    };

    # FIME - need to use _resolve_cond here instead
    my $cond = $inf->{cond};

    if (
      ref $cond eq 'HASH'
        and
      keys %$cond
        and
      ! defined first { $_ !~ /^foreign\./ } (keys %$cond)
        and
      ! defined first { $_ !~ /^self\./ } (values %$cond)
    ) {
      for my $f (keys %$cond) {
        my $s = $cond->{$f};
        $_ =~ s/^ (?: foreign | self ) \.//x for ($f, $s);
        $relinfo->{$rel}{fk_map}{$s} = $f;
      }
    } elsif (blessed($cond) and $cond->isa('Data::Query::ExprBuilder')) {
      my $cols = $self->_join_condition_to_hashref($cond->{expr});
      @{$relinfo->{$rel}{fk_map}}{values %$cols} = keys %$cols;
    }
  }

  # inject non-left fk-bridges from *INNER-JOINED* children (if any)
  for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
    my $ri = $relinfo->{$rel};
    for (keys %{$ri->{fk_map}} ) {
      # need to know source from *our* pov, hence $rel.col
      $my_cols->{$_} ||= { via_fk => "$rel.$ri->{fk_map}{$_}" }
        if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
    }
  }

  # if the parent is already defined *AND* we have an inner reverse relationship
  # (i.e. do not exist without it) , assume all of its related FKs are selected
  # (even if they in fact are NOT in the select list). Keep a record of what we
  # assumed, and if any such phantom-column becomes part of our own collapser,
  # throw everything assumed-from-parent away and replace with the collapser of
  # the parent (whatever it may be)
  my $assumed_from_parent;
  if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
    for my $col ( values %{$args->{_parent_info}{rel_condition} || {}} ) {
      next if exists $my_cols->{$col};
      $my_cols->{$col} = { via_collapse => $args->{_parent_info}{collapse_on_idcols} };
      $assumed_from_parent->{columns}{$col}++;
    }
  }

  # get colinfo for everything
  if ($my_cols) {
    my $ci = $self->columns_info;
    $my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
  }

  my $collapse_map;

  # first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
  # (makes for a leaner coderef later)
  unless ($collapse_map->{-identifying_columns}) {
    $collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
      if $args->{_parent_info}{collapser_reusable};
  }

  # Still don't know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
  if (
    ! $collapse_map->{-identifying_columns}
      and
    $my_cols
      and
    my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
  ) {
    # see if the resulting collapser relies on any implied columns,
    # and fix stuff up if this is the case
    my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;

    $collapse_map->{-identifying_columns} = [ __unique_numlist(
      @{ $args->{_parent_info}{collapse_on_idcols}||[] },

      (map
        {
          my $fqc = join ('.',
            @{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
            ( $my_cols->{$_}{via_fk} || $_ ),
          );

          $common_args->{_as_fq_idx}->{$fqc};
        }
        @reduced_set
      ),
    )];
  }

  # Stil don't know how to collapse - keep descending down 1:1 chains - if
  # a related non-LEFT 1:1 is resolvable - its condition will collapse us
  # too
  unless ($collapse_map->{-identifying_columns}) {
    my @candidates;

    for my $rel (keys %$relinfo) {
      next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});

      if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
        as => $rel_cols->{$rel},
        _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
        _parent_info => { underdefined => 1 },
      }, $common_args)) {
        push @candidates, $rel_collapse->{-identifying_columns};
      }
    }

    # get the set with least amount of columns
    # FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
    # to a single varchar)
    if (@candidates) {
      ($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
    }
  }

  # Stil don't know how to collapse, and we are the root node. Last ditch
  # effort in case we are *NOT* premultiplied.
  # Run through *each multi* all the way down, left or not, and all
  # *left* singles (a single may become a multi underneath) . When everything
  # gets back see if all the rels link to us definitively. If this is the
  # case we are good - either one of them will define us, or if all are NULLs
  # we know we are "unique" due to the "non-premultiplied" check
  if (
    ! $collapse_map->{-identifying_columns}
      and
    ! $args->{premultiplied}
      and
    $args->{_is_top_level}
  ) {
    my (@collapse_sets, $uncollapsible_chain);

    for my $rel (keys %$relinfo) {

      # we already looked at these higher up
      next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});

      if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
        as => $rel_cols->{$rel},
        _rel_chain => [ @{$args->{_rel_chain}}, $rel ],
        _parent_info => { underdefined => 1 },
      }, $common_args) ) {

        # for singles use the idcols wholesale (either there or not)
        if ($relinfo->{$rel}{is_single}) {
          push @collapse_sets, $clps->{-identifying_columns};
        }
        elsif (! $relinfo->{$rel}{fk_map}) {
          $uncollapsible_chain = 1;
          last;
        }
        else {
          my $defined_cols_parent_side;

          for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
            my ($col) = $fq_col =~ /([^\.]+)$/;

            $defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
              { $relinfo->{$rel}{fk_map}{$_} eq $col }
              keys %{$relinfo->{$rel}{fk_map}}
            ;
          }

          if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
            push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
          }
          else {
            $uncollapsible_chain = 1;
            last;
          }
        }
      }
      else {
        $uncollapsible_chain = 1;
        last;
      }
    }

    unless ($uncollapsible_chain) {
      # if we got here - we are good to go, but the construction is tricky
      # since our children will want to include our collapse criteria - we
      # don't give them anything (safe, since they are all collapsible on their own)
      # in addition we record the individual collapse possibilities
      # of all left children node collapsers, and merge them in the rowparser
      # coderef later
      $collapse_map->{-identifying_columns} = [];
      $collapse_map->{-identifying_columns_variants} = [ sort {
        (scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
      } @collapse_sets ];
    }
  }

  # stop descending into children if we were called by a parent for first-pass
  # and don't despair if nothing was found (there may be other parallel branches
  # to dive into)
  if ($args->{_parent_info}{underdefined}) {
    return $collapse_map->{-identifying_columns} ? $collapse_map : undef
  }
  # nothing down the chain resolved - can't calculate a collapse-map
  elsif (! $collapse_map->{-identifying_columns}) {
    $self->throw_exception ( sprintf
      "Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
      $self->source_name,
      @{$args->{_rel_chain}} > 1
        ? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
        : ''
      ,
    );
  }

  # If we got that far - we are collapsable - GREAT! Now go down all children
  # a second time, and fill in the rest

  $collapse_map->{-identifying_columns} = [ __unique_numlist(
    @{ $args->{_parent_info}{collapse_on_idcols}||[] },
    @{ $collapse_map->{-identifying_columns} },
  )];

  my @id_sets;
  for my $rel (sort keys %$relinfo) {

    $collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
      as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
      _rel_chain => [ @{$args->{_rel_chain}}, $rel],
      _parent_info => {
        # shallow copy
        collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],

        rel_condition => $relinfo->{$rel}{fk_map},

        is_optional => ! $relinfo->{$rel}{is_inner},

        # if there is at least one *inner* reverse relationship which is HASH-based (equality only)
        # we can safely assume that the child can not exist without us
        rev_rel_is_optional => ( first
          { ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}||'') !~ /^left/i }
          values %{ $self->reverse_relationship_info($rel) },
        ) ? 0 : 1,

        # if this is a 1:1 our own collapser can be used as a collapse-map
        # (regardless of left or not)
        collapser_reusable => (
          $relinfo->{$rel}{is_single}
            &&
          $relinfo->{$rel}{is_inner}
            &&
          @{$collapse_map->{-identifying_columns}}
        ) ? 1 : 0,
      },
    }, $common_args );

    $collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
    $collapse_map->{$rel}{-is_optional} ||= 1 unless $relinfo->{$rel}{is_inner};
  }

  return $collapse_map;
}

# adding a dep on MoreUtils *just* for this is retarded
sub __unique_numlist {
  sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
}

1;
Commit	Line	Data
4e9fc3f3	1	package # hide from the pauses
4e9fc3f3	2	DBIx::Class::ResultSource::RowParser;
76031e14	3
	4	use strict;
	5	use warnings;
	6
9f98c4b2	7	use base 'DBIx::Class';
9f98c4b2	8
76031e14	9	use Try::Tiny;
fcf32d04	10	use List::Util qw(first max);
6e36cd06	11	use Scalar::Util qw(blessed);
76031e14	12
9f98c4b2	13	use DBIx::Class::ResultSource::RowParser::Util qw(
	14	assemble_simple_parser
	15	assemble_collapsing_parser
	16	);
76031e14	17
9f98c4b2	18	use namespace::clean;
76031e14	19
	20	# Accepts one or more relationships for the current source and returns an
	21	# array of column names for each of those relationships. Column names are
	22	# prefixed relative to the current source, in accordance with where they appear
	23	# in the supplied relationships.
	24	sub _resolve_prefetch {
	25	my ($self, $pre, $alias, $alias_map, $order, $pref_path) = @_;
	26	$pref_path \|\|= [];
	27
	28	if (not defined $pre or not length $pre) {
	29	return ();
	30	}
	31	elsif( ref $pre eq 'ARRAY' ) {
	32	return
	33	map { $self->_resolve_prefetch( $_, $alias, $alias_map, $order, [ @$pref_path ] ) }
	34	@$pre;
	35	}
	36	elsif( ref $pre eq 'HASH' ) {
	37	my @ret =
	38	map {
	39	$self->_resolve_prefetch($_, $alias, $alias_map, $order, [ @$pref_path ] ),
	40	$self->related_source($_)->_resolve_prefetch(
4e9fc3f3	41	$pre->{$_}, "${alias}.$_", $alias_map, $order, [ @$pref_path, $_] )
76031e14	42	} keys %$pre;
	43	return @ret;
	44	}
	45	elsif( ref $pre ) {
	46	$self->throw_exception(
	47	"don't know how to resolve prefetch reftype ".ref($pre));
	48	}
	49	else {
	50	my $p = $alias_map;
	51	$p = $p->{$_} for (@$pref_path, $pre);
	52
	53	$self->throw_exception (
	54	"Unable to resolve prefetch '$pre' - join alias map does not contain an entry for path: "
	55	. join (' -> ', @$pref_path, $pre)
	56	) if (ref $p->{-join_aliases} ne 'ARRAY' or not @{$p->{-join_aliases}} );
	57
	58	my $as = shift @{$p->{-join_aliases}};
	59
	60	my $rel_info = $self->relationship_info( $pre );
	61	$self->throw_exception( $self->source_name . " has no such relationship '$pre'" )
	62	unless $rel_info;
	63
	64	my $as_prefix = ($alias =~ /^.*?\.(.+)$/ ? $1.'.' : '');
76031e14	65
76031e14	66	return map { [ "${as}.$_", "${as_prefix}${pre}.$_", ] }
4e9fc3f3	67	$self->related_source($pre)->columns;
76031e14	68	}
	69	}
	70
9f98c4b2	71	# Takes an arrayref of {as} dbic column aliases and the collapse and select
	72	# attributes from the same $rs (the selector requirement is a temporary
	73	# workaround... I hope), and returns a coderef capable of:
	74	# my $me_pref_clps = $coderef->([$rs->cursor->next/all])
	75	# Where the $me_pref_clps arrayref is the future argument to inflate_result()
	76	#
	77	# For an example of this coderef in action (and to see its guts) look at
	78	# t/resultset/rowparser_internals.t
	79	#
	80	# This is a huge performance win, as we call the same code for every row
	81	# returned from the db, thus avoiding repeated method lookups when traversing
	82	# relationships
	83	#
	84	# Also since the coderef is completely stateless (the returned structure is
	85	# always fresh on every new invocation) this is a very good opportunity for
	86	# memoization if further speed improvements are needed
	87	#
	88	# The way we construct this coderef is somewhat fugly, although the result is
	89	# really worth it. The final coderef does not perform any kind of recursion -
	90	# the entire nested structure constructor is rolled out into a single scope.
	91	#
	92	# In any case - the output of this thing is meticulously micro-tested, so
	93	# any sort of adjustment/rewrite should be relatively easy (fsvo relatively)
	94	#
	95	sub _mk_row_parser {
4a0eed52	96	# $args and $attrs are separated to delineate what is core collapser stuff and
5b309063	97	# what is dbic $rs specific
5b309063	98	my ($self, $args, $attrs) = @_;
9f98c4b2	99
79adc44f	100	die "HRI without pruning makes zero sense"
	101	if ( $args->{hri_style} && ! $args->{prune_null_branches} );
	102
	103	my %common = (
	104	hri_style => $args->{hri_style},
	105	prune_null_branches => $args->{prune_null_branches},
	106	val_index => { map
	107	{ $args->{inflate_map}[$_] => $_ }
	108	( 0 .. $#{$args->{inflate_map}} )
	109	},
	110	);
	111
02a73c96	112	my $check_null_columns;
	113
	114	my $src = (! $args->{collapse} ) ? assemble_simple_parser(\%common) : do {
	115	my $collapse_map = $self->_resolve_collapse ({
	116	# FIXME
	117	# only consider real columns (not functions) during collapse resolution
	118	# this check shouldn't really be here, as fucktards are not supposed to
	119	# alias random crap to existing column names anyway, but still - just in
	120	# case
	121	# FIXME !!!! - this does not yet deal with unbalanced selectors correctly
	122	# (it is now trivial as the attrs specify where things go out of sync
	123	# needs MOAR tests)
	124	as => { map
	125	{ ref $attrs->{select}[$common{val_index}{$_}] ? () : ( $_ => $common{val_index}{$_} ) }
	126	keys %{$common{val_index}}
	127	},
	128	premultiplied => $args->{premultiplied},
	129	});
	130
	131	$check_null_columns = $collapse_map->{-identifying_columns}
	132	if @{$collapse_map->{-identifying_columns}};
	133
	134	assemble_collapsing_parser({
79adc44f	135	%common,
02a73c96	136	collapse_map => $collapse_map,
	137	});
	138	};
	139
	140	return (
	141	$args->{eval} ? ( eval "sub $src" \|\| die $@ ) : $src,
	142	$check_null_columns,
	143	);
9f98c4b2	144	}
	145
	146
2d0b795a	147	# Takes an arrayref selection list and generates a collapse-map representing
76031e14	148	# row-object fold-points. Every relationship is assigned a set of unique,
	149	# non-nullable columns (which may not even be from the same resultset)
	150	# and the collapser will use this information to correctly distinguish
2d0b795a	151	# data of individual to-be-row-objects. See t/resultset/rowparser_internals.t
2d0b795a	152	# for extensive RV examples
76031e14	153	sub _resolve_collapse {
82f0e0aa	154	my ($self, $args, $common_args) = @_;
76031e14	155
76031e14	156	# for comprehensible error messages put ourselves at the head of the relationship chain
82f0e0aa	157	$args->{_rel_chain} \|\|= [ $self->source_name ];
76031e14	158
9f98c4b2	159	# record top-level fully-qualified column index, signify toplevelness
	160	unless ($common_args->{_as_fq_idx}) {
	161	$common_args->{_as_fq_idx} = { %{$args->{as}} };
	162	$args->{_is_top_level} = 1;
82f0e0aa	163	};
76031e14	164
76031e14	165	my ($my_cols, $rel_cols);
82f0e0aa	166	for (keys %{$args->{as}}) {
76031e14	167	if ($_ =~ /^ ([^\.]+) \. (.+) /x) {
	168	$rel_cols->{$1}{$2} = 1;
	169	}
	170	else {
fcf32d04	171	$my_cols->{$_} = {}; # important for \|\|='s below
76031e14	172	}
	173	}
	174
	175	my $relinfo;
fcf32d04	176	# run through relationships, collect metadata
76031e14	177	for my $rel (keys %$rel_cols) {
76031e14	178	my $inf = $self->relationship_info ($rel);
76031e14	179
95e41036	180	$relinfo->{$rel} = {
	181	is_single => ( $inf->{attrs}{accessor} && $inf->{attrs}{accessor} ne 'multi' ),
	182	is_inner => ( ( $inf->{attrs}{join_type} \|\| '' ) !~ /^left/i),
	183	rsrc => $self->related_source($rel),
	184	};
76031e14	185
fcf32d04	186	# FIME - need to use _resolve_cond here instead
76031e14	187	my $cond = $inf->{cond};
	188
	189	if (
	190	ref $cond eq 'HASH'
	191	and
	192	keys %$cond
	193	and
fcf32d04	194	! defined first { $_ !~ /^foreign\./ } (keys %$cond)
76031e14	195	and
fcf32d04	196	! defined first { $_ !~ /^self\./ } (values %$cond)
76031e14	197	) {
	198	for my $f (keys %$cond) {
	199	my $s = $cond->{$f};
	200	$_ =~ s/^ (?: foreign \| self ) \.//x for ($f, $s);
	201	$relinfo->{$rel}{fk_map}{$s} = $f;
76031e14	202	}
6e36cd06	203	} elsif (blessed($cond) and $cond->isa('Data::Query::ExprBuilder')) {
	204	my $cols = $self->_join_condition_to_hashref($cond->{expr});
	205	@{$relinfo->{$rel}{fk_map}}{values %$cols} = keys %$cols;
76031e14	206	}
	207	}
	208
fcf32d04	209	# inject non-left fk-bridges from INNER-JOINED children (if any)
	210	for my $rel (grep { $relinfo->{$_}{is_inner} } keys %$relinfo) {
	211	my $ri = $relinfo->{$rel};
	212	for (keys %{$ri->{fk_map}} ) {
	213	# need to know source from our pov, hence $rel.col
	214	$my_cols->{$_} \|\|= { via_fk => "$rel.$ri->{fk_map}{$_}" }
	215	if defined $rel_cols->{$rel}{$ri->{fk_map}{$_}} # in fact selected
	216	}
	217	}
	218
a0726a33	219	# if the parent is already defined AND we have an inner reverse relationship
a0726a33	220	# (i.e. do not exist without it) , assume all of its related FKs are selected
76031e14	221	# (even if they in fact are NOT in the select list). Keep a record of what we
	222	# assumed, and if any such phantom-column becomes part of our own collapser,
	223	# throw everything assumed-from-parent away and replace with the collapser of
	224	# the parent (whatever it may be)
	225	my $assumed_from_parent;
a0726a33	226	if ( ! $args->{_parent_info}{underdefined} and ! $args->{_parent_info}{rev_rel_is_optional} ) {
fcf32d04	227	for my $col ( values %{$args->{_parent_info}{rel_condition} \|\| {}} ) {
	228	next if exists $my_cols->{$col};
	229	$my_cols->{$col} = { via_collapse => $args->{_parent_info}{collapse_on_idcols} };
	230	$assumed_from_parent->{columns}{$col}++;
	231	}
76031e14	232	}
	233
	234	# get colinfo for everything
	235	if ($my_cols) {
	236	my $ci = $self->columns_info;
	237	$my_cols->{$_}{colinfo} = $ci->{$_} for keys %$my_cols;
	238	}
	239
	240	my $collapse_map;
	241
3faac878	242	# first try to reuse the parent's collapser (i.e. reuse collapser over 1:1)
3faac878	243	# (makes for a leaner coderef later)
9f98c4b2	244	unless ($collapse_map->{-identifying_columns}) {
9f98c4b2	245	$collapse_map->{-identifying_columns} = $args->{_parent_info}{collapse_on_idcols}
3faac878	246	if $args->{_parent_info}{collapser_reusable};
	247	}
	248
4a0eed52	249	# Still don't know how to collapse - try to resolve based on our columns (plus already inserted FK bridges)
76031e14	250	if (
9f98c4b2	251	! $collapse_map->{-identifying_columns}
3faac878	252	and
76031e14	253	$my_cols
76031e14	254	and
4e9fc3f3	255	my $idset = $self->_identifying_column_set ({map { $_ => $my_cols->{$_}{colinfo} } keys %$my_cols})
76031e14	256	) {
	257	# see if the resulting collapser relies on any implied columns,
	258	# and fix stuff up if this is the case
4e9fc3f3	259	my @reduced_set = grep { ! $assumed_from_parent->{columns}{$_} } @$idset;
76031e14	260
9f98c4b2	261	$collapse_map->{-identifying_columns} = [ __unique_numlist(
3faac878	262	@{ $args->{_parent_info}{collapse_on_idcols}\|\|[] },
3faac878	263
76031e14	264	(map
	265	{
	266	my $fqc = join ('.',
82f0e0aa	267	@{$args->{_rel_chain}}[1 .. $#{$args->{_rel_chain}}],
76031e14	268	( $my_cols->{$_}{via_fk} \|\| $_ ),
	269	);
	270
82f0e0aa	271	$common_args->{_as_fq_idx}->{$fqc};
76031e14	272	}
4e9fc3f3	273	@reduced_set
76031e14	274	),
3faac878	275	)];
76031e14	276	}
	277
	278	# Stil don't know how to collapse - keep descending down 1:1 chains - if
	279	# a related non-LEFT 1:1 is resolvable - its condition will collapse us
	280	# too
9f98c4b2	281	unless ($collapse_map->{-identifying_columns}) {
76031e14	282	my @candidates;
	283
	284	for my $rel (keys %$relinfo) {
	285	next unless ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
	286
82f0e0aa	287	if ( my $rel_collapse = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	288	as => $rel_cols->{$rel},
	289	_rel_chain => [ @{$args->{_rel_chain}}, $rel ],
	290	_parent_info => { underdefined => 1 },
	291	}, $common_args)) {
9f98c4b2	292	push @candidates, $rel_collapse->{-identifying_columns};
76031e14	293	}
	294	}
	295
	296	# get the set with least amount of columns
	297	# FIXME - maybe need to implement a data type order as well (i.e. prefer several ints
	298	# to a single varchar)
	299	if (@candidates) {
9f98c4b2	300	($collapse_map->{-identifying_columns}) = sort { scalar @$a <=> scalar @$b } (@candidates);
76031e14	301	}
	302	}
	303
fcf32d04	304	# Stil don't know how to collapse, and we are the root node. Last ditch
	305	# effort in case we are NOT premultiplied.
	306	# Run through each multi all the way down, left or not, and all
	307	# left singles (a single may become a multi underneath) . When everything
	308	# gets back see if all the rels link to us definitively. If this is the
	309	# case we are good - either one of them will define us, or if all are NULLs
	310	# we know we are "unique" due to the "non-premultiplied" check
	311	if (
9f98c4b2	312	! $collapse_map->{-identifying_columns}
fcf32d04	313	and
	314	! $args->{premultiplied}
	315	and
9f98c4b2	316	$args->{_is_top_level}
fcf32d04	317	) {
	318	my (@collapse_sets, $uncollapsible_chain);
	319
	320	for my $rel (keys %$relinfo) {
	321
	322	# we already looked at these higher up
	323	next if ($relinfo->{$rel}{is_single} && $relinfo->{$rel}{is_inner});
	324
	325	if (my $clps = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	326	as => $rel_cols->{$rel},
	327	_rel_chain => [ @{$args->{_rel_chain}}, $rel ],
	328	_parent_info => { underdefined => 1 },
	329	}, $common_args) ) {
	330
	331	# for singles use the idcols wholesale (either there or not)
	332	if ($relinfo->{$rel}{is_single}) {
9f98c4b2	333	push @collapse_sets, $clps->{-identifying_columns};
fcf32d04	334	}
	335	elsif (! $relinfo->{$rel}{fk_map}) {
	336	$uncollapsible_chain = 1;
	337	last;
	338	}
	339	else {
	340	my $defined_cols_parent_side;
	341
	342	for my $fq_col ( grep { /^$rel\.[^\.]+$/ } keys %{$args->{as}} ) {
	343	my ($col) = $fq_col =~ /([^\.]+)$/;
	344
	345	$defined_cols_parent_side->{$_} = $args->{as}{$fq_col} for grep
	346	{ $relinfo->{$rel}{fk_map}{$_} eq $col }
	347	keys %{$relinfo->{$rel}{fk_map}}
	348	;
	349	}
	350
	351	if (my $set = $self->_identifying_column_set([ keys %$defined_cols_parent_side ]) ) {
	352	push @collapse_sets, [ sort map { $defined_cols_parent_side->{$_} } @$set ];
	353	}
	354	else {
	355	$uncollapsible_chain = 1;
	356	last;
	357	}
	358	}
	359	}
	360	else {
	361	$uncollapsible_chain = 1;
	362	last;
	363	}
	364	}
	365
	366	unless ($uncollapsible_chain) {
	367	# if we got here - we are good to go, but the construction is tricky
	368	# since our children will want to include our collapse criteria - we
	369	# don't give them anything (safe, since they are all collapsible on their own)
4a0eed52	370	# in addition we record the individual collapse possibilities
fcf32d04	371	# of all left children node collapsers, and merge them in the rowparser
fcf32d04	372	# coderef later
9f98c4b2	373	$collapse_map->{-identifying_columns} = [];
9f98c4b2	374	$collapse_map->{-identifying_columns_variants} = [ sort {
fcf32d04	375	(scalar @$a) <=> (scalar @$b) or max(@$a) <=> max(@$b)
	376	} @collapse_sets ];
	377	}
	378	}
	379
76031e14	380	# stop descending into children if we were called by a parent for first-pass
	381	# and don't despair if nothing was found (there may be other parallel branches
	382	# to dive into)
82f0e0aa	383	if ($args->{_parent_info}{underdefined}) {
9f98c4b2	384	return $collapse_map->{-identifying_columns} ? $collapse_map : undef
76031e14	385	}
76031e14	386	# nothing down the chain resolved - can't calculate a collapse-map
9f98c4b2	387	elsif (! $collapse_map->{-identifying_columns}) {
76031e14	388	$self->throw_exception ( sprintf
	389	"Unable to calculate a definitive collapse column set for %s%s: fetch more unique non-nullable columns",
	390	$self->source_name,
82f0e0aa	391	@{$args->{_rel_chain}} > 1
82f0e0aa	392	? sprintf (' (last member of the %s chain)', join ' -> ', @{$args->{_rel_chain}} )
76031e14	393	: ''
	394	,
	395	);
	396	}
	397
	398	# If we got that far - we are collapsable - GREAT! Now go down all children
	399	# a second time, and fill in the rest
	400
a0726a33	401	$collapse_map->{-identifying_columns} = [ __unique_numlist(
	402	@{ $args->{_parent_info}{collapse_on_idcols}\|\|[] },
	403	@{ $collapse_map->{-identifying_columns} },
	404	)];
3faac878	405
3faac878	406	my @id_sets;
76031e14	407	for my $rel (sort keys %$relinfo) {
76031e14	408
82f0e0aa	409	$collapse_map->{$rel} = $relinfo->{$rel}{rsrc}->_resolve_collapse ({
	410	as => { map { $_ => 1 } ( keys %{$rel_cols->{$rel}} ) },
	411	_rel_chain => [ @{$args->{_rel_chain}}, $rel],
	412	_parent_info => {
3faac878	413	# shallow copy
9f98c4b2	414	collapse_on_idcols => [ @{$collapse_map->{-identifying_columns}} ],
76031e14	415
	416	rel_condition => $relinfo->{$rel}{fk_map},
	417
a0726a33	418	is_optional => ! $relinfo->{$rel}{is_inner},
	419
	420	# if there is at least one inner reverse relationship which is HASH-based (equality only)
	421	# we can safely assume that the child can not exist without us
	422	rev_rel_is_optional => ( first
	423	{ ref $_->{cond} eq 'HASH' and ($_->{attrs}{join_type}\|\|'') !~ /^left/i }
	424	values %{ $self->reverse_relationship_info($rel) },
	425	) ? 0 : 1,
76031e14	426
	427	# if this is a 1:1 our own collapser can be used as a collapse-map
	428	# (regardless of left or not)
3d8caf63	429	collapser_reusable => (
	430	$relinfo->{$rel}{is_single}
	431	&&
	432	$relinfo->{$rel}{is_inner}
	433	&&
	434	@{$collapse_map->{-identifying_columns}}
	435	) ? 1 : 0,
76031e14	436	},
82f0e0aa	437	}, $common_args );
76031e14	438
	439	$collapse_map->{$rel}{-is_single} = 1 if $relinfo->{$rel}{is_single};
	440	$collapse_map->{$rel}{-is_optional} \|\|= 1 unless $relinfo->{$rel}{is_inner};
3faac878	441	}
76031e14	442
	443	return $collapse_map;
	444	}
	445
76031e14	446	# adding a dep on MoreUtils just for this is retarded
76031e14	447	sub __unique_numlist {
3faac878	448	sort { $a <=> $b } keys %{ {map { $_ => 1 } @_ }}
76031e14	449	}
76031e14	450
76031e14	451	1;