[gitmo/Role-Tiny.git] / lib / Role / Tiny.pm

package Role::Tiny;

sub _getglob { \*{$_[0]} }
sub _getstash { \%{"$_[0]::"} }

use strict;
use warnings FATAL => 'all';

our $VERSION = '1.001005'; # 1.1.5
$VERSION = eval $VERSION;

our %INFO;
our %APPLIED_TO;
our %COMPOSED;
our %COMPOSITE_INFO;

# Module state workaround totally stolen from Zefram's Module::Runtime.

BEGIN {
  *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
}

sub Role::Tiny::__GUARD__::DESTROY {
  delete $INC{$_[0]->[0]} if @{$_[0]};
}

sub _load_module {
  (my $proto = $_[0]) =~ s/::/\//g;
  $proto .= '.pm';
  return 1 if $INC{$proto};
  # can't just ->can('can') because a sub-package Foo::Bar::Baz
  # creates a 'Baz::' key in Foo::Bar's symbol table
  return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
    && bless([ $proto ], 'Role::Tiny::__GUARD__');
  require $proto;
  pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  return 1;
}

sub import {
  my $target = caller;
  my $me = shift;
  strict->import;
  warnings->import(FATAL => 'all');
  return if $INFO{$target}; # already exported into this package
  # get symbol table reference
  my $stash = do { no strict 'refs'; \%{"${target}::"} };
  # install before/after/around subs
  foreach my $type (qw(before after around)) {
    *{_getglob "${target}::${type}"} = sub {
      require Class::Method::Modifiers;
      push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
      return;
    };
  }
  *{_getglob "${target}::requires"} = sub {
    push @{$INFO{$target}{requires}||=[]}, @_;
    return;
  };
  *{_getglob "${target}::with"} = sub {
    $me->apply_roles_to_package($target, @_);
    return;
  };
  # grab all *non-constant* (stash slot is not a scalarref) subs present
  # in the symbol table and store their refaddrs (no need to forcibly
  # inflate constant subs into real subs) - also add '' to here (this
  # is used later) with a map to the coderefs in case of copying or re-use
  my @not_methods = ('', map { *$_{CODE}||() } grep !ref($_), values %$stash);
  @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  # a role does itself
  $APPLIED_TO{$target} = { $target => undef };
}

sub apply_single_role_to_package {
  my ($me, $to, $role) = @_;

  _load_module($role);

  die "This is apply_role_to_package" if ref($to);
  die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};

  $me->_check_requires($to, $role, @{$info->{requires}||[]});

  $me->_install_methods($to, $role);

  $me->_install_modifiers($to, $info->{modifiers});

  # only add does() method to classes and only if they don't have one
  if (not $INFO{$to} and not $to->can('does')) {
    *{_getglob "${to}::does"} = \&does_role;
  }

  # copy our role list into the target's
  @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
}

sub apply_roles_to_object {
  my ($me, $object, @roles) = @_;
  die "No roles supplied!" unless @roles;
  my $class = ref($object);
  bless($object, $me->create_class_with_roles($class, @roles));
  $object;
}

sub create_class_with_roles {
  my ($me, $superclass, @roles) = @_;

  die "No roles supplied!" unless @roles;

  _load_module($superclass);
  {
    my %seen;
    $seen{$_}++ for @roles;
    if (my @dupes = grep $seen{$_} > 1, @roles) {
      die "Duplicated roles: ".join(', ', @dupes);
    }
  }

  my $new_name = join(
    '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
  );

  return $new_name if $COMPOSED{class}{$new_name};

  foreach my $role (@roles) {
    _load_module($role);
    die "${role} is not a Role::Tiny" unless $INFO{$role};
  }

  if ($] >= 5.010) {
    require mro;
  } else {
    require MRO::Compat;
  }

  my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
  if (keys %conflicts) {
    my $fail = 
      join "\n",
        map {
          "Method name conflict for '$_' between roles "
          ."'".join(' and ', sort values %{$conflicts{$_}})."'"
          .", cannot apply these simultaneously to an object."
        } keys %conflicts;
    die $fail;
  }

  my @composable = map $me->_composable_package_for($_), reverse @roles;

  *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];

  my @info = map $INFO{$_}, @roles;

  $me->_check_requires(
    $new_name, $compose_name,
    do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
  );

  *{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');

  @{$APPLIED_TO{$new_name}||={}}{
    map keys %{$APPLIED_TO{$_}}, @roles
  } = ();

  $COMPOSED{class}{$new_name} = 1;
  return $new_name;
}

