cleanup resolveprop apply_to logic a bit

[scpubgit/DX.git] / lib / DX / Step / ResolveProposition.pm

package DX::Step::ResolveProposition;

use Types::Standard qw(ArrayRef);
use DX::Utils qw(deparse);
use DX::Class;

with 'DX::Role::Step';

has actions => (is => 'ro', isa => ArrayRef[Action], required => 1);

has depends_on => (is => 'ro', isa => DependencyGroupList, required => 1);

has resolves => (is => 'ro', isa => Proposition);

has alternative_step => (is => 'ro', isa => Step);

sub but_first {
  my ($self, @actions) = @_;
  $self->but(actions => [ @actions, @{$self->actions} ]);
}

sub but_with_dependencies_on {
  my ($self, @deps) = @_;
  $self->but(depends_on => [ @{$self->depends_on}, @deps ]);
}

sub apply_to {
  my ($self, $ss) = @_;
  trace 'step.apply.old_hyp '.$self => $ss->current_hypothesis;
  trace 'step.apply.actions '.$self => $self->actions;
  my $new_ss = $self->_apply_to_ss($ss);
  return $ss->but(next_step => DX::Step::Backtrack->new) unless $new_ss;
  trace 'step.apply.new_hyp '.$self => $new_ss->current_hypothesis;
  my $ns = do {
    if (my $prop = $new_ss->next_proposition) {
      DX::Step::ConsiderProposition->new(
        proposition => $prop
      )
    } else {
      $new_ss->on_solution_step
    }
  };
  my $alt_step = $self->alternative_step;
  return (
    $new_ss->but(
      next_step => $ns,
      ($alt_step
        ? (alternatives => [
            [ $ss->current_hypothesis, $alt_step ],
            @{$ss->alternatives}
          ])
        : ()
      ),
    ),
  );
}

sub _apply_to_ss {
  my ($self, $old_ss) = @_;
  my $old_hyp = $old_ss->current_hypothesis;
  (my $hyp, my @recheck) = $old_hyp->with_resolution(
    $self->resolves, $self->depends_on, $self->actions
  );
  return undef unless $hyp;
  return $self->_recheck_for(
    $old_ss->but(current_hypothesis => $hyp),
    @recheck
  );
}

sub _recheck_for {
  my ($self, $old_ss, @recheck) = @_;
  return $old_ss unless @recheck;
  my $ss  = $old_ss;
  foreach my $prop (@recheck) {
    return undef unless $ss = $self->_recheck_one($ss, $prop);
  }
  return $ss;
}

sub _recheck_one {
  my ($self, $old_ss, $prop) = @_;

  my $old_hyp = $old_ss->current_hypothesis;

  my $ap = DX::ActionPolicy::LockScope->new(
    lock_to_depth => $old_hyp->scope->depth,
    next_policy => $old_hyp->action_policy,
  );

  # we should probably be doing something about pruning the scope
  # but that's completely pointless until we have rules

  my $hyp = ref($old_hyp)->new(
    scope => $old_hyp->scope,
    resolved_propositions => DX::ResolvedPropositionSet->new_empty,
    actions => [],
    action_applications => [],
    action_policy => $ap,
  );

  my $pseq = DX::PropositionSequence->new(
    members => [ $prop ],
    external_names => {},
    internal_names => {},
  );

  trace 'step.recheck.hyp' => $hyp;

  my $ss = DX::SearchState->new(
    current_hypothesis => $hyp,
    alternatives => [],
    propositions => $pseq,
    next_step => DX::Step::ConsiderProposition->new(
                   proposition => $prop,
                 ),
    is_solution_state => 0,
    on_exhaustion_step => undef,
    on_solution_step => DX::Step::MarkAsSolution->new,
  );

  my $sp = DX::SearchProcess->new(
    current_search_state => $ss,
  );

  my $sol_sp = $sp->find_solution;

  unless ($sol_sp) {
    trace 'step.recheck.fail' => 'argh';
    return undef;
  }

  my $sol_rps = $sol_sp->current_hypothesis->resolved_propositions;

  my $rps = $old_hyp->resolved_propositions;

  $rps = $rps->with_updated_dependencies_for(
    $prop, $sol_rps->dependencies_for($prop)
  );

  trace 'step.recheck.done' => 'yay';

  return $old_ss->but(
    current_hypothesis => $old_hyp->but(resolved_propositions => $rps),
  );
}

1;