[catagits/Catalyst-Runtime.git] / lib / Catalyst / Engine / HTTP.pm

package Catalyst::Engine::HTTP;

use strict;
use base 'Catalyst::Engine::CGI';
use Errno 'EWOULDBLOCK';
use HTTP::Status;
use NEXT;
use Socket;
use IO::Socket::INET ();
use IO::Select       ();

# For PAR
require Catalyst::Engine::HTTP::Restarter;
require Catalyst::Engine::HTTP::Restarter::Watcher;

=head1 NAME

Catalyst::Engine::HTTP - Catalyst HTTP Engine

=head1 SYNOPSIS

A script using the Catalyst::Engine::HTTP module might look like:

    #!/usr/bin/perl -w

    BEGIN {  $ENV{CATALYST_ENGINE} = 'HTTP' }

    use strict;
    use lib '/path/to/MyApp/lib';
    use MyApp;

    MyApp->run;

=head1 DESCRIPTION

This is the Catalyst engine specialized for development and testing.

=head1 METHODS

=head2 $self->finalize_headers($c)

=cut

sub finalize_headers {
    my ( $self, $c ) = @_;
    my $protocol = $c->request->protocol;
    my $status   = $c->response->status;
    my $message  = status_message($status);
    print "$protocol $status $message\015\012";
    $c->response->headers->date(time);
    $c->response->headers->header(
        Connection => $self->_keep_alive ? 'keep-alive' : 'close' );
    $self->NEXT::finalize_headers($c);
}

=head2 $self->finalize_read($c)

=cut

sub finalize_read {
    my ( $self, $c ) = @_;

    # Never ever remove this, it would result in random length output
    # streams if STDIN eq STDOUT (like in the HTTP engine)
    *STDIN->blocking(1);

    return $self->NEXT::finalize_read($c);
}

=head2 $self->prepare_read($c)

=cut

sub prepare_read {
    my ( $self, $c ) = @_;

    # Set the input handle to non-blocking
    *STDIN->blocking(0);

    return $self->NEXT::prepare_read($c);
}

=head2 $self->read_chunk($c, $buffer, $length)

=cut

sub read_chunk {
    my $self = shift;
    my $c    = shift;

    # support for non-blocking IO
    my $rin = '';
    vec( $rin, *STDIN->fileno, 1 ) = 1;

  READ:
    {
        select( $rin, undef, undef, undef );
        my $rc = *STDIN->sysread(@_);
        if ( defined $rc ) {
            return $rc;
        }
        else {
            next READ if $! == EWOULDBLOCK;
            return;
        }
    }
}

=head2 run

=cut

# A very very simple HTTP server that initializes a CGI environment
sub run {
    my ( $self, $class, $port, $host, $options ) = @_;

    $options ||= {};

    my $restart = 0;
    local $SIG{CHLD} = 'IGNORE';

    my $allowed = $options->{allowed} || { '127.0.0.1' => '255.255.255.255' };
    my $addr = $host ? inet_aton($host) : INADDR_ANY;
    if ( $addr eq INADDR_ANY ) {
        require Sys::Hostname;
        $host = lc Sys::Hostname::hostname();
    }
    else {
        $host = gethostbyaddr( $addr, AF_INET ) || inet_ntoa($addr);
    }

    # Handle requests

    # Setup socket
    my $daemon = IO::Socket::INET->new(
        Listen    => SOMAXCONN,
        LocalAddr => inet_ntoa($addr),
        LocalPort => $port,
        Proto     => 'tcp',
        ReuseAddr => 1,
        Type      => SOCK_STREAM,
      )
      or die "Couldn't create daemon: $!";

    my $url = "http://$host";
    $url .= ":$port" unless $port == 80;

    print "You can connect to your server at $url\n";

    $self->_keep_alive( $options->{keepalive} || 0 );

    my $parent = $$;
    my $pid    = undef;
    while ( accept( Remote, $daemon ) )
    {    # TODO: get while ( my $remote = $daemon->accept ) to work

        select Remote;

        # Request data

        Remote->blocking(1);

        next
          unless my ( $method, $uri, $protocol ) =
          $self->_parse_request_line( \*Remote );

        unless ( uc($method) eq 'RESTART' ) {

            # Fork
            if ( $options->{fork} ) { next if $pid = fork }

            $self->_handler( $class, $port, $method, $uri, $protocol );

            $daemon->close if defined $pid;

        }
        else {
            my $sockdata = $self->_socket_data( \*Remote );
            my $ipaddr   = _inet_addr( $sockdata->{peeraddr} );
            my $ready    = 0;
            while ( my ( $ip, $mask ) = each %$allowed and not $ready ) {
                $ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
            }
            if ($ready) {
                $restart = 1;
                last;
            }
        }

        exit if defined $pid;
    }
    continue {
        close Remote;
    }
    $daemon->close;

    if ($restart) {
        $SIG{CHLD} = 'DEFAULT';
        wait;
        exec $^X . ' "' . $0 . '" ' . join( ' ', @{ $options->{argv} } );
    }

    exit;
}