# preserved for compat, and apply_roles_to_package calls it to allow an
# updated Role::Tiny to use a non-updated Moo::Role

sub apply_role_to_package { shift->apply_single_role_to_package(@_) }

sub apply_roles_to_package {
  my ($me, $to, @roles) = @_;

  return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;

  my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
  delete $conflicts{$_} for $me->_concrete_methods_of($to);
  if (keys %conflicts) {
    my $fail = 
      join "\n",
        map {
          "Due to a method name conflict between roles "
          ."'".join(' and ', sort values %{$conflicts{$_}})."'"
          .", the method '$_' must be implemented by '${to}'"
        } keys %conflicts;
    die $fail;
  }

  # the if guard here is essential since otherwise we accidentally create
  # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
  # autovivification hates us and wants us to die()
  if ($INFO{$to}) {
    delete $INFO{$to}{methods}; # reset since we're about to add methods
  }

  $me->apply_role_to_package($to, $_) for @roles;
  $APPLIED_TO{$to}{join('|',@roles)} = 1;
}

sub _composite_info_for {
  my ($me, @roles) = @_;
  $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
    _load_module($_) for @roles;
    my %methods;
    foreach my $role (@roles) {
      my $this_methods = $me->_concrete_methods_of($role);
      $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
    }
    delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
    +{ conflicts => \%methods }
  };
}

sub _composable_package_for {
  my ($me, $role) = @_;
  my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
  return $composed_name if $COMPOSED{role}{$composed_name};
  $me->_install_methods($composed_name, $role);
  my $base_name = $composed_name.'::_BASE';
  *{_getglob("${composed_name}::ISA")} = [ $base_name ];
  my $modifiers = $INFO{$role}{modifiers}||[];
  my @mod_base;
  foreach my $modified (
    do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
  ) {
    push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
  }
  my $e;
  {
    local $@;
    eval(my $code = join "\n", "package ${base_name};", @mod_base);
    $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
  }
  die $e if $e;
  $me->_install_modifiers($composed_name, $modifiers);
  $COMPOSED{role}{$composed_name} = 1;
  return $composed_name;
}

sub _check_requires {
  my ($me, $to, $name, @requires) = @_;
  if (my @requires_fail = grep !$to->can($_), @requires) {
    # role -> role, add to requires, role -> class, error out
    if (my $to_info = $INFO{$to}) {
      push @{$to_info->{requires}||=[]}, @requires_fail;
    } else {
      die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
    }
  }
}

sub _concrete_methods_of {
  my ($me, $role) = @_;
  my $info = $INFO{$role};
  # grab role symbol table
  my $stash = do { no strict 'refs'; \%{"${role}::"}};
  # reverse so our keys become the values (captured coderefs) in case
  # they got copied or re-used since
  my $not_methods = { reverse %{$info->{not_methods}||{}} };
  $info->{methods} ||= +{
    # grab all code entries that aren't in the not_methods list
    map {
      my $code = *{$stash->{$_}}{CODE};
      # rely on the '' key we added in import for "no code here"
      exists $not_methods->{$code||''} ? () : ($_ => $code)
    } grep !ref($stash->{$_}), keys %$stash
  };
}

sub methods_provided_by {
  my ($me, $role) = @_;
  die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
  (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
}

sub _install_methods {
  my ($me, $to, $role) = @_;

  my $info = $INFO{$role};

  my $methods = $me->_concrete_methods_of($role);

  # grab target symbol table
  my $stash = do { no strict 'refs'; \%{"${to}::"}};

  # determine already extant methods of target
  my %has_methods;
  @has_methods{grep
    +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
    keys %$stash
  } = ();

  foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
    no warnings 'once';
    *{_getglob "${to}::${i}"} = $methods->{$i};
  }
}

