Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN {
   7   # needs to happen early for old EUMM
   8   makemaker_args( NORECURS => 1 );
   9
  10   local @INC = ('lib', @INC);
  11   require DBIx::Class::Optional::Dependencies;
  12 }
  13
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  18 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  19 # for that)
  20 BEGIN {
  21   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  22 }
  23
  24 ##
  25 ## TEMPORARY (and non-portable)
  26 ## Get trial Moo
  27 ##
  28 BEGIN {
  29   my $target_libdir = 'lib/DBIx/Class/_TempExtlib';
  30
  31   if ( ($Module::Install::AUTHOR or $ENV{TRAVIS}) and ! $ENV{MAKELEVEL} ) {
  32
  33     `rm -rf $target_libdir`;
  34     `mkdir $target_libdir`;
  35     for (
  36       [ 'Sub::Quote' => master => 'https://github.com/moose/Moo.git' ],
  37     ) {
  38       my $tdir = "/tmp/dbictemplib/$_->[0]/";
  39
  40       `rm -rf $tdir`;
  41
  42       `GIT_SSH=maint/careless_ssh.bash git clone --bare --quiet --branch=$_->[1] --depth=1 $_->[2] $tdir`;
  43       printf "\nIncluding %s git rev %s\n",
  44         $_->[0],
  45         scalar `GIT_DIR=$tdir git rev-parse $_->[1]`,
  46       ;
  47       `git archive --format=tar --remote=file://$tdir $_->[1] lib/ | tar --strip-components=1 -xC $target_libdir`;
  48
  49       #`rm -rf $tdir`;
  50     }
  51
  52     unshift @INC, $target_libdir;
  53
  54     no_index directory => $target_libdir;
  55   }
  56 }
  57
  58 name         'DBIx-Class';
  59 version_from 'lib/DBIx/Class.pm';
  60 perl_version '5.008001';
  61
  62 ###
  63 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  64 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  65 ###
  66 my $runtime_requires = {
  67
  68   # DBI itself should be capable of installation and execution in pure-perl
  69   # mode. However it has never been tested yet, so consider XS for the time
  70   # being
  71 ###
  72 ### IMPORTANT - do not raise this dependency
  73 ### even though many bugfixes are present in newer versions, the general DBIC
  74 ### rule is to bend over backwards for available DBI versions (given upgrading
  75 ### them is often *not* easy or even possible)
  76 ###
  77   'DBI'                      => '1.57',
  78
  79   # XS (or XS-dependent) libs
  80   'Sub::Name'                => '0.04',
  81
  82   # pure-perl (FatPack-able) libs
  83   'Class::Accessor::Grouped' => '0.10012',
  84   'Class::C3::Componentised' => '1.0009',
  85   'Context::Preserve'        => '0.01',
  86   'Data::Page'               => '2.00',
  87   'Devel::GlobalDestruction' => '0.09',
  88   'Hash::Merge'              => '0.12',
  89   'Moo'                      => '2.000',
  90   'MRO::Compat'              => '0.12',
  91   'Module::Find'             => '0.07',
  92   'namespace::clean'         => '0.24',
  93   'Scope::Guard'             => '0.03',
  94   'SQL::Abstract'            => '1.81',
  95   'Try::Tiny'                => '0.07',
  96
  97   # Temp to satisfy TemptExtlib
  98   'Role::Tiny'               => '2.000002',
  99
 100   # Technically this is not a core dependency - it is only required
 101   # by the MySQL codepath. However this particular version is bundled
 102   # since 5.10.0 and is a pure-perl module anyway - let it slide
 103   'Text::Balanced'           => '2.00',
 104 };
 105
 106 my $build_requires = {
 107 };
 108
 109 my $test_requires = {
 110   'File::Temp'               => '0.22',
 111   'Test::Deep'               => '0.101',
 112   'Test::Exception'          => '0.31',
 113   'Test::Warn'               => '0.21',
 114   'Test::More'               => '0.94',
 115
 116   # This has a bug in the caller() override, ideally we need go get rid
 117   # of it entirely, but that's for another maint
 118   #
 119   # FIXME - this does protect tests, but does *NOT* protect the rest of
 120   # DBIC itself from a faulty caller() override. Something more substantial
 121   # needs to be done in the guts of DBIC::Carp
 122   #
 123   'Sub::Uplevel'             => '0.19',
 124
 125   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
 126   # remove and do a manual glob-collection if n::c is no longer a dep
 127   'Package::Stash'           => '0.28',
 128
 129   # needed for testing only, not for operation
 130   # we will move away from this dep eventually, perhaps to DBD::CSV or something
 131   %{ DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_sqlite') },
 132 };
 133
 134 # if the user has some of these env vars set and the deps are not available,
 135 # tests will fail
 136 # Note - these are added as test_requires *directly*, so they get properly
 137 # excluded on META.yml cleansing (even though no dist can be created from this)
 138 # we force these reqs regarless of --with-optdeps, worst case scenario they will
 139 # be specified twice
 140 #
 141 # also note that we *do* set dynamic_config => 0, as these are the only things
 142 # that we determine dynamically, and in all fairness if someone sets these
 143 # envvars *and* is not running a full Makefile/make/maketest cycle - they get
 144 # to keep the pieces
 145 if ( my @optdeps = (
 146   $ENV{DBICTEST_SQLT_DEPLOY} ? 'deploy' : (),
 147   $ENV{DBICTEST_VIA_REPLICATED} ? 'replicated' : (),
 148 )) {
 149   my $extra_deps = DBIx::Class::Optional::Dependencies->req_list_for(\@optdeps);
 150   for (keys %$extra_deps) {
 151     test_requires ($_ => $extra_deps->{$_})
 152   }
 153 }
 154
 155 tests_recursive ('t');
 156 tests_recursive ('xt') if (
 157   $Module::Install::AUTHOR
 158     or
 159   $ENV{DBICTEST_RUN_ALL_TESTS}
 160     or
 161   ( $ENV{TRAVIS}||'' ) eq 'true'
 162     or
 163   ( $ENV{AUTOMATED_TESTING} and ! $ENV{PERL5_CPANM_IS_RUNNING} and ! $ENV{RELEASE_TESTING} )
 164 );
 165
 166 install_script (qw|
 167     script/dbicadmin
 168 |);
 169
 170 # this is so we can order requires alphabetically
 171 # copies are needed for potential author requires injection
 172 my $reqs = {
 173   build_requires => { %$build_requires },
 174   requires => { %$runtime_requires },
 175   test_requires => { %$test_requires },
 176 };
 177
 178 # only do author-includes if not part of a `make` run
 179 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 180   invoke_author_mode()
 181 }
 182 else {
 183   # make sure this Makefile can not be used to make a dist
 184   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 185   postamble <<EOP;
 186 create_distdir: nonauthor_stop_distdir_creation
 187 nonauthor_stop_distdir_creation:
 188 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 189 \t\$(NOECHO) \$(FALSE)
 190 EOP
 191 }
 192
 193 # compose final req list, for alphabetical ordering
 194 my %final_req;
 195 for my $rtype (keys %$reqs) {
 196   for my $mod (keys %{$reqs->{$rtype}} ) {
 197
 198     # sanity check req duplications
 199     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 200       if $final_req{$mod};
 201
 202     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 203   }
 204 }
 205
 206 # actual require
 207 for my $mod (sort keys %final_req) {
 208   my ($rtype, $ver) = @{$final_req{$mod}};
 209   no strict 'refs';
 210   $rtype->($mod, $ver);
 211 }
 212
 213 # author-mode or not - this is where we show a list of missing deps
 214 # IFF we are running interactively
 215 auto_install();
 216
 217 {
 218   # M::I understands unicode in meta but does not write with the right
 219   # layers - fhtagn!!!
 220   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 221   WriteAll();
 222 }
 223
 224 exit 0;
 225
 226
 227 ###
 228 ### Nothing user-serviceable beyond this point
 229 ### (none of this executes on regular install)
 230 ###
 231
 232
 233 # needs to be here to keep 5.8 string eval happy
 234 # (the include of Makefile.PL.inc loop)
 235 my $mm_proto;
 236
 237 sub invoke_author_mode {
 238   # get options here, make $args available to all snippets
 239   require Getopt::Long;
 240   my $getopt = Getopt::Long::Parser->new(
 241     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 242   );
 243   my $args = {
 244     with_optdeps => undef,
 245   };
 246   $getopt->getoptions($args, qw/
 247     with_optdeps|with-optdeps
 248   /);
 249   if (@ARGV) {
 250     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 251   }
 252
 253   # We need the MM facilities to generate the pieces for the final MM run.
 254   # Just instantiate a throaway object here
 255   #
 256   # Also EUMM and MI disagree on what is the format of Meta->name, just
 257   # punt here until a new M::I is shipped (if at all)
 258   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 259   $name =~ s/\-/::/g;
 260   $mm_proto = ExtUtils::MakeMaker->new({
 261     NORECURS => 1,
 262     NAME => $name,
 263   });
 264
 265   # Crutch for DISTBUILDING_IN_HELL
 266   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 267   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 268   # not take into account the CRLF layer present on win32
 269   my $crlf_fixup = sub {
 270     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 271     my $targets = join ', ', map { "q($_)" } @_;
 272     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 273   };
 274
 275   # string-eval, not do(), because we need to provide the
 276   # $mm_proto, $reqs and $*_requires lexicals to the included file
 277   # (some includes *do* modify $reqs above)
 278   for my $inc (sort glob ( 'maint/Makefile.PL.inc/*' ) ) {
 279     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 280     eval "use warnings; use strict; $src" or die sprintf
 281       "Failed execution of %s: %s\n",
 282       $inc,
 283       ($@ || $! || 'Unknown error'),
 284     ;
 285   }
 286 }