Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 use 5.008001;
   6
   7 use FindBin;
   8 use lib "$FindBin::Bin/lib";
   9 use DBIx::Class::Optional::Dependencies;
  10
  11 # get cpanX --installdeps . to behave in a checkout (most users do not need
  12 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  13 # for that)
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  18
  19 ###
  20 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  21 ### All of them should go to DBIx::Class::Optional::Dependencies
  22 ###
  23
  24 name     'DBIx-Class';
  25 perl_version '5.008001';
  26 all_from 'lib/DBIx/Class.pm';
  27
  28 my $build_requires = {
  29   # needed for testing only, not for operation
  30   'DBD::SQLite'              => '1.29',
  31 };
  32
  33 my $test_requires = {
  34   'File::Temp'               => '0.22',
  35   'Test::Exception'          => '0.31',
  36   'Test::Warn'               => '0.21',
  37   'Test::More'               => '0.94',
  38   # not sure if this is necessary at all, ask schwern some day
  39   'Test::Builder'            => '0.94',
  40
  41   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  42   # remove and do a manual glob-collection if n::c is no longer a dep
  43   'Package::Stash'           => '0.28',
  44 };
  45
  46 my $runtime_requires = {
  47   'Class::Accessor::Grouped' => '0.10002',
  48   'Class::C3::Componentised' => '1.0009',
  49   'Class::Inspector'         => '1.24',
  50   'Config::Any'              => '0.20',
  51   'Context::Preserve'        => '0.01',
  52   'Data::Dumper::Concise'    => '2.020',
  53   'Data::Page'               => '2.00',
  54   'Hash::Merge'              => '0.12',
  55   'MRO::Compat'              => '0.09',
  56   'Module::Find'             => '0.06',
  57   'namespace::clean'         => '0.20',
  58   'Path::Class'              => '0.18',
  59   'Scope::Guard'             => '0.03',
  60   'SQL::Abstract'            => '1.72',
  61   'Try::Tiny'                => '0.04',
  62
  63   # XS (or XS-dependent) libs
  64   'DBI'                      => '1.57',
  65   'Sub::Name'                => '0.04',
  66
  67   # dual-life corelibs needing a specific bugfixed version
  68   'File::Path'               => '2.07',
  69
  70   # FIXME - temporary, needs throwing out for something more efficient
  71   'Data::Compare'            => '1.22',
  72 };
  73
  74
  75 # Bail out on parallel testing
  76 if (
  77   ($ENV{HARNESS_OPTIONS}||'') =~ / (?: ^ | \: ) j(\d+) /x
  78     and
  79   $1 > 1
  80 ) { die <<EOP }
  81
  82 ******************************************************************************
  83 ******************************************************************************
  84 ***                                                                        ***
  85 ***      PARALLEL TESTING DETECTED ( \$ENV{HARNESS_OPTIONS} = 'j$1' )        ***
  86 ***                                                                        ***
  87 *** DBIC tests will fail. It is harder to make them parallel-friendly than ***
  88 *** it should be (though work is underway). In the meantime you will have  ***
  89 *** to adjust your environment and re-run the installation. Sorry!         ***
  90 ***                                                                        ***
  91 ******************************************************************************
  92 ******************************************************************************
  93
  94 EOP
  95
  96 require Getopt::Long;
  97 my $getopt = Getopt::Long::Parser->new(
  98   config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
  99 );
 100 my $args = {
 101   skip_author_deps => undef,
 102 };
 103 $getopt->getoptions($args, 'skip_author_deps');
 104 if (@ARGV) {
 105   warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 106 }
 107
 108 # this is so we can order requires alphabetically
 109 # copies are needed for author requires injection
 110 my $reqs = {
 111   build_requires => { %$build_requires },
 112   requires => { %$runtime_requires },
 113   test_requires => { %$test_requires },
 114 };
 115
 116 my %reqs_for_group = %{DBIx::Class::Optional::Dependencies->req_group_list};
 117
 118 # exclude the rdbms_* groups which are for DBIC users
 119 my $opt_testdeps = {
 120   map { %{$reqs_for_group{$_}} } grep { !/^rdbms_/ } keys %reqs_for_group
 121 };
 122
 123 # require extra modules for testing if we're in a checkout
 124 my $optdep_msg;
 125 if ($Module::Install::AUTHOR) {
 126   if ($args->{skip_author_deps}) {
 127     $optdep_msg = <<'EOW';
 128
 129 ******************************************************************************
 130 ******************************************************************************
 131 ***                                                                        ***
 132 *** IGNORING AUTHOR MODE: no optional test dependencies will be forced.    ***
 133 ***                                                                        ***
 134 *** If you are using this checkout with the intention of submitting a DBIC ***
 135 *** patch, you are *STRONGLY ENCOURAGED* to install all dependencies, so   ***
 136 *** that every possible unit-test will run.                                ***
 137 ***                                                                        ***
 138 ******************************************************************************
 139 ******************************************************************************
 140
 141 EOW
 142   }
 143   else {
 144     $optdep_msg = <<'EOW';
 145
 146 ******************************************************************************
 147 ******************************************************************************
 148 ***                                                                        ***
 149 *** AUTHOR MODE: all optional test dependencies converted to hard requires ***
 150 ***       ( to disable re-run Makefile.PL with --skip_author_deps )        ***
 151 ***                                                                        ***
 152 ******************************************************************************
 153 ******************************************************************************
 154
 155 EOW
 156
 157     $reqs->{test_requires} = {
 158       %{$reqs->{test_requires}},
 159       %$opt_testdeps
 160     };
 161   }
 162 }
 163
 164 # compose final req list, for alphabetical ordering
 165 my %final_req;
 166 for my $rtype (keys %$reqs) {
 167   for my $mod (keys %{$reqs->{$rtype}} ) {
 168
 169     # sanity check req duplications
 170     if ($final_req{$mod}) {
 171       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 172     }
 173
 174     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 175   }
 176 }
 177
 178 # actual require
 179 for my $mod (sort keys %final_req) {
 180   my ($rtype, $ver) = @{$final_req{$mod}};
 181   no strict 'refs';
 182   $rtype->($mod, $ver);
 183 }
 184
 185 # output twice since the deplist is > 70 lines
 186 warn $optdep_msg if $Module::Install::AUTHOR;
 187 auto_install();
 188 warn $optdep_msg if $Module::Install::AUTHOR;
 189
 190
 191 # re-create various autogenerated documentation bits
 192 if ($Module::Install::AUTHOR) {
 193
 194   # adjust ENV for $AUTHOR system() calls
 195   require Config;
 196   $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 197
 198   print "Regenerating README\n";
 199   system('pod2text lib/DBIx/Class.pm > README');
 200
 201   if (-f 'MANIFEST') {
 202     print "Removing MANIFEST\n";
 203     unlink 'MANIFEST';
 204   }
 205
 206   print "Regenerating Optional/Dependencies.pod\n";
 207   require DBIx::Class::Optional::Dependencies;
 208   DBIx::Class::Optional::Dependencies->_gen_pod (Meta->version);
 209
 210   # FIXME Disabled due to unsolved issues, ask theorbtwo
 211   #  require Module::Install::Pod::Inherit;
 212   #  PodInherit();
 213 }
 214
 215
 216 tests_recursive (qw|
 217     t
 218 |);
 219
 220 # temporary(?) until I get around to fix M::I wrt xt/
 221 # needs Module::Install::AuthorTests
 222 eval {
 223   # this should not be necessary since the autoloader is supposed
 224   # to work, but there were reports of it failing
 225   require Module::Install::AuthorTests;
 226   recursive_author_tests (qw/xt/);
 227   1;
 228 } || do {
 229   if ($Module::Install::AUTHOR && ! $args->{skip_author_deps}) {
 230     my $err = $@;
 231
 232     # better error message in case of missing dep
 233     eval { require Module::Install::AuthorTests }
 234       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode (or supply --skip_author_deps):\n\n$@\n";
 235
 236     die $err;
 237   }
 238 };
 239
 240
 241 install_script (qw|
 242     script/dbicadmin
 243 |);
 244
 245
 246 ### Mangle makefile - read the comments for more info
 247 #
 248 postamble <<"EOP";
 249
 250 # This will add an extra dep-spec for the distdir target,
 251 # which `make` will fold together in a first-come first-serve
 252 # fashion. What we do here is essentially adding extra
 253 # commands to execute once the distdir is assembled (via
 254 # create_distdir), but before control is returned to a higher
 255 # calling rule.
 256 distdir : dbicadmin_pod_inject
 257
 258 # The pod self-injection code is in fact a hidden option in
 259 # dbicadmin itself
 260 dbicadmin_pod_inject :
 261 \tcd \$(DISTVNAME) && \$(ABSPERL) -Ilib script/dbicadmin --selfinject-pod
 262
 263 # Regenerate manifest before running create_distdir.
 264 create_distdir : manifest
 265
 266 EOP
 267
 268 homepage 'http://www.dbix-class.org/';
 269 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
 270 resources 'license'     => 'http://dev.perl.org/licenses/';
 271 resources 'repository'  => 'git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git';
 272 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
 273 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
 274
 275 # Deprecated/internal modules need no exposure
 276 no_index directory => $_ for (qw|
 277   lib/DBIx/Class/Admin
 278   lib/DBIx/Class/PK/Auto
 279   lib/DBIx/Class/CDBICompat
 280 |);
 281 no_index package => $_ for (qw/
 282   DBIx::Class::Storage::DBIHacks
 283   DBIx::Class::Carp
 284   DBIx::Class::ResultSet::Pager
 285 /);
 286
 287 WriteAll();
 288
 289 # Re-write META.yml to _exclude_ all forced build-requires (we do not want to ship
 290 # this) We are also not using M::I::AuthorRequires as this will be an extra dep,
 291 # and deps in Makefile.PL still suck
 292 # Also always test the result so we stop shipping borked dependency lists to CPAN
 293
 294 # FIXME test_requires is not yet part of META
 295 my %original_build_requires = ( %$build_requires, %$test_requires );
 296 my @all_build_requires = @{delete Meta->{values}{build_requires}};
 297 my %removed_build_requires;
 298
 299 for (@all_build_requires) {
 300   if ($original_build_requires{$_->[0]}) {
 301     push @{Meta->{values}{build_requires}}, $_;
 302   }
 303   else {
 304     $removed_build_requires{$_->[0]} = $_->[1]
 305       unless $_->[0] eq 'ExtUtils::MakeMaker';
 306   }
 307 }
 308
 309 # Rewrite only in author mode, the original META should not contain anything anyway
 310 # if we executed as non-author
 311 if ($Module::Install::AUTHOR && keys %removed_build_requires) {
 312   print "Regenerating META with author requires excluded\n";
 313   Meta->write;
 314 }
 315
 316 # test that we really took things away (just in case, happened twice somehow)
 317 if (! -f 'META.yml') {
 318   warn "No META.yml generated?! aborting...\n";
 319   exit 1;
 320 }
 321 my $meta = do { local @ARGV = 'META.yml'; local $/; <> };
 322
 323 # this is safe as there is a fatal check earlier to make sure $opt_testdeps does
 324 # not contain any real dependencies
 325 my @illegal_leftovers = grep
 326   { $meta =~ /^ \s+ \Q$_\E \: \s+ /mx }
 327   ( sort keys %$opt_testdeps )
 328 ;
 329
 330 if (@illegal_leftovers) {
 331   die join ("\n",
 332     "\n\nFATAL FAIL! It looks like some author dependencies made it to the META.yml:\n",
 333     map { "\t$_" } @illegal_leftovers
 334   ) . "\n\n";
 335 }