sub _install_modifiers {
  my ($me, $to, $modifiers) = @_;
  if (my $info = $INFO{$to}) {
    push @{$info->{modifiers}}, @{$modifiers||[]};
  } else {
    foreach my $modifier (@{$modifiers||[]}) {
      $me->_install_single_modifier($to, @$modifier);
    }
  }
}

sub _install_single_modifier {
  my ($me, @args) = @_;
  Class::Method::Modifiers::install_modifier(@args);
}

sub does_role {
  my ($proto, $role) = @_;
  if ($] >= 5.010) {
    require mro;
  } else {
    require MRO::Compat;
  }
  foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) {
    return 1 if exists $APPLIED_TO{$class}{$role};
  }
  return 0;
}

1;

=head1 NAME

Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.

=head1 SYNOPSIS

 package Some::Role;

 use Role::Tiny;

 sub foo { ... }

 sub bar { ... }

 around baz => sub { ... }

 1;

else where

 package Some::Class;

 use Role::Tiny::With;

 # bar gets imported, but not foo
 with 'Some::Role';

 sub foo { ... }

 # baz is wrapped in the around modifier by Class::Method::Modifiers
 sub baz { ... }

 1;

If you wanted attributes as well, look at L<Moo::Role>.

=head1 DESCRIPTION

C<Role::Tiny> is a minimalist role composition tool.

=head1 ROLE COMPOSITION

Role composition can be thought of as much more clever and meaningful multiple
inheritance.  The basics of this implementation of roles is:

=over 2

=item *

If a method is already defined on a class, that method will not be composed in
from the role.

=item *

If a method that the role L</requires> to be implemented is not implemented,
role application will fail loudly.

=back

Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
composition is the other way around, where the class wins. If multiple roles
are applied in a single call (single with statement), then if any of their
provided methods clash, an exception is raised unless the class provides
a method since this conflict indicates a potential problem.

=head1 IMPORTED SUBROUTINES

=head2 requires

 requires qw(foo bar);

Declares a list of methods that must be defined to compose role.

=head2 with

 with 'Some::Role1';

 with 'Some::Role1', 'Some::Role2';

Composes another role into the current role (or class via L<Role::Tiny::With>).

If you have conflicts and want to resolve them in favour of Some::Role1 you
can instead write: 

 with 'Some::Role1';
 with 'Some::Role2';

If you have conflicts and want to resolve different conflicts in favour of
different roles, please refactor your codebase.

=head2 before

 before foo => sub { ... };

See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head2 around

 around foo => sub { ... };

See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head2 after

 after foo => sub { ... };

See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head1 SUBROUTINES

=head2 does_role

 if (Role::Tiny::does_role($foo, 'Some::Role')) {
   ...
 }

Returns true if class has been composed with role.

This subroutine is also installed as ->does on any class a Role::Tiny is
composed into unless that class already has an ->does method, so

  if ($foo->does('Some::Role')) {
    ...
  }

will work for classes but to test a role, one must use ::does_role directly

=head1 METHODS

=head2 apply_roles_to_package

 Role::Tiny->apply_roles_to_package(
   'Some::Package', 'Some::Role', 'Some::Other::Role'
 );

Composes role with package.  See also L<Role::Tiny::With>.

=head2 apply_roles_to_object

 Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));

Composes roles in order into object directly.  Object is reblessed into the
resulting class.

=head2 create_class_with_roles

 Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));

Creates a new class based on base, with the roles composed into it in order.
New class is returned.

=head1 SEE ALSO

L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
a meta-protocol-less subset of the king of role systems, L<Moose::Role>.

If you don't want method modifiers and do want to be forcibly restricted
to a single role application per class, Ovid's L<Role::Basic> exists. But
Stevan Little (the L<Moose> author) and I don't find the additional
restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
are more a guide to what you should prefer doing, to our mind, rather than
something that needs to be enforced.

