inline _apply_to in ResolveProposition to clarify logic

[scpubgit/DX.git] / lib / DX / Step / ResolveProposition.pm

package DX::Step::ResolveProposition;

use DX::Step::EnterRecheck;
use DX::Step::Backtrack;

use DX::Utils qw(expand_deps);

use DX::Class;

with 'DX::Role::Step';

has resolution_space => (is => 'ro', isa => ResolutionSpace);

sub resolves { shift->resolution_space->proposition }

sub current_resolution { shift->resolution_space->next_resolution }

sub actions { shift->current_resolution->actions }

sub depends_on { shift->current_resolution->veracity_depends_on }

sub but_first {
  my ($self, @actions) = @_;
  $self->but(actions => [ @actions, @{$self->actions} ]);
}

sub but_with_dependencies_on {
  my ($self, @deps) = @_;
  $self->but(depends_on => [ @{$self->depends_on}, @deps ]);
}

sub apply_to {
  my ($self, $old_ss) = @_;
  trace resolve => [ statement => [
    [ symbol => 'resolve' ],
    [ block => [
      [ statement => [
        [ symbol => 'proposition' ],
        @{$self->resolves->for_deparse->[1]},
      ] ],
      (@{$self->actions}
        ? [ statement => [
            [ symbol => 'actions' ],
            [ block => $self->actions ],
          ] ]
        : ()),
      [ statement => [
        [ symbol => 'depends_on' ],
        [ block => [
          map [ statement => [
            [ symbol => (split '::', ${$_->[0]})[-1] ],
            [ value_path => [ @{$_}[1..$#$_] ] ]
          ] ], @{$self->depends_on}
        ] ],
      ] ],
    ] ]
  ] ];
  my $ns = do {
    if (my $prop = $old_ss->next_proposition) {
      DX::Step::ConsiderProposition->new(
        proposition => $prop
      )
    } else {
      $old_ss->on_solution_step
    }
  };
  my $ss = $old_ss->but(
    next_step => $ns,
    decisions_taken => [
      [ $self->resolution_space, $old_ss ],
      @{$old_ss->decisions_taken}
    ],
  );
  my $old_hyp = $old_ss->current_hypothesis;
  (my $hyp, my @recheck) = $old_hyp->with_resolution(
    $self->resolves, $self->depends_on, $self->actions
  );
  return $ss->but(next_step => DX::Step::Backtrack->new) unless $hyp;
  return $self->_recheck_for(
    $ss->but(current_hypothesis => $hyp),
    @recheck
  );
}

sub _recheck_for {
  my ($self, $old_ss, @recheck) = @_;

  return $old_ss unless @recheck;

  my $ss = $old_ss->but(
    next_step => DX::Step::EnterRecheck->new(
      proposition_list => \@recheck,
      on_completion_step => $old_ss->next_step,
      on_failure_step => DX::Step::Backtrack->new,
    ),
  );

  return $ss;
}

1;