lib/DBIx/Class/_Util.pm

   1 package # hide from PAUSE
   2   DBIx::Class::_Util;
   3
   4 use warnings;
   5 use strict;
   6
   7 use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
   8
   9 BEGIN {
  10   package # hide from pause
  11     DBIx::Class::_ENV_;
  12
  13   use Config;
  14
  15   use constant {
  16
  17     # but of course
  18     BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
  19
  20     BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
  21
  22     HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
  23
  24     # ::Runmode would only be loaded by DBICTest, which in turn implies t/
  25     DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
  26
  27     # During 5.13 dev cycle HELEMs started to leak on copy
  28     # add an escape for these perls ON SMOKERS - a user will still get death
  29     PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
  30
  31     SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
  32
  33     ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
  34
  35     ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
  36
  37     STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE => $ENV{DBIC_STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE} ? 1 : 0,
  38
  39     IV_SIZE => $Config{ivsize},
  40
  41     OS_NAME => $^O,
  42   };
  43
  44   if ($] < 5.009_005) {
  45     require MRO::Compat;
  46     constant->import( OLD_MRO => 1 );
  47   }
  48   else {
  49     require mro;
  50     constant->import( OLD_MRO => 0 );
  51   }
  52 }
  53
  54 # FIXME - this is not supposed to be here
  55 # Carp::Skip to the rescue soon
  56 use DBIx::Class::Carp '^DBIx::Class|^DBICTest';
  57
  58 use B ();
  59 use Carp 'croak';
  60 use Storable 'nfreeze';
  61 use Scalar::Util qw(weaken blessed reftype refaddr);
  62 use List::Util qw(first);
  63 use Sub::Quote qw(qsub quote_sub);
  64
  65 use base 'Exporter';
  66 our @EXPORT_OK = qw(
  67   sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt
  68   fail_on_internal_wantarray fail_on_internal_call
  69   refdesc refcount hrefaddr is_exception detected_reinvoked_destructor
  70   quote_sub qsub perlstring serialize
  71   UNRESOLVABLE_CONDITION
  72 );
  73
  74 use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
  75
  76 sub sigwarn_silencer ($) {
  77   my $pattern = shift;
  78
  79   croak "Expecting a regexp" if ref $pattern ne 'Regexp';
  80
  81   my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };
  82
  83   return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
  84 }
  85
  86 sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
  87
  88 sub hrefaddr ($) { sprintf '0x%x', &refaddr||0 }
  89
  90 sub refdesc ($) {
  91   croak "Expecting a reference" if ! length ref $_[0];
  92
  93   # be careful not to trigger stringification,
  94   # reuse @_ as a scratch-pad
  95   sprintf '%s%s(0x%x)',
  96     ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
  97     reftype $_[0],
  98     refaddr($_[0]),
  99   ;
 100 }
 101
 102 sub refcount ($) {
 103   croak "Expecting a reference" if ! length ref $_[0];
 104
 105   # No tempvars - must operate on $_[0], otherwise the pad
 106   # will count as an extra ref
 107   B::svref_2object($_[0])->REFCNT;
 108 }
 109
 110 sub serialize ($) {
 111   local $Storable::canonical = 1;
 112   nfreeze($_[0]);
 113 }
 114
 115 sub is_exception ($) {
 116   my $e = $_[0];
 117
 118   # this is not strictly correct - an eval setting $@ to undef
 119   # is *not* the same as an eval setting $@ to ''
 120   # but for the sake of simplicity assume the following for
 121   # the time being
 122   return 0 unless defined $e;
 123
 124   my ($not_blank, $suberror);
 125   {
 126     local $@;
 127     eval {
 128       $not_blank = ($e ne '') ? 1 : 0;
 129       1;
 130     } or $suberror = $@;
 131   }
 132
 133   if (defined $suberror) {
 134     if (length (my $class = blessed($e) )) {
 135       carp_unique( sprintf(
 136         'External exception class %s implements partial (broken) overloading '
 137       . 'preventing its instances from being used in simple ($x eq $y) '
 138       . 'comparisons. Given Perl\'s "globally cooperative" exception '
 139       . 'handling this type of brokenness is extremely dangerous on '
 140       . 'exception objects, as it may (and often does) result in silent '
 141       . '"exception substitution". DBIx::Class tries to work around this '
 142       . 'as much as possible, but other parts of your software stack may '
 143       . 'not be even aware of this. Please submit a bugreport against the '
 144       . 'distribution containing %s and in the meantime apply a fix similar '
 145       . 'to the one shown at %s, in order to ensure your exception handling '
 146       . 'is saner application-wide. What follows is the actual error text '
 147       . "as generated by Perl itself:\n\n%s\n ",
 148         $class,
 149         $class,
 150         'http://v.gd/DBIC_overload_tempfix/',
 151         $suberror,
 152       ));
 153
 154       # workaround, keeps spice flowing
 155       $not_blank = ("$e" ne '') ? 1 : 0;
 156     }
 157     else {
 158       # not blessed yet failed the 'ne'... this makes 0 sense...
 159       # just throw further
 160       die $suberror
 161     }
 162   }
 163
 164   return $not_blank;
 165 }
 166
 167 {
 168   my $destruction_registry = {};
 169
 170   sub CLONE {
 171     $destruction_registry = { map
 172       { defined $_ ? ( refaddr($_) => $_ ) : () }
 173       values %$destruction_registry
 174     };
 175   }
 176
 177   # This is almost invariably invoked from within DESTROY
 178   # throwing exceptions won't work
 179   sub detected_reinvoked_destructor {
 180
 181     # quick "garbage collection" pass - prevents the registry
 182     # from slowly growing with a bunch of undef-valued keys
 183     defined $destruction_registry->{$_} or delete $destruction_registry->{$_}
 184       for keys %$destruction_registry;
 185
 186     if (! length ref $_[0]) {
 187       printf STDERR '%s() expects a blessed reference %s',
 188         (caller(0))[3],
 189         Carp::longmess,
 190       ;
 191       return undef; # don't know wtf to do
 192     }
 193     elsif (! defined $destruction_registry->{ my $addr = refaddr($_[0]) } ) {
 194       weaken( $destruction_registry->{$addr} = $_[0] );
 195       return 0;
 196     }
 197     else {
 198       carp_unique ( sprintf (
 199         'Preventing *MULTIPLE* DESTROY() invocations on %s - an *EXTREMELY '
 200       . 'DANGEROUS* condition which is *ALMOST CERTAINLY GLOBAL* within your '
 201       . 'application, affecting *ALL* classes without active protection against '
 202       . 'this. Diagnose and fix the root cause ASAP!!!%s',
 203       refdesc $_[0],
 204         ( ( $INC{'Devel/StackTrace.pm'} and ! do { local $@; eval { Devel::StackTrace->VERSION(2) } } )
 205           ? " (likely culprit Devel::StackTrace\@@{[ Devel::StackTrace->VERSION ]} found in %INC, http://is.gd/D_ST_refcap)"
 206           : ''
 207         )
 208       ));
 209
 210       return 1;
 211     }
 212   }
 213 }
 214
 215 sub modver_gt_or_eq ($$) {
 216   my ($mod, $ver) = @_;
 217
 218   croak "Nonsensical module name supplied"
 219     if ! defined $mod or ! length $mod;
 220
 221   croak "Nonsensical minimum version supplied"
 222     if ! defined $ver or $ver =~ /[^0-9\.\_]/;
 223
 224   local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
 225     if SPURIOUS_VERSION_CHECK_WARNINGS;
 226
 227   croak "$mod does not seem to provide a version (perhaps it never loaded)"
 228     unless $mod->VERSION;
 229
 230   local $@;
 231   eval { $mod->VERSION($ver) } ? 1 : 0;
 232 }
 233
 234 sub modver_gt_or_eq_and_lt ($$$) {
 235   my ($mod, $v_ge, $v_lt) = @_;
 236
 237   croak "Nonsensical maximum version supplied"
 238     if ! defined $v_lt or $v_lt =~ /[^0-9\.\_]/;
 239
 240   return (
 241     modver_gt_or_eq($mod, $v_ge)
 242       and
 243     ! modver_gt_or_eq($mod, $v_lt)
 244   ) ? 1 : 0;
 245 }
 246
 247 {
 248   my $list_ctx_ok_stack_marker;
 249
 250   sub fail_on_internal_wantarray () {
 251     return if $list_ctx_ok_stack_marker;
 252
 253     if (! defined wantarray) {
 254       croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
 255     }
 256
 257     my $cf = 1;
 258     while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:
 259
 260       # these are public API parts that alter behavior on wantarray
 261       search | search_related | slice | search_literal
 262
 263         |
 264
 265       # these are explicitly prefixed, since we only recognize them as valid
 266       # escapes when they come from the guts of CDBICompat
 267       CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )
 268
 269     ) $/x ) {
 270       $cf++;
 271     }
 272
 273     my ($fr, $want, $argdesc);
 274     {
 275       package DB;
 276       $fr = [ caller($cf) ];
 277       $want = ( caller($cf-1) )[5];
 278       $argdesc = ref $DB::args[0]
 279         ? DBIx::Class::_Util::refdesc($DB::args[0])
 280         : 'non '
 281       ;
 282     };
 283
 284     if (
 285       $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 286     ) {
 287       DBIx::Class::Exception->throw( sprintf (
 288         "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
 289         $argdesc, @{$fr}[1,2]
 290       ), 'with_stacktrace');
 291     }
 292
 293     my $mark = [];
 294     weaken ( $list_ctx_ok_stack_marker = $mark );
 295     $mark;
 296   }
 297 }
 298
 299 sub fail_on_internal_call {
 300   my ($fr, $argdesc);
 301   {
 302     package DB;
 303     $fr = [ caller(1) ];
 304     $argdesc = ref $DB::args[0]
 305       ? DBIx::Class::_Util::refdesc($DB::args[0])
 306       : undef
 307     ;
 308   };
 309
 310   if (
 311     $argdesc
 312       and
 313     $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
 314       and
 315     $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
 316   ) {
 317     DBIx::Class::Exception->throw( sprintf (
 318       "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
 319       $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
 320         require B::Deparse;
 321         no strict 'refs';
 322         B::Deparse->new->coderef2text(\&{$fr->[3]})
 323       }),
 324     ), 'with_stacktrace');
 325   }
 326 }
 327
 328 1;