[gitmo/Role-Tiny.git] / lib / Role / Tiny.pm

package Role::Tiny;

sub _getglob { \*{$_[0]} }
sub _getstash { \%{"$_[0]::"} }

use strict;
use warnings FATAL => 'all';

our $VERSION = '1.001004'; # 1.1.4
$VERSION = eval $VERSION;

our %INFO;
our %APPLIED_TO;
our %COMPOSED;
our %COMPOSITE_INFO;

# Module state workaround totally stolen from Zefram's Module::Runtime.

BEGIN {
  *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
}

sub Role::Tiny::__GUARD__::DESTROY {
  delete $INC{$_[0]->[0]} if @{$_[0]};
}

sub _load_module {
  (my $proto = $_[0]) =~ s/::/\//g;
  $proto .= '.pm';
  return 1 if $INC{$proto};
  # can't just ->can('can') because a sub-package Foo::Bar::Baz
  # creates a 'Baz::' key in Foo::Bar's symbol table
  return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
    && bless([ $proto ], 'Role::Tiny::__GUARD__');
  require $proto;
  pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  return 1;
}

sub import {
  my $target = caller;
  my $me = shift;
  strict->import;
  warnings->import(FATAL => 'all');
  return if $INFO{$target}; # already exported into this package
  # get symbol table reference
  my $stash = do { no strict 'refs'; \%{"${target}::"} };
  # install before/after/around subs
  foreach my $type (qw(before after around)) {
    *{_getglob "${target}::${type}"} = sub {
      require Class::Method::Modifiers;
      push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
      return;
    };
  }
  *{_getglob "${target}::requires"} = sub {
    push @{$INFO{$target}{requires}||=[]}, @_;
    return;
  };
  *{_getglob "${target}::with"} = sub {
    $me->apply_roles_to_package($target, @_);
    return;
  };
  # grab all *non-constant* (stash slot is not a scalarref) subs present
  # in the symbol table and store their refaddrs (no need to forcibly
  # inflate constant subs into real subs) - also add '' to here (this
  # is used later) with a map to the coderefs in case of copying or re-use
  my @not_methods = ('', map { *$_{CODE}||() } grep !ref($_), values %$stash);
  @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  # a role does itself
  $APPLIED_TO{$target} = { $target => undef };
}

sub apply_single_role_to_package {
  my ($me, $to, $role) = @_;

  _load_module($role);

  die "This is apply_role_to_package" if ref($to);
  die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};

  $me->_check_requires($to, $role, @{$info->{requires}||[]});

  $me->_install_methods($to, $role);

  $me->_install_modifiers($to, $info->{modifiers});

  # only add does() method to classes and only if they don't have one
  if (not $INFO{$to} and not $to->can('does')) {
    *{_getglob "${to}::does"} = \&does_role;
  }

  # copy our role list into the target's
  @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
}

sub apply_roles_to_object {
  my ($me, $object, @roles) = @_;
  die "No roles supplied!" unless @roles;
  my $class = ref($object);
  bless($object, $me->create_class_with_roles($class, @roles));
  $object;
}

sub create_class_with_roles {
  my ($me, $superclass, @roles) = @_;

  die "No roles supplied!" unless @roles;

  {
    my %seen;
    $seen{$_}++ for @roles;
    if (my @dupes = grep $seen{$_} > 1, @roles) {
      die "Duplicated roles: ".join(', ', @dupes);
    }
  }

  my $new_name = join(
    '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
  );

  return $new_name if $COMPOSED{class}{$new_name};

  foreach my $role (@roles) {
    _load_module($role);
    die "${role} is not a Role::Tiny" unless $INFO{$role};
  }

  if ($] >= 5.010) {
    require mro;
  } else {
    require MRO::Compat;
  }

  my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
  if (keys %conflicts) {
    my $fail = 
      join "\n",
        map {
          "Method name conflict for '$_' between roles "
          ."'".join(' and ', sort values %{$conflicts{$_}})."'"
          .", cannot apply these simultaneously to an object."
        } keys %conflicts;
    die $fail;
  }

  my @composable = map $me->_composable_package_for($_), reverse @roles;

  *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];

  my @info = map $INFO{$_}, @roles;

  $me->_check_requires(
    $new_name, $compose_name,
    do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
  );

  *{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');

  @{$APPLIED_TO{$new_name}||={}}{
    map keys %{$APPLIED_TO{$_}}, @roles
  } = ();

  $COMPOSED{class}{$new_name} = 1;
  return $new_name;
}

