[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / _Util.pm

package # hide from PAUSE
  DBIx::Class::_Util;

use warnings;
use strict;

# Temporary - tempextlib
use namespace::clean;
BEGIN {
  require Module::Runtime;
  require File::Spec;

  # There can be only one of these, make sure we get the bundled part and
  # *not* something off the site lib
  for (qw(
    DBIx::Class::SQLMaker
    SQL::Abstract
    SQL::Abstract::Test
  )) {
    if ($INC{Module::Runtime::module_notional_filename($_)}) {
      die "\nUnable to continue - a part of the bundled templib contents "
        . "was already loaded (likely an older version from CPAN). "
        . "Make sure that @{[ __PACKAGE__ ]} is loaded before $_\n\n"
      ;
    }
  }

  our ($HERE) = File::Spec->rel2abs(
    File::Spec->catdir( (File::Spec->splitpath(__FILE__))[1], '_TempExtlib' )
  ) =~ /^(.*)$/; # screw you, taint mode

  die "TempExtlib $HERE does not seem to exist - perhaps you need to run `perl Makefile.PL` in the DBIC checkout?\n"
    unless -d $HERE;

  unshift @INC, $HERE;
}

use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);

BEGIN {
  package # hide from pause
    DBIx::Class::_ENV_;

  use Config;

  use constant {

    # but of course
    BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,

    BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,

    HAS_ITHREADS => $Config{useithreads} ? 1 : 0,

    # ::Runmode would only be loaded by DBICTest, which in turn implies t/
    DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,

    # During 5.13 dev cycle HELEMs started to leak on copy
    # add an escape for these perls ON SMOKERS - a user will still get death
    PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),

    SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,

    ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,

    ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,

    IV_SIZE => $Config{ivsize},

    OS_NAME => $^O,
  };

  if ($] < 5.009_005) {
    require MRO::Compat;
    constant->import( OLD_MRO => 1 );
  }
  else {
    require mro;
    constant->import( OLD_MRO => 0 );
  }
}

# FIXME - this is not supposed to be here
# Carp::Skip to the rescue soon
use DBIx::Class::Carp '^DBIx::Class|^DBICTest';

use Carp 'croak';
use Scalar::Util qw(weaken blessed reftype);
use List::Util qw(first);

# DO NOT edit away without talking to riba first, he will just put it back
# BEGIN pre-Moo2 import block
BEGIN {
  my $initial_fatal_bits = (${^WARNING_BITS}||'') & $warnings::DeadBits{all};

  local $ENV{PERL_STRICTURES_EXTRA} = 0;
  # load all of these now, so that lazy-loading does not escape
  # the current PERL_STRICTURES_EXTRA setting
  require Sub::Quote;
  require Sub::Defer;

  Sub::Quote->import('quote_sub');
  ${^WARNING_BITS} &= ( $initial_fatal_bits | ~ $warnings::DeadBits{all} );
}
sub qsub ($) { goto &quote_sub }  # no point depping on new Moo just for this
# END pre-Moo2 import block

use base 'Exporter';
our @EXPORT_OK = qw(
  sigwarn_silencer modver_gt_or_eq
  fail_on_internal_wantarray fail_on_internal_call
  refdesc refcount hrefaddr is_exception
  quote_sub qsub perlstring serialize
  UNRESOLVABLE_CONDITION
);

use constant UNRESOLVABLE_CONDITION => \ '1 = 0';

sub sigwarn_silencer ($) {
  my $pattern = shift;

  croak "Expecting a regexp" if ref $pattern ne 'Regexp';

  my $orig_sig_warn = $SIG{__WARN__} || sub { CORE::warn(@_) };

  return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
}

sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };

sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr||0 }

