Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 use 5.008001;
   6
   7 use FindBin;
   8 use lib "$FindBin::Bin/lib";
   9
  10 # adjust ENV for $AUTHOR system() calls
  11 use Config;
  12 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  13
  14 use Getopt::Long ();
  15
  16 my $getopt = Getopt::Long::Parser->new(
  17   config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
  18 );
  19 my $args = {
  20   skip_author_deps => undef,
  21 };
  22 $getopt->getoptions($args, 'skip_author_deps');
  23 if (@ARGV) {
  24   warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
  25 }
  26
  27 # get cpanX --installdeps . to behave in a checkout (most users do not need
  28 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  29 # for that)
  30 ##
  31 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  32 ##
  33 $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  34
  35 ###
  36 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  37 ### All of them should go to DBIx::Class::Optional::Dependencies
  38 ###
  39
  40 name     'DBIx-Class';
  41 perl_version '5.008001';
  42 all_from 'lib/DBIx/Class.pm';
  43
  44 my $build_requires = {
  45   'DBD::SQLite'              => '1.29',
  46 };
  47
  48 my $test_requires = {
  49   'File::Temp'               => '0.22',
  50   'Test::Builder'            => '0.33',
  51   'Test::Exception'          => '0',
  52   'Test::More'               => '0.92',
  53   'Test::Warn'               => '0.21',
  54 };
  55
  56 my $runtime_requires = {
  57   'Carp::Clan'               => '6.0',
  58   'Class::Accessor::Grouped' => '0.09004',
  59   'Class::C3::Componentised' => '1.0005',
  60   'Class::Inspector'         => '1.24',
  61   'Data::Page'               => '2.00',
  62   'DBI'                      => '1.609',
  63   'File::Path'               => '2.07',
  64   'MRO::Compat'              => '0.09',
  65   'Module::Find'             => '0.06',
  66   'Path::Class'              => '0.18',
  67   'SQL::Abstract'            => '1.68',
  68   'Sub::Name'                => '0.04',
  69   'Data::Dumper::Concise'    => '1.000',
  70   'Scope::Guard'             => '0.03',
  71   'Context::Preserve'        => '0.01',
  72   'Try::Tiny'                => '0.04',
  73   'namespace::clean'         => '0.14',
  74   'Math::BigInt'             => '1.89',
  75   'Math::Base36'             => '0.07',
  76   'Config::Any'              => '0.20',
  77 };
  78
  79 # this is so we can order requires alphabetically
  80 # copies are needed for author requires injection
  81 my $reqs = {
  82   build_requires => { %$build_requires },
  83   requires => { %$runtime_requires },
  84   test_requires => { %$test_requires },
  85 };
  86
  87
  88 # require extra modules for testing if we're in a checkout
  89 my $optdep_msg;
  90 if ($Module::Install::AUTHOR) {
  91   if ($args->{skip_author_deps}) {
  92     $optdep_msg = <<'EOW';
  93
  94 ******************************************************************************
  95 ******************************************************************************
  96 ***                                                                        ***
  97 *** IGNORING AUTHOR MODE: no optional test dependencies will be forced.    ***
  98 ***                                                                        ***
  99 *** If you are using this checkout with the intention of submitting a DBIC ***
 100 *** patch, you are *STRONGLY ENCOURAGED* to install all dependencies, so   ***
 101 *** that every possible unit-test will run.                                ***
 102 ***                                                                        ***
 103 ******************************************************************************
 104 ******************************************************************************
 105
 106 EOW
 107   }
 108   else {
 109     $optdep_msg = <<'EOW';
 110
 111 ******************************************************************************
 112 ******************************************************************************
 113 ***                                                                        ***
 114 *** AUTHOR MODE: all optional test dependencies converted to hard requires ***
 115 ***       ( to disable re-run Makefile.PL with --skip_author_deps )        ***
 116 ***                                                                        ***
 117 ******************************************************************************
 118 ******************************************************************************
 119
 120 EOW
 121
 122     require DBIx::Class::Optional::Dependencies;
 123     $reqs->{test_requires} = {
 124       %{$reqs->{test_requires}},
 125       map { %$_ } (values %{DBIx::Class::Optional::Dependencies->req_group_list}),
 126     };
 127   }
 128 }
 129
 130 # compose final req list, for alphabetical ordering
 131 my %final_req;
 132 for my $rtype (keys %$reqs) {
 133   for my $mod (keys %{$reqs->{$rtype}} ) {
 134
 135     # sanity check req duplications
 136     if ($final_req{$mod}) {
 137       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 138     }
 139
 140     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 141   }
 142 }
 143
 144 # actual require
 145 for my $mod (sort keys %final_req) {
 146   my ($rtype, $ver) = @{$final_req{$mod}};
 147   no strict 'refs';
 148   $rtype->($mod, $ver);
 149 }
 150
 151 # output twice since the deplist is > 70 lines
 152 warn $optdep_msg if $Module::Install::AUTHOR;
 153 auto_install();
 154 warn $optdep_msg if $Module::Install::AUTHOR;
 155
 156 # re-create various autogenerated documentation bits
 157 if ($Module::Install::AUTHOR) {
 158
 159   print "Regenerating README\n";
 160   system('pod2text lib/DBIx/Class.pm > README');
 161
 162   if (-f 'MANIFEST') {
 163     print "Removing MANIFEST\n";
 164     unlink 'MANIFEST';
 165   }
 166
 167   print "Regenerating Optional/Dependencies.pod\n";
 168   require DBIx::Class::Optional::Dependencies;
 169   DBIx::Class::Optional::Dependencies->_gen_pod (Meta->version);
 170
 171   # FIXME Disabled due to unsolved issues, ask theorbtwo
 172   #  require Module::Install::Pod::Inherit;
 173   #  PodInherit();
 174 }
 175
 176
 177 tests_recursive (qw|
 178     t
 179 |);
 180
 181 # temporary(?) until I get around to fix M::I wrt xt/
 182 # needs Module::Install::AuthorTests
 183 eval {
 184   recursive_author_tests (qw/xt/);
 185   1;
 186 } || do {
 187   if ($Module::Install::AUTHOR && ! $args->{skip_author_deps}) {
 188     my $err = $@;
 189     eval { require Module::Install::AuthorTests }
 190       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode (or supply --skip_author_deps):\n\n$@\n";
 191     die $@;
 192   }
 193 };
 194
 195
 196 install_script (qw|
 197     script/dbicadmin
 198 |);
 199
 200
 201 ### Mangle makefile - read the comments for more info
 202 #
 203 postamble <<"EOP";
 204
 205 # This will add an extra dep-spec for the distdir target,
 206 # which `make` will fold together in a first-come first-serve
 207 # fashion. What we do here is essentially adding extra
 208 # commands to execute once the distdir is assembled (via
 209 # create_distdir), but before control is returned to a higher
 210 # calling rule.
 211 distdir : dbicadmin_pod_inject
 212
 213 # The pod self-injection code is in fact a hidden option in
 214 # dbicadmin itself
 215 dbicadmin_pod_inject :
 216 \tcd \$(DISTVNAME) && \$(ABSPERL) -Ilib script/dbicadmin --selfinject-pod
 217
 218 # Regenerate manifest before running create_distdir.
 219 create_distdir : manifest
 220
 221 EOP
 222
 223 homepage 'http://www.dbix-class.org/';
 224 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
 225 resources 'license'     => 'http://dev.perl.org/licenses/';
 226 resources 'repository'  => 'git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git';
 227 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
 228 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
 229
 230 # Deprecated/internal modules need no exposure
 231 no_index directory => $_ for (qw|
 232   lib/DBIx/Class/Admin
 233   lib/DBIx/Class/PK/Auto
 234   lib/DBIx/Class/CDBICompat
 235 |);
 236 no_index package => $_ for (qw/
 237   DBIx::Class::Storage::DBIHacks
 238 /);
 239
 240 WriteAll();
 241
 242 # Re-write META.yml to _exclude_ all forced requires (we do not want to ship this)
 243 # We are also not using M::I::AuthorRequires as this will be an extra dep, and
 244 # deps in Makefile.PL suck (no autoinstall)
 245 if ($Module::Install::AUTHOR && ! $args->{skip_author_deps} ) {
 246
 247   # FIXME test_requires is not yet part of META
 248   my %original_build_requires = ( %$build_requires, %$test_requires );
 249   my @all_build_requires = @{delete Meta->{values}{build_requires}};
 250   my %removed_build_requires;
 251
 252   for (@all_build_requires) {
 253     if ($original_build_requires{$_->[0]}) {
 254       push @{Meta->{values}{build_requires}}, $_;
 255     }
 256     else {
 257       $removed_build_requires{$_->[0]} = $_->[1]
 258         unless $_->[0] eq 'ExtUtils::MakeMaker';
 259     }
 260   }
 261
 262   print "Regenerating META with author requires excluded\n";
 263   Meta->write;
 264
 265   # test that we really took things away (just in case)
 266   my $meta = do { local @ARGV = 'META.yml'; local $/; <> };
 267   for (keys %removed_build_requires) {
 268     delete $removed_build_requires{$_}
 269       unless $meta =~ /^ \s+ $_: \s+ $removed_build_requires{$_} \s* $/mx
 270   }
 271
 272   if (keys %removed_build_requires) {
 273     die join ("\n",
 274       "\n\nFATAL FAIL! It looks like some author dependencies made it to the META.yml:",
 275       "(most likely a broken Module::Install)\n",
 276       map { "\t$_" } (keys %removed_build_requires)
 277     ) . "\n\n";
 278   }
 279 }