# preserved for compat, and apply_roles_to_package calls it to allow an
# updated Role::Tiny to use a non-updated Moo::Role

sub apply_role_to_package { shift->apply_single_role_to_package(@_) }

sub apply_roles_to_package {
  my ($me, $to, @roles) = @_;

  return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;

  my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
  delete $conflicts{$_} for $me->_concrete_methods_of($to);
  if (keys %conflicts) {
    my $fail = 
      join "\n",
        map {
          "Due to a method name conflict between roles "
          ."'".join(' and ', sort values %{$conflicts{$_}})."'"
          .", the method '$_' must be implemented by '${to}'"
        } keys %conflicts;
    die $fail;
  }

  # the if guard here is essential since otherwise we accidentally create
  # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
  # autovivification hates us and wants us to die()
  if ($INFO{$to}) {
    delete $INFO{$to}{methods}; # reset since we're about to add methods
  }

  $me->apply_role_to_package($to, $_) for @roles;
  $APPLIED_TO{$to}{join('|',@roles)} = 1;
}

sub _composite_info_for {
  my ($me, @roles) = @_;
  $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
    _load_module($_) for @roles;
    my %methods;
    foreach my $role (@roles) {
      my $this_methods = $me->_concrete_methods_of($role);
      $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
    }
    delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
    +{ conflicts => \%methods }
  };
}

sub _composable_package_for {
  my ($me, $role) = @_;
  my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
  return $composed_name if $COMPOSED{role}{$composed_name};
  $me->_install_methods($composed_name, $role);
  my $base_name = $composed_name.'::_BASE';
  *{_getglob("${composed_name}::ISA")} = [ $base_name ];
  my $modifiers = $INFO{$role}{modifiers}||[];
  my @mod_base;
  foreach my $modified (
    do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
  ) {
    push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
  }
  my $e;
  {
    local $@;
    eval(my $code = join "\n", "package ${base_name};", @mod_base);
    $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
  }
  die $e if $e;
  $me->_install_modifiers($composed_name, $modifiers);
  $COMPOSED{role}{$composed_name} = 1;
  return $composed_name;
}

sub _check_requires {
  my ($me, $to, $name, @requires) = @_;
  if (my @requires_fail = grep !$to->can($_), @requires) {
    # role -> role, add to requires, role -> class, error out
    if (my $to_info = $INFO{$to}) {
      push @{$to_info->{requires}||=[]}, @requires_fail;
    } else {
      die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
    }
  }
}

sub _concrete_methods_of {
  my ($me, $role) = @_;
  my $info = $INFO{$role};
  # grab role symbol table
  my $stash = do { no strict 'refs'; \%{"${role}::"}};
  # reverse so our keys become the values (captured coderefs) in case
  # they got copied or re-used since
  my $not_methods = { reverse %{$info->{not_methods}||{}} };
  $info->{methods} ||= +{
    # grab all code entries that aren't in the not_methods list
    map {
      my $code = *{$stash->{$_}}{CODE};
      # rely on the '' key we added in import for "no code here"
      exists $not_methods->{$code||''} ? () : ($_ => $code)
    } grep !ref($stash->{$_}), keys %$stash
  };
}

sub methods_provided_by {
  my ($me, $role) = @_;
  die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
  (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
}

sub _install_methods {
  my ($me, $to, $role) = @_;

  my $info = $INFO{$role};

  my $methods = $me->_concrete_methods_of($role);

  # grab target symbol table
  my $stash = do { no strict 'refs'; \%{"${to}::"}};

  # determine already extant methods of target
  my %has_methods;
  @has_methods{grep
    +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
    keys %$stash
  } = ();

  foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
    no warnings 'once';
    *{_getglob "${to}::${i}"} = $methods->{$i};
  }
}

