Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN {
   7   # needs to happen early for old EUMM
   8   makemaker_args( NORECURS => 1 );
   9
  10   local @INC = ('lib', @INC);
  11   require DBIx::Class::Optional::Dependencies;
  12 }
  13
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  18 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  19 # for that)
  20 BEGIN {
  21   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  22 }
  23
  24 name         'DBIx-Class';
  25 version_from 'lib/DBIx/Class.pm';
  26 perl_version '5.008001';
  27
  28 ###
  29 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  30 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  31 ###
  32 my $runtime_requires = {
  33
  34   # DBI itself should be capable of installation and execution in pure-perl
  35   # mode. However it has never been tested yet, so consider XS for the time
  36   # being
  37 ###
  38 ### IMPORTANT - do not raise this dependency
  39 ### even though many bugfixes are present in newer versions, the general DBIC
  40 ### rule is to bend over backwards for available DBI versions (given upgrading
  41 ### them is often *not* easy or even possible)
  42 ###
  43   'DBI'                      => '1.57',
  44
  45   # XS (or XS-dependent) libs
  46   'Sub::Name'                => '0.04',
  47
  48   # pure-perl (FatPack-able) libs
  49   'Class::Accessor::Grouped' => '0.10012',
  50   'Class::C3::Componentised' => '1.0009',
  51   'Context::Preserve'        => '0.01',
  52   'Data::Page'               => '2.00',
  53   'Devel::GlobalDestruction' => '0.09',
  54   'Hash::Merge'              => '0.12',
  55   'Moo'                      => '2.002002',
  56   'MRO::Compat'              => '0.12',
  57   'Module::Find'             => '0.07',
  58   'namespace::clean'         => '0.24',
  59   'Scope::Guard'             => '0.03',
  60   'SQL::Abstract'            => '1.81',
  61   'Try::Tiny'                => '0.07',
  62
  63   # Technically this is not a core dependency - it is only required
  64   # by the MySQL codepath. However this particular version is bundled
  65   # since 5.10.0 and is a pure-perl module anyway - let it slide
  66   'Text::Balanced'           => '2.00',
  67 };
  68
  69 my $build_requires = {
  70 };
  71
  72 my $test_requires = {
  73   'File::Temp'               => '0.22',
  74   'Test::Deep'               => '0.101',
  75   'Test::Exception'          => '0.31',
  76   'Test::Warn'               => '0.21',
  77   'Test::More'               => '0.94',
  78
  79   # This has a bug in the caller() override, ideally we need go get rid
  80   # of it entirely, but that's for another maint
  81   #
  82   # FIXME - this does protect tests, but does *NOT* protect the rest of
  83   # DBIC itself from a faulty caller() override. Something more substantial
  84   # needs to be done in the guts of DBIC::Carp
  85   #
  86   'Sub::Uplevel'             => '0.19',
  87
  88   # needed for testing only, not for operation
  89   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  90   %{ DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_sqlite') },
  91 };
  92
  93 # if the user has some of these env vars set and the deps are not available,
  94 # tests will fail
  95 # Note - these are added as test_requires *directly*, so they get properly
  96 # excluded on META.yml cleansing (even though no dist can be created from this)
  97 # we force these reqs regarless of --with-optdeps, worst case scenario they will
  98 # be specified twice
  99 #
 100 # also note that we *do* set dynamic_config => 0, as these are the only things
 101 # that we determine dynamically, and in all fairness if someone sets these
 102 # envvars *and* is not running a full Makefile/make/maketest cycle - they get
 103 # to keep the pieces
 104 if ( my @optdeps = (
 105   $ENV{DBICTEST_SQLT_DEPLOY} ? 'deploy' : (),
 106   $ENV{DBICTEST_VIA_REPLICATED} ? 'replicated' : (),
 107 )) {
 108   my $extra_deps = DBIx::Class::Optional::Dependencies->req_list_for(\@optdeps);
 109   for (keys %$extra_deps) {
 110     test_requires ($_ => $extra_deps->{$_})
 111   }
 112 }
 113
 114 tests_recursive ('t');
 115 tests_recursive ('xt') if (
 116   $Module::Install::AUTHOR
 117     or
 118   $ENV{DBICTEST_RUN_ALL_TESTS}
 119     or
 120   ( $ENV{TRAVIS}||'' ) eq 'true'
 121     or
 122   ( $ENV{AUTOMATED_TESTING} and ! $ENV{PERL5_CPANM_IS_RUNNING} and ! $ENV{RELEASE_TESTING} )
 123 );
 124
 125 install_script (qw|
 126     script/dbicadmin
 127 |);
 128
 129 # this is so we can order requires alphabetically
 130 # copies are needed for potential author requires injection
 131 my $reqs = {
 132   build_requires => { %$build_requires },
 133   requires => { %$runtime_requires },
 134   test_requires => { %$test_requires },
 135 };
 136
 137 # only do author-includes if not part of a `make` run
 138 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 139   invoke_author_mode()
 140 }
 141 else {
 142   # make sure this Makefile can not be used to make a dist
 143   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 144   postamble <<EOP;
 145 create_distdir: nonauthor_stop_distdir_creation
 146 nonauthor_stop_distdir_creation:
 147 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 148 \t\$(NOECHO) \$(FALSE)
 149 EOP
 150 }
 151
 152 # compose final req list, for alphabetical ordering
 153 my %final_req;
 154 for my $rtype (keys %$reqs) {
 155   for my $mod (keys %{$reqs->{$rtype}} ) {
 156
 157     # sanity check req duplications
 158     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 159       if $final_req{$mod};
 160
 161     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 162   }
 163 }
 164
 165 # actual require
 166 for my $mod (sort keys %final_req) {
 167   my ($rtype, $ver) = @{$final_req{$mod}};
 168   no strict 'refs';
 169   $rtype->($mod, $ver);
 170 }
 171
 172 # author-mode or not - this is where we show a list of missing deps
 173 # IFF we are running interactively
 174 auto_install();
 175
 176 {
 177   # M::I understands unicode in meta but does not write with the right
 178   # layers - fhtagn!!!
 179   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 180   WriteAll();
 181 }
 182
 183 exit 0;
 184
 185
 186 ###
 187 ### Nothing user-serviceable beyond this point
 188 ### (none of this executes on regular install)
 189 ###
 190
 191
 192 # needs to be here to keep 5.8 string eval happy
 193 # (the include of Makefile.PL.inc loop)
 194 my $mm_proto;
 195
 196 sub invoke_author_mode {
 197   # get options here, make $args available to all snippets
 198   require Getopt::Long;
 199   my $getopt = Getopt::Long::Parser->new(
 200     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 201   );
 202   my $args = {
 203     with_optdeps => undef,
 204   };
 205   $getopt->getoptions($args, qw/
 206     with_optdeps|with-optdeps
 207   /);
 208   if (@ARGV) {
 209     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 210   }
 211
 212   # We need the MM facilities to generate the pieces for the final MM run.
 213   # Just instantiate a throaway object here
 214   #
 215   # Also EUMM and MI disagree on what is the format of Meta->name, just
 216   # punt here until a new M::I is shipped (if at all)
 217   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 218   $name =~ s/\-/::/g;
 219   $mm_proto = ExtUtils::MakeMaker->new({
 220     NORECURS => 1,
 221     NAME => $name,
 222   });
 223
 224   # Crutch for DISTBUILDING_IN_HELL
 225   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 226   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 227   # not take into account the CRLF layer present on win32
 228   my $crlf_fixup = sub {
 229     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 230     my $targets = join ', ', map { "q($_)" } @_;
 231     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 232   };
 233
 234   # string-eval, not do(), because we need to provide the
 235   # $mm_proto, $reqs and $*_requires lexicals to the included file
 236   # (some includes *do* modify $reqs above)
 237   for my $inc (sort glob ( 'maint/Makefile.PL.inc/*' ) ) {
 238     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 239     eval "use warnings; use strict; $src" or die sprintf
 240       "Failed execution of %s: %s\n",
 241       $inc,
 242       ($@ || $! || 'Unknown error'),
 243     ;
 244   }
 245 }