Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6
   7 ##
   8 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
   9 ##
  10 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  11 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  12 # for that)
  13 BEGIN {
  14   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  15   makemaker_args( NORECURS => 1 );
  16 }
  17
  18 homepage 'http://www.dbix-class.org/';
  19 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
  20 resources 'license'     => 'http://dev.perl.org/licenses/';
  21 resources 'repository'  => 'https://github.com/dbsrgits/DBIx-Class';
  22 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
  23 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
  24
  25 name     'DBIx-Class';
  26 perl_version '5.008001';
  27 all_from 'lib/DBIx/Class.pm';
  28 Meta->{values}{x_authority} = 'cpan:RIBASUSHI';
  29
  30 tests_recursive (qw|
  31     t
  32 |);
  33
  34 install_script (qw|
  35     script/dbicadmin
  36 |);
  37
  38 ###
  39 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  40 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  41 ###
  42 my $runtime_requires = {
  43   # FIXME - temporary, needs throwing out for something more efficient
  44   'Data::Compare'            => '1.22',
  45
  46   # DBI itself should be capable of installation and execution in pure-perl
  47   # mode. However it has never been tested yet, so consider XS for the time
  48   # being
  49 ###
  50 ### IMPORTANT - do not raise this dependency
  51 ### even though many bugfixes are present in newer versions, the general DBIC
  52 ### rule is to bend over backwards for available DBI versions (given upgrading
  53 ### them is often *not* easy or even possible)
  54 ###
  55   'DBI'                      => '1.57',
  56
  57   # on older versions first() leaks
  58   # for the time being make it a hard dep - when we get
  59   # rid of Sub::Name will revisit this (possibility is
  60   # to use Devel::HideXS to force the pure-perl version
  61   # or something like that)
  62   'List::Util'               => '1.16',
  63
  64   # XS (or XS-dependent) libs
  65   'Sub::Name'                => '0.04',
  66
  67   # pure-perl (FatPack-able) libs
  68   'Class::Accessor::Grouped' => '0.10010',
  69   'Class::C3::Componentised' => '1.0009',
  70   'Class::Inspector'         => '1.24',
  71   'Config::Any'              => '0.20',
  72   'Context::Preserve'        => '0.01',
  73   'Data::Dumper::Concise'    => '2.020',
  74   'Data::Page'               => '2.00',
  75   'Devel::GlobalDestruction' => '0.09',
  76   'Hash::Merge'              => '0.12',
  77   'Moo'                      => '1.002',
  78   'MRO::Compat'              => '0.12',
  79   'Module::Find'             => '0.07',
  80   'namespace::clean'         => '0.24',
  81   'Path::Class'              => '0.18',
  82   'Scope::Guard'             => '0.03',
  83   'SQL::Abstract'            => '1.77',
  84   'Try::Tiny'                => '0.07',
  85
  86   # Technically this is not a core dependency - it is only required
  87   # by the MySQL codepath. However this particular version is bundled
  88   # since 5.10.0 and is a pure-perl module anyway - let it slide
  89   'Text::Balanced'           => '2.00',
  90 };
  91
  92 my $build_requires = {
  93   # needed for testing only, not for operation
  94   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  95 ###
  96 ### IMPORTANT - do not raise this dependency
  97 ### even though many bugfixes are present in newer versions, the general DBIC
  98 ### rule is to bend over backwards for available DBDs (given upgrading them is
  99 ### often *not* easy or even possible)
 100 ###
 101   'DBD::SQLite'              => '1.29',
 102 };
 103
 104 my $test_requires = {
 105   'File::Temp'               => '0.22',
 106   'Test::Deep'               => '0.101',
 107   'Test::Exception'          => '0.31',
 108   'Test::Warn'               => '0.21',
 109   'Test::More'               => '0.94',
 110
 111   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
 112   # remove and do a manual glob-collection if n::c is no longer a dep
 113   'Package::Stash'           => '0.28',
 114 };
 115
 116 # if the user has this env var set and no SQLT installed, tests will fail
 117 # same rationale for direct test_requires as the strictures stuff above
 118 # (even though no dist will be created from this)
 119 # we force this req regarless of author_deps, worst case scenario it will
 120 # be specified twice
 121 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 122   local @INC = ('lib', @INC);
 123   require DBIx::Class::Optional::Dependencies;
 124   my $dep_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 125   for (keys %$dep_req) {
 126     test_requires ($_ => $dep_req->{$_})
 127   }
 128 }
 129
 130 # this is so we can order requires alphabetically
 131 # copies are needed for potential author requires injection
 132 my $reqs = {
 133   build_requires => { %$build_requires },
 134   requires => { %$runtime_requires },
 135   test_requires => { %$test_requires },
 136 };
 137
 138 # only do author-includes if not part of a `make` run
 139 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 140   # get options here, make $args available to all snippets
 141   require Getopt::Long;
 142   my $getopt = Getopt::Long::Parser->new(
 143     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 144   );
 145   my $args = {
 146     skip_author_deps => undef,
 147   };
 148   $getopt->getoptions($args, qw/
 149     skip_author_deps|skip-author-deps
 150   /);
 151   if (@ARGV) {
 152     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 153   }
 154
 155   # We need the MM facilities to generate the pieces for the final MM run.
 156   # Just instantiate a throaway object here
 157   #
 158   # Also EUMM and MI disagree on what is the format of Meta->name, just
 159   # punt here until a new M::I is shipped (if at all)
 160   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 161   $name =~ s/\-/::/g;
 162   my $mm_proto = ExtUtils::MakeMaker->new({
 163     NORECURS => 1,
 164     NAME => $name,
 165   });
 166
 167   # Crutch for DISTBUILDING_IN_HELL
 168   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 169   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 170   # not take into account the CRLF layer present on win32
 171   my $crlf_fixup = sub {
 172     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 173     my $targets = join ', ', map { "q($_)" } @_;
 174     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 175   };
 176
 177   # we are in the process of (re)writing the makefile - some things we
 178   # call below very well may fail
 179   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 180
 181   require File::Spec;
 182   # string-eval, not do(), because we need to provide the
 183   # $mm_proto, $reqs and $*_requires lexicals to the included file
 184   # (some includes *do* modify $reqs above)
 185   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 186     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 187     eval "use warnings; use strict; $src" or die sprintf
 188       "Failed execution of %s: %s\n",
 189       $inc,
 190       ($@ || $! || 'Unknown error'),
 191     ;
 192   }
 193 }
 194 else {
 195   # make sure this Makefile can not be used to make a dist
 196   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 197   postamble <<EOP;
 198 create_distdir: nonauthor_stop_distdir_creation
 199 nonauthor_stop_distdir_creation:
 200 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 201 \t\$(NOECHO) \$(FALSE)
 202 EOP
 203 }
 204
 205 # compose final req list, for alphabetical ordering
 206 my %final_req;
 207 for my $rtype (keys %$reqs) {
 208   for my $mod (keys %{$reqs->{$rtype}} ) {
 209
 210     # sanity check req duplications
 211     if ($final_req{$mod}) {
 212       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 213     }
 214
 215     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 216   }
 217 }
 218
 219 # actual require
 220 for my $mod (sort keys %final_req) {
 221   my ($rtype, $ver) = @{$final_req{$mod}};
 222   no strict 'refs';
 223   $rtype->($mod, $ver);
 224 }
 225
 226 # author-mode or not - this is where we show a list of missing deps
 227 # IFF we are running interactively
 228 auto_install();
 229
 230 WriteAll();