sub refdesc ($) {
  croak "Expecting a reference" if ! length ref $_[0];

  # be careful not to trigger stringification,
  # reuse @_ as a scratch-pad
  sprintf '%s%s(0x%x)',
    ( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
    reftype $_[0],
    Scalar::Util::refaddr($_[0]),
  ;
}

sub refcount ($) {
  croak "Expecting a reference" if ! length ref $_[0];

  require B;
  # No tempvars - must operate on $_[0], otherwise the pad
  # will count as an extra ref
  B::svref_2object($_[0])->REFCNT;
}

sub serialize ($) {
  require Storable;
  local $Storable::canonical = 1;
  Storable::nfreeze($_[0]);
}

sub is_exception ($) {
  my $e = $_[0];

  # this is not strictly correct - an eval setting $@ to undef
  # is *not* the same as an eval setting $@ to ''
  # but for the sake of simplicity assume the following for
  # the time being
  return 0 unless defined $e;

  my ($not_blank, $suberror);
  {
    local $@;
    eval {
      $not_blank = ($e ne '') ? 1 : 0;
      1;
    } or $suberror = $@;
  }

  if (defined $suberror) {
    if (length (my $class = blessed($e) )) {
      carp_unique( sprintf(
        'External exception class %s implements partial (broken) overloading '
      . 'preventing its instances from being used in simple ($x eq $y) '
      . 'comparisons. Given Perl\'s "globally cooperative" exception '
      . 'handling this type of brokenness is extremely dangerous on '
      . 'exception objects, as it may (and often does) result in silent '
      . '"exception substitution". DBIx::Class tries to work around this '
      . 'as much as possible, but other parts of your software stack may '
      . 'not be even aware of this. Please submit a bugreport against the '
      . 'distribution containing %s and in the meantime apply a fix similar '
      . 'to the one shown at %s, in order to ensure your exception handling '
      . 'is saner application-wide. What follows is the actual error text '
      . "as generated by Perl itself:\n\n%s\n ",
        $class,
        $class,
        'http://v.gd/DBIC_overload_tempfix/',
        $suberror,
      ));

      # workaround, keeps spice flowing
      $not_blank = ("$e" ne '') ? 1 : 0;
    }
    else {
      # not blessed yet failed the 'ne'... this makes 0 sense...
      # just throw further
      die $suberror
    }
  }

  return $not_blank;
}

sub modver_gt_or_eq ($$) {
  my ($mod, $ver) = @_;

  croak "Nonsensical module name supplied"
    if ! defined $mod or ! length $mod;

  croak "Nonsensical minimum version supplied"
    if ! defined $ver or $ver =~ /[^0-9\.\_]/;

  local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
    if SPURIOUS_VERSION_CHECK_WARNINGS;

  croak "$mod does not seem to provide a version (perhaps it never loaded)"
    unless $mod->VERSION;

  local $@;
  eval { $mod->VERSION($ver) } ? 1 : 0;
}

{
  my $list_ctx_ok_stack_marker;

  sub fail_on_internal_wantarray () {
    return if $list_ctx_ok_stack_marker;

    if (! defined wantarray) {
      croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
    }

    my $cf = 1;
    while ( ( (caller($cf+1))[3] || '' ) =~ / :: (?:

      # these are public API parts that alter behavior on wantarray
      search | search_related | slice | search_literal

        |

      # these are explicitly prefixed, since we only recognize them as valid
      # escapes when they come from the guts of CDBICompat
      CDBICompat .*? :: (?: search_where | retrieve_from_sql | retrieve_all )

    ) $/x ) {
      $cf++;
    }

    my ($fr, $want, $argdesc);
    {
      package DB;
      $fr = [ caller($cf) ];
      $want = ( caller($cf-1) )[5];
      $argdesc = ref $DB::args[0]
        ? DBIx::Class::_Util::refdesc($DB::args[0])
        : 'non '
      ;
    };

    if (
      $want and $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
    ) {
      DBIx::Class::Exception->throw( sprintf (
        "Improper use of %s instance in list context at %s line %d\n\n    Stacktrace starts",
        $argdesc, @{$fr}[1,2]
      ), 'with_stacktrace');
    }

    my $mark = [];
    weaken ( $list_ctx_ok_stack_marker = $mark );
    $mark;
  }
}

sub fail_on_internal_call {
  my ($fr, $argdesc);
  {
    package DB;
    $fr = [ caller(1) ];
    $argdesc = ref $DB::args[0]
      ? DBIx::Class::_Util::refdesc($DB::args[0])
      : undef
    ;
  };

  if (
    $argdesc
      and
    $fr->[0] =~ /^(?:DBIx::Class|DBICx::)/
      and
    $fr->[1] !~ /\b(?:CDBICompat|ResultSetProxy)\b/  # no point touching there
  ) {
    DBIx::Class::Exception->throw( sprintf (
      "Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n    Stacktrace starts",
      $fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] || do {
        require B::Deparse;
        no strict 'refs';
        B::Deparse->new->coderef2text(\&{$fr->[3]})
      }),
    ), 'with_stacktrace');
  }
}

1;
Commit	Line	Data
b1dbf716	1	package # hide from PAUSE
	2	DBIx::Class::_Util;
	3
	4	use warnings;
	5	use strict;
	6
