Makefile.PL

   1 use inc::Module::Install 1.00;
   2 use strict;
   3 use warnings;
   4
   5 use 5.008001;
   6
   7 use FindBin;
   8 use lib "$FindBin::Bin/lib";
   9 use DBIx::Class::Optional::Dependencies;
  10
  11 # adjust ENV for $AUTHOR system() calls
  12 use Config;
  13 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
  14
  15 use Getopt::Long ();
  16
  17 my $getopt = Getopt::Long::Parser->new(
  18   config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
  19 );
  20 my $args = {
  21   skip_author_deps => undef,
  22 };
  23 $getopt->getoptions($args, 'skip_author_deps');
  24 if (@ARGV) {
  25   warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
  26 }
  27
  28 # get cpanX --installdeps . to behave in a checkout (most users do not need
  29 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  30 # for that)
  31 ##
  32 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  33 ##
  34 $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  35
  36 ###
  37 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  38 ### All of them should go to DBIx::Class::Optional::Dependencies
  39 ###
  40
  41 name     'DBIx-Class';
  42 perl_version '5.008001';
  43 all_from 'lib/DBIx/Class.pm';
  44
  45 my $build_requires = {
  46   # needed for testing only, not for operation
  47   'DBD::SQLite'              => '1.29',
  48 };
  49
  50 my $test_requires = {
  51   'File::Temp'               => '0.22',
  52   'Test::Builder'            => '0.33',
  53   'Test::Exception'          => '0.31',
  54   'Test::More'               => '0.92',
  55   'Test::Warn'               => '0.21',
  56 };
  57
  58 my $runtime_requires = {
  59   'Class::Accessor::Grouped' => '0.10002',
  60   'Class::C3::Componentised' => '1.0009',
  61   'Class::Inspector'         => '1.24',
  62   'Config::Any'              => '0.20',
  63   'Context::Preserve'        => '0.01',
  64   'Data::Dumper::Concise'    => '2.020',
  65   'Data::Page'               => '2.00',
  66   'Hash::Merge'              => '0.12',
  67   'MRO::Compat'              => '0.09',
  68   'Module::Find'             => '0.06',
  69   'Path::Class'              => '0.18',
  70   'Scope::Guard'             => '0.03',
  71   'SQL::Abstract'            => '1.72',
  72   'Try::Tiny'                => '0.04',
  73
  74   # XS (or XS-dependent) libs
  75   'DBI'                      => '1.609',
  76   'namespace::clean'         => '0.20',
  77   'Sub::Name'                => '0.04',
  78   'Variable::Magic'          => '0.44',
  79
  80   # dual-life corelibs needing a specific bugfixed version
  81   'File::Path'               => '2.07',
  82 };
  83
  84 # this is so we can order requires alphabetically
  85 # copies are needed for author requires injection
  86 my $reqs = {
  87   build_requires => { %$build_requires },
  88   requires => { %$runtime_requires },
  89   test_requires => { %$test_requires },
  90 };
  91
  92 my %reqs_for_group = %{DBIx::Class::Optional::Dependencies->req_group_list};
  93
  94 # exclude the rdbms_* groups which are for DBIC users
  95 my $opt_testdeps = {
  96   map { %{$reqs_for_group{$_}} } grep { !/^rdbms_/ } keys %reqs_for_group
  97 };
  98
  99 # require extra modules for testing if we're in a checkout
 100 my $optdep_msg;
 101 if ($Module::Install::AUTHOR) {
 102   if ($args->{skip_author_deps}) {
 103     $optdep_msg = <<'EOW';
 104
 105 ******************************************************************************
 106 ******************************************************************************
 107 ***                                                                        ***
 108 *** IGNORING AUTHOR MODE: no optional test dependencies will be forced.    ***
 109 ***                                                                        ***
 110 *** If you are using this checkout with the intention of submitting a DBIC ***
 111 *** patch, you are *STRONGLY ENCOURAGED* to install all dependencies, so   ***
 112 *** that every possible unit-test will run.                                ***
 113 ***                                                                        ***
 114 ******************************************************************************
 115 ******************************************************************************
 116
 117 EOW
 118   }
 119   else {
 120     $optdep_msg = <<'EOW';
 121
 122 ******************************************************************************
 123 ******************************************************************************
 124 ***                                                                        ***
 125 *** AUTHOR MODE: all optional test dependencies converted to hard requires ***
 126 ***       ( to disable re-run Makefile.PL with --skip_author_deps )        ***
 127 ***                                                                        ***
 128 ******************************************************************************
 129 ******************************************************************************
 130
 131 EOW
 132
 133     $reqs->{test_requires} = {
 134       %{$reqs->{test_requires}},
 135       %$opt_testdeps
 136     };
 137   }
 138 }
 139
 140 # compose final req list, for alphabetical ordering
 141 my %final_req;
 142 for my $rtype (keys %$reqs) {
 143   for my $mod (keys %{$reqs->{$rtype}} ) {
 144
 145     # sanity check req duplications
 146     if ($final_req{$mod}) {
 147       die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n";
 148     }
 149
 150     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 151   }
 152 }
 153
 154 # actual require
 155 for my $mod (sort keys %final_req) {
 156   my ($rtype, $ver) = @{$final_req{$mod}};
 157   no strict 'refs';
 158   $rtype->($mod, $ver);
 159 }
 160
 161 # output twice since the deplist is > 70 lines
 162 warn $optdep_msg if $Module::Install::AUTHOR;
 163 auto_install();
 164 warn $optdep_msg if $Module::Install::AUTHOR;
 165
 166
 167 # re-create various autogenerated documentation bits
 168 if ($Module::Install::AUTHOR) {
 169
 170   print "Regenerating README\n";
 171   system('pod2text lib/DBIx/Class.pm > README');
 172
 173   if (-f 'MANIFEST') {
 174     print "Removing MANIFEST\n";
 175     unlink 'MANIFEST';
 176   }
 177
 178   print "Regenerating Optional/Dependencies.pod\n";
 179   require DBIx::Class::Optional::Dependencies;
 180   DBIx::Class::Optional::Dependencies->_gen_pod (Meta->version);
 181
 182   # FIXME Disabled due to unsolved issues, ask theorbtwo
 183   #  require Module::Install::Pod::Inherit;
 184   #  PodInherit();
 185 }
 186
 187
 188 tests_recursive (qw|
 189     t
 190 |);
 191
 192 # temporary(?) until I get around to fix M::I wrt xt/
 193 # needs Module::Install::AuthorTests
 194 eval {
 195   # this should not be necessary since the autoloader is supposed
 196   # to work, but there were reports of it failing
 197   require Module::Install::AuthorTests;
 198   recursive_author_tests (qw/xt/);
 199   1;
 200 } || do {
 201   if ($Module::Install::AUTHOR && ! $args->{skip_author_deps}) {
 202     my $err = $@;
 203
 204     # better error message in case of missing dep
 205     eval { require Module::Install::AuthorTests }
 206       || die "\nYou need Module::Install::AuthorTests installed to run this Makefile.PL in author mode (or supply --skip_author_deps):\n\n$@\n";
 207
 208     die $err;
 209   }
 210 };
 211
 212
 213 install_script (qw|
 214     script/dbicadmin
 215 |);
 216
 217
 218 ### Mangle makefile - read the comments for more info
 219 #
 220 postamble <<"EOP";
 221
 222 # This will add an extra dep-spec for the distdir target,
 223 # which `make` will fold together in a first-come first-serve
 224 # fashion. What we do here is essentially adding extra
 225 # commands to execute once the distdir is assembled (via
 226 # create_distdir), but before control is returned to a higher
 227 # calling rule.
 228 distdir : dbicadmin_pod_inject
 229
 230 # The pod self-injection code is in fact a hidden option in
 231 # dbicadmin itself
 232 dbicadmin_pod_inject :
 233 \tcd \$(DISTVNAME) && \$(ABSPERL) -Ilib script/dbicadmin --selfinject-pod
 234
 235 # Regenerate manifest before running create_distdir.
 236 create_distdir : manifest
 237
 238 EOP
 239
 240 homepage 'http://www.dbix-class.org/';
 241 resources 'IRC'         => 'irc://irc.perl.org/#dbix-class';
 242 resources 'license'     => 'http://dev.perl.org/licenses/';
 243 resources 'repository'  => 'git://git.shadowcat.co.uk/dbsrgits/DBIx-Class.git';
 244 resources 'MailingList' => 'http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/dbix-class';
 245 resources 'bugtracker'  => 'http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBIx-Class';
 246
 247 # Deprecated/internal modules need no exposure
 248 no_index directory => $_ for (qw|
 249   lib/DBIx/Class/Admin
 250   lib/DBIx/Class/PK/Auto
 251   lib/DBIx/Class/CDBICompat
 252 |);
 253 no_index package => $_ for (qw/
 254   DBIx::Class::Storage::DBIHacks
 255   DBIx::Class::Carp
 256 /);
 257
 258 WriteAll();
 259
 260 # Re-write META.yml to _exclude_ all forced build-requires (we do not want to ship
 261 # this) We are also not using M::I::AuthorRequires as this will be an extra dep,
 262 # and deps in Makefile.PL still suck
 263 # Also always test the result so we stop shipping borked dependency lists to CPAN
 264
 265 # FIXME test_requires is not yet part of META
 266 my %original_build_requires = ( %$build_requires, %$test_requires );
 267 my @all_build_requires = @{delete Meta->{values}{build_requires}};
 268 my %removed_build_requires;
 269
 270 for (@all_build_requires) {
 271   if ($original_build_requires{$_->[0]}) {
 272     push @{Meta->{values}{build_requires}}, $_;
 273   }
 274   else {
 275     $removed_build_requires{$_->[0]} = $_->[1]
 276       unless $_->[0] eq 'ExtUtils::MakeMaker';
 277   }
 278 }
 279
 280 # Rewrite only in author mode, the original META should not contain anything anyway
 281 # if we executed as non-author
 282 if ($Module::Install::AUTHOR && keys %removed_build_requires) {
 283   print "Regenerating META with author requires excluded\n";
 284   Meta->write;
 285 }
 286
 287 # test that we really took things away (just in case, happened twice somehow)
 288 if (! -f 'META.yml') {
 289   warn "No META.yml generated?! aborting...\n";
 290   exit 1;
 291 }
 292 my $meta = do { local @ARGV = 'META.yml'; local $/; <> };
 293
 294 # this is safe as there is a fatal check earlier to make sure $opt_testdeps does
 295 # not contain any real dependencies
 296 my @illegal_leftovers = grep
 297   { $meta =~ /^ \s+ \Q$_\E \: \s+ /mx }
 298   ( sort keys %$opt_testdeps )
 299 ;
 300
 301 if (@illegal_leftovers) {
 302   die join ("\n",
 303     "\n\nFATAL FAIL! It looks like some author dependencies made it to the META.yml:\n",
 304     map { "\t$_" } @illegal_leftovers
 305   ) . "\n\n";
 306 }