sub _install_modifiers {
  my ($me, $to, $modifiers) = @_;
  if (my $info = $INFO{$to}) {
    push @{$info->{modifiers}}, @{$modifiers||[]};
  } else {
    foreach my $modifier (@{$modifiers||[]}) {
      $me->_install_single_modifier($to, @$modifier);
    }
  }
}

sub _install_single_modifier {
  my ($me, @args) = @_;
  Class::Method::Modifiers::install_modifier(@args);
}

sub does_role {
  my ($proto, $role) = @_;
  if ($] >= 5.010) {
    require mro;
  } else {
    require MRO::Compat;
  }
  foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) {
    return 1 if exists $APPLIED_TO{$class}{$role};
  }
  return 0;
}

1;

=head1 NAME

Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.

=head1 SYNOPSIS

 package Some::Role;

 use Role::Tiny;

 sub foo { ... }

 sub bar { ... }

 around baz => sub { ... }

 1;

else where

 package Some::Class;

 use Role::Tiny::With;

 # bar gets imported, but not foo
 with 'Some::Role';

 sub foo { ... }

 # baz is wrapped in the around modifier by Class::Method::Modifiers
 sub baz { ... }

 1;

If you wanted attributes as well, look at L<Moo::Role>.

=head1 DESCRIPTION

C<Role::Tiny> is a minimalist role composition tool.

=head1 ROLE COMPOSITION

Role composition can be thought of as much more clever and meaningful multiple
inheritance.  The basics of this implementation of roles is:

=over 2

=item *

If a method is already defined on a class, that method will not be composed in
from the role.

=item *

If a method that the role L</requires> to be implemented is not implemented,
role application will fail loudly.

=back

Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
composition is the other way around, where the class wins. If multiple roles
are applied in a single call (single with statement), then if any of their
provided methods clash, an exception is raised unless the class provides
a method since this conflict indicates a potential problem.

=head1 IMPORTED SUBROUTINES

=head2 requires

 requires qw(foo bar);

Declares a list of methods that must be defined to compose role.

=head2 with

 with 'Some::Role1';

 with 'Some::Role1', 'Some::Role2';

Composes another role into the current role (or class via L<Role::Tiny::With>).

If you have conflicts and want to resolve them in favour of Some::Role1 you
can instead write: 

 with 'Some::Role1';
 with 'Some::Role2';

If you have conflicts and want to resolve different conflicts in favour of
different roles, please refactor your codebase.

=head2 before

 before foo => sub { ... };

See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head2 around

 around foo => sub { ... };

See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head2 after

 after foo => sub { ... };

See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head1 SUBROUTINES

=head2 does_role

 if (Role::Tiny::does_role($foo, 'Some::Role')) {
   ...
 }

Returns true if class has been composed with role.

This subroutine is also installed as ->does on any class a Role::Tiny is
composed into unless that class already has an ->does method, so

  if ($foo->does('Some::Role')) {
    ...
  }

will work for classes but to test a role, one must use ::does_role directly

=head1 METHODS

=head2 apply_roles_to_package

 Role::Tiny->apply_roles_to_package(
   'Some::Package', 'Some::Role', 'Some::Other::Role'
 );

Composes role with package.  See also L<Role::Tiny::With>.

=head2 apply_roles_to_object

 Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));

Composes roles in order into object directly.  Object is reblessed into the
resulting class.

=head2 create_class_with_roles

 Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));

Creates a new class based on base, with the roles composed into it in order.
New class is returned.

=head1 SEE ALSO

L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
a meta-protocol-less subset of the king of role systems, L<Moose::Role>.

If you don't want method modifiers and do want to be forcibly restricted
to a single role application per class, Ovid's L<Role::Basic> exists. But
Stevan Little (the L<Moose> author) and I don't find the additional
restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
are more a guide to what you should prefer doing, to our mind, rather than
something that needs to be enforced.