sub _handler {
    my ( $self, $class, $port, $method, $uri, $protocol ) = @_;

    # Ignore broken pipes as an HTTP server should
    local $SIG{PIPE} = sub { close Remote };

    local *STDIN  = \*Remote;
    local *STDOUT = \*Remote;

    # We better be careful and just use 1.0
    $protocol = '1.0';

    my $sockdata    = $self->_socket_data( \*Remote );
    my %copy_of_env = %ENV;

    my $sel = IO::Select->new;
    $sel->add( \*STDIN );

    while (1) {
        my ( $path, $query_string ) = split /\?/, $uri, 2;

        # Initialize CGI environment
        local %ENV = (
            PATH_INFO    => $path         || '',
            QUERY_STRING => $query_string || '',
            REMOTE_ADDR     => $sockdata->{peeraddr},
            REMOTE_HOST     => $sockdata->{peername},
            REQUEST_METHOD  => $method || '',
            SERVER_NAME     => $sockdata->{localname},
            SERVER_PORT     => $port,
            SERVER_PROTOCOL => "HTTP/$protocol",
            %copy_of_env,
        );

        # Parse headers
        if ( $protocol >= 1 ) {
            while (1) {
                my $line = $self->_get_line( \*STDIN );
                last if $line eq '';
                next
                  unless my ( $name, $value ) =
                  $line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;

                $name = uc $name;
                $name = 'COOKIE' if $name eq 'COOKIES';
                $name =~ tr/-/_/;
                $name = 'HTTP_' . $name
                  unless $name =~ m/\A(?:CONTENT_(?:LENGTH|TYPE)|COOKIE)\z/;
                if ( exists $ENV{$name} ) {
                    $ENV{$name} .= "; $value";
                }
                else {
                    $ENV{$name} = $value;
                }
            }
        }

        # Pass flow control to Catalyst
        $class->handle_request;

        my $connection = lc $ENV{HTTP_CONNECTION};
        last
          unless $self->_keep_alive()
          && index( $connection, 'keep-alive' ) > -1
          && index( $connection, 'te' ) == -1          # opera stuff
          && $sel->can_read(5);

        last
          unless ( $method, $uri, $protocol ) =
          $self->_parse_request_line( \*STDIN );
    }

    close Remote;
}

sub _keep_alive {
    my ( $self, $keepalive ) = @_;

    my $r = $self->{_keepalive} || 0;
    $self->{_keepalive} = $keepalive if defined $keepalive;

    return $r;

}

sub _parse_request_line {
    my ( $self, $handle ) = @_;

    # Parse request line
    my $line = $self->_get_line($handle);
    return ()
      unless my ( $method, $uri, $protocol ) =
      $line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;
    return ( $method, $uri, $protocol );
}

sub _socket_data {
    my ( $self, $handle ) = @_;

    my $remote_sockaddr = getpeername($handle);
    my ( undef, $iaddr ) = sockaddr_in($remote_sockaddr);
    my $local_sockaddr = getsockname($handle);
    my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);

    my $data = {
        peername => gethostbyaddr( $iaddr, AF_INET ) || "localhost",
        peeraddr => inet_ntoa($iaddr) || "127.0.0.1",
        localname => gethostbyaddr( $localiaddr, AF_INET ) || "localhost",
        localaddr => inet_ntoa($localiaddr) || "127.0.0.1",
    };

    return $data;
}

sub _get_line {
    my ( $self, $handle ) = @_;

    my $line = '';

    while ( sysread( $handle, my $byte, 1 ) ) {
        last if $byte eq "\012";    # eol
        $line .= $byte;
    }

    1 while $line =~ s/\s\z//;

    return $line;
}

sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }

=head1 SEE ALSO

L<Catalyst>, L<Catalyst::Engine>.

=head1 AUTHORS

Sebastian Riedel, <sri@cpan.org>

Dan Kubb, <dan.kubb-cpan@onautopilot.com>

Sascha Kiefer, <esskar@cpan.org>

=head1 THANKS

Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.

=head1 COPYRIGHT