d0435d75	7	# Temporary - tempextlib
	8	use namespace::clean;
	9	BEGIN {
	10	require Module::Runtime;
	11	require File::Spec;
	12
	13	# There can be only one of these, make sure we get the bundled part and
	14	# not something off the site lib
	15	for (qw(
	16	DBIx::Class::SQLMaker
	17	SQL::Abstract
	18	SQL::Abstract::Test
	19	)) {
	20	if ($INC{Module::Runtime::module_notional_filename($_)}) {
	21	die "\nUnable to continue - a part of the bundled templib contents "
	22	. "was already loaded (likely an older version from CPAN). "
	23	. "Make sure that @{[ __PACKAGE__ ]} is loaded before $_\n\n"
	24	;
	25	}
	26	}
	27
	28	our ($HERE) = File::Spec->rel2abs(
	29	File::Spec->catdir( (File::Spec->splitpath(__FILE__))[1], '_TempExtlib' )
	30	) =~ /^(.*)$/; # screw you, taint mode
	31
c1ce337f	32	die "TempExtlib $HERE does not seem to exist - perhaps you need to run `perl Makefile.PL` in the DBIC checkout?\n"
	33	unless -d $HERE;
	34
d0435d75	35	unshift @INC, $HERE;
	36	}
	37
b1dbf716	38	use constant SPURIOUS_VERSION_CHECK_WARNINGS => ($] < 5.010 ? 1 : 0);
b1dbf716	39
37873f78	40	BEGIN {
	41	package # hide from pause
	42	DBIx::Class::_ENV_;
	43
	44	use Config;
	45
	46	use constant {
	47
	48	# but of course
	49	BROKEN_FORK => ($^O eq 'MSWin32') ? 1 : 0,
	50
8d73fcd4	51	BROKEN_GOTO => ($] < '5.008003') ? 1 : 0,
8d73fcd4	52
37873f78	53	HAS_ITHREADS => $Config{useithreads} ? 1 : 0,
	54
	55	# ::Runmode would only be loaded by DBICTest, which in turn implies t/
	56	DBICTEST => eval { DBICTest::RunMode->is_author } ? 1 : 0,
	57
	58	# During 5.13 dev cycle HELEMs started to leak on copy
6cfb1d2f	59	# add an escape for these perls ON SMOKERS - a user will still get death
6cfb1d2f	60	PEEPEENESS => ( eval { DBICTest::RunMode->is_smoker } && ($] >= 5.013005 and $] <= 5.013006) ),
37873f78	61
1b658919	62	SHUFFLE_UNORDERED_RESULTSETS => $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} ? 1 : 0,
1b658919	63
37873f78	64	ASSERT_NO_INTERNAL_WANTARRAY => $ENV{DBIC_ASSERT_NO_INTERNAL_WANTARRAY} ? 1 : 0,
37873f78	65
77c3a5dc	66	ASSERT_NO_INTERNAL_INDIRECT_CALLS => $ENV{DBIC_ASSERT_NO_INTERNAL_INDIRECT_CALLS} ? 1 : 0,
77c3a5dc	67
37873f78	68	IV_SIZE => $Config{ivsize},
00882d2c	69
00882d2c	70	OS_NAME => $^O,
37873f78	71	};
	72
	73	if ($] < 5.009_005) {
	74	require MRO::Compat;
	75	constant->import( OLD_MRO => 1 );
	76	}
	77	else {
	78	require mro;
	79	constant->import( OLD_MRO => 0 );
	80	}
	81	}
	82
841efcb3	83	# FIXME - this is not supposed to be here
	84	# Carp::Skip to the rescue soon
	85	use DBIx::Class::Carp '^DBIx::Class\|^DBICTest';
	86
	87	use Carp 'croak';
bf302897	88	use Scalar::Util qw(weaken blessed reftype);
3705e3b2	89	use List::Util qw(first);
b1dbf716	90
7f9a3f70	91	# DO NOT edit away without talking to riba first, he will just put it back
	92	# BEGIN pre-Moo2 import block
	93	BEGIN {
	94	my $initial_fatal_bits = (${^WARNING_BITS}\|\|'') & $warnings::DeadBits{all};
cbd7f87a	95
7f9a3f70	96	local $ENV{PERL_STRICTURES_EXTRA} = 0;
cbd7f87a	97	# load all of these now, so that lazy-loading does not escape
	98	# the current PERL_STRICTURES_EXTRA setting
	99	require Sub::Quote;
	100	require Sub::Defer;
	101
	102	Sub::Quote->import('quote_sub');
7f9a3f70	103	${^WARNING_BITS} &= ( $initial_fatal_bits \| ~ $warnings::DeadBits{all} );
	104	}
	105	sub qsub ($) { goto &quote_sub } # no point depping on new Moo just for this
	106	# END pre-Moo2 import block
	107
