move recheck logic into resolution step

[scpubgit/DX.git] / lib / DX / Step / ResolveProposition.pm

package DX::Step::ResolveProposition;

use Types::Standard qw(ArrayRef);
use DX::Utils qw(deparse);
use DX::Class;

with 'DX::Role::Step';

has actions => (is => 'ro', isa => ArrayRef[Action], required => 1);

has depends_on => (is => 'ro', isa => DependencyGroupList, required => 1);

has resolves => (is => 'ro', isa => Proposition);

has alternative_step => (is => 'ro', isa => Step);

sub but_first {
  my ($self, @actions) = @_;
  $self->but(actions => [ @actions, @{$self->actions} ]);
}

sub but_with_dependencies_on {
  my ($self, @deps) = @_;
  $self->but(depends_on => [ @{$self->depends_on}, @deps ]);
}

sub apply_to {
  my ($self, $ss) = @_;
  my $old_hyp = $ss->current_hypothesis;
  trace 'step.apply.old_hyp '.$self => $old_hyp;
  trace 'step.apply.actions '.$self => $self->actions;
  my $new_hyp = $self->_apply_to_hyp($old_hyp);
  return $ss->but(next_step => DX::Step::Backtrack->new) unless $new_hyp;
  trace 'step.apply.new_hyp '.$self => $new_hyp;
  my $ns = do {
    if (my $prop = $ss->next_proposition($new_hyp)) {
      DX::Step::ConsiderProposition->new(
        proposition => $prop
      )
    } else {
      $ss->on_solution_step
    }
  };
  my $alt_step = $self->alternative_step;
  return (
    $ss->but(
      current_hypothesis => $new_hyp,
      next_step => $ns,
      ($alt_step
        ? (alternatives => [ [ $old_hyp, $alt_step ], @{$ss->alternatives} ])
        : ()
      ),
    ),
  );
}

sub _apply_to_hyp {
  my ($self, $old_hyp) = @_;
  (my $hyp, my @recheck) = $old_hyp->with_resolution(
    $self->resolves, $self->depends_on, $self->actions
  );
  return $self->_recheck_hyp_for($hyp, @recheck);
}

sub _recheck_hyp_for {
  my ($self, $old_hyp, @recheck) = @_;
  return undef unless $old_hyp;
  return $old_hyp unless @recheck;

  my $ap = DX::ActionPolicy::LockScope->new(
    lock_to_depth => $old_hyp->scope->depth,
    next_policy => $old_hyp->action_policy,
  );

  # we should probably be doing something about pruning the scope
  # but that's completely pointless until we have rules

  my $hyp = ref($old_hyp)->new(
    scope => $old_hyp->scope,
    resolved_propositions => DX::ResolvedPropositionSet->new_empty,
    actions => [],
    action_applications => [],
    action_policy => $ap,
  );

  my $pseq = DX::PropositionSequence->new(
    members => \@recheck,
    external_names => {},
    internal_names => {},
  );

  trace 'step.recheck.hyp' => $hyp;

  my $ss = DX::SearchProcess->new_for($hyp, $pseq);

  my $sol_ss = $ss->find_solution;

  unless ($sol_ss) {
    trace 'step.recheck.fail' => 'argh';
    return undef;
  }

  my $sol_rps = $sol_ss->current_hypothesis->resolved_propositions;

  my $rps = $old_hyp->resolved_propositions;

  $rps = $rps->with_updated_dependencies_for(
    $_, $sol_rps->dependencies_for($_)
  ) for @recheck;

  trace 'step.recheck.done' => 'yay';

  return $old_hyp->but(resolved_propositions => $rps);
}

1;