This program is free software, you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
Commit	Line	Data
ca61af20	1	package Catalyst::Engine::HTTP;
45374ac6	2
45374ac6	3	use strict;
fbcc39ad	4	use base 'Catalyst::Engine::CGI';
	5	use Errno 'EWOULDBLOCK';
	6	use HTTP::Status;
	7	use NEXT;
	8	use Socket;
6c7a1d2f	9	use IO::Socket::INET ();
b5ecfcf0	10	use IO::Select ();
45374ac6	11
71fd2e0f	12	# For PAR
	13	require Catalyst::Engine::HTTP::Restarter;
	14	require Catalyst::Engine::HTTP::Restarter::Watcher;
	15
45374ac6	16	=head1 NAME
45374ac6	17
ca61af20	18	Catalyst::Engine::HTTP - Catalyst HTTP Engine
45374ac6	19
	20	=head1 SYNOPSIS
	21
ca61af20	22	A script using the Catalyst::Engine::HTTP module might look like:
45374ac6	23
	24	#!/usr/bin/perl -w
	25
ca61af20	26	BEGIN { $ENV{CATALYST_ENGINE} = 'HTTP' }
45374ac6	27
	28	use strict;
	29	use lib '/path/to/MyApp/lib';
	30	use MyApp;
	31
	32	MyApp->run;
	33
	34	=head1 DESCRIPTION
	35
	36	This is the Catalyst engine specialized for development and testing.
	37
fbcc39ad	38	=head1 METHODS
fbcc39ad	39
b5ecfcf0	40	=head2 $self->finalize_headers($c)
fbcc39ad	41
	42	=cut
	43
	44	sub finalize_headers {
	45	my ( $self, $c ) = @_;
	46	my $protocol = $c->request->protocol;
	47	my $status = $c->response->status;
	48	my $message = status_message($status);
	49	print "$protocol $status $message\015\012";
	50	$c->response->headers->date(time);
6c7a1d2f	51	$c->response->headers->header(
6c7a1d2f	52	Connection => $self->_keep_alive ? 'keep-alive' : 'close' );
fbcc39ad	53	$self->NEXT::finalize_headers($c);
	54	}
	55
b5ecfcf0	56	=head2 $self->finalize_read($c)
fbcc39ad	57
	58	=cut
	59
	60	sub finalize_read {
	61	my ( $self, $c ) = @_;
	62
	63	# Never ever remove this, it would result in random length output
	64	# streams if STDIN eq STDOUT (like in the HTTP engine)
4f5ebacd	65	*STDIN->blocking(1);
fbcc39ad	66
	67	return $self->NEXT::finalize_read($c);
	68	}
	69
b5ecfcf0	70	=head2 $self->prepare_read($c)
fbcc39ad	71
	72	=cut
	73
	74	sub prepare_read {
	75	my ( $self, $c ) = @_;
	76
	77	# Set the input handle to non-blocking
4f5ebacd	78	*STDIN->blocking(0);
fbcc39ad	79
	80	return $self->NEXT::prepare_read($c);
	81	}
	82
b5ecfcf0	83	=head2 $self->read_chunk($c, $buffer, $length)
fbcc39ad	84
	85	=cut
	86
	87	sub read_chunk {
	88	my $self = shift;
	89	my $c = shift;
	90
	91	# support for non-blocking IO
4f5ebacd	92	my $rin = '';
4f5ebacd	93	vec( $rin, *STDIN->fileno, 1 ) = 1;
fbcc39ad	94
	95	READ:
	96	{
	97	select( $rin, undef, undef, undef );
4f5ebacd	98	my $rc = *STDIN->sysread(@_);
fbcc39ad	99	if ( defined $rc ) {
	100	return $rc;
	101	}
	102	else {
	103	next READ if $! == EWOULDBLOCK;
	104	return;
	105	}
	106	}
	107	}
	108