=head1 AUTHOR

mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>

=head1 CONTRIBUTORS

dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>

frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>

hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>

jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>

ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>

chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>

ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>

doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>

perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>

Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>

ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>

=head1 COPYRIGHT

Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
as listed above.

=head1 LICENSE

This library is free software and may be distributed under the same terms
as perl itself.

=cut
Commit	Line	Data
ab3370e7	1	package Role::Tiny;
ab3370e7	2
119014a7	3	sub _getglob { \*{$_[0]} }
5e03b55c	4	sub _getstash { \%{"$_[0]::"} }
119014a7	5
b1eebd55	6	use strict;
b1eebd55	7	use warnings FATAL => 'all';
ab3370e7	8
fbe6dc87	9	our $VERSION = '1.001005'; # 1.1.5
c334a5c1	10	$VERSION = eval $VERSION;
c334a5c1	11
ab3370e7	12	our %INFO;
ab3370e7	13	our %APPLIED_TO;
1947330a	14	our %COMPOSED;
836aea1b	15	our %COMPOSITE_INFO;
ab3370e7	16
cf62c989	17	# Module state workaround totally stolen from Zefram's Module::Runtime.
	18
	19	BEGIN {
	20	*_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
	21	}
	22
	23	sub Role::Tiny::__GUARD__::DESTROY {
	24	delete $INC{$_[0]->[0]} if @{$_[0]};
	25	}
5e03b55c	26
fb5074f6	27	sub _load_module {
fb5074f6	28	(my $proto = $_[0]) =~ s/::/\//g;
cf62c989	29	$proto .= '.pm';
cf62c989	30	return 1 if $INC{$proto};
5e03b55c	31	# can't just ->can('can') because a sub-package Foo::Bar::Baz
	32	# creates a 'Baz::' key in Foo::Bar's symbol table
	33	return 1 if grep !/::$/, keys %{_getstash($_[0])\|\|{}};
cf62c989	34	my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
	35	&& bless([ $proto ], 'Role::Tiny::__GUARD__');
	36	require $proto;
	37	pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
fb5074f6	38	return 1;
	39	}
	40
