Revision history for Perl extension MooseX-Getopt
+0.22
+ * MooseX::Getopt
+ - Split into MooseX::Getopt::Basic (without the G::L::Descriptive support)
+ and MooseX::Getopt::GLD.
+
0.21 Thu. Aug 27 2009
* MooseX::Getopt
- Enable and document the argv parameter to the constructor.
--- /dev/null
+package MooseX::Getopt::Basic;
+use Moose::Role;
+
+use MooseX::Getopt::OptionTypeMap;
+use MooseX::Getopt::Meta::Attribute;
+use MooseX::Getopt::Meta::Attribute::NoGetopt;
+use Carp ();
+
+use Getopt::Long (); # GLD uses it anyway, doesn't hurt
+
+our $VERSION = '0.20';
+our $AUTHORITY = 'cpan:STEVAN';
+
+has ARGV => (is => 'rw', isa => 'ArrayRef', metaclass => "NoGetopt");
+has extra_argv => (is => 'rw', isa => 'ArrayRef', metaclass => "NoGetopt");
+
+# _getopt_spec() and _getoptions() are overrided by MooseX::Getopt::GLD.
+
+sub _getopt_spec {
+ my ($class, %params) = @_;
+ return $class->_traditional_spec(%params)
+}
+
+sub _get_options {
+ my ($class, undef, $opt_spec) = @_;
+ my %options;
+ Getopt::Long::GetOptions(\%options, @$opt_spec);
+ return ( \%options, undef );
+}
+
+sub new_with_options {
+ my ($class, @params) = @_;
+
+ my $config_from_file;
+ if($class->meta->does_role('MooseX::ConfigFromFile')) {
+ local @ARGV = @ARGV;
+
+ my $configfile;
+ my $opt_parser = Getopt::Long::Parser->new( config => [ qw( pass_through ) ] );
+ $opt_parser->getoptions( "configfile=s" => \$configfile );
+
+ if(!defined $configfile) {
+ my $cfmeta = $class->meta->find_attribute_by_name('configfile');
+ $configfile = $cfmeta->default if $cfmeta->has_default;
+ }
+
+ if (defined $configfile) {
+ $config_from_file = eval {
+ $class->get_config_from_file($configfile);
+ };
+ if ($@) {
+ die $@ unless $@ =~ /Specified configfile '\Q$configfile\E' does not exist/;
+ }
+ }
+ }
+
+ my $constructor_params = ( @params == 1 ? $params[0] : {@params} );
+
+ Carp::croak("Single parameters to new_with_options() must be a HASH ref")
+ unless ref($constructor_params) eq 'HASH';
+
+ my %processed = $class->_parse_argv(
+ options => [
+ $class->_attrs_to_options( $config_from_file )
+ ],
+ params => $constructor_params,
+ );
+
+ my $params = $config_from_file ? { %$config_from_file, %{$processed{params}} } : $processed{params};
+
+ # did the user request usage information?
+ if ( $processed{usage} && ($params->{'?'} or $params->{help} or $params->{usage}) )
+ {
+ $processed{usage}->die();
+ }
+
+ $class->new(
+ ARGV => $processed{argv_copy},
+ extra_argv => $processed{argv},
+ %$constructor_params, # explicit params to ->new
+ %$params, # params from CLI
+ );
+}
+
+sub _parse_argv {
+ my ( $class, %params ) = @_;
+
+ local @ARGV = @{ $params{params}{argv} || \@ARGV };
+
+ my ( $opt_spec, $name_to_init_arg ) = $class->_getopt_spec(%params);
+
+ # Get a clean copy of the original @ARGV
+ my $argv_copy = [ @ARGV ];
+
+ my @err;
+
+ my ( $parsed_options, $usage ) = eval {
+ local $SIG{__WARN__} = sub { push @err, @_ };
+
+ return $class->_get_options(\%params, $opt_spec);
+ };
+
+ die join "", grep { defined } @err, $@ if @err or $@;
+
+ # Get a copy of the Getopt::Long-mangled @ARGV
+ my $argv_mangled = [ @ARGV ];
+
+ my %constructor_args = (
+ map {
+ $name_to_init_arg->{$_} => $parsed_options->{$_}
+ } keys %$parsed_options,
+ );
+
+ return (
+ params => \%constructor_args,
+ argv_copy => $argv_copy,
+ argv => $argv_mangled,
+ ( defined($usage) ? ( usage => $usage ) : () ),
+ );
+}
+
+sub _usage_format {
+ return "usage: %c %o";
+}
+
+sub _traditional_spec {
+ my ( $class, %params ) = @_;
+
+ my ( @options, %name_to_init_arg, %options );
+
+ foreach my $opt ( @{ $params{options} } ) {
+ push @options, $opt->{opt_string};
+
+ my $identifier = $opt->{name};
+ $identifier =~ s/\W/_/g; # Getopt::Long does this to all option names
+
+ $name_to_init_arg{$identifier} = $opt->{init_arg};
+ }
+
+ return ( \@options, \%name_to_init_arg );
+}
+
+sub _compute_getopt_attrs {
+ my $class = shift;
+ grep {
+ $_->does("MooseX::Getopt::Meta::Attribute::Trait")
+ or
+ $_->name !~ /^_/
+ } grep {
+ !$_->does('MooseX::Getopt::Meta::Attribute::Trait::NoGetopt')
+ } $class->meta->get_all_attributes
+}
+
+sub _get_cmd_flags_for_attr {
+ my ( $class, $attr ) = @_;
+
+ my $flag = $attr->name;
+
+ my @aliases;
+
+ if ($attr->does('MooseX::Getopt::Meta::Attribute::Trait')) {
+ $flag = $attr->cmd_flag if $attr->has_cmd_flag;
+ @aliases = @{ $attr->cmd_aliases } if $attr->has_cmd_aliases;
+ }
+
+ return ( $flag, @aliases );
+}
+
+sub _attrs_to_options {
+ my $class = shift;
+ my $config_from_file = shift || {};
+
+ my @options;
+
+ foreach my $attr ($class->_compute_getopt_attrs) {
+ my ( $flag, @aliases ) = $class->_get_cmd_flags_for_attr($attr);
+
+ my $opt_string = join(q{|}, $flag, @aliases);
+
+ if ($attr->name eq 'configfile') {
+ $opt_string .= '=s';
+ }
+ elsif ($attr->has_type_constraint) {
+ my $type = $attr->type_constraint;
+ if (MooseX::Getopt::OptionTypeMap->has_option_type($type)) {
+ $opt_string .= MooseX::Getopt::OptionTypeMap->get_option_type($type)
+ }
+ }
+
+ push @options, {
+ name => $flag,
+ init_arg => $attr->init_arg,
+ opt_string => $opt_string,
+ required => $attr->is_required && !$attr->has_default && !$attr->has_builder && !exists $config_from_file->{$attr->name},
+ # NOTE:
+ # this "feature" was breaking because
+ # Getopt::Long::Descriptive would return
+ # the default value as if it was a command
+ # line flag, which would then override the
+ # one passed into a constructor.
+ # See 100_gld_default_bug.t for an example
+ # - SL
+ #( ( $attr->has_default && ( $attr->is_default_a_coderef xor $attr->is_lazy ) ) ? ( default => $attr->default({}) ) : () ),
+ ( $attr->has_documentation ? ( doc => $attr->documentation ) : () ),
+ }
+ }
+
+ return @options;
+}
+
+no Moose::Role; 1;
+
+1;
+
+=pod
+
+=head1 NAME
+
+MooseX::Getopt::Basic - role to implement the basic functionality of
+L<MooseX::Getopt> without GLD.
+
+=head1 SYNOPSIS
+
+ ## In your class
+ package My::App;
+ use Moose;
+
+ with 'MooseX::Getopt::Basic';
+
+ has 'out' => (is => 'rw', isa => 'Str', required => 1);
+ has 'in' => (is => 'rw', isa => 'Str', required => 1);
+
+ # ... rest of the class here
+
+ ## in your script
+ #!/usr/bin/perl
+
+ use My::App;
+
+ my $app = My::App->new_with_options();
+ # ... rest of the script here
+
+ ## on the command line
+ % perl my_app_script.pl --in file.input --out file.dump
+
+=head1 DESCRIPTION
+
+This is like L<MooseX::Getopt> and can be used instead except that it
+doesn't make use of L<Getopt::Long::Descriptive> (or "GLD" for short).
+
+=head1 METHODS
+
+=over 4
+
+=item B<new_with_options>
+
+See L<MooseX::Getopt> .
+
+=item B<meta>
+
+This returns the role meta object.
+
+=back
+
+=head1 BUGS
+
+All complex software has bugs lurking in it, and this module is no
+exception. If you find a bug please either email me, or add the bug
+to cpan-RT.
+
+=head1 AUTHOR
+
+Stevan Little E<lt>stevan@iinteractive.comE<gt>
+
+Brandon L. Black, E<lt>blblack@gmail.comE<gt>
+
+Yuval Kogman, E<lt>nothingmuch@woobling.orgE<gt>
+
+=head1 CONTRIBUTORS
+
+Ryan D Johnson, E<lt>ryan@innerfence.comE<gt>
+
+Drew Taylor, E<lt>drew@drewtaylor.comE<gt>
+
+Shlomi Fish E<lt>shlomif@cpan.orgE<gt>
+
+=head1 COPYRIGHT AND LICENSE
+
+Copyright 2007-2008 by Infinity Interactive, Inc.
+
+L<http://www.iinteractive.com>
+
+This library is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.
+
+=cut
+
--- /dev/null
+package MooseX::Getopt::GLD;
+
+use Moose::Role;
+
+around '_getopt_spec' => sub {
+ my $orig = shift;
+ my $self = shift;
+
+ return $self->_gld_spec(@_);
+ # Ignore $orig, code for _gld_spec here
+};
+
+around '_get_options' => sub {
+ my $orig = shift;
+ my $class = shift;
+
+ my ($params, $opt_spec) = @_;
+ return Getopt::Long::Descriptive::describe_options(
+ $class->_usage_format(%$params), @$opt_spec
+ );
+};
+
+
+sub _gld_spec {
+ my ( $class, %params ) = @_;
+
+ my ( @options, %name_to_init_arg );
+
+ my $constructor_params = $params{params};
+
+ foreach my $opt ( @{ $params{options} } ) {
+ push @options, [
+ $opt->{opt_string},
+ $opt->{doc} || ' ', # FIXME new GLD shouldn't need this hack
+ {
+ ( ( $opt->{required} && !exists($constructor_params->{$opt->{init_arg}}) ) ? (required => $opt->{required}) : () ),
+ # NOTE:
+ # remove this 'feature' because it didn't work
+ # all the time, and so is better to not bother
+ # since Moose will handle the defaults just
+ # fine anyway.
+ # - SL
+ #( exists $opt->{default} ? (default => $opt->{default}) : () ),
+ },
+ ];
+
+ my $identifier = $opt->{name};
+ $identifier =~ s/\W/_/g; # Getopt::Long does this to all option names
+
+ $name_to_init_arg{$identifier} = $opt->{init_arg};
+ }
+
+ return ( \@options, \%name_to_init_arg );
+}
+
+1;
+
+__END__
+
+=pod
+
+=head1 NAME
+
+MooseX::Getopt::GLD - role to implement specific functionality for
+L<Getopt::Long::Descriptive>
+
+=head1 SYNOPSIS
+
+For internal use.
+
+=head1 DESCRIPTION
+
+This is a role for C<MooseX::Getopt>.
+
+=head1 METHODS
+
+=over 4
+
+=item meta
+
+=back
+
+=head1 BUGS
+
+All complex software has bugs lurking in it, and this module is no
+exception. If you find a bug please either email me, or add the bug
+to cpan-RT.
+
+=head1 AUTHOR
+
+Dagfinn Ilmari MannsE<aring>ker E<lt>ilmari@ilmari.orgE<gt>
+
+Stevan Little E<lt>stevan@iinteractive.comE<gt>
+
+Yuval Kogman C<< <nuffin@cpan.org> >>
+
+=head1 COPYRIGHT AND LICENSE
+
+Copyright 2007-2008 by Infinity Interactive, Inc.
+
+L<http://www.iinteractive.com>
+
+This library is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.
+
+=cut
+=head1
--- /dev/null
+#!/usr/bin/perl
+
+use strict;
+use warnings;
+
+use Test::More tests => 69;
+
+BEGIN {
+ use_ok('MooseX::Getopt::Basic');
+}
+
+{
+ package App;
+ use Moose;
+
+ with 'MooseX::Getopt::Basic';
+
+ has 'data' => (
+ metaclass => 'MooseX::Getopt::Meta::Attribute',
+ is => 'ro',
+ isa => 'Str',
+ default => 'file.dat',
+ cmd_flag => 'f',
+ );
+
+ has 'cow' => (
+ metaclass => 'Getopt',
+ is => 'ro',
+ isa => 'Str',
+ default => 'moo',
+ cmd_aliases => [qw/ moocow m c /],
+ );
+
+ has 'horse' => (
+ metaclass => 'MooseX::Getopt::Meta::Attribute',
+ is => 'ro',
+ isa => 'Str',
+ default => 'bray',
+ cmd_flag => 'horsey',
+ cmd_aliases => 'x',
+ );
+
+ has 'length' => (
+ is => 'ro',
+ isa => 'Int',
+ default => 24
+ );
+
+ has 'verbose' => (
+ is => 'ro',
+ isa => 'Bool',
+ );
+
+ has 'libs' => (
+ is => 'ro',
+ isa => 'ArrayRef',
+ default => sub { [] },
+ );
+
+ has 'details' => (
+ is => 'ro',
+ isa => 'HashRef',
+ default => sub { {} },
+ );
+
+ has '_private_stuff' => (
+ is => 'ro',
+ isa => 'Int',
+ default => 713
+ );
+
+ has '_private_stuff_cmdline' => (
+ metaclass => 'MooseX::Getopt::Meta::Attribute',
+ is => 'ro',
+ isa => 'Int',
+ default => 832,
+ cmd_flag => 'p',
+ );
+
+}
+
+foreach my $attr_name (qw(data cow horse _private_stuff_cmdline)) {
+ my $attr = App->meta->get_attribute($attr_name);
+ isa_ok($attr, 'Moose::Meta::Attribute');
+ isa_ok($attr, 'MooseX::Getopt::Meta::Attribute');
+ can_ok($attr, 'cmd_flag');
+ can_ok($attr, 'cmd_aliases');
+}
+
+{
+ local @ARGV = ();
+
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+
+ ok(!$app->verbose, '... verbosity is off as expected');
+ is($app->length, 24, '... length is 24 as expected');
+ is($app->data, 'file.dat', '... data is file.dat as expected');
+ is_deeply($app->libs, [], '... libs is [] as expected');
+ is_deeply($app->details, {}, '... details is {} as expected');
+}
+
+{
+ local @ARGV = ('--verbose', '--length', 50);
+
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+
+ ok($app->verbose, '... verbosity is turned on as expected');
+ is($app->length, 50, '... length is 50 as expected');
+ is($app->data, 'file.dat', '... data is file.dat as expected');
+ is_deeply($app->libs, [], '... libs is [] as expected');
+ is_deeply($app->details, {}, '... details is {} as expected');
+}
+
+{
+ local @ARGV = ('--verbose', '-f', 'foo.txt');
+
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+
+ ok($app->verbose, '... verbosity is turned on as expected');
+ is($app->length, 24, '... length is 24 as expected');
+ is($app->data, 'foo.txt', '... data is foo.txt as expected');
+ is_deeply($app->libs, [], '... libs is [] as expected');
+ is_deeply($app->details, {}, '... details is {} as expected');
+}
+
+{
+ local @ARGV = ('--verbose', '--libs', 'libs/', '--libs', 'includes/lib');
+
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+
+ ok($app->verbose, '... verbosity is turned on as expected');
+ is($app->length, 24, '... length is 24 as expected');
+ is($app->data, 'file.dat', '... data is foo.txt as expected');
+ is_deeply($app->libs,
+ ['libs/', 'includes/lib'],
+ '... libs is [libs/, includes/lib] as expected');
+ is_deeply($app->details, {}, '... details is {} as expected');
+}
+
+{
+ local @ARGV = ('--details', 'os=mac', '--details', 'name=foo');
+
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+
+ ok(!$app->verbose, '... verbosity is turned on as expected');
+ is($app->length, 24, '... length is 24 as expected');
+ is($app->data, 'file.dat', '... data is foo.txt as expected');
+ is_deeply($app->libs, [], '... libs is [] as expected');
+ is_deeply($app->details,
+ { os => 'mac', name => 'foo' },
+ '... details is { os => mac, name => foo } as expected');
+}
+
+{
+ # Test negation on booleans too ...
+ local @ARGV = ('--noverbose');
+
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+
+ ok(!$app->verbose, '... verbosity is turned off as expected');
+ is($app->length, 24, '... length is 24 as expected');
+ is($app->data, 'file.dat', '... file is file.dat as expected');
+ is_deeply($app->libs, [], '... libs is [] as expected');
+ is_deeply($app->details, {}, '... details is {} as expected');
+}
+
+# Test cmd_alias without cmd_flag
+{
+ local @ARGV = ('--cow', '42');
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+ is($app->cow, 42, 'cmd_alias, but not using it');
+}
+{
+ local @ARGV = ('--moocow', '88');
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+ is($app->cow, 88, 'cmd_alias, using long one');
+}
+{
+ local @ARGV = ('-c', '99');
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+ is($app->cow, 99, 'cmd_alias, using short one');
+}
+
+# Test cmd_alias + cmd_flag
+{
+ local @ARGV = ('--horsey', '123');
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+ is($app->horse, 123, 'cmd_alias+cmd_flag, using flag');
+}
+{
+ local @ARGV = ('-x', '321');
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+ is($app->horse, 321, 'cmd_alias+cmd_flag, using alias');
+}
+
+# Test _foo + cmd_flag
+{
+ local @ARGV = ('-p', '666');
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+ is($app->_private_stuff_cmdline, 666, '_foo + cmd_flag');
+}
+
+# Test ARGV support
+{
+ my @args = ('-p', 12345, '-c', 99, '-');
+ local @ARGV = @args;
+ my $app = App->new_with_options;
+ isa_ok($app, 'App');
+ is_deeply($app->ARGV, \@args, 'ARGV accessor');
+ is_deeply(\@ARGV, \@args, '@ARGV unmangled');
+ is_deeply($app->extra_argv, ['-'], 'extra_argv accessor');
+}
projects / gitmo/MooseX-Getopt.git / commitdiff