Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN {
   7   # needs to happen early for old EUMM
   8   makemaker_args( NORECURS => 1 );
   9
  10   local @INC = ('lib', @INC);
  11   require DBIx::Class::Optional::Dependencies;
  12 }
  13
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  18 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  19 # for that)
  20 BEGIN {
  21   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  22 }
  23
  24 name         'DBIx-Class';
  25 version_from 'lib/DBIx/Class.pm';
  26 perl_version '5.008001';
  27
  28 ###
  29 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  30 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  31 ###
  32 my $runtime_requires = {
  33
  34   # DBI itself should be capable of installation and execution in pure-perl
  35   # mode. However it has never been tested yet, so consider XS for the time
  36   # being
  37 ###
  38 ### IMPORTANT - do not raise this dependency
  39 ### even though many bugfixes are present in newer versions, the general DBIC
  40 ### rule is to bend over backwards for available DBI versions (given upgrading
  41 ### them is often *not* easy or even possible)
  42 ###
  43   'DBI'                      => '1.57',
  44
  45   # on older versions first() leaks
  46   # for the time being make it a hard dep - when we get
  47   # rid of Sub::Name will revisit this (possibility is
  48   # to use Devel::HideXS to force the pure-perl version
  49   # or something like that)
  50   'List::Util'               => '1.16',
  51
  52   # XS (or XS-dependent) libs
  53   'Sub::Name'                => '0.04',
  54
  55   # pure-perl (FatPack-able) libs
  56   'Class::Accessor::Grouped' => '0.10012',
  57   'Class::C3::Componentised' => '1.0009',
  58   'Class::Inspector'         => '1.24',
  59   'Config::Any'              => '0.20',
  60   'Context::Preserve'        => '0.01',
  61   'Data::Dumper::Concise'    => '2.020',
  62   'Data::Page'               => '2.00',
  63   'Devel::GlobalDestruction' => '0.09',
  64   'Hash::Merge'              => '0.12',
  65   'Moo'                      => '2.000',
  66   'MRO::Compat'              => '0.12',
  67   'Module::Find'             => '0.07',
  68   'namespace::clean'         => '0.24',
  69   'Path::Class'              => '0.18',
  70   'Scope::Guard'             => '0.03',
  71   'SQL::Abstract'            => '1.81',
  72   'Try::Tiny'                => '0.07',
  73
  74   # Technically this is not a core dependency - it is only required
  75   # by the MySQL codepath. However this particular version is bundled
  76   # since 5.10.0 and is a pure-perl module anyway - let it slide
  77   'Text::Balanced'           => '2.00',
  78 };
  79
  80 my $build_requires = {
  81 };
  82
  83 my $test_requires = {
  84   'File::Temp'               => '0.22',
  85   'Test::Deep'               => '0.101',
  86   'Test::Exception'          => '0.31',
  87   'Test::Warn'               => '0.21',
  88   'Test::More'               => '0.94',
  89
  90   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  91   # remove and do a manual glob-collection if n::c is no longer a dep
  92   'Package::Stash'           => '0.28',
  93
  94   # needed for testing only, not for operation
  95   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  96   %{ DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_sqlite') },
  97 };
  98
  99 # if the user has some of these env vars set and the deps are not available,
 100 # tests will fail
 101 # Note - these are added as test_requires *directly*, so they get properly
 102 # excluded on META.yml cleansing (even though no dist can be created from this)
 103 # we force these reqs regarless of author_deps, worst case scenario they will
 104 # be specified twice
 105 #
 106 # also note that we *do* set dynamic_config => 0, as these are the only things
 107 # that we determine dynamically, and in all fairness if someone sets these
 108 # envvars *and* is not running a full Makefile/make/maketest cycle - they get
 109 # to keep the pieces
 110 if ( my @optdeps = (
 111   $ENV{DBICTEST_SQLT_DEPLOY} ? 'deploy' : (),
 112   $ENV{DBICTEST_VIA_REPLICATED} ? 'replicated' : (),
 113 )) {
 114   my $extra_deps = DBIx::Class::Optional::Dependencies->req_list_for(\@optdeps);
 115   for (keys %$extra_deps) {
 116     test_requires ($_ => $extra_deps->{$_})
 117   }
 118 }
 119
 120 tests_recursive ('t');
 121 tests_recursive ('xt') if (
 122   $Module::Install::AUTHOR
 123     or
 124   $ENV{DBICTEST_RUN_ALL_TESTS}
 125     or
 126   ( $ENV{TRAVIS}||'' ) eq 'true'
 127     or
 128   ( $ENV{AUTOMATED_TESTING} and ! $ENV{PERL5_CPANM_IS_RUNNING} and ! $ENV{RELEASE_TESTING} )
 129 );
 130
 131 install_script (qw|
 132     script/dbicadmin
 133 |);
 134
 135 # this is so we can order requires alphabetically
 136 # copies are needed for potential author requires injection
 137 my $reqs = {
 138   build_requires => { %$build_requires },
 139   requires => { %$runtime_requires },
 140   test_requires => { %$test_requires },
 141 };
 142
 143 # only do author-includes if not part of a `make` run
 144 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 145   invoke_author_mode()
 146 }
 147 else {
 148   # make sure this Makefile can not be used to make a dist
 149   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 150   postamble <<EOP;
 151 create_distdir: nonauthor_stop_distdir_creation
 152 nonauthor_stop_distdir_creation:
 153 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 154 \t\$(NOECHO) \$(FALSE)
 155 EOP
 156 }
 157
 158 # compose final req list, for alphabetical ordering
 159 my %final_req;
 160 for my $rtype (keys %$reqs) {
 161   for my $mod (keys %{$reqs->{$rtype}} ) {
 162
 163     # sanity check req duplications
 164     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 165       if $final_req{$mod};
 166
 167     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 168   }
 169 }
 170
 171 # actual require
 172 for my $mod (sort keys %final_req) {
 173   my ($rtype, $ver) = @{$final_req{$mod}};
 174   no strict 'refs';
 175   $rtype->($mod, $ver);
 176 }
 177
 178 # author-mode or not - this is where we show a list of missing deps
 179 # IFF we are running interactively
 180 auto_install();
 181
 182 {
 183   # M::I understands unicode in meta but does not write with the right
 184   # layers - fhtagn!!!
 185   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 186   WriteAll();
 187 }
 188
 189 exit 0;
 190
 191
 192 ###
 193 ### Nothing user-serviceable beyond this point
 194 ### (none of this executes on regular install)
 195 ###
 196
 197
 198 # needs to be here to keep 5.8 string eval happy
 199 # (the include of Makefile.PL.inc loop)
 200 my $mm_proto;
 201
 202 sub invoke_author_mode {
 203   # get options here, make $args available to all snippets
 204   require Getopt::Long;
 205   my $getopt = Getopt::Long::Parser->new(
 206     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 207   );
 208   my $args = {
 209     skip_author_deps => undef,
 210   };
 211   $getopt->getoptions($args, qw/
 212     skip_author_deps|skip-author-deps
 213   /);
 214   if (@ARGV) {
 215     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 216   }
 217
 218   # We need the MM facilities to generate the pieces for the final MM run.
 219   # Just instantiate a throaway object here
 220   #
 221   # Also EUMM and MI disagree on what is the format of Meta->name, just
 222   # punt here until a new M::I is shipped (if at all)
 223   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 224   $name =~ s/\-/::/g;
 225   $mm_proto = ExtUtils::MakeMaker->new({
 226     NORECURS => 1,
 227     NAME => $name,
 228   });
 229
 230   # Crutch for DISTBUILDING_IN_HELL
 231   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 232   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 233   # not take into account the CRLF layer present on win32
 234   my $crlf_fixup = sub {
 235     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 236     my $targets = join ', ', map { "q($_)" } @_;
 237     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 238   };
 239
 240   # we are in the process of (re)writing the makefile - some things we
 241   # call below very well may fail
 242   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 243
 244   require File::Spec;
 245   # string-eval, not do(), because we need to provide the
 246   # $mm_proto, $reqs and $*_requires lexicals to the included file
 247   # (some includes *do* modify $reqs above)
 248   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 249     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 250     eval "use warnings; use strict; $src" or die sprintf
 251       "Failed execution of %s: %s\n",
 252       $inc,
 253       ($@ || $! || 'Unknown error'),
 254     ;
 255   }
 256 }