=head1 AUTHOR

mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>

=head1 CONTRIBUTORS

dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>

frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>

hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>

jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>

ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>

chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>

ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>

doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>

perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>

Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>

ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>

=head1 COPYRIGHT

Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
as listed above.

=head1 LICENSE

This library is free software and may be distributed under the same terms
as perl itself.

=cut
Commit	Line	Data
ab3370e7	1	package Role::Tiny;
ab3370e7	2
119014a7	3	sub _getglob { \*{$_[0]} }
5e03b55c	4	sub _getstash { \%{"$_[0]::"} }
119014a7	5
b1eebd55	6	use strict;
b1eebd55	7	use warnings FATAL => 'all';
ab3370e7	8
4a9cd2d9	9	our $VERSION = '1.001004'; # 1.1.4
c334a5c1	10	$VERSION = eval $VERSION;
c334a5c1	11
ab3370e7	12	our %INFO;
ab3370e7	13	our %APPLIED_TO;
1947330a	14	our %COMPOSED;
836aea1b	15	our %COMPOSITE_INFO;
ab3370e7	16
cf62c989	17	# Module state workaround totally stolen from Zefram's Module::Runtime.
	18
	19	BEGIN {
	20	*_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
	21	}
	22
	23	sub Role::Tiny::__GUARD__::DESTROY {
	24	delete $INC{$_[0]->[0]} if @{$_[0]};
	25	}
5e03b55c	26
fb5074f6	27	sub _load_module {
fb5074f6	28	(my $proto = $_[0]) =~ s/::/\//g;
cf62c989	29	$proto .= '.pm';
cf62c989	30	return 1 if $INC{$proto};
5e03b55c	31	# can't just ->can('can') because a sub-package Foo::Bar::Baz
	32	# creates a 'Baz::' key in Foo::Bar's symbol table
	33	return 1 if grep !/::$/, keys %{_getstash($_[0])\|\|{}};
cf62c989	34	my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
	35	&& bless([ $proto ], 'Role::Tiny::__GUARD__');
	36	require $proto;
	37	pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
fb5074f6	38	return 1;
	39	}
	40
