t/resultset/as_subselect_rs.t

   1 BEGIN { do "./t/lib/ANFANG.pm" or die ( $@ || $! ) }
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8
   9
  10 use DBICTest ':DiffSQL';
  11
  12 my $schema = DBICTest->init_schema();
  13
  14 my $new_rs = $schema->resultset('Artist')->search({
  15    'artwork_to_artist.artist_id' => 1
  16 }, {
  17    join => 'artwork_to_artist'
  18 });
  19 lives_ok { $new_rs->count } 'regular search works';
  20 lives_ok { $new_rs->search({ 'artwork_to_artist.artwork_cd_id' => 1})->count }
  21    '... and chaining off that using join works';
  22 lives_ok { $new_rs->search({ 'artwork_to_artist.artwork_cd_id' => 1})->as_subselect_rs->count }
  23    '... and chaining off the virtual view works';
  24 dies_ok  { $new_rs->as_subselect_rs->search({'artwork_to_artist.artwork_cd_id'=> 1})->count }
  25    q{... but chaining off of a virtual view using join doesn't work};
  26
  27 my $book_rs = $schema->resultset ('BooksInLibrary')->search ({}, { join => 'owner' });
  28
  29 is_same_sql_bind (
  30   $book_rs->as_subselect_rs->as_query,
  31   '(SELECT me.id, me.source, me.owner, me.title, me.price
  32       FROM (
  33         SELECT me.id, me.source, me.owner, me.title, me.price
  34           FROM books me
  35           JOIN owners owner ON owner.id = me.owner
  36         WHERE ( source = ? )
  37       ) me
  38   )',
  39   [ [ { sqlt_datatype => 'varchar', sqlt_size => 100, dbic_colname => 'source' }
  40       => 'Library' ] ],
  41   'Resultset-class attributes do not seep outside of the subselect',
  42 );
  43
  44 is_same_sql_bind(
  45   $schema->resultset('CD')->search ({}, {
  46     rows => 2,
  47     join => [ 'genre', { artist => 'cds' } ],
  48     distinct => 1,
  49     columns => {
  50       title => 'me.title',
  51       artist__name => 'artist.name',
  52       genre__name => 'genre.name',
  53       cds_for_artist => \ '(SELECT COUNT(*) FROM cds WHERE cd.artist = artist.id)',
  54     },
  55     order_by => { -desc => 'me.year' },
  56   })->count_rs->as_query,
  57   '(
  58     SELECT COUNT( * )
  59       FROM (
  60         SELECT artist.name AS artist__name, (SELECT COUNT(*) FROM cds WHERE cd.artist = artist.id), genre.name AS genre__name, me.title, me.year
  61           FROM cd me
  62           LEFT JOIN genre genre
  63             ON genre.genreid = me.genreid
  64           JOIN artist artist ON artist.artistid = me.artist
  65         GROUP BY artist.name, (SELECT COUNT(*) FROM cds WHERE cd.artist = artist.id), genre.name, me.title, me.year
  66         LIMIT ?
  67       ) me
  68   )',
  69   [ [{ sqlt_datatype => 'integer' } => 2 ] ],
  70 );
  71
  72 done_testing;