b1dbf716	108	use base 'Exporter';
3705e3b2	109	our @EXPORT_OK = qw(
77c3a5dc	110	sigwarn_silencer modver_gt_or_eq
77c3a5dc	111	fail_on_internal_wantarray fail_on_internal_call
8433421f	112	refdesc refcount hrefaddr is_exception
b34d9331	113	quote_sub qsub perlstring serialize
facd0e8e	114	UNRESOLVABLE_CONDITION
3705e3b2	115	);
052a832c	116
facd0e8e	117	use constant UNRESOLVABLE_CONDITION => \ '1 = 0';
facd0e8e	118
bf302897	119	sub sigwarn_silencer ($) {
052a832c	120	my $pattern = shift;
	121
	122	croak "Expecting a regexp" if ref $pattern ne 'Regexp';
	123
	124	my $orig_sig_warn = $SIG{__WARN__} \|\| sub { CORE::warn(@_) };
	125
	126	return sub { &$orig_sig_warn unless $_[0] =~ $pattern };
	127	}
b1dbf716	128
01b25f12	129	sub perlstring ($) { q{"}. quotemeta( shift ). q{"} };
01b25f12	130
8433421f	131	sub hrefaddr ($) { sprintf '0x%x', &Scalar::Util::refaddr\|\|0 }
	132
	133	sub refdesc ($) {
	134	croak "Expecting a reference" if ! length ref $_[0];
	135
	136	# be careful not to trigger stringification,
	137	# reuse @_ as a scratch-pad
	138	sprintf '%s%s(0x%x)',
	139	( defined( $_[1] = blessed $_[0]) ? "$_[1]=" : '' ),
	140	reftype $_[0],
	141	Scalar::Util::refaddr($_[0]),
	142	;
	143	}
bf302897	144
bf302897	145	sub refcount ($) {
dac7972a	146	croak "Expecting a reference" if ! length ref $_[0];
	147
	148	require B;
	149	# No tempvars - must operate on $_[0], otherwise the pad
	150	# will count as an extra ref
	151	B::svref_2object($_[0])->REFCNT;
	152	}
	153
b34d9331	154	sub serialize ($) {
	155	require Storable;
	156	local $Storable::canonical = 1;
	157	Storable::nfreeze($_[0]);
	158	}
	159
841efcb3	160	sub is_exception ($) {
	161	my $e = $_[0];
	162
a0414138	163	# this is not strictly correct - an eval setting $@ to undef
	164	# is not the same as an eval setting $@ to ''
	165	# but for the sake of simplicity assume the following for
	166	# the time being
	167	return 0 unless defined $e;
	168
841efcb3	169	my ($not_blank, $suberror);
	170	{
	171	local $@;
	172	eval {
	173	$not_blank = ($e ne '') ? 1 : 0;
	174	1;
	175	} or $suberror = $@;
	176	}
	177
	178	if (defined $suberror) {
	179	if (length (my $class = blessed($e) )) {
	180	carp_unique( sprintf(
9bea2000	181	'External exception class %s implements partial (broken) overloading '
9bea2000	182	. 'preventing its instances from being used in simple ($x eq $y) '
841efcb3	183	. 'comparisons. Given Perl\'s "globally cooperative" exception '
	184	. 'handling this type of brokenness is extremely dangerous on '
	185	. 'exception objects, as it may (and often does) result in silent '
	186	. '"exception substitution". DBIx::Class tries to work around this '
	187	. 'as much as possible, but other parts of your software stack may '
	188	. 'not be even aware of this. Please submit a bugreport against the '
	189	. 'distribution containing %s and in the meantime apply a fix similar '
	190	. 'to the one shown at %s, in order to ensure your exception handling '
	191	. 'is saner application-wide. What follows is the actual error text '
	192	. "as generated by Perl itself:\n\n%s\n ",
9bea2000	193	$class,
841efcb3	194	$class,
	195	'http://v.gd/DBIC_overload_tempfix/',
	196	$suberror,
	197	));
	198
	199	# workaround, keeps spice flowing
	200	$not_blank = ("$e" ne '') ? 1 : 0;
	201	}
	202	else {
	203	# not blessed yet failed the 'ne'... this makes 0 sense...
	204	# just throw further
	205	die $suberror
	206	}
	207	}
	208
	209	return $not_blank;
	210	}
	211