b5ecfcf0	109	=head2 run
fbcc39ad	110
	111	=cut
	112
	113	# A very very simple HTTP server that initializes a CGI environment
	114	sub run {
37553dc8	115	my ( $self, $class, $port, $host, $options ) = @_;
fbcc39ad	116
4eeca0f2	117	$options \|\|= {};
1cf1c56a	118
57a87bb3	119	my $restart = 0;
31b426c0	120	local $SIG{CHLD} = 'IGNORE';
fbcc39ad	121
1cf1c56a	122	my $allowed = $options->{allowed} \|\| { '127.0.0.1' => '255.255.255.255' };
6c7a1d2f	123	my $addr = $host ? inet_aton($host) : INADDR_ANY;
6c7a1d2f	124	if ( $addr eq INADDR_ANY ) {
fbcc39ad	125	require Sys::Hostname;
6c7a1d2f	126	$host = lc Sys::Hostname::hostname();
fbcc39ad	127	}
fbcc39ad	128	else {
6c7a1d2f	129	$host = gethostbyaddr( $addr, AF_INET ) \|\| inet_ntoa($addr);
fbcc39ad	130	}
6c7a1d2f	131
	132	# Handle requests
	133
	134	# Setup socket
	135	my $daemon = IO::Socket::INET->new(
	136	Listen => SOMAXCONN,
	137	LocalAddr => inet_ntoa($addr),
	138	LocalPort => $port,
	139	Proto => 'tcp',
	140	ReuseAddr => 1,
	141	Type => SOCK_STREAM,
	142	)
	143	or die "Couldn't create daemon: $!";
	144
	145	my $url = "http://$host";
	146	$url .= ":$port" unless $port == 80;
	147
fbcc39ad	148	print "You can connect to your server at $url\n";
fbcc39ad	149
6c7a1d2f	150	$self->_keep_alive( $options->{keepalive} \|\| 0 );
6c7a1d2f	151
57a87bb3	152	my $parent = $$;
57a87bb3	153	my $pid = undef;
6c7a1d2f	154	while ( accept( Remote, $daemon ) )
6c7a1d2f	155	{ # TODO: get while ( my $remote = $daemon->accept ) to work
fbcc39ad	156
57a87bb3	157	select Remote;
fbcc39ad	158
fbcc39ad	159	# Request data
fbcc39ad	160
57a87bb3	161	Remote->blocking(1);
fbcc39ad	162
fbcc39ad	163	next
fbcc39ad	164	unless my ( $method, $uri, $protocol ) =
6c7a1d2f	165	$self->_parse_request_line( \*Remote );
fbcc39ad	166
57a87bb3	167	unless ( uc($method) eq 'RESTART' ) {
	168
	169	# Fork
	170	if ( $options->{fork} ) { next if $pid = fork }
	171
6c7a1d2f	172	$self->_handler( $class, $port, $method, $uri, $protocol );
	173
	174	$daemon->close if defined $pid;
fbcc39ad	175
1cf1c56a	176	}
1cf1c56a	177	else {
6c7a1d2f	178	my $sockdata = $self->_socket_data( \*Remote );
	179	my $ipaddr = _inet_addr( $sockdata->{peeraddr} );
	180	my $ready = 0;
1cf1c56a	181	while ( my ( $ip, $mask ) = each %$allowed and not $ready ) {
	182	$ready = ( $ipaddr & _inet_addr($mask) ) == _inet_addr($ip);
	183	}
	184	if ($ready) {
57a87bb3	185	$restart = 1;
1cf1c56a	186	last;
	187	}
	188	}
57a87bb3	189
fbcc39ad	190	exit if defined $pid;
	191	}
	192	continue {
	193	close Remote;
	194	}
6c7a1d2f	195	$daemon->close;
37553dc8	196
57a87bb3	197	if ($restart) {
60c38e3e	198	$SIG{CHLD} = 'DEFAULT';
6844bc1c	199	wait;
1cf1c56a	200	exec $^X . ' "' . $0 . '" ' . join( ' ', @{ $options->{argv} } );
60c38e3e	201	}
57a87bb3	202
57a87bb3	203	exit;
fbcc39ad	204	}
fbcc39ad	205
6c7a1d2f	206	sub _handler {
	207	my ( $self, $class, $port, $method, $uri, $protocol ) = @_;
	208
	209	# Ignore broken pipes as an HTTP server should
	210	local $SIG{PIPE} = sub { close Remote };
	211
	212	local STDIN = \Remote;
	213	local STDOUT = \Remote;
	214
	215	# We better be careful and just use 1.0
	216	$protocol = '1.0';
	217
	218	my $sockdata = $self->_socket_data( \*Remote );
	219	my %copy_of_env = %ENV;
	220
	221	my $sel = IO::Select->new;
	222	$sel->add( \*STDIN );
	223
	224	while (1) {
	225	my ( $path, $query_string ) = split /\?/, $uri, 2;
	226
	227	# Initialize CGI environment
	228	local %ENV = (
b5ecfcf0	229	PATH_INFO => $path \|\| '',
b5ecfcf0	230	QUERY_STRING => $query_string \|\| '',
6c7a1d2f	231	REMOTE_ADDR => $sockdata->{peeraddr},
	232	REMOTE_HOST => $sockdata->{peername},
	233	REQUEST_METHOD => $method \|\| '',
	234	SERVER_NAME => $sockdata->{localname},
	235	SERVER_PORT => $port,
	236	SERVER_PROTOCOL => "HTTP/$protocol",
	237	%copy_of_env,
	238	);
	239
	240	# Parse headers
	241	if ( $protocol >= 1 ) {
	242	while (1) {
	243	my $line = $self->_get_line( \*STDIN );
	244	last if $line eq '';
	245	next
	246	unless my ( $name, $value ) =
	247	$line =~ m/\A(\w(?:-?\w+)*):\s(.+)\z/;
	248
	249	$name = uc $name;
	250	$name = 'COOKIE' if $name eq 'COOKIES';
	251	$name =~ tr/-/_/;
	252	$name = 'HTTP_' . $name
	253	unless $name =~ m/\A(?:CONTENT_(?:LENGTH\|TYPE)\|COOKIE)\z/;
	254	if ( exists $ENV{$name} ) {
	255	$ENV{$name} .= "; $value";
	256	}
	257	else {
	258	$ENV{$name} = $value;
	259	}
	260	}
	261	}
	262
	263	# Pass flow control to Catalyst
	264	$class->handle_request;
	265
	266	my $connection = lc $ENV{HTTP_CONNECTION};
	267	last
	268	unless $self->_keep_alive()
	269	&& index( $connection, 'keep-alive' ) > -1
	270	&& index( $connection, 'te' ) == -1 # opera stuff
	271	&& $sel->can_read(5);
	272
	273	last
	274	unless ( $method, $uri, $protocol ) =
	275	$self->_parse_request_line( \*STDIN );
	276	}
	277
	278	close Remote;
	279	}
	280
	281	sub _keep_alive {
	282	my ( $self, $keepalive ) = @_;
	283
	284	my $r = $self->{_keepalive} \|\| 0;
	285	$self->{_keepalive} = $keepalive if defined $keepalive;
	286
	287	return $r;
	288
	289	}
	290
	291	sub _parse_request_line {
	292	my ( $self, $handle ) = @_;
	293
	294	# Parse request line
295	my $line = $self->_get_line($handle);
296	return ()
297	unless my ( $method, $uri, $protocol ) =
298	$line =~ m/\A(\w+)\s+(\S+)(?:\s+HTTP\/(\d+(?:\.\d+)?))?\z/;
299	return ( $method, $uri, $protocol );
300	}
301
302	sub _socket_data {
303	my ( $self, $handle ) = @_;
304
305	my $remote_sockaddr = getpeername($handle);
306	my ( undef, $iaddr ) = sockaddr_in($remote_sockaddr);
307	my $local_sockaddr = getsockname($handle);
308	my ( undef, $localiaddr ) = sockaddr_in($local_sockaddr);
309
310	my $data = {
311	peername => gethostbyaddr( $iaddr, AF_INET ) \|\| "localhost",
312	peeraddr => inet_ntoa($iaddr) \|\| "127.0.0.1",
313	localname => gethostbyaddr( $localiaddr, AF_INET ) \|\| "localhost",
314	localaddr => inet_ntoa($localiaddr) \|\| "127.0.0.1",
315	};
316
317	return $data;
318	}
319
fbcc39ad	320	sub _get_line {
	321	my ( $self, $handle ) = @_;
	322
	323	my $line = '';
	324
	325	while ( sysread( $handle, my $byte, 1 ) ) {
	326	last if $byte eq "\012"; # eol
	327	$line .= $byte;
	328	}
	329
	330	1 while $line =~ s/\s\z//;
	331
	332	return $line;
	333	}
	334
1cf1c56a	335	sub _inet_addr { unpack "N*", inet_aton( $_[0] ) }
1cf1c56a	336
45374ac6	337	=head1 SEE ALSO
45374ac6	338
fbcc39ad	339	L<Catalyst>, L<Catalyst::Engine>.
	340
	341	=head1 AUTHORS
	342
	343	Sebastian Riedel, <sri@cpan.org>
	344
	345	Dan Kubb, <dan.kubb-cpan@onautopilot.com>
45374ac6	346
6c7a1d2f	347	Sascha Kiefer, <esskar@cpan.org>
6c7a1d2f	348
fbcc39ad	349	=head1 THANKS
45374ac6	350
fbcc39ad	351	Many parts are ripped out of C<HTTP::Server::Simple> by Jesse Vincent.
45374ac6	352
	353	=head1 COPYRIGHT
	354
	355	This program is free software, you can redistribute it and/or modify it under
	356	the same terms as Perl itself.
	357
	358	=cut
	359
45374ac6	360	1;