Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6
   7 ##
   8 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
   9 ##
  10 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  11 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  12 # for that)
  13 BEGIN {
  14   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  15   makemaker_args( NORECURS => 1 );
  16 }
  17
  18 homepage 'http://www.dbix-class.org/';
  19 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
  20 resources 'license'     => 'http://dev.perl.org/licenses/';
  21 resources 'repository'  => 'https://github.com/dbsrgits/DBIx-Class';
  22 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
  23 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
  24
  25 name     'DBIx-Class';
  26 perl_version '5.008001';
  27 all_from 'lib/DBIx/Class.pm';
  28 Meta->{values}{x_authority} = 'cpan:RIBASUSHI';
  29
  30 tests_recursive (qw|
  31     t
  32 |);
  33
  34 install_script (qw|
  35     script/dbicadmin
  36 |);
  37
  38 ###
  39 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  40 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  41 ###
  42 my $runtime_requires = {
  43   # FIXME - temporary, needs throwing out for something more efficient
  44   'Data::Compare'            => '1.22',
  45
  46   # DBI itself should be capable of installation and execution in pure-perl
  47   # mode. However it has never been tested yet, so consider XS for the time
  48   # being
  49   'DBI'                      => '1.57',
  50
  51   # on older versions first() leaks
  52   # for the time being make it a hard dep - when we get
  53   # rid of Sub::Name will revisit this (possibility is
  54   # to use Devel::HideXS to force the pure-perl version
  55   # or something like that)
  56   'List::Util'               => '1.16',
  57
  58   # XS (or XS-dependent) libs
  59   'Sub::Name'                => '0.04',
  60
  61   # pure-perl (FatPack-able) libs
  62   'Class::Accessor::Grouped' => '0.10010',
  63   'Class::C3::Componentised' => '1.0009',
  64   'Class::Inspector'         => '1.24',
  65   'Config::Any'              => '0.20',
  66   'Context::Preserve'        => '0.01',
  67   'Data::Dumper::Concise'    => '2.020',
  68   'Data::Page'               => '2.00',
  69   'Devel::GlobalDestruction' => '0.09',
  70   'Hash::Merge'              => '0.12',
  71   'Moo'                      => '1.000006',
  72   'MRO::Compat'              => '0.12',
  73   'Module::Find'             => '0.07',
  74   'namespace::clean'         => '0.24',
  75   'Path::Class'              => '0.18',
  76   'Scope::Guard'             => '0.03',
  77   'SQL::Abstract'            => '1.73',
  78   'Try::Tiny'                => '0.07',
  79
  80   # Technically this is not a core dependency - it is only required
  81   # by the MySQL codepath. However this particular version is bundled
  82   # since 5.10.0 and is a pure-perl module anyway - let it slide
  83   'Text::Balanced'           => '2.00',
  84 };
  85
  86 my $build_requires = {
  87   # needed for testing only, not for operation
  88   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  89   'DBD::SQLite'              => '1.29',
  90 };
  91
  92 my $test_requires = {
  93   'File::Temp'               => '0.22',
  94   'Test::Deep'               => '0.101',
  95   'Test::Exception'          => '0.31',
  96   'Test::Warn'               => '0.21',
  97   'Test::More'               => '0.94',
  98   # not sure if this is necessary at all, ask schwern some day
  99   'Test::Builder'            => '0.94',
 100
 101   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
 102   # remove and do a manual glob-collection if n::c is no longer a dep
 103   'Package::Stash'           => '0.28',
 104 };
 105
 106 # if the user has this env var set and no SQLT installed, tests will fail
 107 # same rationale for direct test_requires as the strictures stuff above
 108 # (even though no dist will be created from this)
 109 # we force this req regarless of author_deps, worst case scenario it will
 110 # be specified twice
 111 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 112   local @INC = ('lib', @INC);
 113   require DBIx::Class::Optional::Dependencies;
 114   my $dep_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 115   for (keys %$dep_req) {
 116     test_requires ($_ => $dep_req->{$_})
 117   }
 118 }
 119
 120 # this is so we can order requires alphabetically
 121 # copies are needed for potential author requires injection
 122 my $reqs = {
 123   build_requires => { %$build_requires },
 124   requires => { %$runtime_requires },
 125   test_requires => { %$test_requires },
 126 };
 127
 128 # only do author-includes if not part of a `make` run
 129 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 130   # get options here, make $args available to all snippets
 131   require Getopt::Long;
 132   my $getopt = Getopt::Long::Parser->new(
 133     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 134   );
 135   my $args = {
 136     skip_author_deps => undef,
 137   };
 138   $getopt->getoptions($args, qw/
 139     skip_author_deps|skip-author-deps
 140   /);
 141   if (@ARGV) {
 142     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 143   }
 144
 145   # We need the MM facilities to generate the pieces for the final MM run.
 146   # Just instantiate a throaway object here
 147   my $mm_proto = ExtUtils::MakeMaker->new({
 148     NORECURS => 1,
 149     NAME => Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?',
 150   });
 151
 152   # Crutch for DISTBUILDING_IN_HELL
 153   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 154   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 155   # not take into account the CRLF layer present on win32
 156   my $crlf_fixup = sub {
 157     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 158     my $targets = join ', ', map { "q($_)" } @_;
 159     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 160   };
 161
 162   # we are in the process of (re)writing the makefile - some things we
 163   # call below very well may fail
 164   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 165
 166   require File::Spec;
 167   # string-eval, not do(), because we need to provide the
 168   # $mm_proto, $reqs and $*_requires lexicals to the included file
 169   # (some includes *do* modify $reqs above)
 170   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 171     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 172     eval "use warnings; use strict; $src" or die sprintf
 173       "Failed execution of %s: %s\n",
 174       $inc,
 175       ($@ || $! || 'Unknown error'),
 176     ;
 177   }
 178 }
 179 else {
 180   # make sure this Makefile can not be used to make a dist
 181   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 182   postamble <<EOP;
 183 create_distdir: nonauthor_stop_distdir_creation
 184 nonauthor_stop_distdir_creation:
 185 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 186 \t\$(NOECHO) \$(FALSE)
 187 EOP
 188 }
 189
 190 # compose final req list, for alphabetical ordering
 191 my %final_req;
 192 for my $rtype (keys %$reqs) {
 193   for my $mod (keys %{$reqs->{$rtype}} ) {
 194
 195     # sanity check req duplications
 196     if ($final_req{$mod}) {
 197       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 198     }
 199
 200     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 201   }
 202 }
 203
 204 # actual require
 205 for my $mod (sort keys %final_req) {
 206   my ($rtype, $ver) = @{$final_req{$mod}};
 207   no strict 'refs';
 208   $rtype->($mod, $ver);
 209 }
 210
 211 # author-mode or not - this is where we show a list of missing deps
 212 # IFF we are running interactively
 213 auto_install();
 214
 215 WriteAll();