bf302897	212	sub modver_gt_or_eq ($$) {
b1dbf716	213	my ($mod, $ver) = @_;
	214
	215	croak "Nonsensical module name supplied"
	216	if ! defined $mod or ! length $mod;
	217
	218	croak "Nonsensical minimum version supplied"
	219	if ! defined $ver or $ver =~ /[^0-9\.\_]/;
	220
052a832c	221	local $SIG{__WARN__} = sigwarn_silencer( qr/\Qisn't numeric in subroutine entry/ )
052a832c	222	if SPURIOUS_VERSION_CHECK_WARNINGS;
b1dbf716	223
56270bba	224	croak "$mod does not seem to provide a version (perhaps it never loaded)"
	225	unless $mod->VERSION;
	226
b1dbf716	227	local $@;
	228	eval { $mod->VERSION($ver) } ? 1 : 0;
	229	}
	230
a9da9b6a	231	{
	232	my $list_ctx_ok_stack_marker;
	233
e89c7968	234	sub fail_on_internal_wantarray () {
a9da9b6a	235	return if $list_ctx_ok_stack_marker;
	236
	237	if (! defined wantarray) {
	238	croak('fail_on_internal_wantarray() needs a tempvar to save the stack marker guard');
	239	}
	240
	241	my $cf = 1;
	242	while ( ( (caller($cf+1))[3] \|\| '' ) =~ / :: (?:
	243
	244	# these are public API parts that alter behavior on wantarray
	245	search \| search_related \| slice \| search_literal
	246
	247	\|
	248
	249	# these are explicitly prefixed, since we only recognize them as valid
	250	# escapes when they come from the guts of CDBICompat
	251	CDBICompat .*? :: (?: search_where \| retrieve_from_sql \| retrieve_all )
	252
	253	) $/x ) {
	254	$cf++;
	255	}
	256
e89c7968	257	my ($fr, $want, $argdesc);
	258	{
	259	package DB;
	260	$fr = [ caller($cf) ];
	261	$want = ( caller($cf-1) )[5];
	262	$argdesc = ref $DB::args[0]
	263	? DBIx::Class::_Util::refdesc($DB::args[0])
	264	: 'non '
	265	;
	266	};
	267
a9da9b6a	268	if (
e89c7968	269	$want and $fr->[0] =~ /^(?:DBIx::Class\|DBICx::)/
a9da9b6a	270	) {
a9da9b6a	271	DBIx::Class::Exception->throw( sprintf (
e89c7968	272	"Improper use of %s instance in list context at %s line %d\n\n Stacktrace starts",
e89c7968	273	$argdesc, @{$fr}[1,2]
a9da9b6a	274	), 'with_stacktrace');
	275	}
	276
	277	my $mark = [];
	278	weaken ( $list_ctx_ok_stack_marker = $mark );
	279	$mark;
	280	}
	281	}
	282
77c3a5dc	283	sub fail_on_internal_call {
	284	my ($fr, $argdesc);
	285	{
	286	package DB;
	287	$fr = [ caller(1) ];
	288	$argdesc = ref $DB::args[0]
	289	? DBIx::Class::_Util::refdesc($DB::args[0])
	290	: undef
	291	;
	292	};
	293
	294	if (
	295	$argdesc
	296	and
	297	$fr->[0] =~ /^(?:DBIx::Class\|DBICx::)/
	298	and
	299	$fr->[1] !~ /\b(?:CDBICompat\|ResultSetProxy)\b/ # no point touching there
	300	) {
	301	DBIx::Class::Exception->throw( sprintf (
	302	"Illegal internal call of indirect proxy-method %s() with argument %s: examine the last lines of the proxy method deparse below to determine what to call directly instead at %s on line %d\n\n%s\n\n Stacktrace starts",
	303	$fr->[3], $argdesc, @{$fr}[1,2], ( $fr->[6] \|\| do {
	304	require B::Deparse;
	305	no strict 'refs';
	306	B::Deparse->new->coderef2text(\&{$fr->[3]})
	307	}),
	308	), 'with_stacktrace');
	309	}
	310	}
	311
b1dbf716	312	1;