ab3370e7	41	sub import {
ab3370e7	42	my $target = caller;
a1164a0b	43	my $me = shift;
3ca7ff56	44	strict->import;
3ca7ff56	45	warnings->import(FATAL => 'all');
1ba11455	46	return if $INFO{$target}; # already exported into this package
ab3370e7	47	# get symbol table reference
	48	my $stash = do { no strict 'refs'; \%{"${target}::"} };
	49	# install before/after/around subs
	50	foreach my $type (qw(before after around)) {
5a247406	51	*{_getglob "${target}::${type}"} = sub {
7568ba55	52	require Class::Method::Modifiers;
ab3370e7	53	push @{$INFO{$target}{modifiers}\|\|=[]}, [ $type => @_ ];
ef2da711	54	return;
ab3370e7	55	};
ab3370e7	56	}
5a247406	57	*{_getglob "${target}::requires"} = sub {
ab3370e7	58	push @{$INFO{$target}{requires}\|\|=[]}, @_;
ef2da711	59	return;
ab3370e7	60	};
5a247406	61	*{_getglob "${target}::with"} = sub {
836aea1b	62	$me->apply_roles_to_package($target, @_);
ef2da711	63	return;
96d3f07a	64	};
7b8177f8	65	# grab all non-constant (stash slot is not a scalarref) subs present
ab3370e7	66	# in the symbol table and store their refaddrs (no need to forcibly
ab3370e7	67	# inflate constant subs into real subs) - also add '' to here (this
12f8eb0b	68	# is used later) with a map to the coderefs in case of copying or re-use
	69	my @not_methods = ('', map { *$_{CODE}\|\|() } grep !ref($_), values %$stash);
	70	@{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
ab3370e7	71	# a role does itself
	72	$APPLIED_TO{$target} = { $target => undef };
	73	}
	74
836aea1b	75	sub apply_single_role_to_package {
369a4c50	76	my ($me, $to, $role) = @_;
1947330a	77
fb5074f6	78	_load_module($role);
fb5074f6	79
ab3370e7	80	die "This is apply_role_to_package" if ref($to);
1947330a	81	die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
	82
	83	$me->_check_requires($to, $role, @{$info->{requires}\|\|[]});
	84
	85	$me->_install_methods($to, $role);
	86
	87	$me->_install_modifiers($to, $info->{modifiers});
	88
	89	# only add does() method to classes and only if they don't have one
	90	if (not $INFO{$to} and not $to->can('does')) {
	91	*{_getglob "${to}::does"} = \&does_role;
	92	}
	93
1947330a	94	# copy our role list into the target's
	95	@{$APPLIED_TO{$to}\|\|={}}{keys %{$APPLIED_TO{$role}}} = ();
	96	}
	97
	98	sub apply_roles_to_object {
	99	my ($me, $object, @roles) = @_;
	100	die "No roles supplied!" unless @roles;
	101	my $class = ref($object);
	102	bless($object, $me->create_class_with_roles($class, @roles));
	103	$object;
	104	}
	105
	106	sub create_class_with_roles {
	107	my ($me, $superclass, @roles) = @_;
	108
fb5074f6	109	die "No roles supplied!" unless @roles;
fb5074f6	110
2c580674	111	{
	112	my %seen;
	113	$seen{$_}++ for @roles;
	114	if (my @dupes = grep $seen{$_} > 1, @roles) {
	115	die "Duplicated roles: ".join(', ', @dupes);
	116	}
	117	}
	118
c69190f1	119	my $new_name = join(
	120	'__WITH__', $superclass, my $compose_name = join '__AND__', @roles
	121	);
	122
1947330a	123	return $new_name if $COMPOSED{class}{$new_name};
	124
	125	foreach my $role (@roles) {
fb5074f6	126	_load_module($role);
29dde8ba	127	die "${role} is not a Role::Tiny" unless $INFO{$role};
1947330a	128	}
1947330a	129
786e5ba0	130	if ($] >= 5.010) {
7568ba55	131	require mro;
b1eebd55	132	} else {
7568ba55	133	require MRO::Compat;
b1eebd55	134	}
1947330a	135
471419f6	136	my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
	137	if (keys %conflicts) {
	138	my $fail =
	139	join "\n",
	140	map {
	141	"Method name conflict for '$_' between roles "
	142	."'".join(' and ', sort values %{$conflicts{$_}})."'"
	143	.", cannot apply these simultaneously to an object."
	144	} keys %conflicts;
	145	die $fail;
	146	}
	147
1947330a	148	my @composable = map $me->_composable_package_for($_), reverse @roles;
	149
	150	*{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
	151
29dde8ba	152	my @info = map $INFO{$_}, @roles;
1947330a	153
	154	$me->_check_requires(
	155	$new_name, $compose_name,
	156	do { my %h; @h{map @{$_->{requires}\|\|[]}, @info} = (); keys %h }
	157	);
1947330a	158
	159	*{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does');
	160
	161	@{$APPLIED_TO{$new_name}\|\|={}}{
91037640	162	map keys %{$APPLIED_TO{$_}}, @roles
1947330a	163	} = ();
	164
	165	$COMPOSED{class}{$new_name} = 1;
	166	return $new_name;
	167	}
	168
92e1c5f8	169	# preserved for compat, and apply_roles_to_package calls it to allow an
	170	# updated Role::Tiny to use a non-updated Moo::Role
	171
836aea1b	172	sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
	173
	174	sub apply_roles_to_package {
60dfe768	175	my ($me, $to, @roles) = @_;
60dfe768	176
92e1c5f8	177	return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
60dfe768	178
836aea1b	179	my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
671b5a88	180	delete $conflicts{$_} for $me->_concrete_methods_of($to);
671b5a88	181	if (keys %conflicts) {
60dfe768	182	my $fail =
60dfe768	183	join "\n",
671b5a88	184	map {
	185	"Due to a method name conflict between roles "
	186	."'".join(' and ', sort values %{$conflicts{$_}})."'"
	187	.", the method '$_' must be implemented by '${to}'"
	188	} keys %conflicts;
	189	die $fail;
60dfe768	190	}
06b06c8e	191
	192	# the if guard here is essential since otherwise we accidentally create
	193	# a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
	194	# autovivification hates us and wants us to die()
	195	if ($INFO{$to}) {
	196	delete $INFO{$to}{methods}; # reset since we're about to add methods
	197	}
	198
92e1c5f8	199	$me->apply_role_to_package($to, $_) for @roles;
671b5a88	200	$APPLIED_TO{$to}{join('\|',@roles)} = 1;
	201	}
	202
836aea1b	203	sub _composite_info_for {
671b5a88	204	my ($me, @roles) = @_;
836aea1b	205	$COMPOSITE_INFO{join('\|', sort @roles)} \|\|= do {
671b5a88	206	_load_module($_) for @roles;
	207	my %methods;
	208	foreach my $role (@roles) {
	209	my $this_methods = $me->_concrete_methods_of($role);
	210	$methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
	211	}
	212	delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
	213	+{ conflicts => \%methods }
	214	};
60dfe768	215	}
60dfe768	216
1947330a	217	sub _composable_package_for {
	218	my ($me, $role) = @_;
	219	my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
	220	return $composed_name if $COMPOSED{role}{$composed_name};
	221	$me->_install_methods($composed_name, $role);
	222	my $base_name = $composed_name.'::_BASE';
	223	*{_getglob("${composed_name}::ISA")} = [ $base_name ];
	224	my $modifiers = $INFO{$role}{modifiers}\|\|[];
b1eebd55	225	my @mod_base;
1947330a	226	foreach my $modified (
	227	do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
	228	) {
b1eebd55	229	push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
1947330a	230	}
385f5087	231	my $e;
59812c87	232	{
	233	local $@;
	234	eval(my $code = join "\n", "package ${base_name};", @mod_base);
385f5087	235	$e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
59812c87	236	}
385f5087	237	die $e if $e;
1947330a	238	$me->_install_modifiers($composed_name, $modifiers);
	239	$COMPOSED{role}{$composed_name} = 1;
	240	return $composed_name;
	241	}
	242
	243	sub _check_requires {
	244	my ($me, $to, $name, @requires) = @_;
	245	if (my @requires_fail = grep !$to->can($_), @requires) {
	246	# role -> role, add to requires, role -> class, error out
	247	if (my $to_info = $INFO{$to}) {
	248	push @{$to_info->{requires}\|\|=[]}, @requires_fail;
	249	} else {
	250	die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
	251	}
	252	}
	253	}
	254
4db3a740	255	sub _concrete_methods_of {
4db3a740	256	my ($me, $role) = @_;
1947330a	257	my $info = $INFO{$role};
60dfe768	258	# grab role symbol table
60dfe768	259	my $stash = do { no strict 'refs'; \%{"${role}::"}};
12f8eb0b	260	# reverse so our keys become the values (captured coderefs) in case
12f8eb0b	261	# they got copied or re-used since
123a5a6e	262	my $not_methods = { reverse %{$info->{not_methods}\|\|{}} };
eb8fcb2d	263	$info->{methods} \|\|= +{
60dfe768	264	# grab all code entries that aren't in the not_methods list
	265	map {
	266	my $code = *{$stash->{$_}}{CODE};
	267	# rely on the '' key we added in import for "no code here"
	268	exists $not_methods->{$code\|\|''} ? () : ($_ => $code)
	269	} grep !ref($stash->{$_}), keys %$stash
ab3370e7	270	};
4db3a740	271	}
	272
	273	sub methods_provided_by {
	274	my ($me, $role) = @_;
	275	die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
	276	(keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}\|\|[]});
	277	}
	278
	279	sub _install_methods {
	280	my ($me, $to, $role) = @_;
	281
	282	my $info = $INFO{$role};
	283
	284	my $methods = $me->_concrete_methods_of($role);
1947330a	285
ab3370e7	286	# grab target symbol table
ab3370e7	287	my $stash = do { no strict 'refs'; \%{"${to}::"}};
1947330a	288
ab3370e7	289	# determine already extant methods of target
	290	my %has_methods;
	291	@has_methods{grep
faa9ce11	292	+(ref($stash->{$_}) \|\| *{$stash->{$_}}{CODE}),
ab3370e7	293	keys %$stash
ab3370e7	294	} = ();
ab3370e7	295
1947330a	296	foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
ab3370e7	297	no warnings 'once';
5a247406	298	*{_getglob "${to}::${i}"} = $methods->{$i};
ab3370e7	299	}
1947330a	300	}
ab3370e7	301
1947330a	302	sub _install_modifiers {
1947330a	303	my ($me, $to, $modifiers) = @_;
dccea57d	304	if (my $info = $INFO{$to}) {
	305	push @{$info->{modifiers}}, @{$modifiers\|\|[]};
	306	} else {
	307	foreach my $modifier (@{$modifiers\|\|[]}) {
	308	$me->_install_single_modifier($to, @$modifier);
	309	}
96d3f07a	310	}
ab3370e7	311	}
ab3370e7	312
dccea57d	313	sub _install_single_modifier {
	314	my ($me, @args) = @_;
	315	Class::Method::Modifiers::install_modifier(@args);
	316	}
	317
