lib/SQL/Translator/Parser/DBIx/Class.pm

   1 package SQL::Translator::Parser::DBIx::Class;
   2
   3 # AUTHOR: Jess Robinson
   4
   5 # Some mistakes the fault of Matt S Trout
   6
   7 # Others the fault of Ash Berlin
   8
   9 use strict;
  10 use warnings;
  11 our ($DEBUG, $VERSION, @EXPORT_OK);
  12 $VERSION = '1.10';
  13 $DEBUG = 0 unless defined $DEBUG;
  14
  15 use Exporter;
  16 use SQL::Translator::Utils qw(debug normalize_name);
  17 use DBIx::Class::Carp qw/^SQL::Translator|^DBIx::Class|^Try::Tiny/;
  18 use DBIx::Class::_Util qw( dbic_internal_try dbic_internal_catch );
  19 use Class::C3::Componentised;
  20 use Scalar::Util 'blessed';
  21 use namespace::clean;
  22
  23 use base qw(Exporter);
  24
  25 @EXPORT_OK = qw(parse);
  26
  27 # -------------------------------------------------------------------
  28 # parse($tr, $data)
  29 #
  30 # setting parser_args => { add_fk_index => 0 } will prevent
  31 # the auto-generation of an index for each FK.
  32 #
  33 # Note that $data, in the case of this parser, is not useful.
  34 # We're working with DBIx::Class Schemas, not data streams.
  35 # -------------------------------------------------------------------
  36 sub parse {
  37     my ($tr, $data)   = @_;
  38     my $args          = $tr->parser_args;
  39
  40     my $dbicschema = $data || $args->{dbic_schema};
  41
  42     for (qw(DBIx::Class::Schema DBIx::Schema package)) {
  43       if (defined (my $s = delete $args->{$_} )) {
  44         carp_unique("Supplying a schema via  ... parser_args => { '$_' => \$schema } is deprecated. Please use parser_args => { dbic_schema => \$schema } instead");
  45
  46         # move it from the deprecated to the proper $args slot
  47         unless ($dbicschema) {
  48           $args->{dbic_schema} = $dbicschema = $s;
  49         }
  50       }
  51     }
  52
  53     DBIx::Class::Exception->throw('No DBIx::Class::Schema') unless ($dbicschema);
  54
  55     if (!ref $dbicschema) {
  56       dbic_internal_try {
  57         Class::C3::Componentised->ensure_class_loaded($dbicschema)
  58       }
  59       dbic_internal_catch {
  60         DBIx::Class::Exception->throw("Can't load $dbicschema: $_");
  61       }
  62     }
  63
  64     if (
  65       ref $args->{dbic_schema}
  66         and
  67       $args->{dbic_schema}->storage
  68     ) {
  69       # we have a storage-holding $schema instance in $args
  70       # we need to dissociate it from that $storage
  71       # otherwise SQLT insanity may ensue due to how some
  72       # serializing producers treat $args (crazy crazy shit)
  73       local $args->{dbic_schema}{storage};
  74       $args->{dbic_schema} = $args->{dbic_schema}->clone;
  75     }
  76
  77     my $schema      = $tr->schema;
  78     my $table_no    = 0;
  79
  80     $schema->name( ref($dbicschema) . " v" . ($dbicschema->schema_version || '1.x'))
  81       unless ($schema->name);
  82
  83     my @monikers = sort $dbicschema->sources;
  84     if (my $limit_sources = $args->{'sources'}) {
  85         my $ref = ref $limit_sources || '';
  86         $dbicschema->throw_exception ("'sources' parameter must be an array or hash ref")
  87           unless( $ref eq 'ARRAY' || ref eq 'HASH' );
  88
  89         # limit monikers to those specified in
  90         my $sources;
  91         if ($ref eq 'ARRAY') {
  92             $sources->{$_} = 1 for (@$limit_sources);
  93         } else {
  94             $sources = $limit_sources;
  95         }
  96         @monikers = grep { $sources->{$_} } @monikers;
  97     }
  98
  99
 100     my(%table_monikers, %view_monikers);
 101     for my $moniker (@monikers){
 102       my $source = $dbicschema->source($moniker);
 103        if ( $source->isa('DBIx::Class::ResultSource::Table') ) {
 104          $table_monikers{$moniker}++;
 105       } elsif( $source->isa('DBIx::Class::ResultSource::View') ){
 106           next if $source->is_virtual;
 107          $view_monikers{$moniker}++;
 108       }
 109     }
 110
 111     my %tables;
 112     foreach my $moniker (sort keys %table_monikers)
 113     {
 114         my $source = $dbicschema->source($moniker);
 115         my $table_name = $source->name;
 116
 117         # FIXME - this isn't the right way to do it, but sqlt does not
 118         # support quoting properly to be signaled about this
 119         $table_name = $$table_name if ref $table_name eq 'SCALAR';
 120
 121         # It's possible to have multiple DBIC sources using the same table
 122         next if $tables{$table_name};
 123
 124         $tables{$table_name}{source} = $source;
 125         my $table = $tables{$table_name}{object} = SQL::Translator::Schema::Table->new(
 126                                        name => $table_name,
 127                                        type => 'TABLE',
 128                                        );
 129
 130         my $ci = $source->columns_info;
 131
 132         # same order as add_columns
 133         foreach my $col ($source->columns)
 134         {
 135             # assuming column_info in dbic is the same as DBI (?)
 136             # data_type is a number, column_type is text?
 137             my %colinfo = (
 138               name => $col,
 139               size => 0,
 140               is_auto_increment => 0,
 141               is_foreign_key => 0,
 142               is_nullable => 0,
 143               %{$ci->{$col} || {}}
 144             );
 145             if ($colinfo{is_nullable}) {
 146               $colinfo{default} = '' unless exists $colinfo{default};
 147             }
 148             my $f = $table->add_field(%colinfo)
 149               || $dbicschema->throw_exception ($table->error);
 150         }
 151
 152         my @primary = $source->primary_columns;
 153
 154         $table->primary_key(@primary) if @primary;
 155
 156         my %unique_constraints = $source->unique_constraints;
 157         foreach my $uniq (sort keys %unique_constraints) {
 158             if (!$source->_compare_relationship_keys($unique_constraints{$uniq}, \@primary)) {
 159                 $table->add_constraint(
 160                             type             => 'unique',
 161                             name             => $uniq,
 162                             fields           => $unique_constraints{$uniq}
 163                 );
 164             }
 165         }
 166
 167         my @rels = $source->relationships();
 168
 169         my %created_FK_rels;
 170
 171         # global add_fk_index set in parser_args
 172         my $add_fk_index = (exists $args->{add_fk_index} && ! $args->{add_fk_index}) ? 0 : 1;
 173
 174         REL:
 175         foreach my $rel (sort @rels) {
 176
 177             my $rel_info = $source->relationship_info($rel);
 178
 179             # Ignore any rel cond that isn't a straight hash
 180             next unless ref $rel_info->{cond} eq 'HASH';
 181
 182             my $relsource = dbic_internal_try { $source->related_source($rel) };
 183             unless ($relsource) {
 184               carp "Ignoring relationship '$rel' on '$moniker' - related resultsource '$rel_info->{class}' is not registered with this schema\n";
 185               next;
 186             };
 187
 188             # related sources might be excluded via a {sources} filter or might be views
 189             next unless exists $table_monikers{$relsource->source_name};
 190
 191             my $rel_table = $relsource->name;
 192
 193             # FIXME - this isn't the right way to do it, but sqlt does not
 194             # support quoting properly to be signaled about this
 195             $rel_table = $$rel_table if ref $rel_table eq 'SCALAR';
 196
 197             # Force the order of @cond to match the order of ->add_columns
 198             my $idx;
 199             my %other_columns_idx = map {'foreign.'.$_ => ++$idx } $relsource->columns;
 200
 201             for ( keys %{$rel_info->{cond}} ) {
 202               unless (exists $other_columns_idx{$_}) {
 203                 carp "Ignoring relationship '$rel' on '$moniker' - related resultsource '@{[ $relsource->source_name ]}' does not contain one of the specified columns: '$_'\n";
 204                 next REL;
 205               }
 206             }
 207
 208             my @cond = sort { $other_columns_idx{$a} <=> $other_columns_idx{$b} } keys(%{$rel_info->{cond}});
 209
 210             # Get the key information, mapping off the foreign/self markers
 211             my @refkeys = map {/^\w+\.(\w+)$/} @cond;
 212             my @keys = map {$rel_info->{cond}->{$_} =~ /^\w+\.(\w+)$/} @cond;
 213
 214             # determine if this relationship is a self.fk => foreign.pk (i.e. belongs_to)
 215             my $fk_constraint;
 216
 217             #first it can be specified explicitly
 218             if ( exists $rel_info->{attrs}{is_foreign_key_constraint} ) {
 219                 $fk_constraint = $rel_info->{attrs}{is_foreign_key_constraint};
 220             }
 221             # it can not be multi
 222             elsif ( $rel_info->{attrs}{accessor}
 223                     && $rel_info->{attrs}{accessor} eq 'multi' ) {
 224                 $fk_constraint = 0;
 225             }
 226             # if indeed single, check if all self.columns are our primary keys.
 227             # this is supposed to indicate a has_one/might_have...
 228             # where's the introspection!!?? :)
 229             else {
 230                 $fk_constraint = not $source->_compare_relationship_keys(\@keys, \@primary);
 231             }
 232
 233             my ($otherrelname, $otherrelationship) = %{ $source->reverse_relationship_info($rel) };
 234
 235             my $cascade;
 236             for my $c (qw/delete update/) {
 237                 if (exists $rel_info->{attrs}{"on_$c"}) {
 238                     if ($fk_constraint) {
 239                         $cascade->{$c} = $rel_info->{attrs}{"on_$c"};
 240                     }
 241                     elsif ( $rel_info->{attrs}{"on_$c"} ) {
 242                         carp "SQLT attribute 'on_$c' was supplied for relationship '$moniker/$rel', which does not appear to be a foreign constraint. "
 243                             . "If you are sure that SQLT must generate a constraint for this relationship, add 'is_foreign_key_constraint => 1' to the attributes.\n";
 244                     }
 245                 }
 246                 elsif (defined $otherrelationship and $otherrelationship->{attrs}{$c eq 'update' ? 'cascade_copy' : 'cascade_delete'}) {
 247                     $cascade->{$c} = 'CASCADE';
 248                 }
 249             }
 250
 251             if($rel_table) {
 252                 # Constraints are added only if applicable
 253                 next unless $fk_constraint;
 254
 255                 # Make sure we don't create the same foreign key constraint twice
 256                 my $key_test = join("\x00", sort @keys);
 257                 next if $created_FK_rels{$rel_table}->{$key_test};
 258
 259                 if (scalar(@keys)) {
 260                   $created_FK_rels{$rel_table}->{$key_test} = 1;
 261
 262                   my $is_deferrable = $rel_info->{attrs}{is_deferrable};
 263
 264                   # calculate dependencies: do not consider deferrable constraints and
 265                   # self-references for dependency calculations
 266                   if (! $is_deferrable and $rel_table ne $table_name) {
 267                     $tables{$table_name}{foreign_table_deps}{$rel_table}++;
 268                   }
 269
 270                   # trim schema before generating constraint/index names
 271                   (my $table_abbrev = $table_name) =~ s/ ^ [^\.]+ \. //x;
 272
 273                   $table->add_constraint(
 274                     type             => 'foreign_key',
 275                     name             => join('_', $table_abbrev, 'fk', @keys),
 276                     fields           => \@keys,
 277                     reference_fields => \@refkeys,
 278                     reference_table  => $rel_table,
 279                     on_delete        => uc ($cascade->{delete} || ''),
 280                     on_update        => uc ($cascade->{update} || ''),
 281                     (defined $is_deferrable ? ( deferrable => $is_deferrable ) : ()),
 282                   );
 283
 284                   # global parser_args add_fk_index param can be overridden on the rel def
 285                   my $add_fk_index_rel = (exists $rel_info->{attrs}{add_fk_index}) ? $rel_info->{attrs}{add_fk_index} : $add_fk_index;
 286
 287                   # Check that we do not create an index identical to the PK index
 288                   # (some RDBMS croak on this, and it generally doesn't make much sense)
 289                   # NOTE: we do not sort the key columns because the order of
 290                   # columns is important for indexes and two indexes with the
 291                   # same cols but different order are allowed and sometimes
 292                   # needed
 293                   next if join("\x00", @keys) eq join("\x00", @primary);
 294
 295                   if ($add_fk_index_rel) {
 296                       (my $idx_name = $table_name) =~ s/ ^ [^\.]+ \. //x;
 297                       my $index = $table->add_index(
 298                           name   => join('_', $table_abbrev, 'idx', @keys),
 299                           fields => \@keys,
 300                           type   => 'NORMAL',
 301                       );
 302                   }
 303               }
 304             }
 305         }
 306
 307     }
 308
 309     # attach the tables to the schema in dependency order
 310     my $dependencies = {
 311       map { $_ => _resolve_deps ($_, \%tables) } (keys %tables)
 312     };
 313
 314     for my $table (sort
 315       {
 316         keys %{$dependencies->{$a} || {} } <=> keys %{ $dependencies->{$b} || {} }
 317           ||
 318         $a cmp $b
 319       }
 320       (keys %tables)
 321     ) {
 322       $schema->add_table ($tables{$table}{object});
 323       $tables{$table}{source} -> _invoke_sqlt_deploy_hook( $tables{$table}{object} );
 324
 325       # the hook might have already removed the table
 326       if ($schema->get_table($table) && $table =~ /^ \s* \( \s* SELECT \s+/ix) {
 327         carp <<'EOW';
 328
 329 Custom SQL through ->name(\'( SELECT ...') is DEPRECATED, for more details see
 330 "Arbitrary SQL through a custom ResultSource" in DBIx::Class::Manual::Cookbook
 331 or http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod
 332
 333 EOW
 334
 335         # remove the table as there is no way someone might want to
 336         # actually deploy this
 337         $schema->drop_table ($table);
 338       }
 339     }
 340
 341     my %views;
 342     my @views = map { $dbicschema->source($_) } keys %view_monikers;
 343
 344     my $view_dependencies = {
 345         map {
 346             $_ => _resolve_deps( $dbicschema->source($_), \%view_monikers )
 347           } ( keys %view_monikers )
 348     };
 349
 350     my @view_sources =
 351       sort {
 352         keys %{ $view_dependencies->{ $a->source_name }   || {} } <=>
 353           keys %{ $view_dependencies->{ $b->source_name } || {} }
 354           || $a->source_name cmp $b->source_name
 355       }
 356       map { $dbicschema->source($_) }
 357       keys %view_monikers;
 358
 359     foreach my $source (@view_sources)
 360     {
 361         my $view_name = $source->name;
 362
 363         # FIXME - this isn't the right way to do it, but sqlt does not
 364         # support quoting properly to be signaled about this
 365         $view_name = $$view_name if ref $view_name eq 'SCALAR';
 366
 367         # Skip custom query sources
 368         next if ref $view_name;
 369
 370         # Its possible to have multiple DBIC source using same table
 371         next if $views{$view_name}++;
 372
 373         $dbicschema->throw_exception ("view $view_name is missing a view_definition")
 374             unless $source->view_definition;
 375
 376         my $view = $schema->add_view (
 377           name => $view_name,
 378           fields => [ $source->columns ],
 379           $source->view_definition ? ( 'sql' => $source->view_definition ) : ()
 380         ) || $dbicschema->throw_exception ($schema->error);
 381
 382         $source->_invoke_sqlt_deploy_hook($view);
 383     }
 384
 385
 386     if ($dbicschema->can('sqlt_deploy_hook')) {
 387       $dbicschema->sqlt_deploy_hook($schema);
 388     }
 389
 390     return 1;
 391 }
 392
 393 #
 394 # Quick and dirty dependency graph calculator
 395 #
 396 sub _resolve_deps {
 397     my ( $question, $answers, $seen ) = @_;
 398     my $ret = {};
 399     $seen ||= {};
 400     my @deps;
 401
 402     # copy and bump all deps by one (so we can reconstruct the chain)
 403     my %seen = map { $_ => $seen->{$_} + 1 } ( keys %$seen );
 404     if ( blessed($question)
 405         && $question->isa('DBIx::Class::ResultSource::View') )
 406     {
 407         $seen{ $question->result_class } = 1;
 408         @deps = keys %{ $question->{deploy_depends_on} };
 409     }
 410     else {
 411         $seen{$question} = 1;
 412         @deps = keys %{ $answers->{$question}{foreign_table_deps} };
 413     }
 414
 415     for my $dep (@deps) {
 416         if ( $seen->{$dep} ) {
 417             return {};
 418         }
 419         my $next_dep;
 420
 421         if ( blessed($question)
 422             && $question->isa('DBIx::Class::ResultSource::View') )
 423         {
 424             no warnings 'uninitialized';
 425             my ($next_dep_source_name) =
 426               grep {
 427                 $question->schema->source($_)->result_class eq $dep
 428                   && !( $question->schema->source($_)
 429                     ->isa('DBIx::Class::ResultSource::Table') )
 430               } @{ [ $question->schema->sources ] };
 431             return {} unless $next_dep_source_name;
 432             $next_dep = $question->schema->source($next_dep_source_name);
 433         }
 434         else {
 435             $next_dep = $dep;
 436         }
 437         my $subdeps = _resolve_deps( $next_dep, $answers, \%seen );
 438         $ret->{$_} += $subdeps->{$_} for ( keys %$subdeps );
 439         ++$ret->{$dep};
 440     }
 441     return $ret;
 442 }
 443
 444 1;
 445
 446 =head1 NAME
 447
 448 SQL::Translator::Parser::DBIx::Class - Create a SQL::Translator schema
 449 from a DBIx::Class::Schema instance
 450
 451 =head1 SYNOPSIS
 452
 453  ## Via DBIx::Class
 454  use MyApp::Schema;
 455  my $schema = MyApp::Schema->connect("dbi:SQLite:something.db");
 456  $schema->create_ddl_dir();
 457  ## or
 458  $schema->deploy();
 459
 460  ## Standalone
 461  use MyApp::Schema;
 462  use SQL::Translator;
 463
 464  my $schema = MyApp::Schema->connect;
 465  my $trans  = SQL::Translator->new (
 466       parser      => 'SQL::Translator::Parser::DBIx::Class',
 467       parser_args => {
 468           dbic_schema => $schema,
 469           add_fk_index => 0,
 470           sources => [qw/
 471             Artist
 472             CD
 473           /],
 474       },
 475       producer    => 'SQLite',
 476      ) or die SQL::Translator->error;
 477  my $out = $trans->translate() or die $trans->error;
 478
 479 =head1 DESCRIPTION
 480
 481 This class requires L<SQL::Translator> installed to work.
 482
 483 C<SQL::Translator::Parser::DBIx::Class> reads a DBIx::Class schema,
 484 interrogates the columns, and stuffs it all in an $sqlt_schema object.
 485
 486 Its primary use is in deploying database layouts described as a set
 487 of L<DBIx::Class> classes, to a database. To do this, see
 488 L<DBIx::Class::Schema/deploy>.
 489
 490 This can also be achieved by having DBIx::Class export the schema as a
 491 set of SQL files ready for import into your database, or passed to
 492 other machines that need to have your application installed but don't
 493 have SQL::Translator installed. To do this see
 494 L<DBIx::Class::Schema/create_ddl_dir>.
 495
 496 =head1 PARSER OPTIONS
 497
 498 =head2 dbic_schema
 499
 500 The DBIx::Class schema (either an instance or a class name) to be parsed.
 501 This argument is in fact optional - instead one can supply it later at
 502 translation time as an argument to L<SQL::Translator/translate>. In
 503 other words both of the following invocations are valid and will produce
 504 conceptually identical output:
 505
 506   my $yaml = SQL::Translator->new(
 507     parser => 'SQL::Translator::Parser::DBIx::Class',
 508     parser_args => {
 509       dbic_schema => $schema,
 510     },
 511     producer => 'SQL::Translator::Producer::YAML',
 512   )->translate;
 513
 514   my $yaml = SQL::Translator->new(
 515     parser => 'SQL::Translator::Parser::DBIx::Class',
 516     producer => 'SQL::Translator::Producer::YAML',
 517   )->translate(data => $schema);
 518
 519 =head2 add_fk_index
 520
 521 Create an index for each foreign key.
 522 Enabled by default, as having indexed foreign key columns is normally the
 523 sensible thing to do.
 524
 525 =head2 sources
 526
 527 =over 4
 528
 529 =item Arguments: \@class_names
 530
 531 =back
 532
 533 Limit the amount of parsed sources by supplying an explicit list of source names.
 534
 535 =head1 SEE ALSO
 536
 537 L<SQL::Translator>, L<DBIx::Class::Schema>
 538
 539 =head1 FURTHER QUESTIONS?
 540
 541 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 542
 543 =head1 COPYRIGHT AND LICENSE
 544
 545 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 546 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 547 redistribute it and/or modify it under the same terms as the
 548 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.