ab3370e7	41	sub import {
ab3370e7	42	my $target = caller;
a1164a0b	43	my $me = shift;
3ca7ff56	44	strict->import;
3ca7ff56	45	warnings->import(FATAL => 'all');
1ba11455	46	return if $INFO{$target}; # already exported into this package
ab3370e7	47	# get symbol table reference
	48	my $stash = do { no strict 'refs'; \%{"${target}::"} };
	49	# install before/after/around subs
	50	foreach my $type (qw(before after around)) {
5a247406	51	*{_getglob "${target}::${type}"} = sub {
7568ba55	52	require Class::Method::Modifiers;
ab3370e7	53	push @{$INFO{$target}{modifiers}\|\|=[]}, [ $type => @_ ];
ef2da711	54	return;
ab3370e7	55	};
ab3370e7	56	}
5a247406	57	*{_getglob "${target}::requires"} = sub {
ab3370e7	58	push @{$INFO{$target}{requires}\|\|=[]}, @_;
ef2da711	59	return;
ab3370e7	60	};
5a247406	61	*{_getglob "${target}::with"} = sub {
836aea1b	62	$me->apply_roles_to_package($target, @_);
ef2da711	63	return;
96d3f07a	64	};
7b8177f8	65	# grab all non-constant (stash slot is not a scalarref) subs present
ab3370e7	66	# in the symbol table and store their refaddrs (no need to forcibly
ab3370e7	67	# inflate constant subs into real subs) - also add '' to here (this
12f8eb0b	68	# is used later) with a map to the coderefs in case of copying or re-use
	69	my @not_methods = ('', map { *$_{CODE}\|\|() } grep !ref($_), values %$stash);
	70	@{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
ab3370e7	71	# a role does itself
	72	$APPLIED_TO{$target} = { $target => undef };
	73	}
	74
836aea1b	75	sub apply_single_role_to_package {
369a4c50	76	my ($me, $to, $role) = @_;
1947330a	77
fb5074f6	78	_load_module($role);
fb5074f6	79
ab3370e7	80	die "This is apply_role_to_package" if ref($to);
1947330a	81	die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
	82
	83	$me->_check_requires($to, $role, @{$info->{requires}\|\|[]});
	84
	85	$me->_install_methods($to, $role);
	86
	87	$me->_install_modifiers($to, $info->{modifiers});
	88
	89	# only add does() method to classes and only if they don't have one
	90	if (not $INFO{$to} and not $to->can('does')) {
	91	*{_getglob "${to}::does"} = \&does_role;
	92	}
	93
1947330a	94	# copy our role list into the target's
	95	@{$APPLIED_TO{$to}\|\|={}}{keys %{$APPLIED_TO{$role}}} = ();
	96	}
	97
	98	sub apply_roles_to_object {
	99	my ($me, $object, @roles) = @_;
	100	die "No roles supplied!" unless @roles;
	101	my $class = ref($object);
	102	bless($object, $me->create_class_with_roles($class, @roles));
	103	$object;
	104	}
	105
	106	sub create_class_with_roles {
	107	my ($me, $superclass, @roles) = @_;
	108
fb5074f6	109	die "No roles supplied!" unless @roles;
fb5074f6	110
f52b9821	111	_load_module($superclass);
2c580674	112	{
	113	my %seen;
	114	$seen{$_}++ for @roles;
	115	if (my @dupes = grep $seen{$_} > 1, @roles) {
	116	die "Duplicated roles: ".join(', ', @dupes);
	117	}
	118	}
	119
c69190f1	120	my $new_name = join(
	121	'__WITH__', $superclass, my $compose_name = join '__AND__', @roles
	122	);
	123
1947330a	124	return $new_name if $COMPOSED{class}{$new_name};
	125
	126	foreach my $role (@roles) {
fb5074f6	127	_load_module($role);
29dde8ba	128	die "${role} is not a Role::Tiny" unless $INFO{$role};
1947330a	129	}
1947330a	130
786e5ba0	131	if ($] >= 5.010) {
7568ba55	132	require mro;
b1eebd55	133	} else {
7568ba55	134	require MRO::Compat;
b1eebd55	135	}
1947330a	136
471419f6	137	my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
	138	if (keys %conflicts) {
	139	my $fail =
	140	join "\n",
	141	map {
	142	"Method name conflict for '$_' between roles "
	143	."'".join(' and ', sort values %{$conflicts{$_}})."'"
	144	.", cannot apply these simultaneously to an object."
	145	} keys %conflicts;
	146	die $fail;
	147	}
	148
1947330a	149	my @composable = map $me->_composable_package_for($_), reverse @roles;
	150
	151	*{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
	152
29dde8ba	153	my @info = map $INFO{$_}, @roles;
1947330a	154
	155	$me->_check_requires(
	156	$new_name, $compose_name,
	157	do { my %h; @h{map @{$_->{requires}\|\|[]}, @info} = (); keys %h }
	158	);
1947330a	159
	160	*{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');
	161
	162	@{$APPLIED_TO{$new_name}\|\|={}}{
91037640	163	map keys %{$APPLIED_TO{$_}}, @roles
1947330a	164	} = ();
	165
	166	$COMPOSED{class}{$new_name} = 1;
	167	return $new_name;
	168	}
	169
92e1c5f8	170	# preserved for compat, and apply_roles_to_package calls it to allow an
	171	# updated Role::Tiny to use a non-updated Moo::Role
	172
836aea1b	173	sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
	174
	175	sub apply_roles_to_package {
60dfe768	176	my ($me, $to, @roles) = @_;
60dfe768	177
92e1c5f8	178	return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
60dfe768	179
836aea1b	180	my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
671b5a88	181	delete $conflicts{$_} for $me->_concrete_methods_of($to);
671b5a88	182	if (keys %conflicts) {
60dfe768	183	my $fail =
60dfe768	184	join "\n",
671b5a88	185	map {
	186	"Due to a method name conflict between roles "
	187	."'".join(' and ', sort values %{$conflicts{$_}})."'"
	188	.", the method '$_' must be implemented by '${to}'"
	189	} keys %conflicts;
	190	die $fail;
60dfe768	191	}
06b06c8e	192
	193	# the if guard here is essential since otherwise we accidentally create
	194	# a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
	195	# autovivification hates us and wants us to die()
	196	if ($INFO{$to}) {
	197	delete $INFO{$to}{methods}; # reset since we're about to add methods
	198	}
	199
92e1c5f8	200	$me->apply_role_to_package($to, $_) for @roles;
671b5a88	201	$APPLIED_TO{$to}{join('\|',@roles)} = 1;
	202	}
	203
836aea1b	204	sub _composite_info_for {
671b5a88	205	my ($me, @roles) = @_;
836aea1b	206	$COMPOSITE_INFO{join('\|', sort @roles)} \|\|= do {
671b5a88	207	_load_module($_) for @roles;
	208	my %methods;
	209	foreach my $role (@roles) {
	210	my $this_methods = $me->_concrete_methods_of($role);
	211	$methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
	212	}
	213	delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
	214	+{ conflicts => \%methods }
	215	};
60dfe768	216	}
60dfe768	217
1947330a	218	sub _composable_package_for {
	219	my ($me, $role) = @_;
	220	my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
	221	return $composed_name if $COMPOSED{role}{$composed_name};
	222	$me->_install_methods($composed_name, $role);
	223	my $base_name = $composed_name.'::_BASE';
	224	*{_getglob("${composed_name}::ISA")} = [ $base_name ];
	225	my $modifiers = $INFO{$role}{modifiers}\|\|[];
b1eebd55	226	my @mod_base;
1947330a	227	foreach my $modified (
	228	do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
	229	) {
b1eebd55	230	push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
1947330a	231	}
385f5087	232	my $e;
59812c87	233	{
	234	local $@;
	235	eval(my $code = join "\n", "package ${base_name};", @mod_base);
385f5087	236	$e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
59812c87	237	}
385f5087	238	die $e if $e;
1947330a	239	$me->_install_modifiers($composed_name, $modifiers);
	240	$COMPOSED{role}{$composed_name} = 1;
	241	return $composed_name;
	242	}
	243
	244	sub _check_requires {
	245	my ($me, $to, $name, @requires) = @_;
	246	if (my @requires_fail = grep !$to->can($_), @requires) {
	247	# role -> role, add to requires, role -> class, error out
	248	if (my $to_info = $INFO{$to}) {
	249	push @{$to_info->{requires}\|\|=[]}, @requires_fail;
	250	} else {
	251	die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
	252	}
	253	}
	254	}
	255
4db3a740	256	sub _concrete_methods_of {
4db3a740	257	my ($me, $role) = @_;
1947330a	258	my $info = $INFO{$role};
60dfe768	259	# grab role symbol table
60dfe768	260	my $stash = do { no strict 'refs'; \%{"${role}::"}};
12f8eb0b	261	# reverse so our keys become the values (captured coderefs) in case
12f8eb0b	262	# they got copied or re-used since
123a5a6e	263	my $not_methods = { reverse %{$info->{not_methods}\|\|{}} };
eb8fcb2d	264	$info->{methods} \|\|= +{
60dfe768	265	# grab all code entries that aren't in the not_methods list
	266	map {
	267	my $code = *{$stash->{$_}}{CODE};
	268	# rely on the '' key we added in import for "no code here"
	269	exists $not_methods->{$code\|\|''} ? () : ($_ => $code)
	270	} grep !ref($stash->{$_}), keys %$stash
ab3370e7	271	};
4db3a740	272	}
	273
	274	sub methods_provided_by {
	275	my ($me, $role) = @_;
	276	die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
	277	(keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}\|\|[]});
	278	}
	279
	280	sub _install_methods {
	281	my ($me, $to, $role) = @_;
	282
	283	my $info = $INFO{$role};
	284
	285	my $methods = $me->_concrete_methods_of($role);
1947330a	286
ab3370e7	287	# grab target symbol table
ab3370e7	288	my $stash = do { no strict 'refs'; \%{"${to}::"}};
1947330a	289
ab3370e7	290	# determine already extant methods of target
	291	my %has_methods;
	292	@has_methods{grep
faa9ce11	293	+(ref($stash->{$_}) \|\| *{$stash->{$_}}{CODE}),
ab3370e7	294	keys %$stash
ab3370e7	295	} = ();
ab3370e7	296
1947330a	297	foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
ab3370e7	298	no warnings 'once';
5a247406	299	*{_getglob "${to}::${i}"} = $methods->{$i};
ab3370e7	300	}
1947330a	301	}
ab3370e7	302
1947330a	303	sub _install_modifiers {
1947330a	304	my ($me, $to, $modifiers) = @_;
dccea57d	305	if (my $info = $INFO{$to}) {
	306	push @{$info->{modifiers}}, @{$modifiers\|\|[]};
	307	} else {
	308	foreach my $modifier (@{$modifiers\|\|[]}) {
	309	$me->_install_single_modifier($to, @$modifier);
	310	}
96d3f07a	311	}
ab3370e7	312	}
ab3370e7	313
dccea57d	314	sub _install_single_modifier {
	315	my ($me, @args) = @_;
	316	Class::Method::Modifiers::install_modifier(@args);
	317	}
	318