ab3370e7	318	sub does_role {
390ac406	319	my ($proto, $role) = @_;
91037640	320	if ($] >= 5.010) {
	321	require mro;
	322	} else {
	323	require MRO::Compat;
	324	}
	325	foreach my $class (@{mro::get_linear_isa(ref($proto)\|\|$proto)}) {
	326	return 1 if exists $APPLIED_TO{$class}{$role};
	327	}
	328	return 0;
ab3370e7	329	}
	330
	331	1;
5febcf4d	332
0b6e5fff	333	=head1 NAME
0b6e5fff	334
70061353	335	Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
5febcf4d	336
	337	=head1 SYNOPSIS
	338
	339	package Some::Role;
	340
	341	use Role::Tiny;
	342
	343	sub foo { ... }
	344
	345	sub bar { ... }
	346
adcb6c3d	347	around baz => sub { ... }
adcb6c3d	348
5febcf4d	349	1;
	350
	351	else where
	352
	353	package Some::Class;
	354
a1164a0b	355	use Role::Tiny::With;
5febcf4d	356
5febcf4d	357	# bar gets imported, but not foo
a1164a0b	358	with 'Some::Role';
5febcf4d	359
	360	sub foo { ... }
	361
adcb6c3d	362	# baz is wrapped in the around modifier by Class::Method::Modifiers
	363	sub baz { ... }
	364
