Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN { makemaker_args( NORECURS => 1 ) } # needs to happen early for old EUMM
   7
   8 ##
   9 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  10 ##
  11 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  12 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  13 # for that)
  14 BEGIN {
  15   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  16 }
  17
  18 ##
  19 ## TEMPORARY (and non-portable)
  20 ## Get trial SQLA
  21 ##
  22 BEGIN {
  23   my $target_libdir = 'lib/DBIx/Class/_TempExtlib';
  24
  25   if ( ($Module::Install::AUTHOR or $ENV{TRAVIS}) and ! $ENV{MAKELEVEL} ) {
  26
  27     `rm -rf $target_libdir`;
  28     `mkdir $target_libdir`;
  29     for (
  30       [ 'SQL-Abstract' => 'master' ],
  31     ) {
  32       my $tdir = "/tmp/dbictemplib/$_->[0]/";
  33
  34       `rm -rf $tdir`;
  35
  36       `GIT_SSH=maint/careless_ssh.bash git clone --bare --quiet --branch=$_->[1] --depth=1 git://git.shadowcat.co.uk/dbsrgits/$_->[0] $tdir`;
  37       printf "\nIncluding %s git rev %s\n",
  38         $_->[0],
  39         scalar `GIT_DIR=$tdir git rev-parse $_->[1]`,
  40       ;
  41       `git archive --format=tar --remote=file://$tdir $_->[1] lib/ | tar --strip-components=1 -xC $target_libdir`;
  42
  43       #`rm -rf $tdir`;
  44     }
  45
  46     unshift @INC, $target_libdir;
  47
  48     no_index directory => $target_libdir;
  49   }
  50 }
  51
  52 name         'DBIx-Class';
  53 version_from 'lib/DBIx/Class.pm';
  54 perl_version '5.008001';
  55
  56 ###
  57 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  58 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  59 ###
  60 my $runtime_requires = {
  61   # FIXME - temporary, needs throwing out for something more efficient
  62   'Data::Compare'            => '1.22',
  63
  64   # DBI itself should be capable of installation and execution in pure-perl
  65   # mode. However it has never been tested yet, so consider XS for the time
  66   # being
  67 ###
  68 ### IMPORTANT - do not raise this dependency
  69 ### even though many bugfixes are present in newer versions, the general DBIC
  70 ### rule is to bend over backwards for available DBI versions (given upgrading
  71 ### them is often *not* easy or even possible)
  72 ###
  73   'DBI'                      => '1.57',
  74
  75   # on older versions first() leaks
  76   # for the time being make it a hard dep - when we get
  77   # rid of Sub::Name will revisit this (possibility is
  78   # to use Devel::HideXS to force the pure-perl version
  79   # or something like that)
  80   'List::Util'               => '1.16',
  81
  82   # XS (or XS-dependent) libs
  83   'Sub::Name'                => '0.04',
  84
  85   # pure-perl (FatPack-able) libs
  86   'Class::Accessor::Grouped' => '0.10010',
  87   'Class::C3::Componentised' => '1.0009',
  88   'Class::Inspector'         => '1.24',
  89   'Config::Any'              => '0.20',
  90   'Context::Preserve'        => '0.01',
  91   'Data::Dumper::Concise'    => '2.020',
  92   'Data::Page'               => '2.00',
  93   'Devel::GlobalDestruction' => '0.09',
  94   'Hash::Merge'              => '0.12',
  95   'Moo'                      => '1.004005',
  96   'MRO::Compat'              => '0.12',
  97   'Module::Find'             => '0.07',
  98   'namespace::clean'         => '0.24',
  99   'Path::Class'              => '0.18',
 100   'Scope::Guard'             => '0.03',
 101   'SQL::Abstract'            => '1.78',
 102   'Try::Tiny'                => '0.07',
 103
 104   # Technically this is not a core dependency - it is only required
 105   # by the MySQL codepath. However this particular version is bundled
 106   # since 5.10.0 and is a pure-perl module anyway - let it slide
 107   'Text::Balanced'           => '2.00',
 108 };
 109
 110 my $build_requires = {
 111 };
 112
 113 my $test_requires = {
 114   'File::Temp'               => '0.22',
 115   'Test::Deep'               => '0.101',
 116   'Test::Exception'          => '0.31',
 117   'Test::Warn'               => '0.21',
 118   'Test::More'               => '0.94',
 119
 120   # needed for testing only, not for operation
 121   # we will move away from this dep eventually, perhaps to DBD::CSV or something
 122 ###
 123 ### IMPORTANT - do not raise this dependency
 124 ### even though many bugfixes are present in newer versions, the general DBIC
 125 ### rule is to bend over backwards for available DBDs (given upgrading them is
 126 ### often *not* easy or even possible)
 127 ###
 128   'DBD::SQLite'              => '1.29',
 129
 130   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
 131   # remove and do a manual glob-collection if n::c is no longer a dep
 132   'Package::Stash'           => '0.28',
 133 };
 134
 135 # if the user has this env var set and no SQLT installed, tests will fail
 136 # Note - this is added as test_requires *directly*, so it gets properly
 137 # excluded on META.yml cleansing (even though no dist can be created from this)
 138 # we force this req regarless of author_deps, worst case scenario it will
 139 # be specified twice
 140 #
 141 # also note that we *do* set dynamic_config => 0, as this is the only thing
 142 # that we determine dynamically, and in all fairness if someone sets the
 143 # envvar *and* is not running a full Makefile/make/maketest cycle - they get
 144 # to keep the pieces
 145 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 146   local @INC = ('lib', @INC);
 147   require DBIx::Class::Optional::Dependencies;
 148   my $dep_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 149   for (keys %$dep_req) {
 150     test_requires ($_ => $dep_req->{$_})
 151   }
 152 }
 153
 154 tests_recursive (qw|
 155     t
 156 |);
 157
 158 install_script (qw|
 159     script/dbicadmin
 160 |);
 161
 162 # this is so we can order requires alphabetically
 163 # copies are needed for potential author requires injection
 164 my $reqs = {
 165   build_requires => { %$build_requires },
 166   requires => { %$runtime_requires },
 167   test_requires => { %$test_requires },
 168 };
 169
 170 # only do author-includes if not part of a `make` run
 171 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 172   invoke_author_mode()
 173 }
 174 else {
 175   # make sure this Makefile can not be used to make a dist
 176   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 177   postamble <<EOP;
 178 create_distdir: nonauthor_stop_distdir_creation
 179 nonauthor_stop_distdir_creation:
 180 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 181 \t\$(NOECHO) \$(FALSE)
 182 EOP
 183 }
 184
 185 # compose final req list, for alphabetical ordering
 186 my %final_req;
 187 for my $rtype (keys %$reqs) {
 188   for my $mod (keys %{$reqs->{$rtype}} ) {
 189
 190     # sanity check req duplications
 191     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 192       if $final_req{$mod};
 193
 194     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 195   }
 196 }
 197
 198 # actual require
 199 for my $mod (sort keys %final_req) {
 200   my ($rtype, $ver) = @{$final_req{$mod}};
 201   no strict 'refs';
 202   $rtype->($mod, $ver);
 203 }
 204
 205 # author-mode or not - this is where we show a list of missing deps
 206 # IFF we are running interactively
 207 auto_install();
 208
 209 {
 210   # M::I understands unicode in meta but does not write with the right
 211   # layers - fhtagn!!!
 212   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 213   WriteAll();
 214 }
 215
 216 exit 0;
 217
 218
 219 ###
 220 ### Nothing user-serviceable beyond this point
 221 ### (none of this executes on regular install)
 222 ###
 223
 224
 225 # needs to be here to keep 5.8 string eval happy
 226 # (the include of Makefile.PL.inc loop)
 227 my $mm_proto;
 228
 229 sub invoke_author_mode {
 230   # get options here, make $args available to all snippets
 231   require Getopt::Long;
 232   my $getopt = Getopt::Long::Parser->new(
 233     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 234   );
 235   my $args = {
 236     skip_author_deps => undef,
 237   };
 238   $getopt->getoptions($args, qw/
 239     skip_author_deps|skip-author-deps
 240   /);
 241   if (@ARGV) {
 242     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 243   }
 244
 245   # We need the MM facilities to generate the pieces for the final MM run.
 246   # Just instantiate a throaway object here
 247   #
 248   # Also EUMM and MI disagree on what is the format of Meta->name, just
 249   # punt here until a new M::I is shipped (if at all)
 250   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 251   $name =~ s/\-/::/g;
 252   $mm_proto = ExtUtils::MakeMaker->new({
 253     NORECURS => 1,
 254     NAME => $name,
 255   });
 256
 257   # Crutch for DISTBUILDING_IN_HELL
 258   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 259   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 260   # not take into account the CRLF layer present on win32
 261   my $crlf_fixup = sub {
 262     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 263     my $targets = join ', ', map { "q($_)" } @_;
 264     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 265   };
 266
 267   # we are in the process of (re)writing the makefile - some things we
 268   # call below very well may fail
 269   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 270
 271   require File::Spec;
 272   # string-eval, not do(), because we need to provide the
 273   # $mm_proto, $reqs and $*_requires lexicals to the included file
 274   # (some includes *do* modify $reqs above)
 275   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 276     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 277     eval "use warnings; use strict; $src" or die sprintf
 278       "Failed execution of %s: %s\n",
 279       $inc,
 280       ($@ || $! || 'Unknown error'),
 281     ;
 282   }
 283 }