Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN { makemaker_args( NORECURS => 1 ) } # needs to happen early for old EUMM
   7
   8 ##
   9 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  10 ##
  11 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  12 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  13 # for that)
  14 BEGIN {
  15   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  16 }
  17
  18 name         'DBIx-Class';
  19 version_from 'lib/DBIx/Class.pm';
  20 perl_version '5.008001';
  21
  22 ###
  23 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  24 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  25 ###
  26 my $runtime_requires = {
  27
  28   # DBI itself should be capable of installation and execution in pure-perl
  29   # mode. However it has never been tested yet, so consider XS for the time
  30   # being
  31 ###
  32 ### IMPORTANT - do not raise this dependency
  33 ### even though many bugfixes are present in newer versions, the general DBIC
  34 ### rule is to bend over backwards for available DBI versions (given upgrading
  35 ### them is often *not* easy or even possible)
  36 ###
  37   'DBI'                      => '1.57',
  38
  39   # on older versions first() leaks
  40   # for the time being make it a hard dep - when we get
  41   # rid of Sub::Name will revisit this (possibility is
  42   # to use Devel::HideXS to force the pure-perl version
  43   # or something like that)
  44   'List::Util'               => '1.16',
  45
  46   # XS (or XS-dependent) libs
  47   'Sub::Name'                => '0.04',
  48
  49   # pure-perl (FatPack-able) libs
  50   'Class::Accessor::Grouped' => '0.10010',
  51   'Class::C3::Componentised' => '1.0009',
  52   'Class::Inspector'         => '1.24',
  53   'Config::Any'              => '0.20',
  54   'Context::Preserve'        => '0.01',
  55   'Data::Dumper::Concise'    => '2.020',
  56   'Data::Page'               => '2.00',
  57   'Devel::GlobalDestruction' => '0.09',
  58   'Hash::Merge'              => '0.12',
  59   'Moo'                      => '1.004005',
  60   'MRO::Compat'              => '0.12',
  61   'Module::Find'             => '0.07',
  62   'namespace::clean'         => '0.24',
  63   'Path::Class'              => '0.18',
  64   'Scope::Guard'             => '0.03',
  65   'SQL::Abstract'            => '1.79',
  66   'Try::Tiny'                => '0.07',
  67
  68   # Technically this is not a core dependency - it is only required
  69   # by the MySQL codepath. However this particular version is bundled
  70   # since 5.10.0 and is a pure-perl module anyway - let it slide
  71   'Text::Balanced'           => '2.00',
  72 };
  73
  74 my $build_requires = {
  75 };
  76
  77 my $test_requires = {
  78   'File::Temp'               => '0.22',
  79   'Test::Deep'               => '0.101',
  80   'Test::Exception'          => '0.31',
  81   'Test::Warn'               => '0.21',
  82   'Test::More'               => '0.94',
  83
  84   # needed for testing only, not for operation
  85   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  86 ###
  87 ### IMPORTANT - do not raise this dependency
  88 ### even though many bugfixes are present in newer versions, the general DBIC
  89 ### rule is to bend over backwards for available DBDs (given upgrading them is
  90 ### often *not* easy or even possible)
  91 ###
  92   'DBD::SQLite'              => '1.29',
  93
  94   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  95   # remove and do a manual glob-collection if n::c is no longer a dep
  96   'Package::Stash'           => '0.28',
  97 };
  98
  99 # if the user has this env var set and no SQLT installed, tests will fail
 100 # Note - this is added as test_requires *directly*, so it gets properly
 101 # excluded on META.yml cleansing (even though no dist can be created from this)
 102 # we force this req regarless of author_deps, worst case scenario it will
 103 # be specified twice
 104 #
 105 # also note that we *do* set dynamic_config => 0, as this is the only thing
 106 # that we determine dynamically, and in all fairness if someone sets the
 107 # envvar *and* is not running a full Makefile/make/maketest cycle - they get
 108 # to keep the pieces
 109 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 110   local @INC = ('lib', @INC);
 111   require DBIx::Class::Optional::Dependencies;
 112   my $dep_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 113   for (keys %$dep_req) {
 114     test_requires ($_ => $dep_req->{$_})
 115   }
 116 }
 117
 118 tests_recursive (qw|
 119     t
 120 |);
 121
 122 install_script (qw|
 123     script/dbicadmin
 124 |);
 125
 126 # this is so we can order requires alphabetically
 127 # copies are needed for potential author requires injection
 128 my $reqs = {
 129   build_requires => { %$build_requires },
 130   requires => { %$runtime_requires },
 131   test_requires => { %$test_requires },
 132 };
 133
 134 # only do author-includes if not part of a `make` run
 135 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 136   invoke_author_mode()
 137 }
 138 else {
 139   # make sure this Makefile can not be used to make a dist
 140   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 141   postamble <<EOP;
 142 create_distdir: nonauthor_stop_distdir_creation
 143 nonauthor_stop_distdir_creation:
 144 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 145 \t\$(NOECHO) \$(FALSE)
 146 EOP
 147 }
 148
 149 # compose final req list, for alphabetical ordering
 150 my %final_req;
 151 for my $rtype (keys %$reqs) {
 152   for my $mod (keys %{$reqs->{$rtype}} ) {
 153
 154     # sanity check req duplications
 155     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 156       if $final_req{$mod};
 157
 158     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 159   }
 160 }
 161
 162 # actual require
 163 for my $mod (sort keys %final_req) {
 164   my ($rtype, $ver) = @{$final_req{$mod}};
 165   no strict 'refs';
 166   $rtype->($mod, $ver);
 167 }
 168
 169 # author-mode or not - this is where we show a list of missing deps
 170 # IFF we are running interactively
 171 auto_install();
 172
 173 {
 174   # M::I understands unicode in meta but does not write with the right
 175   # layers - fhtagn!!!
 176   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 177   WriteAll();
 178 }
 179
 180 exit 0;
 181
 182
 183 ###
 184 ### Nothing user-serviceable beyond this point
 185 ### (none of this executes on regular install)
 186 ###
 187
 188
 189 # needs to be here to keep 5.8 string eval happy
 190 # (the include of Makefile.PL.inc loop)
 191 my $mm_proto;
 192
 193 sub invoke_author_mode {
 194   # get options here, make $args available to all snippets
 195   require Getopt::Long;
 196   my $getopt = Getopt::Long::Parser->new(
 197     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 198   );
 199   my $args = {
 200     skip_author_deps => undef,
 201   };
 202   $getopt->getoptions($args, qw/
 203     skip_author_deps|skip-author-deps
 204   /);
 205   if (@ARGV) {
 206     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 207   }
 208
 209   # We need the MM facilities to generate the pieces for the final MM run.
 210   # Just instantiate a throaway object here
 211   #
 212   # Also EUMM and MI disagree on what is the format of Meta->name, just
 213   # punt here until a new M::I is shipped (if at all)
 214   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 215   $name =~ s/\-/::/g;
 216   $mm_proto = ExtUtils::MakeMaker->new({
 217     NORECURS => 1,
 218     NAME => $name,
 219   });
 220
 221   # Crutch for DISTBUILDING_IN_HELL
 222   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 223   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 224   # not take into account the CRLF layer present on win32
 225   my $crlf_fixup = sub {
 226     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 227     my $targets = join ', ', map { "q($_)" } @_;
 228     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 229   };
 230
 231   # we are in the process of (re)writing the makefile - some things we
 232   # call below very well may fail
 233   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 234
 235   require File::Spec;
 236   # string-eval, not do(), because we need to provide the
 237   # $mm_proto, $reqs and $*_requires lexicals to the included file
 238   # (some includes *do* modify $reqs above)
 239   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 240     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 241     eval "use warnings; use strict; $src" or die sprintf
 242       "Failed execution of %s: %s\n",
 243       $inc,
 244       ($@ || $! || 'Unknown error'),
 245     ;
 246   }
 247 }