xt/podcoverage.t

   1 use warnings;
   2 use strict;
   3
   4 use Test::More;
   5 use List::Util 'first';
   6 use lib qw(t/lib maint/.Generated_Pod/lib);
   7 use DBICTest;
   8 use namespace::clean;
   9
  10 require DBIx::Class;
  11 unless ( DBIx::Class::Optional::Dependencies->req_ok_for ('test_podcoverage') ) {
  12   my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('test_podcoverage');
  13   $ENV{RELEASE_TESTING}
  14     ? die ("Failed to load release-testing module requirements: $missing")
  15     : plan skip_all => "Test needs: $missing"
  16 }
  17
  18 # this has already been required but leave it here for CPANTS static analysis
  19 require Test::Pod::Coverage;
  20
  21 # Since this is about checking documentation, a little documentation
  22 # of what this is doing might be in order.
  23 # The exceptions structure below is a hash keyed by the module
  24 # name. Any * in a name is treated like a wildcard and will behave
  25 # as expected. Modules are matched by longest string first, so
  26 # A::B::C will match even if there is A::B*
  27
  28 # The value for each is a hash, which contains one or more
  29 # (although currently more than one makes no sense) of the following
  30 # things:-
  31 #   skip   => a true value means this module is not checked
  32 #   ignore => array ref containing list of methods which
  33 #             do not need to be documented.
  34 my $exceptions = {
  35     'DBIx::Class' => {
  36         ignore => [qw/
  37             MODIFY_CODE_ATTRIBUTES
  38             component_base_class
  39             mk_classdata
  40             mk_classaccessor
  41         /]
  42     },
  43     'DBIx::Class::Carp' => {
  44         ignore => [qw/
  45             unimport
  46         /]
  47     },
  48     'DBIx::Class::Row' => {
  49         ignore => [qw/
  50             MULTICREATE_DEBUG
  51         /],
  52     },
  53     'DBIx::Class::FilterColumn' => {
  54         ignore => [qw/
  55             new
  56             update
  57             store_column
  58             get_column
  59             get_columns
  60             get_dirty_columns
  61             has_column_loaded
  62         /],
  63     },
  64     'DBIx::Class::ResultSource' => {
  65         ignore => [qw/
  66             compare_relationship_keys
  67             pk_depends_on
  68             resolve_condition
  69             resolve_join
  70             resolve_prefetch
  71             STORABLE_freeze
  72             STORABLE_thaw
  73         /],
  74     },
  75     'DBIx::Class::ResultSet' => {
  76         ignore => [qw/
  77             STORABLE_freeze
  78             STORABLE_thaw
  79         /],
  80     },
  81     'DBIx::Class::ResultSourceHandle' => {
  82         ignore => [qw/
  83             schema
  84             source_moniker
  85         /],
  86     },
  87     'DBIx::Class::Storage' => {
  88         ignore => [qw/
  89             schema
  90             cursor
  91         /]
  92     },
  93     'DBIx::Class::Schema' => {
  94         ignore => [qw/
  95             setup_connection_class
  96         /]
  97     },
  98
  99     'DBIx::Class::Schema::Versioned' => {
 100         ignore => [ qw/
 101             connection
 102         /]
 103     },
 104
 105     'DBIx::Class::Admin'        => {
 106         ignore => [ qw/
 107             BUILD
 108         /]
 109      },
 110
 111     'DBIx::Class::Storage::DBI::Replicated*'        => {
 112         ignore => [ qw/
 113             connect_call_do_sql
 114             disconnect_call_do_sql
 115         /]
 116     },
 117
 118     'DBIx::Class::Admin::*'                         => { skip => 1 },
 119     'DBIx::Class::ClassResolver::PassThrough'       => { skip => 1 },
 120     'DBIx::Class::Componentised'                    => { skip => 1 },
 121     'DBIx::Class::AccessorGroup'                    => { skip => 1 },
 122     'DBIx::Class::Relationship::*'                  => { skip => 1 },
 123     'DBIx::Class::ResultSetProxy'                   => { skip => 1 },
 124     'DBIx::Class::ResultSourceProxy'                => { skip => 1 },
 125     'DBIx::Class::ResultSource::*'                  => { skip => 1 },
 126     'DBIx::Class::Storage::Statistics'              => { skip => 1 },
 127     'DBIx::Class::Storage::DBI::Replicated::Types'  => { skip => 1 },
 128     'DBIx::Class::GlobalDestruction'                => { skip => 1 },
 129     'DBIx::Class::Storage::BlockRunner'             => { skip => 1 }, # temporary
 130
 131 # test some specific components whose parents are exempt below
 132     'DBIx::Class::Relationship::Base'               => {},
 133     'DBIx::Class::SQLMaker::LimitDialects'          => {},
 134
 135 # internals
 136     'DBIx::Class::_Util'                            => { skip => 1 },
 137     'DBIx::Class::SQLMaker*'                        => { skip => 1 },
 138     'DBIx::Class::SQLAHacks*'                       => { skip => 1 },
 139     'DBIx::Class::Storage::DBI*'                    => { skip => 1 },
 140     'SQL::Translator::*'                            => { skip => 1 },
 141
 142 # deprecated / backcompat stuff
 143     'DBIx::Class::Serialize::Storable'              => { skip => 1 },
 144     'DBIx::Class::CDBICompat*'                      => { skip => 1 },
 145     'DBIx::Class::ResultSetManager'                 => { skip => 1 },
 146     'DBIx::Class::DB'                               => { skip => 1 },
 147
 148 # skipped because the synopsis covers it clearly
 149     'DBIx::Class::InflateColumn::File'              => { skip => 1 },
 150
 151 # internal subclass, nothing to POD
 152     'DBIx::Class::ResultSet::Pager'                 => { skip => 1 },
 153 };
 154
 155 my $ex_lookup = {};
 156 for my $string (keys %$exceptions) {
 157   my $ex = $exceptions->{$string};
 158   $string =~ s/\*/'.*?'/ge;
 159   my $re = qr/^$string$/;
 160   $ex_lookup->{$re} = $ex;
 161 }
 162
 163 my @modules = sort { $a cmp $b } Test::Pod::Coverage::all_modules('lib');
 164
 165 foreach my $module (@modules) {
 166   SKIP: {
 167
 168     my ($match) =
 169       first { $module =~ $_ }
 170       (sort { length $b <=> length $a || $b cmp $a } (keys %$ex_lookup) )
 171     ;
 172
 173     my $ex = $ex_lookup->{$match} if $match;
 174
 175     skip ("$module exempt", 1) if ($ex->{skip});
 176
 177     # build parms up from ignore list
 178     my $parms = {};
 179     $parms->{trustme} =
 180       [ map { qr/^$_$/ } @{ $ex->{ignore} } ]
 181         if exists($ex->{ignore});
 182
 183     # run the test with the potentially modified parm set
 184     Test::Pod::Coverage::pod_coverage_ok($module, $parms, "$module POD coverage");
 185   }
 186 }
 187
 188 done_testing;