Makefile.PL

   1 use strict;
   2 use warnings;
   3
   4 use 5.008001;
   5 use inc::Module::Install 1.06;
   6 BEGIN {
   7   # needs to happen early for old EUMM
   8   makemaker_args( NORECURS => 1 );
   9
  10   local @INC = ('lib', @INC);
  11   require DBIx::Class::Optional::Dependencies;
  12 }
  13
  14 ##
  15 ## DO NOT USE THIS HACK IN YOUR DISTS!!! (it makes #toolchain sad)
  16 ##
  17 # get cpanX --installdeps . to behave in a checkout (most users do not expect
  18 # the deps for a full test suite run, and if they do - there's MI::AutoInstall
  19 # for that)
  20 BEGIN {
  21   $Module::Install::AUTHOR = 0 if (grep { $ENV{"PERL5_${_}_IS_RUNNING"} } (qw/CPANM CPANPLUS CPAN/) );
  22 }
  23
  24 name         'DBIx-Class';
  25 version_from 'lib/DBIx/Class.pm';
  26 perl_version '5.008001';
  27
  28 ###
  29 ### DO NOT ADD OPTIONAL DEPENDENCIES HERE, EVEN AS recommends()
  30 ### All of them *MUST* go to DBIx::Class::Optional::Dependencies
  31 ###
  32 my $runtime_requires = {
  33
  34   # DBI itself should be capable of installation and execution in pure-perl
  35   # mode. However it has never been tested yet, so consider XS for the time
  36   # being
  37 ###
  38 ### IMPORTANT - do not raise this dependency
  39 ### even though many bugfixes are present in newer versions, the general DBIC
  40 ### rule is to bend over backwards for available DBI versions (given upgrading
  41 ### them is often *not* easy or even possible)
  42 ###
  43   'DBI'                      => '1.57',
  44
  45   # on older versions first() leaks
  46   # for the time being make it a hard dep - when we get
  47   # rid of Sub::Name will revisit this (possibility is
  48   # to use Devel::HideXS to force the pure-perl version
  49   # or something like that)
  50   'List::Util'               => '1.16',
  51
  52   # XS (or XS-dependent) libs
  53   'Sub::Name'                => '0.04',
  54
  55   # pure-perl (FatPack-able) libs
  56   'Class::Accessor::Grouped' => '0.10012',
  57   'Class::C3::Componentised' => '1.0009',
  58   'Context::Preserve'        => '0.01',
  59   'Data::Page'               => '2.00',
  60   'Devel::GlobalDestruction' => '0.09',
  61   'Hash::Merge'              => '0.12',
  62   'Moo'                      => '2.000',
  63   'MRO::Compat'              => '0.12',
  64   'Module::Find'             => '0.07',
  65   'namespace::clean'         => '0.24',
  66   'Scope::Guard'             => '0.03',
  67   'SQL::Abstract'            => '1.81',
  68   'Try::Tiny'                => '0.07',
  69
  70   # Technically this is not a core dependency - it is only required
  71   # by the MySQL codepath. However this particular version is bundled
  72   # since 5.10.0 and is a pure-perl module anyway - let it slide
  73   'Text::Balanced'           => '2.00',
  74 };
  75
  76 my $build_requires = {
  77 };
  78
  79 my $test_requires = {
  80   'File::Temp'               => '0.22',
  81   'Test::Deep'               => '0.101',
  82   'Test::Exception'          => '0.31',
  83   'Test::Warn'               => '0.21',
  84   'Test::More'               => '0.94',
  85
  86   # this is already a dep of n::c, but just in case - used by t/55namespaces_cleaned.t
  87   # remove and do a manual glob-collection if n::c is no longer a dep
  88   'Package::Stash'           => '0.28',
  89
  90   # needed for testing only, not for operation
  91   # we will move away from this dep eventually, perhaps to DBD::CSV or something
  92   %{ DBIx::Class::Optional::Dependencies->req_list_for('test_rdbms_sqlite') },
  93 };
  94
  95 # if the user has some of these env vars set and the deps are not available,
  96 # tests will fail
  97 # Note - these are added as test_requires *directly*, so they get properly
  98 # excluded on META.yml cleansing (even though no dist can be created from this)
  99 # we force these reqs regarless of --with-optdeps, worst case scenario they will
 100 # be specified twice
 101 #
 102 # also note that we *do* set dynamic_config => 0, as these are the only things
 103 # that we determine dynamically, and in all fairness if someone sets these
 104 # envvars *and* is not running a full Makefile/make/maketest cycle - they get
 105 # to keep the pieces
 106 if ( my @optdeps = (
 107   $ENV{DBICTEST_SQLT_DEPLOY} ? 'deploy' : (),
 108   $ENV{DBICTEST_VIA_REPLICATED} ? 'replicated' : (),
 109 )) {
 110   my $extra_deps = DBIx::Class::Optional::Dependencies->req_list_for(\@optdeps);
 111   for (keys %$extra_deps) {
 112     test_requires ($_ => $extra_deps->{$_})
 113   }
 114 }
 115
 116 tests_recursive ('t');
 117 tests_recursive ('xt') if (
 118   $Module::Install::AUTHOR
 119     or
 120   $ENV{DBICTEST_RUN_ALL_TESTS}
 121     or
 122   ( $ENV{TRAVIS}||'' ) eq 'true'
 123     or
 124   ( $ENV{AUTOMATED_TESTING} and ! $ENV{PERL5_CPANM_IS_RUNNING} and ! $ENV{RELEASE_TESTING} )
 125 );
 126
 127 install_script (qw|
 128     script/dbicadmin
 129 |);
 130
 131 # this is so we can order requires alphabetically
 132 # copies are needed for potential author requires injection
 133 my $reqs = {
 134   build_requires => { %$build_requires },
 135   requires => { %$runtime_requires },
 136   test_requires => { %$test_requires },
 137 };
 138
 139 # only do author-includes if not part of a `make` run
 140 if ($Module::Install::AUTHOR  and ! $ENV{MAKELEVEL}) {
 141   invoke_author_mode()
 142 }
 143 else {
 144   # make sure this Makefile can not be used to make a dist
 145   # (without the author includes there are no meta cleanup, no sanity checks, etc)
 146   postamble <<EOP;
 147 create_distdir: nonauthor_stop_distdir_creation
 148 nonauthor_stop_distdir_creation:
 149 \t\$(NOECHO) \$(ECHO) Creation of dists in non-author mode is not allowed
 150 \t\$(NOECHO) \$(FALSE)
 151 EOP
 152 }
 153
 154 # compose final req list, for alphabetical ordering
 155 my %final_req;
 156 for my $rtype (keys %$reqs) {
 157   for my $mod (keys %{$reqs->{$rtype}} ) {
 158
 159     # sanity check req duplications
 160     die "$mod specified as both a '$rtype' and a '$final_req{$mod}[0]'\n"
 161       if $final_req{$mod};
 162
 163     $final_req{$mod} = [ $rtype, $reqs->{$rtype}{$mod}||0 ],
 164   }
 165 }
 166
 167 # actual require
 168 for my $mod (sort keys %final_req) {
 169   my ($rtype, $ver) = @{$final_req{$mod}};
 170   no strict 'refs';
 171   $rtype->($mod, $ver);
 172 }
 173
 174 # author-mode or not - this is where we show a list of missing deps
 175 # IFF we are running interactively
 176 auto_install();
 177
 178 {
 179   # M::I understands unicode in meta but does not write with the right
 180   # layers - fhtagn!!!
 181   local $SIG{__WARN__} = sub { warn $_[0] unless $_[0] =~ /Wide character in print/ };
 182   WriteAll();
 183 }
 184
 185 exit 0;
 186
 187
 188 ###
 189 ### Nothing user-serviceable beyond this point
 190 ### (none of this executes on regular install)
 191 ###
 192
 193
 194 # needs to be here to keep 5.8 string eval happy
 195 # (the include of Makefile.PL.inc loop)
 196 my $mm_proto;
 197
 198 sub invoke_author_mode {
 199   # get options here, make $args available to all snippets
 200   require Getopt::Long;
 201   my $getopt = Getopt::Long::Parser->new(
 202     config => [qw/gnu_getopt bundling_override no_ignore_case pass_through/]
 203   );
 204   my $args = {
 205     with_optdeps => undef,
 206   };
 207   $getopt->getoptions($args, qw/
 208     with_optdeps|with-optdeps
 209   /);
 210   if (@ARGV) {
 211     warn "\nIgnoring unrecognized option(s): @ARGV\n\n";
 212   }
 213
 214   # We need the MM facilities to generate the pieces for the final MM run.
 215   # Just instantiate a throaway object here
 216   #
 217   # Also EUMM and MI disagree on what is the format of Meta->name, just
 218   # punt here until a new M::I is shipped (if at all)
 219   my $name = Meta->name || die 'The Module::Install metadata must be available at this point but is not - did you rearrange the Makefile.PL...?';
 220   $name =~ s/\-/::/g;
 221   $mm_proto = ExtUtils::MakeMaker->new({
 222     NORECURS => 1,
 223     NAME => $name,
 224   });
 225
 226   # Crutch for DISTBUILDING_IN_HELL
 227   # Spits back a working dos2unix snippet to be used on the supplied path(s)
 228   # Ironically EUMM's dos2unix is broken on win32 itself - it does
 229   # not take into account the CRLF layer present on win32
 230   my $crlf_fixup = sub {
 231     return '' unless ($^O eq 'MSWin32' or $^O eq 'cygwin');
 232     my $targets = join ', ', map { "q($_)" } @_;
 233     "\t" . $mm_proto->oneliner( qq(\$ENV{PERLIO}='unix' and system( \$^X, qw( -MExtUtils::Command -e dos2unix -- ), $targets ) ) );
 234   };
 235
 236   # string-eval, not do(), because we need to provide the
 237   # $mm_proto, $reqs and $*_requires lexicals to the included file
 238   # (some includes *do* modify $reqs above)
 239   for my $inc (sort glob ( 'maint/Makefile.PL.inc/*' ) ) {
 240     my $src = do { local (@ARGV, $/) = $inc; <> } or die $!;
 241     eval "use warnings; use strict; $src" or die sprintf
 242       "Failed execution of %s: %s\n",
 243       $inc,
 244       ($@ || $! || 'Unknown error'),
 245     ;
 246   }
 247 }