Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN {
   7   # needs to happen early for old EUMM
   8   makemaker_args( NORECURS => 1 );
   9
  10   local @INC = ('lib', @INC);
  11   require DBIx::Class::Optional::Dependencies;
  12 }
  13
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  18 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  19 # for that)
  20 BEGIN {
  21   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  22 }
  23
  24 name         'DBIx-Class';
  25 version_from 'lib/DBIx/Class.pm';
  26 perl_version '5.008001';
  27
  28 ###
  29 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  30 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  31 ###
  32 my $runtime_requires = {
  33
  34   # DBI itself should be capable of installation and execution in pure-perl
  35   # mode. However it has never been tested yet, so consider XS for the time
  36   # being
  37 ###
  38 ### IMPORTANT - do not raise this dependency
  39 ### even though many bugfixes are present in newer versions, the general DBIC
  40 ### rule is to bend over backwards for available DBI versions (given upgrading
  41 ### them is often *not* easy or even possible)
  42 ###
  43   'DBI'                      => '1.57',
  44
  45   # XS (or XS-dependent) libs
  46   'Sub::Name'                => '0.04',
  47
  48   # pure-perl (FatPack-able) libs
  49   'Class::Accessor::Grouped' => '0.10012',
  50   'Class::C3::Componentised' => '1.0009',
  51   'Context::Preserve'        => '0.01',
  52   'Data::Page'               => '2.00',
  53   'Devel::GlobalDestruction' => '0.09',
  54   'Hash::Merge'              => '0.12',
  55   'Moo'                      => '2.000',
  56   'MRO::Compat'              => '0.12',
  57   'Module::Find'             => '0.07',
  58   'namespace::clean'         => '0.24',
  59   'Scope::Guard'             => '0.03',
  60   'SQL::Abstract'            => '1.81',
  61   'Try::Tiny'                => '0.07',
  62
  63   # Technically this is not a core dependency - it is only required
  64   # by the MySQL codepath. However this particular version is bundled
  65   # since 5.10.0 and is a pure-perl module anyway - let it slide
  66   'Text::Balanced'           => '2.00',
  67 };
  68
  69 my $build_requires = {
  70 };
  71
  72 my $test_requires = {
  73   'File::Temp'               => '0.22',
  74   'Test::Deep'               => '0.101',
  75   'Test::Exception'          => '0.31',
  76   'Test::Warn'               => '0.21',
  77   'Test::More'               => '0.94',
  78
  79   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  80   # remove and do a manual glob-collection if n::c is no longer a dep
  81   'Package::Stash'           => '0.28',
  82
  83   # needed for testing only, not for operation
  84   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  85   %{ DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_sqlite') },
  86 };
  87
  88 # if the user has some of these env vars set and the deps are not available,
  89 # tests will fail
  90 # Note - these are added as test_requires *directly*, so they get properly
  91 # excluded on META.yml cleansing (even though no dist can be created from this)
  92 # we force these reqs regarless of --with-optdeps, worst case scenario they will
  93 # be specified twice
  94 #
  95 # also note that we *do* set dynamic_config => 0, as these are the only things
  96 # that we determine dynamically, and in all fairness if someone sets these
  97 # envvars *and* is not running a full Makefile/make/maketest cycle - they get
  98 # to keep the pieces
  99 if ( my @optdeps = (
 100   $ENV{DBICTEST_SQLT_DEPLOY} ? 'deploy' : (),
 101   $ENV{DBICTEST_VIA_REPLICATED} ? 'replicated' : (),
 102 )) {
 103   my $extra_deps = DBIx::Class::Optional::Dependencies->req_list_for(\@optdeps);
 104   for (keys %$extra_deps) {
 105     test_requires ($_ => $extra_deps->{$_})
 106   }
 107 }
 108
 109 tests_recursive ('t');
 110 tests_recursive ('xt') if (
 111   $Module::Install::AUTHOR
 112     or
 113   $ENV{DBICTEST_RUN_ALL_TESTS}
 114     or
 115   ( $ENV{TRAVIS}||'' ) eq 'true'
 116     or
 117   ( $ENV{AUTOMATED_TESTING} and ! $ENV{PERL5_CPANM_IS_RUNNING} and ! $ENV{RELEASE_TESTING} )
 118 );
 119
 120 install_script (qw|
 121     script/dbicadmin
 122 |);
 123
 124 # this is so we can order requires alphabetically
 125 # copies are needed for potential author requires injection
 126 my $reqs = {
 127   build_requires => { %$build_requires },
 128   requires => { %$runtime_requires },
 129   test_requires => { %$test_requires },
 130 };
 131
 132 # only do author-includes if not part of a `make` run
 133 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 134   invoke_author_mode()
 135 }
 136 else {
 137   # make sure this Makefile can not be used to make a dist
 138   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 139   postamble <<EOP;
 140 create_distdir: nonauthor_stop_distdir_creation
 141 nonauthor_stop_distdir_creation:
 142 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 143 \t\$(NOECHO) \$(FALSE)
 144 EOP
 145 }
 146
 147 # compose final req list, for alphabetical ordering
 148 my %final_req;
 149 for my $rtype (keys %$reqs) {
 150   for my $mod (keys %{$reqs->{$rtype}} ) {
 151
 152     # sanity check req duplications
 153     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 154       if $final_req{$mod};
 155
 156     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 157   }
 158 }
 159
 160 # actual require
 161 for my $mod (sort keys %final_req) {
 162   my ($rtype, $ver) = @{$final_req{$mod}};
 163   no strict 'refs';
 164   $rtype->($mod, $ver);
 165 }
 166
 167 # author-mode or not - this is where we show a list of missing deps
 168 # IFF we are running interactively
 169 auto_install();
 170
 171 {
 172   # M::I understands unicode in meta but does not write with the right
 173   # layers - fhtagn!!!
 174   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 175   WriteAll();
 176 }
 177
 178 exit 0;
 179
 180
 181 ###
 182 ### Nothing user-serviceable beyond this point
 183 ### (none of this executes on regular install)
 184 ###
 185
 186
 187 # needs to be here to keep 5.8 string eval happy
 188 # (the include of Makefile.PL.inc loop)
 189 my $mm_proto;
 190
 191 sub invoke_author_mode {
 192   # get options here, make $args available to all snippets
 193   require Getopt::Long;
 194   my $getopt = Getopt::Long::Parser->new(
 195     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 196   );
 197   my $args = {
 198     with_optdeps => undef,
 199   };
 200   $getopt->getoptions($args, qw/
 201     with_optdeps|with-optdeps
 202   /);
 203   if (@ARGV) {
 204     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 205   }
 206
 207   # We need the MM facilities to generate the pieces for the final MM run.
 208   # Just instantiate a throaway object here
 209   #
 210   # Also EUMM and MI disagree on what is the format of Meta->name, just
 211   # punt here until a new M::I is shipped (if at all)
 212   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 213   $name =~ s/\-/::/g;
 214   $mm_proto = ExtUtils::MakeMaker->new({
 215     NORECURS => 1,
 216     NAME => $name,
 217   });
 218
 219   # Crutch for DISTBUILDING_IN_HELL
 220   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 221   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 222   # not take into account the CRLF layer present on win32
 223   my $crlf_fixup = sub {
 224     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 225     my $targets = join ', ', map { "q($_)" } @_;
 226     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 227   };
 228
 229   # string-eval, not do(), because we need to provide the
 230   # $mm_proto, $reqs and $*_requires lexicals to the included file
 231   # (some includes *do* modify $reqs above)
 232   for my $inc (sort glob ( 'maint/Makefile.PL.inc/*' ) ) {
 233     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 234     eval "use warnings; use strict; $src" or die sprintf
 235       "Failed execution of %s: %s\n",
 236       $inc,
 237       ($@ || $! || 'Unknown error'),
 238     ;
 239   }
 240 }