5febcf4d	365	1;
5febcf4d	366
adcb6c3d	367	If you wanted attributes as well, look at L<Moo::Role>.
adcb6c3d	368
5febcf4d	369	=head1 DESCRIPTION
	370
	371	C<Role::Tiny> is a minimalist role composition tool.
	372
	373	=head1 ROLE COMPOSITION
	374
	375	Role composition can be thought of as much more clever and meaningful multiple
	376	inheritance. The basics of this implementation of roles is:
	377
	378	=over 2
	379
	380	=item *
	381
	382	If a method is already defined on a class, that method will not be composed in
	383	from the role.
	384
	385	=item *
	386
	387	If a method that the role L</requires> to be implemented is not implemented,
	388	role application will fail loudly.
	389
0d39f9d3	390	=back
0d39f9d3	391
5febcf4d	392	Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
836aea1b	393	composition is the other way around, where the class wins. If multiple roles
	394	are applied in a single call (single with statement), then if any of their
	395	provided methods clash, an exception is raised unless the class provides
	396	a method since this conflict indicates a potential problem.
5febcf4d	397
5febcf4d	398	=head1 IMPORTED SUBROUTINES
	399
	400	=head2 requires
	401
	402	requires qw(foo bar);
	403
	404	Declares a list of methods that must be defined to compose role.
	405
	406	=head2 with
	407
	408	with 'Some::Role1';
