Commit | Line | Data |
ab3370e7 |
1 | package Role::Tiny; |
2 | |
119014a7 |
3 | sub _getglob { \*{$_[0]} } |
5e03b55c |
4 | sub _getstash { \%{"$_[0]::"} } |
119014a7 |
5 | |
b1eebd55 |
6 | use strict; |
7 | use warnings FATAL => 'all'; |
ab3370e7 |
8 | |
48ff3812 |
9 | our $VERSION = '1.001002'; # 1.1.2 |
c334a5c1 |
10 | $VERSION = eval $VERSION; |
11 | |
ab3370e7 |
12 | our %INFO; |
13 | our %APPLIED_TO; |
1947330a |
14 | our %COMPOSED; |
836aea1b |
15 | our %COMPOSITE_INFO; |
ab3370e7 |
16 | |
cf62c989 |
17 | # Module state workaround totally stolen from Zefram's Module::Runtime. |
18 | |
19 | BEGIN { |
20 | *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0}; |
21 | } |
22 | |
23 | sub Role::Tiny::__GUARD__::DESTROY { |
24 | delete $INC{$_[0]->[0]} if @{$_[0]}; |
25 | } |
5e03b55c |
26 | |
fb5074f6 |
27 | sub _load_module { |
fb5074f6 |
28 | (my $proto = $_[0]) =~ s/::/\//g; |
cf62c989 |
29 | $proto .= '.pm'; |
30 | return 1 if $INC{$proto}; |
5e03b55c |
31 | # can't just ->can('can') because a sub-package Foo::Bar::Baz |
32 | # creates a 'Baz::' key in Foo::Bar's symbol table |
33 | return 1 if grep !/::$/, keys %{_getstash($_[0])||{}}; |
cf62c989 |
34 | my $guard = _WORK_AROUND_BROKEN_MODULE_STATE |
35 | && bless([ $proto ], 'Role::Tiny::__GUARD__'); |
36 | require $proto; |
37 | pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE; |
fb5074f6 |
38 | return 1; |
39 | } |
40 | |
ab3370e7 |
41 | sub import { |
42 | my $target = caller; |
a1164a0b |
43 | my $me = shift; |
3ca7ff56 |
44 | strict->import; |
45 | warnings->import(FATAL => 'all'); |
1ba11455 |
46 | return if $INFO{$target}; # already exported into this package |
ab3370e7 |
47 | # get symbol table reference |
48 | my $stash = do { no strict 'refs'; \%{"${target}::"} }; |
49 | # install before/after/around subs |
50 | foreach my $type (qw(before after around)) { |
5a247406 |
51 | *{_getglob "${target}::${type}"} = sub { |
7568ba55 |
52 | require Class::Method::Modifiers; |
ab3370e7 |
53 | push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ]; |
ef2da711 |
54 | return; |
ab3370e7 |
55 | }; |
56 | } |
5a247406 |
57 | *{_getglob "${target}::requires"} = sub { |
ab3370e7 |
58 | push @{$INFO{$target}{requires}||=[]}, @_; |
ef2da711 |
59 | return; |
ab3370e7 |
60 | }; |
5a247406 |
61 | *{_getglob "${target}::with"} = sub { |
836aea1b |
62 | $me->apply_roles_to_package($target, @_); |
ef2da711 |
63 | return; |
96d3f07a |
64 | }; |
7b8177f8 |
65 | # grab all *non-constant* (stash slot is not a scalarref) subs present |
ab3370e7 |
66 | # in the symbol table and store their refaddrs (no need to forcibly |
67 | # inflate constant subs into real subs) - also add '' to here (this |
12f8eb0b |
68 | # is used later) with a map to the coderefs in case of copying or re-use |
69 | my @not_methods = ('', map { *$_{CODE}||() } grep !ref($_), values %$stash); |
70 | @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods; |
ab3370e7 |
71 | # a role does itself |
72 | $APPLIED_TO{$target} = { $target => undef }; |
73 | } |
74 | |
836aea1b |
75 | sub apply_single_role_to_package { |
369a4c50 |
76 | my ($me, $to, $role) = @_; |
1947330a |
77 | |
fb5074f6 |
78 | _load_module($role); |
79 | |
ab3370e7 |
80 | die "This is apply_role_to_package" if ref($to); |
1947330a |
81 | die "${role} is not a Role::Tiny" unless my $info = $INFO{$role}; |
82 | |
83 | $me->_check_requires($to, $role, @{$info->{requires}||[]}); |
84 | |
85 | $me->_install_methods($to, $role); |
86 | |
87 | $me->_install_modifiers($to, $info->{modifiers}); |
88 | |
89 | # only add does() method to classes and only if they don't have one |
90 | if (not $INFO{$to} and not $to->can('does')) { |
91 | *{_getglob "${to}::does"} = \&does_role; |
92 | } |
93 | |
1947330a |
94 | # copy our role list into the target's |
95 | @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = (); |
96 | } |
97 | |
98 | sub apply_roles_to_object { |
99 | my ($me, $object, @roles) = @_; |
100 | die "No roles supplied!" unless @roles; |
101 | my $class = ref($object); |
102 | bless($object, $me->create_class_with_roles($class, @roles)); |
103 | $object; |
104 | } |
105 | |
106 | sub create_class_with_roles { |
107 | my ($me, $superclass, @roles) = @_; |
108 | |
fb5074f6 |
109 | die "No roles supplied!" unless @roles; |
110 | |
2c580674 |
111 | { |
112 | my %seen; |
113 | $seen{$_}++ for @roles; |
114 | if (my @dupes = grep $seen{$_} > 1, @roles) { |
115 | die "Duplicated roles: ".join(', ', @dupes); |
116 | } |
117 | } |
118 | |
c69190f1 |
119 | my $new_name = join( |
120 | '__WITH__', $superclass, my $compose_name = join '__AND__', @roles |
121 | ); |
122 | |
1947330a |
123 | return $new_name if $COMPOSED{class}{$new_name}; |
124 | |
125 | foreach my $role (@roles) { |
fb5074f6 |
126 | _load_module($role); |
29dde8ba |
127 | die "${role} is not a Role::Tiny" unless $INFO{$role}; |
1947330a |
128 | } |
129 | |
786e5ba0 |
130 | if ($] >= 5.010) { |
7568ba55 |
131 | require mro; |
b1eebd55 |
132 | } else { |
7568ba55 |
133 | require MRO::Compat; |
b1eebd55 |
134 | } |
1947330a |
135 | |
471419f6 |
136 | my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}}; |
137 | if (keys %conflicts) { |
138 | my $fail = |
139 | join "\n", |
140 | map { |
141 | "Method name conflict for '$_' between roles " |
142 | ."'".join(' and ', sort values %{$conflicts{$_}})."'" |
143 | .", cannot apply these simultaneously to an object." |
144 | } keys %conflicts; |
145 | die $fail; |
146 | } |
147 | |
1947330a |
148 | my @composable = map $me->_composable_package_for($_), reverse @roles; |
149 | |
150 | *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ]; |
151 | |
29dde8ba |
152 | my @info = map $INFO{$_}, @roles; |
1947330a |
153 | |
154 | $me->_check_requires( |
155 | $new_name, $compose_name, |
156 | do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h } |
157 | ); |
1947330a |
158 | |
159 | *{_getglob "${new_name}::does"} = \&does_role unless $new_name->can('does'); |
160 | |
161 | @{$APPLIED_TO{$new_name}||={}}{ |
162 | map keys %{$APPLIED_TO{$_}}, @roles |
163 | } = (); |
164 | |
165 | $COMPOSED{class}{$new_name} = 1; |
166 | return $new_name; |
167 | } |
168 | |
92e1c5f8 |
169 | # preserved for compat, and apply_roles_to_package calls it to allow an |
170 | # updated Role::Tiny to use a non-updated Moo::Role |
171 | |
836aea1b |
172 | sub apply_role_to_package { shift->apply_single_role_to_package(@_) } |
173 | |
174 | sub apply_roles_to_package { |
60dfe768 |
175 | my ($me, $to, @roles) = @_; |
176 | |
92e1c5f8 |
177 | return $me->apply_role_to_package($to, $roles[0]) if @roles == 1; |
60dfe768 |
178 | |
836aea1b |
179 | my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}}; |
671b5a88 |
180 | delete $conflicts{$_} for $me->_concrete_methods_of($to); |
181 | if (keys %conflicts) { |
60dfe768 |
182 | my $fail = |
183 | join "\n", |
671b5a88 |
184 | map { |
185 | "Due to a method name conflict between roles " |
186 | ."'".join(' and ', sort values %{$conflicts{$_}})."'" |
187 | .", the method '$_' must be implemented by '${to}'" |
188 | } keys %conflicts; |
189 | die $fail; |
60dfe768 |
190 | } |
eb8fcb2d |
191 | delete $INFO{$to}{methods}; # reset since we're about to add methods |
92e1c5f8 |
192 | $me->apply_role_to_package($to, $_) for @roles; |
671b5a88 |
193 | $APPLIED_TO{$to}{join('|',@roles)} = 1; |
194 | } |
195 | |
836aea1b |
196 | sub _composite_info_for { |
671b5a88 |
197 | my ($me, @roles) = @_; |
836aea1b |
198 | $COMPOSITE_INFO{join('|', sort @roles)} ||= do { |
671b5a88 |
199 | _load_module($_) for @roles; |
200 | my %methods; |
201 | foreach my $role (@roles) { |
202 | my $this_methods = $me->_concrete_methods_of($role); |
203 | $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods; |
204 | } |
205 | delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods; |
206 | +{ conflicts => \%methods } |
207 | }; |
60dfe768 |
208 | } |
209 | |
1947330a |
210 | sub _composable_package_for { |
211 | my ($me, $role) = @_; |
212 | my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role; |
213 | return $composed_name if $COMPOSED{role}{$composed_name}; |
214 | $me->_install_methods($composed_name, $role); |
215 | my $base_name = $composed_name.'::_BASE'; |
216 | *{_getglob("${composed_name}::ISA")} = [ $base_name ]; |
217 | my $modifiers = $INFO{$role}{modifiers}||[]; |
b1eebd55 |
218 | my @mod_base; |
1947330a |
219 | foreach my $modified ( |
220 | do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h } |
221 | ) { |
b1eebd55 |
222 | push @mod_base, "sub ${modified} { shift->next::method(\@_) }"; |
1947330a |
223 | } |
385f5087 |
224 | my $e; |
59812c87 |
225 | { |
226 | local $@; |
227 | eval(my $code = join "\n", "package ${base_name};", @mod_base); |
385f5087 |
228 | $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@; |
59812c87 |
229 | } |
385f5087 |
230 | die $e if $e; |
1947330a |
231 | $me->_install_modifiers($composed_name, $modifiers); |
232 | $COMPOSED{role}{$composed_name} = 1; |
233 | return $composed_name; |
234 | } |
235 | |
236 | sub _check_requires { |
237 | my ($me, $to, $name, @requires) = @_; |
238 | if (my @requires_fail = grep !$to->can($_), @requires) { |
239 | # role -> role, add to requires, role -> class, error out |
240 | if (my $to_info = $INFO{$to}) { |
241 | push @{$to_info->{requires}||=[]}, @requires_fail; |
242 | } else { |
243 | die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail); |
244 | } |
245 | } |
246 | } |
247 | |
4db3a740 |
248 | sub _concrete_methods_of { |
249 | my ($me, $role) = @_; |
1947330a |
250 | my $info = $INFO{$role}; |
60dfe768 |
251 | # grab role symbol table |
252 | my $stash = do { no strict 'refs'; \%{"${role}::"}}; |
12f8eb0b |
253 | # reverse so our keys become the values (captured coderefs) in case |
254 | # they got copied or re-used since |
123a5a6e |
255 | my $not_methods = { reverse %{$info->{not_methods}||{}} }; |
eb8fcb2d |
256 | $info->{methods} ||= +{ |
60dfe768 |
257 | # grab all code entries that aren't in the not_methods list |
258 | map { |
259 | my $code = *{$stash->{$_}}{CODE}; |
260 | # rely on the '' key we added in import for "no code here" |
261 | exists $not_methods->{$code||''} ? () : ($_ => $code) |
262 | } grep !ref($stash->{$_}), keys %$stash |
ab3370e7 |
263 | }; |
4db3a740 |
264 | } |
265 | |
266 | sub methods_provided_by { |
267 | my ($me, $role) = @_; |
268 | die "${role} is not a Role::Tiny" unless my $info = $INFO{$role}; |
269 | (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]}); |
270 | } |
271 | |
272 | sub _install_methods { |
273 | my ($me, $to, $role) = @_; |
274 | |
275 | my $info = $INFO{$role}; |
276 | |
277 | my $methods = $me->_concrete_methods_of($role); |
1947330a |
278 | |
ab3370e7 |
279 | # grab target symbol table |
280 | my $stash = do { no strict 'refs'; \%{"${to}::"}}; |
1947330a |
281 | |
ab3370e7 |
282 | # determine already extant methods of target |
283 | my %has_methods; |
284 | @has_methods{grep |
faa9ce11 |
285 | +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}), |
ab3370e7 |
286 | keys %$stash |
287 | } = (); |
ab3370e7 |
288 | |
1947330a |
289 | foreach my $i (grep !exists $has_methods{$_}, keys %$methods) { |
ab3370e7 |
290 | no warnings 'once'; |
5a247406 |
291 | *{_getglob "${to}::${i}"} = $methods->{$i}; |
ab3370e7 |
292 | } |
1947330a |
293 | } |
ab3370e7 |
294 | |
1947330a |
295 | sub _install_modifiers { |
296 | my ($me, $to, $modifiers) = @_; |
dccea57d |
297 | if (my $info = $INFO{$to}) { |
298 | push @{$info->{modifiers}}, @{$modifiers||[]}; |
299 | } else { |
300 | foreach my $modifier (@{$modifiers||[]}) { |
301 | $me->_install_single_modifier($to, @$modifier); |
302 | } |
96d3f07a |
303 | } |
ab3370e7 |
304 | } |
305 | |
dccea57d |
306 | sub _install_single_modifier { |
307 | my ($me, @args) = @_; |
308 | Class::Method::Modifiers::install_modifier(@args); |
309 | } |
310 | |
ab3370e7 |
311 | sub does_role { |
390ac406 |
312 | my ($proto, $role) = @_; |
313 | return exists $APPLIED_TO{ref($proto)||$proto}{$role}; |
ab3370e7 |
314 | } |
315 | |
316 | 1; |
5febcf4d |
317 | |
0b6e5fff |
318 | =head1 NAME |
319 | |
70061353 |
320 | Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose. |
5febcf4d |
321 | |
322 | =head1 SYNOPSIS |
323 | |
324 | package Some::Role; |
325 | |
326 | use Role::Tiny; |
327 | |
328 | sub foo { ... } |
329 | |
330 | sub bar { ... } |
331 | |
adcb6c3d |
332 | around baz => sub { ... } |
333 | |
5febcf4d |
334 | 1; |
335 | |
336 | else where |
337 | |
338 | package Some::Class; |
339 | |
a1164a0b |
340 | use Role::Tiny::With; |
5febcf4d |
341 | |
342 | # bar gets imported, but not foo |
a1164a0b |
343 | with 'Some::Role'; |
5febcf4d |
344 | |
345 | sub foo { ... } |
346 | |
adcb6c3d |
347 | # baz is wrapped in the around modifier by Class::Method::Modifiers |
348 | sub baz { ... } |
349 | |
5febcf4d |
350 | 1; |
351 | |
adcb6c3d |
352 | If you wanted attributes as well, look at L<Moo::Role>. |
353 | |
5febcf4d |
354 | =head1 DESCRIPTION |
355 | |
356 | C<Role::Tiny> is a minimalist role composition tool. |
357 | |
358 | =head1 ROLE COMPOSITION |
359 | |
360 | Role composition can be thought of as much more clever and meaningful multiple |
361 | inheritance. The basics of this implementation of roles is: |
362 | |
363 | =over 2 |
364 | |
365 | =item * |
366 | |
367 | If a method is already defined on a class, that method will not be composed in |
368 | from the role. |
369 | |
370 | =item * |
371 | |
372 | If a method that the role L</requires> to be implemented is not implemented, |
373 | role application will fail loudly. |
374 | |
0d39f9d3 |
375 | =back |
376 | |
5febcf4d |
377 | Unlike L<Class::C3>, where the B<last> class inherited from "wins," role |
836aea1b |
378 | composition is the other way around, where the class wins. If multiple roles |
379 | are applied in a single call (single with statement), then if any of their |
380 | provided methods clash, an exception is raised unless the class provides |
381 | a method since this conflict indicates a potential problem. |
5febcf4d |
382 | |
5febcf4d |
383 | =head1 IMPORTED SUBROUTINES |
384 | |
385 | =head2 requires |
386 | |
387 | requires qw(foo bar); |
388 | |
389 | Declares a list of methods that must be defined to compose role. |
390 | |
391 | =head2 with |
392 | |
393 | with 'Some::Role1'; |
836aea1b |
394 | |
395 | with 'Some::Role1', 'Some::Role2'; |
396 | |
397 | Composes another role into the current role (or class via L<Role::Tiny::With>). |
398 | |
399 | If you have conflicts and want to resolve them in favour of Some::Role1 you |
400 | can instead write: |
401 | |
402 | with 'Some::Role1'; |
5febcf4d |
403 | with 'Some::Role2'; |
404 | |
836aea1b |
405 | If you have conflicts and want to resolve different conflicts in favour of |
406 | different roles, please refactor your codebase. |
5febcf4d |
407 | |
408 | =head2 before |
409 | |
410 | before foo => sub { ... }; |
411 | |
412 | See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full |
413 | documentation. |
414 | |
adcb6c3d |
415 | Note that since you are not required to use method modifiers, |
416 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
417 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
418 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
419 | |
5febcf4d |
420 | =head2 around |
421 | |
422 | around foo => sub { ... }; |
423 | |
424 | See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full |
425 | documentation. |
426 | |
adcb6c3d |
427 | Note that since you are not required to use method modifiers, |
428 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
429 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
430 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
431 | |
5febcf4d |
432 | =head2 after |
433 | |
434 | after foo => sub { ... }; |
435 | |
436 | See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full |
437 | documentation. |
438 | |
adcb6c3d |
439 | Note that since you are not required to use method modifiers, |
440 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
441 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
442 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
443 | |
ec28e16b |
444 | =head1 SUBROUTINES |
445 | |
446 | =head2 does_role |
447 | |
448 | if (Role::Tiny::does_role($foo, 'Some::Role')) { |
449 | ... |
450 | } |
451 | |
452 | Returns true if class has been composed with role. |
453 | |
454 | This subroutine is also installed as ->does on any class a Role::Tiny is |
455 | composed into unless that class already has an ->does method, so |
456 | |
457 | if ($foo->does('Some::Role')) { |
458 | ... |
459 | } |
460 | |
461 | will work for classes but to test a role, one must use ::does_role directly |
462 | |
463 | =head1 METHODS |
464 | |
465 | =head2 apply_roles_to_package |
466 | |
467 | Role::Tiny->apply_roles_to_package( |
468 | 'Some::Package', 'Some::Role', 'Some::Other::Role' |
469 | ); |
470 | |
471 | Composes role with package. See also L<Role::Tiny::With>. |
472 | |
473 | =head2 apply_roles_to_object |
474 | |
475 | Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2)); |
476 | |
477 | Composes roles in order into object directly. Object is reblessed into the |
478 | resulting class. |
479 | |
480 | =head2 create_class_with_roles |
481 | |
482 | Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2)); |
483 | |
484 | Creates a new class based on base, with the roles composed into it in order. |
485 | New class is returned. |
486 | |
adcb6c3d |
487 | =head1 SEE ALSO |
488 | |
489 | L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is |
490 | a meta-protocol-less subset of the king of role systems, L<Moose::Role>. |
491 | |
492 | If you don't want method modifiers and do want to be forcibly restricted |
493 | to a single role application per class, Ovid's L<Role::Basic> exists. But |
259ce3a0 |
494 | Stevan Little (the L<Moose> author) and I don't find the additional |
495 | restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices |
496 | are more a guide to what you should prefer doing, to our mind, rather than |
497 | something that needs to be enforced. |
adcb6c3d |
498 | |
c334a5c1 |
499 | =head1 AUTHOR |
500 | |
501 | mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk> |
502 | |
503 | =head1 CONTRIBUTORS |
504 | |
505 | dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx> |
506 | |
507 | frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com> |
508 | |
509 | hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org> |
510 | |
511 | jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com> |
512 | |
513 | ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org> |
514 | |
515 | chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com> |
516 | |
517 | ajgb - Alex J. G. BurzyĆski (cpan:AJGB) <ajgb@cpan.org> |
518 | |
519 | doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net> |
520 | |
521 | perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org> |
522 | |
ec28e16b |
523 | Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com> |
524 | |
c334a5c1 |
525 | =head1 COPYRIGHT |
40f3e3aa |
526 | |
c334a5c1 |
527 | Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS> |
528 | as listed above. |
40f3e3aa |
529 | |
c334a5c1 |
530 | =head1 LICENSE |
40f3e3aa |
531 | |
c334a5c1 |
532 | This library is free software and may be distributed under the same terms |
533 | as perl itself. |
40f3e3aa |
534 | |
535 | =cut |