Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6
   7 ##
   8 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
   9 ##
  10 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  11 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  12 # for that)
  13 BEGIN {
  14   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  15   makemaker_args( NORECURS => 1 );
  16 }
  17
  18 homepage 'http://www.dbix-class.org/';
  19 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
  20 resources 'license'     => 'http://dev.perl.org/licenses/';
  21 resources 'repository'  => 'https://github.com/dbsrgits/DBIx-Class';
  22 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
  23 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
  24
  25 name     'DBIx-Class';
  26 perl_version '5.008001';
  27 all_from 'lib/DBIx/Class.pm';
  28 Meta->{values}{x_authority} = 'cpan:RIBASUSHI';
  29
  30 tests_recursive (qw|
  31     t
  32 |);
  33
  34 install_script (qw|
  35     script/dbicadmin
  36 |);
  37
  38 ###
  39 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  40 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  41 ###
  42 my $runtime_requires = {
  43   # FIXME - temporary, needs throwing out for something more efficient
  44   'Data::Compare'            => '1.22',
  45
  46   # DBI itself should be capable of installation and execution in pure-perl
  47   # mode. However it has never been tested yet, so consider XS for the time
  48   # being
  49   'DBI'                      => '1.57',
  50
  51   # on older versions first() leaks
  52   # for the time being make it a hard dep - when we get
  53   # rid of Sub::Name will revisit this (possibility is
  54   # to use Devel::HideXS to force the pure-perl version
  55   # or something like that)
  56   'List::Util'               => '1.16',
  57
  58   # XS (or XS-dependent) libs
  59   'Sub::Name'                => '0.04',
  60
  61   # pure-perl (FatPack-able) libs
  62   'Class::Accessor::Grouped' => '0.10009',
  63   'Class::C3::Componentised' => '1.0009',
  64   'Class::Inspector'         => '1.24',
  65   'Config::Any'              => '0.20',
  66   'Context::Preserve'        => '0.01',
  67   'Data::Dumper::Concise'    => '2.020',
  68   'Data::Page'               => '2.00',
  69   'Devel::GlobalDestruction' => '0.09',
  70   'Hash::Merge'              => '0.12',
  71   'Moo'                      => '1.000006',
  72   'MRO::Compat'              => '0.12',
  73   'Module::Find'             => '0.07',
  74   'namespace::clean'         => '0.24',
  75   'Path::Class'              => '0.18',
  76   'Scope::Guard'             => '0.03',
  77   'SQL::Abstract'            => '1.73',
  78   'Try::Tiny'                => '0.07',
  79
  80   # Technically this is not a core dependency - it is only required
  81   # by the MySQL codepath. However this particular version is bundled
  82   # since 5.10.0 and is a pure-perl module anyway - let it slide
  83   'Text::Balanced'           => '2.00',
  84 };
  85
  86 my $build_requires = {
  87   # needed for testing only, not for operation
  88   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  89   'DBD::SQLite'              => '1.29',
  90 };
  91
  92 my $test_requires = {
  93   'File::Temp'               => '0.22',
  94   'Test::Exception'          => '0.31',
  95   'Test::Warn'               => '0.21',
  96   'Test::More'               => '0.94',
  97   # not sure if this is necessary at all, ask schwern some day
  98   'Test::Builder'            => '0.94',
  99
 100   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
 101   # remove and do a manual glob-collection if n::c is no longer a dep
 102   'Package::Stash'           => '0.28',
 103 };
 104
 105 # make strictures.pm happy (DO NOT LIKE, TOO MUCH XS!)
 106 # (i.e. what if the .git/.svn is *not* because of DBIC?)
 107 #
 108 # Note - this is added as test_requires *directly*, so it gets properly
 109 # excluded on META.yml cleansing
 110 if (-e '.git' or -e '.svn') {
 111   test_requires 'indirect'              => '0.25';
 112   test_requires 'multidimensional'      => '0.008';
 113   test_requires 'bareword::filehandles' => '0.003';
 114 }
 115
 116 # if the user has this env var set and no SQLT installed, tests will fail
 117 # same rationale for direct test_requires as the strictures stuff above
 118 # (even though no dist will be created from this)
 119 # we force this req regarless of author_deps, worst case scenario it will
 120 # be specified twice
 121 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 122   local @INC = ('lib', @INC);
 123   require DBIx::Class::Optional::Dependencies;
 124   my $dep_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 125   for (keys %$dep_req) {
 126     test_requires ($_ => $dep_req->{$_})
 127   }
 128 }
 129
 130 # this is so we can order requires alphabetically
 131 # copies are needed for potential author requires injection
 132 my $reqs = {
 133   build_requires => { %$build_requires },
 134   requires => { %$runtime_requires },
 135   test_requires => { %$test_requires },
 136 };
 137
 138 # only do author-includes if not part of a `make` run
 139 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 140   # get options here, make $args available to all snippets
 141   require Getopt::Long;
 142   my $getopt = Getopt::Long::Parser->new(
 143     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 144   );
 145   my $args = {
 146     skip_author_deps => undef,
 147   };
 148   $getopt->getoptions($args, qw/
 149     skip_author_deps|skip-author-deps
 150   /);
 151   if (@ARGV) {
 152     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 153   }
 154
 155   # We need the MM facilities to generate the pieces for the final MM run.
 156   # Just instantiate a throaway object here
 157   my $mm_proto = ExtUtils::MakeMaker->new({
 158     NORECURS => 1,
 159     NAME => Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?',
 160   });
 161
 162   # Crutch for DISTBUILDING_IN_HELL
 163   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 164   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 165   # not take into account the CRLF layer present on win32
 166   my $crlf_fixup = sub {
 167     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 168     my $targets = join ', ', map { "q($_)" } @_;
 169     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 170   };
 171
 172   # we are in the process of (re)writing the makefile - some things we
 173   # call below very well may fail
 174   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 175
 176   require File::Spec;
 177   # string-eval, not do(), because we need to provide the
 178   # $mm_proto, $reqs and $*_requires lexicals to the included file
 179   # (some includes *do* modify $reqs above)
 180   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 181     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 182     eval "use warnings; use strict; $src" or die sprintf
 183       "Failed execution of %s: %s\n",
 184       $inc,
 185       ($@ || $! || 'Unknown error'),
 186     ;
 187   }
 188 }
 189 else {
 190   # make sure this Makefile can not be used to make a dist
 191   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 192   postamble <<EOP;
 193 create_distdir: nonauthor_stop_distdir_creation
 194 nonauthor_stop_distdir_creation:
 195 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 196 \t\$(NOECHO) \$(FALSE)
 197 EOP
 198 }
 199
 200 # compose final req list, for alphabetical ordering
 201 my %final_req;
 202 for my $rtype (keys %$reqs) {
 203   for my $mod (keys %{$reqs->{$rtype}} ) {
 204
 205     # sanity check req duplications
 206     if ($final_req{$mod}) {
 207       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 208     }
 209
 210     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 211   }
 212 }
 213
 214 # actual require
 215 for my $mod (sort keys %final_req) {
 216   my ($rtype, $ver) = @{$final_req{$mod}};
 217   no strict 'refs';
 218   $rtype->($mod, $ver);
 219 }
 220
 221 # author-mode or not - this is where we show a list of missing deps
 222 # IFF we are running interactively
 223 auto_install();
 224
 225 WriteAll();