836aea1b	409
	410	with 'Some::Role1', 'Some::Role2';
	411
	412	Composes another role into the current role (or class via L<Role::Tiny::With>).
	413
	414	If you have conflicts and want to resolve them in favour of Some::Role1 you
	415	can instead write:
	416
	417	with 'Some::Role1';
5febcf4d	418	with 'Some::Role2';
5febcf4d	419
836aea1b	420	If you have conflicts and want to resolve different conflicts in favour of
836aea1b	421	different roles, please refactor your codebase.
5febcf4d	422
	423	=head2 before
	424
	425	before foo => sub { ... };
	426
	427	See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
	428	documentation.
	429
adcb6c3d	430	Note that since you are not required to use method modifiers,
	431	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	432	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	433	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	434
5febcf4d	435	=head2 around
	436
	437	around foo => sub { ... };
	438
	439	See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
	440	documentation.
	441
adcb6c3d	442	Note that since you are not required to use method modifiers,
	443	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	444	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	445	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	446
5febcf4d	447	=head2 after
	448
	449	after foo => sub { ... };
	450
	451	See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
	452	documentation.
	453
adcb6c3d	454	Note that since you are not required to use method modifiers,
	455	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	456	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	457	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	458
ec28e16b	459	=head1 SUBROUTINES
	460
	461	=head2 does_role
	462
	463	if (Role::Tiny::does_role($foo, 'Some::Role')) {
	464	...
	465	}
	466
	467	Returns true if class has been composed with role.
	468
	469	This subroutine is also installed as ->does on any class a Role::Tiny is
	470	composed into unless that class already has an ->does method, so
	471
	472	if ($foo->does('Some::Role')) {
	473	...
	474	}
	475
	476	will work for classes but to test a role, one must use ::does_role directly
	477
	478	=head1 METHODS
	479
	480	=head2 apply_roles_to_package
	481
	482	Role::Tiny->apply_roles_to_package(
	483	'Some::Package', 'Some::Role', 'Some::Other::Role'
	484	);
	485
	486	Composes role with package. See also L<Role::Tiny::With>.
	487
	488	=head2 apply_roles_to_object
	489
	490	Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
	491
	492	Composes roles in order into object directly. Object is reblessed into the
	493	resulting class.
	494
	495	=head2 create_class_with_roles
	496
	497	Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
	498
	499	Creates a new class based on base, with the roles composed into it in order.
	500	New class is returned.
	501
adcb6c3d	502	=head1 SEE ALSO
	503
	504	L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
	505	a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
	506
	507	If you don't want method modifiers and do want to be forcibly restricted
	508	to a single role application per class, Ovid's L<Role::Basic> exists. But
259ce3a0	509	Stevan Little (the L<Moose> author) and I don't find the additional
	510	restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
	511	are more a guide to what you should prefer doing, to our mind, rather than
	512	something that needs to be enforced.
adcb6c3d	513
c334a5c1	514	=head1 AUTHOR
	515
	516	mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
	517
	518	=head1 CONTRIBUTORS
	519
	520	dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
	521
	522	frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
	523
	524	hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
	525
	526	jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
	527
	528	ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
	529
	530	chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
	531
	532	ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
	533
	534	doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
	535
	536	perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
	537
ec28e16b	538	Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
ec28e16b	539
91037640	540	ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
91037640	541
c334a5c1	542	=head1 COPYRIGHT
40f3e3aa	543
c334a5c1	544	Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
c334a5c1	545	as listed above.
40f3e3aa	546
c334a5c1	547	=head1 LICENSE
40f3e3aa	548
c334a5c1	549	This library is free software and may be distributed under the same terms
c334a5c1	550	as perl itself.
40f3e3aa	551
40f3e3aa	552	=cut