Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN { makemaker_args( NORECURS => 1 ) } # needs to happen early for old EUMM
   7
   8 ##
   9 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  10 ##
  11 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  12 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  13 # for that)
  14 BEGIN {
  15   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  16 }
  17
  18 homepage 'http://www.dbix-class.org/';
  19 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
  20 resources 'license'     => 'http://dev.perl.org/licenses/';
  21 resources 'repository'  => 'https://github.com/dbsrgits/DBIx-Class';
  22 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
  23 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
  24
  25 name     'DBIx-Class';
  26 perl_version '5.008001';
  27 all_from 'lib/DBIx/Class.pm';
  28 Meta->{values}{x_authority} = 'cpan:RIBASUSHI';
  29
  30 # nothing determined at runtime, except for possibly SQLT dep, see
  31 # comment further down
  32 dynamic_config 0;
  33
  34 tests_recursive (qw|
  35     t
  36 |);
  37
  38 install_script (qw|
  39     script/dbicadmin
  40 |);
  41
  42 ###
  43 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  44 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  45 ###
  46 my $runtime_requires = {
  47   # FIXME - temporary, needs throwing out for something more efficient
  48   'Data::Compare'            => '1.22',
  49
  50   # DBI itself should be capable of installation and execution in pure-perl
  51   # mode. However it has never been tested yet, so consider XS for the time
  52   # being
  53 ###
  54 ### IMPORTANT - do not raise this dependency
  55 ### even though many bugfixes are present in newer versions, the general DBIC
  56 ### rule is to bend over backwards for available DBI versions (given upgrading
  57 ### them is often *not* easy or even possible)
  58 ###
  59   'DBI'                      => '1.57',
  60
  61   # on older versions first() leaks
  62   # for the time being make it a hard dep - when we get
  63   # rid of Sub::Name will revisit this (possibility is
  64   # to use Devel::HideXS to force the pure-perl version
  65   # or something like that)
  66   'List::Util'               => '1.16',
  67
  68   # XS (or XS-dependent) libs
  69   'Sub::Name'                => '0.04',
  70
  71   # pure-perl (FatPack-able) libs
  72   'Class::Accessor::Grouped' => '0.10010',
  73   'Class::C3::Componentised' => '1.0009',
  74   'Class::Inspector'         => '1.24',
  75   'Config::Any'              => '0.20',
  76   'Context::Preserve'        => '0.01',
  77   'Data::Dumper::Concise'    => '2.020',
  78   'Data::Page'               => '2.00',
  79   'Devel::GlobalDestruction' => '0.09',
  80   'Hash::Merge'              => '0.12',
  81   'Moo'                      => '1.002',
  82   'MRO::Compat'              => '0.12',
  83   'Module::Find'             => '0.07',
  84   'namespace::clean'         => '0.24',
  85   'Path::Class'              => '0.18',
  86   'Scope::Guard'             => '0.03',
  87   'SQL::Abstract'            => '1.77',
  88   'Try::Tiny'                => '0.07',
  89
  90   # Technically this is not a core dependency - it is only required
  91   # by the MySQL codepath. However this particular version is bundled
  92   # since 5.10.0 and is a pure-perl module anyway - let it slide
  93   'Text::Balanced'           => '2.00',
  94 };
  95
  96 my $build_requires = {
  97 };
  98
  99 my $test_requires = {
 100   'File::Temp'               => '0.22',
 101   'Test::Deep'               => '0.101',
 102   'Test::Exception'          => '0.31',
 103   'Test::Warn'               => '0.21',
 104   'Test::More'               => '0.94',
 105
 106   # needed for testing only, not for operation
 107   # we will move away from this dep eventually, perhaps to DBD::CSV or something
 108 ###
 109 ### IMPORTANT - do not raise this dependency
 110 ### even though many bugfixes are present in newer versions, the general DBIC
 111 ### rule is to bend over backwards for available DBDs (given upgrading them is
 112 ### often *not* easy or even possible)
 113 ###
 114   'DBD::SQLite'              => '1.29',
 115
 116   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
 117   # remove and do a manual glob-collection if n::c is no longer a dep
 118   'Package::Stash'           => '0.28',
 119 };
 120
 121 # if the user has this env var set and no SQLT installed, tests will fail
 122 # Note - this is added as test_requires *directly*, so it gets properly
 123 # excluded on META.yml cleansing (even though no dist can be created from this)
 124 # we force this req regarless of author_deps, worst case scenario it will
 125 # be specified twice
 126 #
 127 # also note that we *do* set dynamic_config => 0, as this is the only thing
 128 # that we determine dynamically, and in all fairness if someone sets the
 129 # envvar *and* is not running a full Makefile/make/maketest cycle - they get
 130 # to keep the pieces
 131 if ($ENV{DBICTEST_SQLT_DEPLOY}) {
 132   local @INC = ('lib', @INC);
 133   require DBIx::Class::Optional::Dependencies;
 134   my $dep_req = DBIx::Class::Optional::Dependencies->req_list_for('deploy');
 135   for (keys %$dep_req) {
 136     test_requires ($_ => $dep_req->{$_})
 137   }
 138 }
 139
 140 # this is so we can order requires alphabetically
 141 # copies are needed for potential author requires injection
 142 my $reqs = {
 143   build_requires => { %$build_requires },
 144   requires => { %$runtime_requires },
 145   test_requires => { %$test_requires },
 146 };
 147
 148 # only do author-includes if not part of a `make` run
 149 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 150   invoke_author_mode()
 151 }
 152 else {
 153   # make sure this Makefile can not be used to make a dist
 154   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 155   postamble <<EOP;
 156 create_distdir: nonauthor_stop_distdir_creation
 157 nonauthor_stop_distdir_creation:
 158 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 159 \t\$(NOECHO) \$(FALSE)
 160 EOP
 161 }
 162
 163 # compose final req list, for alphabetical ordering
 164 my %final_req;
 165 for my $rtype (keys %$reqs) {
 166   for my $mod (keys %{$reqs->{$rtype}} ) {
 167
 168     # sanity check req duplications
 169     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 170       if $final_req{$mod};
 171
 172     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 173   }
 174 }
 175
 176 # actual require
 177 for my $mod (sort keys %final_req) {
 178   my ($rtype, $ver) = @{$final_req{$mod}};
 179   no strict 'refs';
 180   $rtype->($mod, $ver);
 181 }
 182
 183 # author-mode or not - this is where we show a list of missing deps
 184 # IFF we are running interactively
 185 auto_install();
 186
 187 WriteAll();
 188
 189 exit 0;
 190
 191 # needs to be here to keep 5.8 string eval happy
 192 # (the include of Makefile.PL.inc loop)
 193 my $mm_proto;
 194
 195 sub invoke_author_mode {
 196   # get options here, make $args available to all snippets
 197   require Getopt::Long;
 198   my $getopt = Getopt::Long::Parser->new(
 199     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 200   );
 201   my $args = {
 202     skip_author_deps => undef,
 203   };
 204   $getopt->getoptions($args, qw/
 205     skip_author_deps|skip-author-deps
 206   /);
 207   if (@ARGV) {
 208     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 209   }
 210
 211   # We need the MM facilities to generate the pieces for the final MM run.
 212   # Just instantiate a throaway object here
 213   #
 214   # Also EUMM and MI disagree on what is the format of Meta->name, just
 215   # punt here until a new M::I is shipped (if at all)
 216   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 217   $name =~ s/\-/::/g;
 218   $mm_proto = ExtUtils::MakeMaker->new({
 219     NORECURS => 1,
 220     NAME => $name,
 221   });
 222
 223   # Crutch for DISTBUILDING_IN_HELL
 224   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 225   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 226   # not take into account the CRLF layer present on win32
 227   my $crlf_fixup = sub {
 228     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 229     my $targets = join ', ', map { "q($_)" } @_;
 230     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 231   };
 232
 233   # we are in the process of (re)writing the makefile - some things we
 234   # call below very well may fail
 235   local $ENV{DBICTEST_NO_MAKEFILE_VERIFICATION} = 1;
 236
 237   require File::Spec;
 238   # string-eval, not do(), because we need to provide the
 239   # $mm_proto, $reqs and $*_requires lexicals to the included file
 240   # (some includes *do* modify $reqs above)
 241   for my $inc (sort glob ( File::Spec->catfile('maint', 'Makefile.PL.inc', '*') ) ) {
 242     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 243     eval "use warnings; use strict; $src" or die sprintf
 244       "Failed execution of %s: %s\n",
 245       $inc,
 246       ($@ || $! || 'Unknown error'),
 247     ;
 248   }
 249 }