ab3370e7	319	sub does_role {
390ac406	320	my ($proto, $role) = @_;
91037640	321	if ($] >= 5.010) {
	322	require mro;
	323	} else {
	324	require MRO::Compat;
	325	}
	326	foreach my $class (@{mro::get_linear_isa(ref($proto)\|\|$proto)}) {
	327	return 1 if exists $APPLIED_TO{$class}{$role};
	328	}
	329	return 0;
ab3370e7	330	}
	331
	332	1;
5febcf4d	333
0b6e5fff	334	=head1 NAME
0b6e5fff	335
70061353	336	Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
5febcf4d	337
	338	=head1 SYNOPSIS
	339
	340	package Some::Role;
	341
	342	use Role::Tiny;
	343
	344	sub foo { ... }
	345
	346	sub bar { ... }
	347
adcb6c3d	348	around baz => sub { ... }
adcb6c3d	349
5febcf4d	350	1;
	351
	352	else where
	353
	354	package Some::Class;
	355
a1164a0b	356	use Role::Tiny::With;
5febcf4d	357
5febcf4d	358	# bar gets imported, but not foo
a1164a0b	359	with 'Some::Role';
5febcf4d	360
	361	sub foo { ... }
	362
adcb6c3d	363	# baz is wrapped in the around modifier by Class::Method::Modifiers
	364	sub baz { ... }
	365
