Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN {
   7   # needs to happen early for old EUMM
   8   makemaker_args( NORECURS => 1 );
   9
  10   local @INC = ('lib', @INC);
  11   require DBIx::Class::Optional::Dependencies;
  12 }
  13
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  18 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  19 # for that)
  20 BEGIN {
  21   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  22 }
  23
  24 name         'DBIx-Class';
  25 version_from 'lib/DBIx/Class.pm';
  26 perl_version '5.008001';
  27
  28 ###
  29 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  30 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  31 ###
  32 my $runtime_requires = {
  33
  34   # DBI itself should be capable of installation and execution in pure-perl
  35   # mode. However it has never been tested yet, so consider XS for the time
  36   # being
  37 ###
  38 ### IMPORTANT - do not raise this dependency
  39 ### even though many bugfixes are present in newer versions, the general DBIC
  40 ### rule is to bend over backwards for available DBI versions (given upgrading
  41 ### them is often *not* easy or even possible)
  42 ###
  43   'DBI'                      => '1.57',
  44
  45   # on older versions first() leaks
  46   # for the time being make it a hard dep - when we get
  47   # rid of Sub::Name will revisit this (possibility is
  48   # to use Devel::HideXS to force the pure-perl version
  49   # or something like that)
  50   'List::Util'               => '1.16',
  51
  52   # XS (or XS-dependent) libs
  53   'Sub::Name'                => '0.04',
  54
  55   # pure-perl (FatPack-able) libs
  56   'Class::Accessor::Grouped' => '0.10012',
  57   'Class::C3::Componentised' => '1.0009',
  58   'Class::Inspector'         => '1.24',
  59   'Context::Preserve'        => '0.01',
  60   'Data::Dumper::Concise'    => '2.020',
  61   'Data::Page'               => '2.00',
  62   'Devel::GlobalDestruction' => '0.09',
  63   'Hash::Merge'              => '0.12',
  64   'Moo'                      => '2.000',
  65   'MRO::Compat'              => '0.12',
  66   'Module::Find'             => '0.07',
  67   'namespace::clean'         => '0.24',
  68   'Path::Class'              => '0.18',
  69   'Scope::Guard'             => '0.03',
  70   'SQL::Abstract'            => '1.81',
  71   'Try::Tiny'                => '0.07',
  72
  73   # Technically this is not a core dependency - it is only required
  74   # by the MySQL codepath. However this particular version is bundled
  75   # since 5.10.0 and is a pure-perl module anyway - let it slide
  76   'Text::Balanced'           => '2.00',
  77 };
  78
  79 my $build_requires = {
  80 };
  81
  82 my $test_requires = {
  83   'File::Temp'               => '0.22',
  84   'Test::Deep'               => '0.101',
  85   'Test::Exception'          => '0.31',
  86   'Test::Warn'               => '0.21',
  87   'Test::More'               => '0.94',
  88
  89   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  90   # remove and do a manual glob-collection if n::c is no longer a dep
  91   'Package::Stash'           => '0.28',
  92
  93   # needed for testing only, not for operation
  94   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  95   %{ DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_sqlite') },
  96 };
  97
  98 # if the user has some of these env vars set and the deps are not available,
  99 # tests will fail
 100 # Note - these are added as test_requires *directly*, so they get properly
 101 # excluded on META.yml cleansing (even though no dist can be created from this)
 102 # we force these reqs regarless of author_deps, worst case scenario they will
 103 # be specified twice
 104 #
 105 # also note that we *do* set dynamic_config => 0, as these are the only things
 106 # that we determine dynamically, and in all fairness if someone sets these
 107 # envvars *and* is not running a full Makefile/make/maketest cycle - they get
 108 # to keep the pieces
 109 if ( my @optdeps = (
 110   $ENV{DBICTEST_SQLT_DEPLOY} ? 'deploy' : (),
 111   $ENV{DBICTEST_VIA_REPLICATED} ? 'replicated' : (),
 112 )) {
 113   my $extra_deps = DBIx::Class::Optional::Dependencies->req_list_for(\@optdeps);
 114   for (keys %$extra_deps) {
 115     test_requires ($_ => $extra_deps->{$_})
 116   }
 117 }
 118
 119 tests_recursive ('t');
 120 tests_recursive ('xt') if (
 121   $Module::Install::AUTHOR
 122     or
 123   $ENV{DBICTEST_RUN_ALL_TESTS}
 124     or
 125   ( $ENV{TRAVIS}||'' ) eq 'true'
 126     or
 127   ( $ENV{AUTOMATED_TESTING} and ! $ENV{PERL5_CPANM_IS_RUNNING} and ! $ENV{RELEASE_TESTING} )
 128 );
 129
 130 install_script (qw|
 131     script/dbicadmin
 132 |);
 133
 134 # this is so we can order requires alphabetically
 135 # copies are needed for potential author requires injection
 136 my $reqs = {
 137   build_requires => { %$build_requires },
 138   requires => { %$runtime_requires },
 139   test_requires => { %$test_requires },
 140 };
 141
 142 # only do author-includes if not part of a `make` run
 143 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 144   invoke_author_mode()
 145 }
 146 else {
 147   # make sure this Makefile can not be used to make a dist
 148   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 149   postamble <<EOP;
 150 create_distdir: nonauthor_stop_distdir_creation
 151 nonauthor_stop_distdir_creation:
 152 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 153 \t\$(NOECHO) \$(FALSE)
 154 EOP
 155 }
 156
 157 # compose final req list, for alphabetical ordering
 158 my %final_req;
 159 for my $rtype (keys %$reqs) {
 160   for my $mod (keys %{$reqs->{$rtype}} ) {
 161
 162     # sanity check req duplications
 163     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 164       if $final_req{$mod};
 165
 166     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 167   }
 168 }
 169
 170 # actual require
 171 for my $mod (sort keys %final_req) {
 172   my ($rtype, $ver) = @{$final_req{$mod}};
 173   no strict 'refs';
 174   $rtype->($mod, $ver);
 175 }
 176
 177 # author-mode or not - this is where we show a list of missing deps
 178 # IFF we are running interactively
 179 auto_install();
 180
 181 {
 182   # M::I understands unicode in meta but does not write with the right
 183   # layers - fhtagn!!!
 184   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 185   WriteAll();
 186 }
 187
 188 exit 0;
 189
 190
 191 ###
 192 ### Nothing user-serviceable beyond this point
 193 ### (none of this executes on regular install)
 194 ###
 195
 196
 197 # needs to be here to keep 5.8 string eval happy
 198 # (the include of Makefile.PL.inc loop)
 199 my $mm_proto;
 200
 201 sub invoke_author_mode {
 202   # get options here, make $args available to all snippets
 203   require Getopt::Long;
 204   my $getopt = Getopt::Long::Parser->new(
 205     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 206   );
 207   my $args = {
 208     skip_author_deps => undef,
 209   };
 210   $getopt->getoptions($args, qw/
 211     skip_author_deps|skip-author-deps
 212   /);
 213   if (@ARGV) {
 214     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 215   }
 216
 217   # We need the MM facilities to generate the pieces for the final MM run.
 218   # Just instantiate a throaway object here
 219   #
 220   # Also EUMM and MI disagree on what is the format of Meta->name, just
 221   # punt here until a new M::I is shipped (if at all)
 222   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 223   $name =~ s/\-/::/g;
 224   $mm_proto = ExtUtils::MakeMaker->new({
 225     NORECURS => 1,
 226     NAME => $name,
 227   });
 228
 229   # Crutch for DISTBUILDING_IN_HELL
 230   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 231   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 232   # not take into account the CRLF layer present on win32
 233   my $crlf_fixup = sub {
 234     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 235     my $targets = join ', ', map { "q($_)" } @_;
 236     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 237   };
 238
 239   # we are in the process of (re)writing the makefile - some things we
 240   # call below very well may fail
 241   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 242
 243   require File::Spec;
 244   # string-eval, not do(), because we need to provide the
 245   # $mm_proto, $reqs and $*_requires lexicals to the included file
 246   # (some includes *do* modify $reqs above)
 247   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 248     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 249     eval "use warnings; use strict; $src" or die sprintf
 250       "Failed execution of %s: %s\n",
 251       $inc,
 252       ($@ || $! || 'Unknown error'),
 253     ;
 254   }
 255 }