Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 use 5.008001;
   6
   7 use FindBin;
   8 use lib "$FindBin::Bin/lib";
   9 use DBIx::Class::Optional::Dependencies;
  10
  11 # get cpanX --installdeps . to behave in a checkout (most users do not need
  12 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  13 # for that)
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  18
  19 ###
  20 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  21 ### All of them should go to DBIx::Class::Optional::Dependencies
  22 ###
  23
  24 name     'DBIx-Class';
  25 perl_version '5.008001';
  26 all_from 'lib/DBIx/Class.pm';
  27
  28 my $build_requires = {
  29   # needed for testing only, not for operation
  30   'DBD::SQLite'              => '1.29',
  31 };
  32
  33 my $test_requires = {
  34   'File::Temp'               => '0.22',
  35   'Test::Builder'            => '0.33',
  36   'Test::Exception'          => '0.31',
  37   'Test::More'               => '0.92',
  38   'Test::Warn'               => '0.21',
  39
  40   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  41   # remove and do a manual glob-collection if n::c is no longer a dep
  42   'Package::Stash'           => '0.28',
  43 };
  44
  45 my $runtime_requires = {
  46   'Class::Accessor::Grouped' => '0.10002',
  47   'Class::C3::Componentised' => '1.0009',
  48   'Class::Inspector'         => '1.24',
  49   'Config::Any'              => '0.20',
  50   'Context::Preserve'        => '0.01',
  51   'Data::Dumper::Concise'    => '2.020',
  52   'Data::Page'               => '2.00',
  53   'Hash::Merge'              => '0.12',
  54   'MRO::Compat'              => '0.09',
  55   'Module::Find'             => '0.06',
  56   'namespace::clean'         => '0.20',
  57   'Path::Class'              => '0.18',
  58   'Scope::Guard'             => '0.03',
  59   'SQL::Abstract'            => '1.72',
  60   'Try::Tiny'                => '0.04',
  61
  62   # XS (or XS-dependent) libs
  63   'DBI'                      => '1.57',
  64   'Sub::Name'                => '0.04',
  65
  66   # dual-life corelibs needing a specific bugfixed version
  67   'File::Path'               => '2.07',
  68
  69   # FIXME - temporary, needs throwing out for something more efficient
  70   'Data::Compare'            => '1.22',
  71 };
  72
  73
  74 # Bail out on parallel testing
  75 if (
  76   ($ENV{HARNESS_OPTIONS}||'') =~ / (?: ^ | \: ) j(\d+) /x
  77     and
  78   $1 > 1
  79 ) { die <<EOP }
  80
  81 ******************************************************************************
  82 ******************************************************************************
  83 ***                                                                        ***
  84 ***      PARALLEL TESTING DETECTED ( \$ENV{HARNESS_OPTIONS} = 'j$1' )        ***
  85 ***                                                                        ***
  86 *** DBIC tests will fail. It is harder to make them parallel-friendly than ***
  87 *** it should be (though work is underway). In the meantime you will have  ***
  88 *** to adjust your environment and re-run the installation. Sorry!         ***
  89 ***                                                                        ***
  90 ******************************************************************************
  91 ******************************************************************************
  92
  93 EOP
  94
  95 require Getopt::Long;
  96 my $getopt = Getopt::Long::Parser->new(
  97   config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
  98 );
  99 my $args = {
 100   skip_author_deps => undef,
 101 };
 102 $getopt->getoptions($args, 'skip_author_deps');
 103 if (@ARGV) {
 104   warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 105 }
 106
 107 # this is so we can order requires alphabetically
 108 # copies are needed for author requires injection
 109 my $reqs = {
 110   build_requires => { %$build_requires },
 111   requires => { %$runtime_requires },
 112   test_requires => { %$test_requires },
 113 };
 114
 115 my %reqs_for_group = %{DBIx::Class::Optional::Dependencies->req_group_list};
 116
 117 # exclude the rdbms_* groups which are for DBIC users
 118 my $opt_testdeps = {
 119   map { %{$reqs_for_group{$_}} } grep { !/^rdbms_/ } keys %reqs_for_group
 120 };
 121
 122 # require extra modules for testing if we're in a checkout
 123 my $optdep_msg;
 124 if ($Module::Install::AUTHOR) {
 125   if ($args->{skip_author_deps}) {
 126     $optdep_msg = <<'EOW';
 127
 128 ******************************************************************************
 129 ******************************************************************************
 130 ***                                                                        ***
 131 *** IGNORING AUTHOR MODE: no optional test dependencies will be forced.    ***
 132 ***                                                                        ***
 133 *** If you are using this checkout with the intention of submitting a DBIC ***
 134 *** patch, you are *STRONGLY ENCOURAGED* to install all dependencies, so   ***
 135 *** that every possible unit-test will run.                                ***
 136 ***                                                                        ***
 137 ******************************************************************************
 138 ******************************************************************************
 139
 140 EOW
 141   }
 142   else {
 143     $optdep_msg = <<'EOW';
 144
 145 ******************************************************************************
 146 ******************************************************************************
 147 ***                                                                        ***
 148 *** AUTHOR MODE: all optional test dependencies converted to hard requires ***
 149 ***       ( to disable re-run Makefile.PL with --skip_author_deps )        ***
 150 ***                                                                        ***
 151 ******************************************************************************
 152 ******************************************************************************
 153
 154 EOW
 155
 156     $reqs->{test_requires} = {
 157       %{$reqs->{test_requires}},
 158       %$opt_testdeps
 159     };
 160   }
 161 }
 162
 163 # compose final req list, for alphabetical ordering
 164 my %final_req;
 165 for my $rtype (keys %$reqs) {
 166   for my $mod (keys %{$reqs->{$rtype}} ) {
 167
 168     # sanity check req duplications
 169     if ($final_req{$mod}) {
 170       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 171     }
 172
 173     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 174   }
 175 }
 176
 177 # actual require
 178 for my $mod (sort keys %final_req) {
 179   my ($rtype, $ver) = @{$final_req{$mod}};
 180   no strict 'refs';
 181   $rtype->($mod, $ver);
 182 }
 183
 184 # output twice since the deplist is > 70 lines
 185 warn $optdep_msg if $Module::Install::AUTHOR;
 186 auto_install();
 187 warn $optdep_msg if $Module::Install::AUTHOR;
 188
 189
 190 # re-create various autogenerated documentation bits
 191 if ($Module::Install::AUTHOR) {
 192
 193   # adjust ENV for $AUTHOR system() calls
 194   require Config;
 195   $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 196
 197   print "Regenerating README\n";
 198   system('pod2text lib/DBIx/Class.pm > README');
 199
 200   if (-f 'MANIFEST') {
 201     print "Removing MANIFEST\n";
 202     unlink 'MANIFEST';
 203   }
 204
 205   print "Regenerating Optional/Dependencies.pod\n";
 206   require DBIx::Class::Optional::Dependencies;
 207   DBIx::Class::Optional::Dependencies->_gen_pod (Meta->version);
 208
 209   # FIXME Disabled due to unsolved issues, ask theorbtwo
 210   #  require Module::Install::Pod::Inherit;
 211   #  PodInherit();
 212 }
 213
 214
 215 tests_recursive (qw|
 216     t
 217 |);
 218
 219 # temporary(?) until I get around to fix M::I wrt xt/
 220 # needs Module::Install::AuthorTests
 221 eval {
 222   # this should not be necessary since the autoloader is supposed
 223   # to work, but there were reports of it failing
 224   require Module::Install::AuthorTests;
 225   recursive_author_tests (qw/xt/);
 226   1;
 227 } || do {
 228   if ($Module::Install::AUTHOR && ! $args->{skip_author_deps}) {
 229     my $err = $@;
 230
 231     # better error message in case of missing dep
 232     eval { require Module::Install::AuthorTests }
 233       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode (or supply --skip_author_deps):\n\n$@\n";
 234
 235     die $err;
 236   }
 237 };
 238
 239
 240 install_script (qw|
 241     script/dbicadmin
 242 |);
 243
 244
 245 ### Mangle makefile - read the comments for more info
 246 #
 247 postamble <<"EOP";
 248
 249 # This will add an extra dep-spec for the distdir target,
 250 # which `make` will fold together in a first-come first-serve
 251 # fashion. What we do here is essentially adding extra
 252 # commands to execute once the distdir is assembled (via
 253 # create_distdir), but before control is returned to a higher
 254 # calling rule.
 255 distdir : dbicadmin_pod_inject
 256
 257 # The pod self-injection code is in fact a hidden option in
 258 # dbicadmin itself
 259 dbicadmin_pod_inject :
 260 \tcd \$(DISTVNAME) && \$(ABSPERL) -Ilib script/dbicadmin --selfinject-pod
 261
 262 # Regenerate manifest before running create_distdir.
 263 create_distdir : manifest
 264
 265 EOP
 266
 267 homepage 'http://www.dbix-class.org/';
 268 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
 269 resources 'license'     => 'http://dev.perl.org/licenses/';
 270 resources 'repository'  => 'git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git';
 271 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
 272 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
 273
 274 # Deprecated/internal modules need no exposure
 275 no_index directory => $_ for (qw|
 276   lib/DBIx/Class/Admin
 277   lib/DBIx/Class/PK/Auto
 278   lib/DBIx/Class/CDBICompat
 279 |);
 280 no_index package => $_ for (qw/
 281   DBIx::Class::Storage::DBIHacks
 282   DBIx::Class::Carp
 283   DBIx::Class::ResultSet::Pager
 284 /);
 285
 286 WriteAll();
 287
 288 # Re-write META.yml to _exclude_ all forced build-requires (we do not want to ship
 289 # this) We are also not using M::I::AuthorRequires as this will be an extra dep,
 290 # and deps in Makefile.PL still suck
 291 # Also always test the result so we stop shipping borked dependency lists to CPAN
 292
 293 # FIXME test_requires is not yet part of META
 294 my %original_build_requires = ( %$build_requires, %$test_requires );
 295 my @all_build_requires = @{delete Meta->{values}{build_requires}};
 296 my %removed_build_requires;
 297
 298 for (@all_build_requires) {
 299   if ($original_build_requires{$_->[0]}) {
 300     push @{Meta->{values}{build_requires}}, $_;
 301   }
 302   else {
 303     $removed_build_requires{$_->[0]} = $_->[1]
 304       unless $_->[0] eq 'ExtUtils::MakeMaker';
 305   }
 306 }
 307
 308 # Rewrite only in author mode, the original META should not contain anything anyway
 309 # if we executed as non-author
 310 if ($Module::Install::AUTHOR && keys %removed_build_requires) {
 311   print "Regenerating META with author requires excluded\n";
 312   Meta->write;
 313 }
 314
 315 # test that we really took things away (just in case, happened twice somehow)
 316 if (! -f 'META.yml') {
 317   warn "No META.yml generated?! aborting...\n";
 318   exit 1;
 319 }
 320 my $meta = do { local @ARGV = 'META.yml'; local $/; <> };
 321
 322 # this is safe as there is a fatal check earlier to make sure $opt_testdeps does
 323 # not contain any real dependencies
 324 my @illegal_leftovers = grep
 325   { $meta =~ /^ \s+ \Q$_\E \: \s+ /mx }
 326   ( sort keys %$opt_testdeps )
 327 ;
 328
 329 if (@illegal_leftovers) {
 330   die join ("\n",
 331     "\n\nFATAL FAIL! It looks like some author dependencies made it to the META.yml:\n",
 332     map { "\t$_" } @illegal_leftovers
 333   ) . "\n\n";
 334 }