5febcf4d	366	1;
5febcf4d	367
adcb6c3d	368	If you wanted attributes as well, look at L<Moo::Role>.
adcb6c3d	369
5febcf4d	370	=head1 DESCRIPTION
	371
	372	C<Role::Tiny> is a minimalist role composition tool.
	373
	374	=head1 ROLE COMPOSITION
	375
	376	Role composition can be thought of as much more clever and meaningful multiple
	377	inheritance. The basics of this implementation of roles is:
	378
	379	=over 2
	380
	381	=item *
	382
	383	If a method is already defined on a class, that method will not be composed in
	384	from the role.
	385
	386	=item *
	387
	388	If a method that the role L</requires> to be implemented is not implemented,
	389	role application will fail loudly.
	390
0d39f9d3	391	=back
0d39f9d3	392
5febcf4d	393	Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
836aea1b	394	composition is the other way around, where the class wins. If multiple roles
	395	are applied in a single call (single with statement), then if any of their
	396	provided methods clash, an exception is raised unless the class provides
	397	a method since this conflict indicates a potential problem.
5febcf4d	398
5febcf4d	399	=head1 IMPORTED SUBROUTINES
	400
	401	=head2 requires
	402
	403	requires qw(foo bar);
	404
	405	Declares a list of methods that must be defined to compose role.
	406
	407	=head2 with
	408
	409	with 'Some::Role1';
