Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN {
   7   # needs to happen early for old EUMM
   8   makemaker_args( NORECURS => 1 );
   9
  10   local @INC = ('lib', @INC);
  11   require DBIx::Class::Optional::Dependencies;
  12 }
  13
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  18 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  19 # for that)
  20 BEGIN {
  21   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  22 }
  23
  24 name         'DBIx-Class';
  25 version_from 'lib/DBIx/Class.pm';
  26 perl_version '5.008001';
  27
  28 ###
  29 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  30 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  31 ###
  32 my $runtime_requires = {
  33
  34   # DBI itself should be capable of installation and execution in pure-perl
  35   # mode. However it has never been tested yet, so consider XS for the time
  36   # being
  37 ###
  38 ### IMPORTANT - do not raise this dependency
  39 ### even though many bugfixes are present in newer versions, the general DBIC
  40 ### rule is to bend over backwards for available DBI versions (given upgrading
  41 ### them is often *not* easy or even possible)
  42 ###
  43   'DBI'                      => '1.57',
  44
  45   # XS (or XS-dependent) libs
  46   'Sub::Name'                => '0.04',
  47
  48   # pure-perl (FatPack-able) libs
  49   'Class::Accessor::Grouped' => '0.10012',
  50   'Class::C3::Componentised' => '1.0009',
  51   'Context::Preserve'        => '0.01',
  52   'Data::Page'               => '2.00',
  53   'Devel::GlobalDestruction' => '0.09',
  54   'Hash::Merge'              => '0.12',
  55   'Moo'                      => '2.002002',
  56   'MRO::Compat'              => '0.12',
  57   'Module::Find'             => '0.07',
  58   'namespace::clean'         => '0.24',
  59   'Scope::Guard'             => '0.03',
  60   'SQL::Abstract'            => '1.81',
  61
  62   # Technically this is not a core dependency - it is only required
  63   # by the MySQL codepath. However this particular version is bundled
  64   # since 5.10.0 and is a pure-perl module anyway - let it slide
  65   'Text::Balanced'           => '2.00',
  66 };
  67
  68 my $build_requires = {
  69 };
  70
  71 my $test_requires = {
  72   'File::Temp'               => '0.22',
  73   'Test::Deep'               => '0.101',
  74   'Test::Exception'          => '0.31',
  75   'Test::Warn'               => '0.21',
  76   'Test::More'               => '0.94',
  77
  78   # This has a bug in the caller() override, ideally we need go get rid
  79   # of it entirely, but that's for another maint
  80   #
  81   # FIXME - this does protect tests, but does *NOT* protect the rest of
  82   # DBIC itself from a faulty caller() override. Something more substantial
  83   # needs to be done in the guts of DBIC::Carp
  84   #
  85   'Sub::Uplevel'             => '0.19',
  86
  87   # needed for testing only, not for operation
  88   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  89   %{ DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_sqlite') },
  90 };
  91
  92 # if the user has some of these env vars set and the deps are not available,
  93 # tests will fail
  94 # Note - these are added as test_requires *directly*, so they get properly
  95 # excluded on META.yml cleansing (even though no dist can be created from this)
  96 # we force these reqs regarless of --with-optdeps, worst case scenario they will
  97 # be specified twice
  98 #
  99 # also note that we *do* set dynamic_config => 0, as these are the only things
 100 # that we determine dynamically, and in all fairness if someone sets these
 101 # envvars *and* is not running a full Makefile/make/maketest cycle - they get
 102 # to keep the pieces
 103 if ( my @optdeps = (
 104   $ENV{DBICTEST_SQLT_DEPLOY} ? 'deploy' : (),
 105   $ENV{DBICTEST_VIA_REPLICATED} ? 'replicated' : (),
 106 )) {
 107   my $extra_deps = DBIx::Class::Optional::Dependencies->req_list_for(\@optdeps);
 108   for (keys %$extra_deps) {
 109     test_requires ($_ => $extra_deps->{$_})
 110   }
 111 }
 112
 113 tests_recursive ('t');
 114 tests_recursive ('xt') if (
 115   $Module::Install::AUTHOR
 116     or
 117   $ENV{DBICTEST_RUN_ALL_TESTS}
 118     or
 119   ( $ENV{TRAVIS}||'' ) eq 'true'
 120     or
 121   ( $ENV{AUTOMATED_TESTING} and ! $ENV{PERL5_CPANM_IS_RUNNING} and ! $ENV{RELEASE_TESTING} )
 122 );
 123
 124 install_script (qw|
 125     script/dbicadmin
 126 |);
 127
 128 # this is so we can order requires alphabetically
 129 # copies are needed for potential author requires injection
 130 my $reqs = {
 131   build_requires => { %$build_requires },
 132   requires => { %$runtime_requires },
 133   test_requires => { %$test_requires },
 134 };
 135
 136 # only do author-includes if not part of a `make` run
 137 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 138   invoke_author_mode()
 139 }
 140 else {
 141   # make sure this Makefile can not be used to make a dist
 142   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 143   postamble <<EOP;
 144 create_distdir: nonauthor_stop_distdir_creation
 145 nonauthor_stop_distdir_creation:
 146 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 147 \t\$(NOECHO) \$(FALSE)
 148 EOP
 149 }
 150
 151 # compose final req list, for alphabetical ordering
 152 my %final_req;
 153 for my $rtype (keys %$reqs) {
 154   for my $mod (keys %{$reqs->{$rtype}} ) {
 155
 156     # sanity check req duplications
 157     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 158       if $final_req{$mod};
 159
 160     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 161   }
 162 }
 163
 164 # actual require
 165 for my $mod (sort keys %final_req) {
 166   my ($rtype, $ver) = @{$final_req{$mod}};
 167   no strict 'refs';
 168   $rtype->($mod, $ver);
 169 }
 170
 171 # author-mode or not - this is where we show a list of missing deps
 172 # IFF we are running interactively
 173 auto_install();
 174
 175 {
 176   # M::I understands unicode in meta but does not write with the right
 177   # layers - fhtagn!!!
 178   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 179   WriteAll();
 180 }
 181
 182 exit 0;
 183
 184
 185 ###
 186 ### Nothing user-serviceable beyond this point
 187 ### (none of this executes on regular install)
 188 ###
 189
 190
 191 # needs to be here to keep 5.8 string eval happy
 192 # (the include of Makefile.PL.inc loop)
 193 my $mm_proto;
 194
 195 sub invoke_author_mode {
 196   # get options here, make $args available to all snippets
 197   require Getopt::Long;
 198   my $getopt = Getopt::Long::Parser->new(
 199     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 200   );
 201   my $args = {
 202     with_optdeps => undef,
 203   };
 204   $getopt->getoptions($args, qw/
 205     with_optdeps|with-optdeps
 206   /);
 207   if (@ARGV) {
 208     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 209   }
 210
 211   # We need the MM facilities to generate the pieces for the final MM run.
 212   # Just instantiate a throaway object here
 213   #
 214   # Also EUMM and MI disagree on what is the format of Meta->name, just
 215   # punt here until a new M::I is shipped (if at all)
 216   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 217   $name =~ s/\-/::/g;
 218   $mm_proto = ExtUtils::MakeMaker->new({
 219     NORECURS => 1,
 220     NAME => $name,
 221   });
 222
 223   # Crutch for DISTBUILDING_IN_HELL
 224   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 225   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 226   # not take into account the CRLF layer present on win32
 227   my $crlf_fixup = sub {
 228     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 229     my $targets = join ', ', map { "q($_)" } @_;
 230     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 231   };
 232
 233   # string-eval, not do(), because we need to provide the
 234   # $mm_proto, $reqs and $*_requires lexicals to the included file
 235   # (some includes *do* modify $reqs above)
 236   for my $inc (sort glob ( 'maint/Makefile.PL.inc/*' ) ) {
 237     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 238     eval "use warnings; use strict; $src" or die sprintf
 239       "Failed execution of %s: %s\n",
 240       $inc,
 241       ($@ || $! || 'Unknown error'),
 242     ;
 243   }
 244 }