Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 use 5.008001;
   6
   7 use FindBin;
   8 use lib "$FindBin::Bin/lib";
   9 use DBIx::Class::Optional::Dependencies;
  10
  11 # adjust ENV for $AUTHOR system() calls
  12 use Config;
  13 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  14
  15 use Getopt::Long ();
  16
  17 my $getopt = Getopt::Long::Parser->new(
  18   config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
  19 );
  20 my $args = {
  21   skip_author_deps => undef,
  22 };
  23 $getopt->getoptions($args, 'skip_author_deps');
  24 if (@ARGV) {
  25   warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
  26 }
  27
  28 # get cpanX --installdeps . to behave in a checkout (most users do not need
  29 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  30 # for that)
  31 ##
  32 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  33 ##
  34 $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  35
  36 ###
  37 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  38 ### All of them should go to DBIx::Class::Optional::Dependencies
  39 ###
  40
  41 name     'DBIx-Class';
  42 perl_version '5.008001';
  43 all_from 'lib/DBIx/Class.pm';
  44
  45 my $build_requires = {
  46   'DBD::SQLite'              => '1.29',
  47 };
  48
  49 my $test_requires = {
  50   'File::Temp'               => '0.22',
  51   'Test::Builder'            => '0.33',
  52   'Test::Exception'          => '0.31',
  53   'Test::More'               => '0.92',
  54   'Test::Warn'               => '0.21',
  55 };
  56
  57 my $runtime_requires = {
  58   'Carp::Clan'               => '6.0',
  59   'Class::Accessor::Grouped' => '0.09008',
  60   'Class::C3::Componentised' => '1.0005',
  61   'Class::Inspector'         => '1.24',
  62   'Data::Page'               => '2.00',
  63   'DBI'                      => '1.609',
  64   'File::Path'               => '2.07',
  65   'MRO::Compat'              => '0.09',
  66   'Module::Find'             => '0.06',
  67   'Path::Class'              => '0.18',
  68   'SQL::Abstract'            => '1.71',
  69   'Sub::Name'                => '0.04',
  70   'Variable::Magic'          => '0.44',
  71   'Data::Dumper::Concise'    => '1.000',
  72   'Scope::Guard'             => '0.03',
  73   'Context::Preserve'        => '0.01',
  74   'Try::Tiny'                => '0.04',
  75   'namespace::clean'         => '0.14',
  76   'Math::BigInt'             => '1.89',
  77   'Math::Base36'             => '0.07',
  78   'Config::Any'              => '0.20',
  79 };
  80
  81 # this is so we can order requires alphabetically
  82 # copies are needed for author requires injection
  83 my $reqs = {
  84   build_requires => { %$build_requires },
  85   requires => { %$runtime_requires },
  86   test_requires => { %$test_requires },
  87 };
  88
  89 my $opt_testdeps = {
  90   map { %$_ } (values %{DBIx::Class::Optional::Dependencies->req_group_list})
  91 };
  92
  93 # require extra modules for testing if we're in a checkout
  94 my $optdep_msg;
  95 if ($Module::Install::AUTHOR) {
  96   if ($args->{skip_author_deps}) {
  97     $optdep_msg = <<'EOW';
  98
  99 ******************************************************************************
 100 ******************************************************************************
 101 ***                                                                        ***
 102 *** IGNORING AUTHOR MODE: no optional test dependencies will be forced.    ***
 103 ***                                                                        ***
 104 *** If you are using this checkout with the intention of submitting a DBIC ***
 105 *** patch, you are *STRONGLY ENCOURAGED* to install all dependencies, so   ***
 106 *** that every possible unit-test will run.                                ***
 107 ***                                                                        ***
 108 ******************************************************************************
 109 ******************************************************************************
 110
 111 EOW
 112   }
 113   else {
 114     $optdep_msg = <<'EOW';
 115
 116 ******************************************************************************
 117 ******************************************************************************
 118 ***                                                                        ***
 119 *** AUTHOR MODE: all optional test dependencies converted to hard requires ***
 120 ***       ( to disable re-run Makefile.PL with --skip_author_deps )        ***
 121 ***                                                                        ***
 122 ******************************************************************************
 123 ******************************************************************************
 124
 125 EOW
 126
 127     $reqs->{test_requires} = {
 128       %{$reqs->{test_requires}},
 129       %$opt_testdeps
 130     };
 131   }
 132 }
 133
 134 # compose final req list, for alphabetical ordering
 135 my %final_req;
 136 for my $rtype (keys %$reqs) {
 137   for my $mod (keys %{$reqs->{$rtype}} ) {
 138
 139     # sanity check req duplications
 140     if ($final_req{$mod}) {
 141       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 142     }
 143
 144     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 145   }
 146 }
 147
 148 # actual require
 149 for my $mod (sort keys %final_req) {
 150   my ($rtype, $ver) = @{$final_req{$mod}};
 151   no strict 'refs';
 152   $rtype->($mod, $ver);
 153 }
 154
 155 # output twice since the deplist is > 70 lines
 156 warn $optdep_msg if $Module::Install::AUTHOR;
 157 auto_install();
 158 warn $optdep_msg if $Module::Install::AUTHOR;
 159
 160 # re-create various autogenerated documentation bits
 161 if ($Module::Install::AUTHOR) {
 162
 163   print "Regenerating README\n";
 164   system('pod2text lib/DBIx/Class.pm > README');
 165
 166   if (-f 'MANIFEST') {
 167     print "Removing MANIFEST\n";
 168     unlink 'MANIFEST';
 169   }
 170
 171   print "Regenerating Optional/Dependencies.pod\n";
 172   require DBIx::Class::Optional::Dependencies;
 173   DBIx::Class::Optional::Dependencies->_gen_pod (Meta->version);
 174
 175   # FIXME Disabled due to unsolved issues, ask theorbtwo
 176   #  require Module::Install::Pod::Inherit;
 177   #  PodInherit();
 178 }
 179
 180
 181 tests_recursive (qw|
 182     t
 183 |);
 184
 185 # temporary(?) until I get around to fix M::I wrt xt/
 186 # needs Module::Install::AuthorTests
 187 eval {
 188   recursive_author_tests (qw/xt/);
 189   1;
 190 } || do {
 191   if ($Module::Install::AUTHOR && ! $args->{skip_author_deps}) {
 192     my $err = $@;
 193     eval { require Module::Install::AuthorTests }
 194       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode (or supply --skip_author_deps):\n\n$@\n";
 195     die $@;
 196   }
 197 };
 198
 199
 200 install_script (qw|
 201     script/dbicadmin
 202 |);
 203
 204
 205 ### Mangle makefile - read the comments for more info
 206 #
 207 postamble <<"EOP";
 208
 209 # This will add an extra dep-spec for the distdir target,
 210 # which `make` will fold together in a first-come first-serve
 211 # fashion. What we do here is essentially adding extra
 212 # commands to execute once the distdir is assembled (via
 213 # create_distdir), but before control is returned to a higher
 214 # calling rule.
 215 distdir : dbicadmin_pod_inject
 216
 217 # The pod self-injection code is in fact a hidden option in
 218 # dbicadmin itself
 219 dbicadmin_pod_inject :
 220 \tcd \$(DISTVNAME) && \$(ABSPERL) -Ilib script/dbicadmin --selfinject-pod
 221
 222 # Regenerate manifest before running create_distdir.
 223 create_distdir : manifest
 224
 225 EOP
 226
 227 homepage 'http://www.dbix-class.org/';
 228 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
 229 resources 'license'     => 'http://dev.perl.org/licenses/';
 230 resources 'repository'  => 'git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git';
 231 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
 232 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
 233
 234 # Deprecated/internal modules need no exposure
 235 no_index directory => $_ for (qw|
 236   lib/DBIx/Class/Admin
 237   lib/DBIx/Class/PK/Auto
 238   lib/DBIx/Class/CDBICompat
 239 |);
 240 no_index package => $_ for (qw/
 241   DBIx::Class::Storage::DBIHacks
 242 /);
 243
 244 WriteAll();
 245
 246 # Re-write META.yml to _exclude_ all forced build-requires (we do not want to ship
 247 # this) We are also not using M::I::AuthorRequires as this will be an extra dep,
 248 # and deps in Makefile.PL still suck
 249 # Also always test the result so we stop shipping borked dependency lists to CPAN
 250
 251 # FIXME test_requires is not yet part of META
 252 my %original_build_requires = ( %$build_requires, %$test_requires );
 253 my @all_build_requires = @{delete Meta->{values}{build_requires}};
 254 my %removed_build_requires;
 255
 256 for (@all_build_requires) {
 257   if ($original_build_requires{$_->[0]}) {
 258     push @{Meta->{values}{build_requires}}, $_;
 259   }
 260   else {
 261     $removed_build_requires{$_->[0]} = $_->[1]
 262       unless $_->[0] eq 'ExtUtils::MakeMaker';
 263   }
 264 }
 265
 266 # Rewrite only in author mode, the original META should not contain anything anyway
 267 # if we executed as non-author
 268 if ($Module::Install::AUTHOR && keys %removed_build_requires) {
 269   print "Regenerating META with author requires excluded\n";
 270   Meta->write;
 271 }
 272
 273 # test that we really took things away (just in case, happened twice somehow)
 274 exit 0 unless -f 'META.yml';  # in case bizarro comes around
 275 my $meta = do { local @ARGV = 'META.yml'; local $/; <> };
 276
 277 # this is safe as there is a fatal check earlier to make sure $opt_testdeps does
 278 # not contain any real dependencies
 279 my @illegal_leftovers = grep
 280   { $meta =~ /^ \s+ \Q$_\E \: \s+ /mx }
 281   ( sort keys %$opt_testdeps )
 282 ;
 283
 284 if (@illegal_leftovers) {
 285   die join ("\n",
 286     "\n\nFATAL FAIL! It looks like some author dependencies made it to the META.yml:\n",
 287     map { "\t$_" } @illegal_leftovers
 288   ) . "\n\n";
 289 }