836aea1b	410
	411	with 'Some::Role1', 'Some::Role2';
	412
	413	Composes another role into the current role (or class via L<Role::Tiny::With>).
	414
	415	If you have conflicts and want to resolve them in favour of Some::Role1 you
	416	can instead write:
	417
	418	with 'Some::Role1';
5febcf4d	419	with 'Some::Role2';
5febcf4d	420
836aea1b	421	If you have conflicts and want to resolve different conflicts in favour of
836aea1b	422	different roles, please refactor your codebase.
5febcf4d	423
	424	=head2 before
	425
	426	before foo => sub { ... };
	427
	428	See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
	429	documentation.
	430
adcb6c3d	431	Note that since you are not required to use method modifiers,
	432	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	433	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	434	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	435
5febcf4d	436	=head2 around
	437
	438	around foo => sub { ... };
	439
	440	See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
	441	documentation.
	442
adcb6c3d	443	Note that since you are not required to use method modifiers,
	444	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	445	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	446	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	447
5febcf4d	448	=head2 after
	449
	450	after foo => sub { ... };
	451
	452	See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
	453	documentation.
	454
adcb6c3d	455	Note that since you are not required to use method modifiers,
	456	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	457	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	458	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	459
ec28e16b	460	=head1 SUBROUTINES
	461
	462	=head2 does_role
	463
	464	if (Role::Tiny::does_role($foo, 'Some::Role')) {
	465	...
	466	}
	467
	468	Returns true if class has been composed with role.
	469
	470	This subroutine is also installed as ->does on any class a Role::Tiny is
	471	composed into unless that class already has an ->does method, so
	472
	473	if ($foo->does('Some::Role')) {
	474	...
	475	}
	476
	477	will work for classes but to test a role, one must use ::does_role directly
	478
	479	=head1 METHODS
	480
	481	=head2 apply_roles_to_package
	482
	483	Role::Tiny->apply_roles_to_package(
	484	'Some::Package', 'Some::Role', 'Some::Other::Role'
	485	);
	486
	487	Composes role with package. See also L<Role::Tiny::With>.
	488
	489	=head2 apply_roles_to_object
	490
	491	Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
	492
	493	Composes roles in order into object directly. Object is reblessed into the
	494	resulting class.
	495
	496	=head2 create_class_with_roles
	497
	498	Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
	499
	500	Creates a new class based on base, with the roles composed into it in order.
	501	New class is returned.
	502
adcb6c3d	503	=head1 SEE ALSO
	504
	505	L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
	506	a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
	507
	508	If you don't want method modifiers and do want to be forcibly restricted
	509	to a single role application per class, Ovid's L<Role::Basic> exists. But
259ce3a0	510	Stevan Little (the L<Moose> author) and I don't find the additional
	511	restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
	512	are more a guide to what you should prefer doing, to our mind, rather than
	513	something that needs to be enforced.
adcb6c3d	514
c334a5c1	515	=head1 AUTHOR
	516
	517	mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
	518
	519	=head1 CONTRIBUTORS
	520
	521	dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
	522
	523	frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
	524
	525	hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
	526
	527	jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
	528
	529	ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
	530
	531	chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
	532
	533	ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
	534
	535	doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
	536
	537	perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
	538
ec28e16b	539	Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
ec28e16b	540
91037640	541	ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
91037640	542
c334a5c1	543	=head1 COPYRIGHT
40f3e3aa	544
c334a5c1	545	Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
c334a5c1	546	as listed above.
40f3e3aa	547
c334a5c1	548	=head1 LICENSE
40f3e3aa	549
c334a5c1	550	This library is free software and may be distributed under the same terms
c334a5c1	551	as perl itself.
40f3e3aa	552
40f3e3aa	553	=cut