[gitmo/Role-Tiny.git] / lib / Role / Tiny.pm

package Role::Tiny;

sub _getglob { \*{$_[0]} }
sub _getstash { \%{"$_[0]::"} }

use strict;
use warnings FATAL => 'all';

our $VERSION = '1.002004'; # 1.2.4
$VERSION = eval $VERSION;

our %INFO;
our %APPLIED_TO;
our %COMPOSED;
our %COMPOSITE_INFO;

# Module state workaround totally stolen from Zefram's Module::Runtime.

BEGIN {
  *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
}

sub Role::Tiny::__GUARD__::DESTROY {
  delete $INC{$_[0]->[0]} if @{$_[0]};
}

sub _load_module {
  (my $proto = $_[0]) =~ s/::/\//g;
  $proto .= '.pm';
  return 1 if $INC{$proto};
  # can't just ->can('can') because a sub-package Foo::Bar::Baz
  # creates a 'Baz::' key in Foo::Bar's symbol table
  return 1 if grep !/::$/, keys %{_getstash($_[0])||{}};
  my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
    && bless([ $proto ], 'Role::Tiny::__GUARD__');
  require $proto;
  pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
  return 1;
}

sub import {
  my $target = caller;
  my $me = shift;
  strict->import;
  warnings->import(FATAL => 'all');
  return if $INFO{$target}; # already exported into this package
  # get symbol table reference
  my $stash = _getstash($target);
  # install before/after/around subs
  foreach my $type (qw(before after around)) {
    *{_getglob "${target}::${type}"} = sub {
      require Class::Method::Modifiers;
      push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ];
      return;
    };
  }
  *{_getglob "${target}::requires"} = sub {
    push @{$INFO{$target}{requires}||=[]}, @_;
    return;
  };
  *{_getglob "${target}::with"} = sub {
    $me->apply_roles_to_package($target, @_);
    return;
  };
  # grab all *non-constant* (stash slot is not a scalarref) subs present
  # in the symbol table and store their refaddrs (no need to forcibly
  # inflate constant subs into real subs) - also add '' to here (this
  # is used later) with a map to the coderefs in case of copying or re-use
  my @not_methods = ('', map { *$_{CODE}||() } grep !ref($_), values %$stash);
  @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
  # a role does itself
  $APPLIED_TO{$target} = { $target => undef };
}

sub apply_single_role_to_package {
  my ($me, $to, $role) = @_;

  _load_module($role);

  die "This is apply_role_to_package" if ref($to);
  die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};

  $me->_check_requires($to, $role, @{$info->{requires}||[]});

  $me->_install_methods($to, $role);

  $me->_install_modifiers($to, $info->{modifiers});

  # copy our role list into the target's
  @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = ();
}

sub apply_roles_to_object {
  my ($me, $object, @roles) = @_;
  die "No roles supplied!" unless @roles;
  my $class = ref($object);
  bless($object, $me->create_class_with_roles($class, @roles));
  $object;
}

sub create_class_with_roles {
  my ($me, $superclass, @roles) = @_;

  die "No roles supplied!" unless @roles;

  _load_module($superclass);
  {
    my %seen;
    $seen{$_}++ for @roles;
    if (my @dupes = grep $seen{$_} > 1, @roles) {
      die "Duplicated roles: ".join(', ', @dupes);
    }
  }

  my $new_name = join(
    '__WITH__', $superclass, my $compose_name = join '__AND__', @roles
  );

  return $new_name if $COMPOSED{class}{$new_name};

  foreach my $role (@roles) {
    _load_module($role);
    die "${role} is not a Role::Tiny" unless $INFO{$role};
  }

  if ($] >= 5.010) {
    require mro;
  } else {
    require MRO::Compat;
  }

  my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
  if (keys %conflicts) {
    my $fail = 
      join "\n",
        map {
          "Method name conflict for '$_' between roles "
          ."'".join(' and ', sort values %{$conflicts{$_}})."'"
          .", cannot apply these simultaneously to an object."
        } keys %conflicts;
    die $fail;
  }

  my @composable = map $me->_composable_package_for($_), reverse @roles;

  *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];

  my @info = map $INFO{$_}, @roles;

  $me->_check_requires(
    $new_name, $compose_name,
    do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h }
  );

  @{$APPLIED_TO{$new_name}||={}}{
    map keys %{$APPLIED_TO{$_}}, @roles
  } = ();

  $COMPOSED{class}{$new_name} = 1;
  return $new_name;
}

# preserved for compat, and apply_roles_to_package calls it to allow an
# updated Role::Tiny to use a non-updated Moo::Role

sub apply_role_to_package { shift->apply_single_role_to_package(@_) }

sub apply_roles_to_package {
  my ($me, $to, @roles) = @_;

  return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;

  my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
  delete $conflicts{$_} for $me->_concrete_methods_of($to);
  if (keys %conflicts) {
    my $fail = 
      join "\n",
        map {
          "Due to a method name conflict between roles "
          ."'".join(' and ', sort values %{$conflicts{$_}})."'"
          .", the method '$_' must be implemented by '${to}'"
        } keys %conflicts;
    die $fail;
  }

  # the if guard here is essential since otherwise we accidentally create
  # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
  # autovivification hates us and wants us to die()
  if ($INFO{$to}) {
    delete $INFO{$to}{methods}; # reset since we're about to add methods
  }

  foreach my $role (@roles) {
    $me->apply_single_role_to_package($to, $role);
  }
  $APPLIED_TO{$to}{join('|',@roles)} = 1;
}

sub _composite_info_for {
  my ($me, @roles) = @_;
  $COMPOSITE_INFO{join('|', sort @roles)} ||= do {
    foreach my $role (@roles) {
      _load_module($role);
    }
    my %methods;
    foreach my $role (@roles) {
      my $this_methods = $me->_concrete_methods_of($role);
      $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
    }
    delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
    +{ conflicts => \%methods }
  };
}

sub _composable_package_for {
  my ($me, $role) = @_;
  my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
  return $composed_name if $COMPOSED{role}{$composed_name};
  $me->_install_methods($composed_name, $role);
  my $base_name = $composed_name.'::_BASE';
  # Not using _getglob, since setting @ISA via the typeglob breaks
  # inheritance on 5.10.0 if the stash has previously been accessed an
  # then a method called on the class (in that order!), which
  # ->_install_methods (with the help of ->_install_does) ends up doing.
  { no strict 'refs'; @{"${composed_name}::ISA"} = ( $base_name ); }
  my $modifiers = $INFO{$role}{modifiers}||[];
  my @mod_base;
  foreach my $modified (
    do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
  ) {
    push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
  }
  my $e;
  {
    local $@;
    eval(my $code = join "\n", "package ${base_name};", @mod_base);
    $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
  }
  die $e if $e;
  $me->_install_modifiers($composed_name, $modifiers);
  $COMPOSED{role}{$composed_name} = 1;
  return $composed_name;
}

sub _check_requires {
  my ($me, $to, $name, @requires) = @_;
  if (my @requires_fail = grep !$to->can($_), @requires) {
    # role -> role, add to requires, role -> class, error out
    if (my $to_info = $INFO{$to}) {
      push @{$to_info->{requires}||=[]}, @requires_fail;
    } else {
      die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
    }
  }
}

sub _concrete_methods_of {
  my ($me, $role) = @_;
  my $info = $INFO{$role};
  # grab role symbol table
  my $stash = _getstash($role);
  # reverse so our keys become the values (captured coderefs) in case
  # they got copied or re-used since
  my $not_methods = { reverse %{$info->{not_methods}||{}} };
  $info->{methods} ||= +{
    # grab all code entries that aren't in the not_methods list
    map {
      my $code = *{$stash->{$_}}{CODE};
      # rely on the '' key we added in import for "no code here"
      exists $not_methods->{$code||''} ? () : ($_ => $code)
    } grep !ref($stash->{$_}), keys %$stash
  };
}

sub methods_provided_by {
  my ($me, $role) = @_;
  die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
  (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]});
}

sub _install_methods {
  my ($me, $to, $role) = @_;

  my $info = $INFO{$role};

  my $methods = $me->_concrete_methods_of($role);

  # grab target symbol table
  my $stash = _getstash($to);

  # determine already extant methods of target
  my %has_methods;
  @has_methods{grep
    +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}),
    keys %$stash
  } = ();

  foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
    no warnings 'once';
    *{_getglob "${to}::${i}"} = $methods->{$i};
  }
  
  $me->_install_does($to);
}

sub _install_modifiers {
  my ($me, $to, $modifiers) = @_;
  if (my $info = $INFO{$to}) {
    push @{$info->{modifiers}}, @{$modifiers||[]};
  } else {
    foreach my $modifier (@{$modifiers||[]}) {
      $me->_install_single_modifier($to, @$modifier);
    }
  }
}

sub _install_single_modifier {
  my ($me, @args) = @_;
  Class::Method::Modifiers::install_modifier(@args);
}

my $FALLBACK = sub { 0 };
sub _install_does {
  my ($me, $to) = @_;
  
  # only add does() method to classes
  return if $INFO{$to};
  
  # add does() only if they don't have one
  *{_getglob "${to}::does"} = \&does_role unless $to->can('does');
  
  return if ($to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') || 0));
  
  my $existing = $to->can('DOES') || $to->can('isa') || $FALLBACK;
  my $new_sub = sub {
    my ($proto, $role) = @_;
    Role::Tiny::does_role($proto, $role) or $proto->$existing($role);
  };
  no warnings 'redefine';
  *{_getglob "${to}::DOES"} = $new_sub;
}

sub does_role {
  my ($proto, $role) = @_;
  if ($] >= 5.010) {
    require mro;
  } else {
    require MRO::Compat;
  }
  foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) {
    return 1 if exists $APPLIED_TO{$class}{$role};
  }
  return 0;
}

1;

=head1 NAME

Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.

=head1 SYNOPSIS

 package Some::Role;

 use Role::Tiny;

 sub foo { ... }

 sub bar { ... }

 around baz => sub { ... }

 1;

else where

 package Some::Class;

 use Role::Tiny::With;

 # bar gets imported, but not foo
 with 'Some::Role';

 sub foo { ... }

 # baz is wrapped in the around modifier by Class::Method::Modifiers
 sub baz { ... }

 1;

If you wanted attributes as well, look at L<Moo::Role>.

=head1 DESCRIPTION

C<Role::Tiny> is a minimalist role composition tool.

=head1 ROLE COMPOSITION

Role composition can be thought of as much more clever and meaningful multiple
inheritance.  The basics of this implementation of roles is:

=over 2

=item *

If a method is already defined on a class, that method will not be composed in
from the role.

=item *

If a method that the role L</requires> to be implemented is not implemented,
role application will fail loudly.

=back

Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
composition is the other way around, where the class wins. If multiple roles
are applied in a single call (single with statement), then if any of their
provided methods clash, an exception is raised unless the class provides
a method since this conflict indicates a potential problem.

=head1 IMPORTED SUBROUTINES

=head2 requires

 requires qw(foo bar);

Declares a list of methods that must be defined to compose role.

=head2 with

 with 'Some::Role1';

 with 'Some::Role1', 'Some::Role2';

Composes another role into the current role (or class via L<Role::Tiny::With>).

If you have conflicts and want to resolve them in favour of Some::Role1 you
can instead write: 

 with 'Some::Role1';
 with 'Some::Role2';

If you have conflicts and want to resolve different conflicts in favour of
different roles, please refactor your codebase.

=head2 before

 before foo => sub { ... };

See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head2 around

 around foo => sub { ... };

See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head2 after

 after foo => sub { ... };

See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
documentation.

Note that since you are not required to use method modifiers,
L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
both L<Class::Method::Modifiers> and L<Role::Tiny>.

=head1 SUBROUTINES

=head2 does_role

 if (Role::Tiny::does_role($foo, 'Some::Role')) {
   ...
 }

Returns true if class has been composed with role.

This subroutine is also installed as ->does on any class a Role::Tiny is
composed into unless that class already has an ->does method, so

  if ($foo->does('Some::Role')) {
    ...
  }

will work for classes but to test a role, one must use ::does_role directly.

Additionally, Role::Tiny will override the standard Perl C<DOES> method
for your class. However, if C<any> class in your class' inheritance
heirarchy provides C<DOES>, then Role::Tiny will not override it.

=head1 METHODS

=head2 apply_roles_to_package

 Role::Tiny->apply_roles_to_package(
   'Some::Package', 'Some::Role', 'Some::Other::Role'
 );

Composes role with package.  See also L<Role::Tiny::With>.

=head2 apply_roles_to_object

 Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));

Composes roles in order into object directly.  Object is reblessed into the
resulting class.

=head2 create_class_with_roles

 Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));

Creates a new class based on base, with the roles composed into it in order.
New class is returned.

=head1 SEE ALSO

L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
a meta-protocol-less subset of the king of role systems, L<Moose::Role>.

If you don't want method modifiers and do want to be forcibly restricted
to a single role application per class, Ovid's L<Role::Basic> exists. But
Stevan Little (the L<Moose> author) and I don't find the additional
restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
are more a guide to what you should prefer doing, to our mind, rather than
something that needs to be enforced.

=head1 AUTHOR

mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>

=head1 CONTRIBUTORS

dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>

frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>

hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>

jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>

ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>

chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>

ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>

doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>

perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>

Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>

ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>

tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>

=head1 COPYRIGHT

Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
as listed above.

=head1 LICENSE

This library is free software and may be distributed under the same terms
as perl itself.

=cut
Commit	Line	Data
ab3370e7	1	package Role::Tiny;
ab3370e7	2
119014a7	3	sub _getglob { \*{$_[0]} }
5e03b55c	4	sub _getstash { \%{"$_[0]::"} }
119014a7	5
b1eebd55	6	use strict;
b1eebd55	7	use warnings FATAL => 'all';
ab3370e7	8
1205ded4	9	our $VERSION = '1.002004'; # 1.2.4
c334a5c1	10	$VERSION = eval $VERSION;
c334a5c1	11
ab3370e7	12	our %INFO;
ab3370e7	13	our %APPLIED_TO;
1947330a	14	our %COMPOSED;
836aea1b	15	our %COMPOSITE_INFO;
ab3370e7	16
cf62c989	17	# Module state workaround totally stolen from Zefram's Module::Runtime.
	18
	19	BEGIN {
	20	*_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0};
	21	}
	22
	23	sub Role::Tiny::__GUARD__::DESTROY {
	24	delete $INC{$_[0]->[0]} if @{$_[0]};
	25	}
5e03b55c	26
fb5074f6	27	sub _load_module {
fb5074f6	28	(my $proto = $_[0]) =~ s/::/\//g;
cf62c989	29	$proto .= '.pm';
cf62c989	30	return 1 if $INC{$proto};
5e03b55c	31	# can't just ->can('can') because a sub-package Foo::Bar::Baz
	32	# creates a 'Baz::' key in Foo::Bar's symbol table
	33	return 1 if grep !/::$/, keys %{_getstash($_[0])\|\|{}};
cf62c989	34	my $guard = _WORK_AROUND_BROKEN_MODULE_STATE
	35	&& bless([ $proto ], 'Role::Tiny::__GUARD__');
	36	require $proto;
	37	pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE;
fb5074f6	38	return 1;
	39	}
	40
ab3370e7	41	sub import {
ab3370e7	42	my $target = caller;
a1164a0b	43	my $me = shift;
3ca7ff56	44	strict->import;
3ca7ff56	45	warnings->import(FATAL => 'all');
1ba11455	46	return if $INFO{$target}; # already exported into this package
ab3370e7	47	# get symbol table reference
76acfa6c	48	my $stash = _getstash($target);
ab3370e7	49	# install before/after/around subs
ab3370e7	50	foreach my $type (qw(before after around)) {
5a247406	51	*{_getglob "${target}::${type}"} = sub {
7568ba55	52	require Class::Method::Modifiers;
ab3370e7	53	push @{$INFO{$target}{modifiers}\|\|=[]}, [ $type => @_ ];
ef2da711	54	return;
ab3370e7	55	};
ab3370e7	56	}
5a247406	57	*{_getglob "${target}::requires"} = sub {
ab3370e7	58	push @{$INFO{$target}{requires}\|\|=[]}, @_;
ef2da711	59	return;
ab3370e7	60	};
5a247406	61	*{_getglob "${target}::with"} = sub {
836aea1b	62	$me->apply_roles_to_package($target, @_);
ef2da711	63	return;
96d3f07a	64	};
7b8177f8	65	# grab all non-constant (stash slot is not a scalarref) subs present
ab3370e7	66	# in the symbol table and store their refaddrs (no need to forcibly
ab3370e7	67	# inflate constant subs into real subs) - also add '' to here (this
12f8eb0b	68	# is used later) with a map to the coderefs in case of copying or re-use
	69	my @not_methods = ('', map { *$_{CODE}\|\|() } grep !ref($_), values %$stash);
	70	@{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods;
ab3370e7	71	# a role does itself
	72	$APPLIED_TO{$target} = { $target => undef };
	73	}
	74
836aea1b	75	sub apply_single_role_to_package {
369a4c50	76	my ($me, $to, $role) = @_;
1947330a	77
fb5074f6	78	_load_module($role);
fb5074f6	79
ab3370e7	80	die "This is apply_role_to_package" if ref($to);
1947330a	81	die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
	82
	83	$me->_check_requires($to, $role, @{$info->{requires}\|\|[]});
	84
	85	$me->_install_methods($to, $role);
	86
	87	$me->_install_modifiers($to, $info->{modifiers});
	88
1947330a	89	# copy our role list into the target's
	90	@{$APPLIED_TO{$to}\|\|={}}{keys %{$APPLIED_TO{$role}}} = ();
	91	}
	92
	93	sub apply_roles_to_object {
	94	my ($me, $object, @roles) = @_;
	95	die "No roles supplied!" unless @roles;
	96	my $class = ref($object);
	97	bless($object, $me->create_class_with_roles($class, @roles));
	98	$object;
	99	}
	100
	101	sub create_class_with_roles {
	102	my ($me, $superclass, @roles) = @_;
	103
fb5074f6	104	die "No roles supplied!" unless @roles;
fb5074f6	105
f52b9821	106	_load_module($superclass);
2c580674	107	{
	108	my %seen;
	109	$seen{$_}++ for @roles;
	110	if (my @dupes = grep $seen{$_} > 1, @roles) {
	111	die "Duplicated roles: ".join(', ', @dupes);
	112	}
	113	}
	114
c69190f1	115	my $new_name = join(
	116	'__WITH__', $superclass, my $compose_name = join '__AND__', @roles
	117	);
	118
1947330a	119	return $new_name if $COMPOSED{class}{$new_name};
	120
	121	foreach my $role (@roles) {
fb5074f6	122	_load_module($role);
29dde8ba	123	die "${role} is not a Role::Tiny" unless $INFO{$role};
1947330a	124	}
1947330a	125
786e5ba0	126	if ($] >= 5.010) {
7568ba55	127	require mro;
b1eebd55	128	} else {
7568ba55	129	require MRO::Compat;
b1eebd55	130	}
1947330a	131
471419f6	132	my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
	133	if (keys %conflicts) {
	134	my $fail =
	135	join "\n",
	136	map {
	137	"Method name conflict for '$_' between roles "
	138	."'".join(' and ', sort values %{$conflicts{$_}})."'"
	139	.", cannot apply these simultaneously to an object."
	140	} keys %conflicts;
	141	die $fail;
	142	}
	143
1947330a	144	my @composable = map $me->_composable_package_for($_), reverse @roles;
	145
	146	*{_getglob("${new_name}::ISA")} = [ @composable, $superclass ];
	147
29dde8ba	148	my @info = map $INFO{$_}, @roles;
1947330a	149
	150	$me->_check_requires(
	151	$new_name, $compose_name,
	152	do { my %h; @h{map @{$_->{requires}\|\|[]}, @info} = (); keys %h }
	153	);
1947330a	154
1947330a	155	@{$APPLIED_TO{$new_name}\|\|={}}{
91037640	156	map keys %{$APPLIED_TO{$_}}, @roles
1947330a	157	} = ();
	158
	159	$COMPOSED{class}{$new_name} = 1;
	160	return $new_name;
	161	}
	162
92e1c5f8	163	# preserved for compat, and apply_roles_to_package calls it to allow an
	164	# updated Role::Tiny to use a non-updated Moo::Role
	165
836aea1b	166	sub apply_role_to_package { shift->apply_single_role_to_package(@_) }
	167
	168	sub apply_roles_to_package {
60dfe768	169	my ($me, $to, @roles) = @_;
60dfe768	170
92e1c5f8	171	return $me->apply_role_to_package($to, $roles[0]) if @roles == 1;
60dfe768	172
836aea1b	173	my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}};
671b5a88	174	delete $conflicts{$_} for $me->_concrete_methods_of($to);
671b5a88	175	if (keys %conflicts) {
60dfe768	176	my $fail =
60dfe768	177	join "\n",
671b5a88	178	map {
	179	"Due to a method name conflict between roles "
	180	."'".join(' and ', sort values %{$conflicts{$_}})."'"
	181	.", the method '$_' must be implemented by '${to}'"
	182	} keys %conflicts;
	183	die $fail;
60dfe768	184	}
06b06c8e	185
	186	# the if guard here is essential since otherwise we accidentally create
	187	# a $INFO for something that isn't a Role::Tiny (or Moo::Role) because
	188	# autovivification hates us and wants us to die()
	189	if ($INFO{$to}) {
	190	delete $INFO{$to}{methods}; # reset since we're about to add methods
	191	}
	192
667f4e70	193	foreach my $role (@roles) {
	194	$me->apply_single_role_to_package($to, $role);
	195	}
671b5a88	196	$APPLIED_TO{$to}{join('\|',@roles)} = 1;
	197	}
	198
836aea1b	199	sub _composite_info_for {
671b5a88	200	my ($me, @roles) = @_;
836aea1b	201	$COMPOSITE_INFO{join('\|', sort @roles)} \|\|= do {
667f4e70	202	foreach my $role (@roles) {
	203	_load_module($role);
	204	}
671b5a88	205	my %methods;
	206	foreach my $role (@roles) {
	207	my $this_methods = $me->_concrete_methods_of($role);
	208	$methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods;
	209	}
	210	delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods;
	211	+{ conflicts => \%methods }
	212	};
60dfe768	213	}
60dfe768	214
1947330a	215	sub _composable_package_for {
	216	my ($me, $role) = @_;
	217	my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role;
	218	return $composed_name if $COMPOSED{role}{$composed_name};
	219	$me->_install_methods($composed_name, $role);
	220	my $base_name = $composed_name.'::_BASE';
c49b0f72	221	# Not using _getglob, since setting @ISA via the typeglob breaks
	222	# inheritance on 5.10.0 if the stash has previously been accessed an
	223	# then a method called on the class (in that order!), which
	224	# ->_install_methods (with the help of ->_install_does) ends up doing.
	225	{ no strict 'refs'; @{"${composed_name}::ISA"} = ( $base_name ); }
1947330a	226	my $modifiers = $INFO{$role}{modifiers}\|\|[];
b1eebd55	227	my @mod_base;
1947330a	228	foreach my $modified (
	229	do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h }
	230	) {
b1eebd55	231	push @mod_base, "sub ${modified} { shift->next::method(\@_) }";
1947330a	232	}
385f5087	233	my $e;
59812c87	234	{
	235	local $@;
	236	eval(my $code = join "\n", "package ${base_name};", @mod_base);
385f5087	237	$e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@;
59812c87	238	}
385f5087	239	die $e if $e;
1947330a	240	$me->_install_modifiers($composed_name, $modifiers);
	241	$COMPOSED{role}{$composed_name} = 1;
	242	return $composed_name;
	243	}
	244
	245	sub _check_requires {
	246	my ($me, $to, $name, @requires) = @_;
	247	if (my @requires_fail = grep !$to->can($_), @requires) {
	248	# role -> role, add to requires, role -> class, error out
	249	if (my $to_info = $INFO{$to}) {
	250	push @{$to_info->{requires}\|\|=[]}, @requires_fail;
	251	} else {
	252	die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail);
	253	}
	254	}
	255	}
	256
4db3a740	257	sub _concrete_methods_of {
4db3a740	258	my ($me, $role) = @_;
1947330a	259	my $info = $INFO{$role};
60dfe768	260	# grab role symbol table
76acfa6c	261	my $stash = _getstash($role);
12f8eb0b	262	# reverse so our keys become the values (captured coderefs) in case
12f8eb0b	263	# they got copied or re-used since
123a5a6e	264	my $not_methods = { reverse %{$info->{not_methods}\|\|{}} };
eb8fcb2d	265	$info->{methods} \|\|= +{
60dfe768	266	# grab all code entries that aren't in the not_methods list
	267	map {
	268	my $code = *{$stash->{$_}}{CODE};
	269	# rely on the '' key we added in import for "no code here"
	270	exists $not_methods->{$code\|\|''} ? () : ($_ => $code)
	271	} grep !ref($stash->{$_}), keys %$stash
ab3370e7	272	};
4db3a740	273	}
	274
	275	sub methods_provided_by {
	276	my ($me, $role) = @_;
	277	die "${role} is not a Role::Tiny" unless my $info = $INFO{$role};
	278	(keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}\|\|[]});
	279	}
	280
	281	sub _install_methods {
	282	my ($me, $to, $role) = @_;
	283
	284	my $info = $INFO{$role};
	285
	286	my $methods = $me->_concrete_methods_of($role);
1947330a	287
ab3370e7	288	# grab target symbol table
76acfa6c	289	my $stash = _getstash($to);
1947330a	290
ab3370e7	291	# determine already extant methods of target
	292	my %has_methods;
	293	@has_methods{grep
faa9ce11	294	+(ref($stash->{$_}) \|\| *{$stash->{$_}}{CODE}),
ab3370e7	295	keys %$stash
ab3370e7	296	} = ();
ab3370e7	297
1947330a	298	foreach my $i (grep !exists $has_methods{$_}, keys %$methods) {
ab3370e7	299	no warnings 'once';
5a247406	300	*{_getglob "${to}::${i}"} = $methods->{$i};
ab3370e7	301	}
fa89d582	302
fa89d582	303	$me->_install_does($to);
1947330a	304	}
ab3370e7	305
1947330a	306	sub _install_modifiers {
1947330a	307	my ($me, $to, $modifiers) = @_;
dccea57d	308	if (my $info = $INFO{$to}) {
	309	push @{$info->{modifiers}}, @{$modifiers\|\|[]};
	310	} else {
	311	foreach my $modifier (@{$modifiers\|\|[]}) {
	312	$me->_install_single_modifier($to, @$modifier);
	313	}
96d3f07a	314	}
ab3370e7	315	}
ab3370e7	316
dccea57d	317	sub _install_single_modifier {
	318	my ($me, @args) = @_;
	319	Class::Method::Modifiers::install_modifier(@args);
	320	}
	321
fa89d582	322	my $FALLBACK = sub { 0 };
	323	sub _install_does {
	324	my ($me, $to) = @_;
	325
	326	# only add does() method to classes
	327	return if $INFO{$to};
	328
	329	# add does() only if they don't have one
	330	*{_getglob "${to}::does"} = \&does_role unless $to->can('does');
	331
211178ea	332	return if ($to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') \|\| 0));
fa89d582	333
	334	my $existing = $to->can('DOES') \|\| $to->can('isa') \|\| $FALLBACK;
	335	my $new_sub = sub {
	336	my ($proto, $role) = @_;
	337	Role::Tiny::does_role($proto, $role) or $proto->$existing($role);
	338	};
	339	no warnings 'redefine';
	340	*{_getglob "${to}::DOES"} = $new_sub;
	341	}
	342
ab3370e7	343	sub does_role {
390ac406	344	my ($proto, $role) = @_;
91037640	345	if ($] >= 5.010) {
	346	require mro;
	347	} else {
	348	require MRO::Compat;
	349	}
	350	foreach my $class (@{mro::get_linear_isa(ref($proto)\|\|$proto)}) {
	351	return 1 if exists $APPLIED_TO{$class}{$role};
	352	}
	353	return 0;
ab3370e7	354	}
	355
	356	1;
5febcf4d	357
0b6e5fff	358	=head1 NAME
0b6e5fff	359
70061353	360	Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose.
5febcf4d	361
	362	=head1 SYNOPSIS
	363
	364	package Some::Role;
	365
	366	use Role::Tiny;
	367
	368	sub foo { ... }
	369
	370	sub bar { ... }
	371
adcb6c3d	372	around baz => sub { ... }
adcb6c3d	373
5febcf4d	374	1;
	375
	376	else where
	377
	378	package Some::Class;
	379
a1164a0b	380	use Role::Tiny::With;
5febcf4d	381
5febcf4d	382	# bar gets imported, but not foo
a1164a0b	383	with 'Some::Role';
5febcf4d	384
	385	sub foo { ... }
	386
adcb6c3d	387	# baz is wrapped in the around modifier by Class::Method::Modifiers
	388	sub baz { ... }
	389
5febcf4d	390	1;
5febcf4d	391
adcb6c3d	392	If you wanted attributes as well, look at L<Moo::Role>.
adcb6c3d	393
5febcf4d	394	=head1 DESCRIPTION
	395
	396	C<Role::Tiny> is a minimalist role composition tool.
	397
	398	=head1 ROLE COMPOSITION
	399
	400	Role composition can be thought of as much more clever and meaningful multiple
	401	inheritance. The basics of this implementation of roles is:
	402
	403	=over 2
	404
	405	=item *
	406
	407	If a method is already defined on a class, that method will not be composed in
	408	from the role.
	409
	410	=item *
	411
	412	If a method that the role L</requires> to be implemented is not implemented,
	413	role application will fail loudly.
	414
0d39f9d3	415	=back
0d39f9d3	416
5febcf4d	417	Unlike L<Class::C3>, where the B<last> class inherited from "wins," role
836aea1b	418	composition is the other way around, where the class wins. If multiple roles
	419	are applied in a single call (single with statement), then if any of their
	420	provided methods clash, an exception is raised unless the class provides
	421	a method since this conflict indicates a potential problem.
5febcf4d	422
5febcf4d	423	=head1 IMPORTED SUBROUTINES
	424
	425	=head2 requires
	426
	427	requires qw(foo bar);
	428
	429	Declares a list of methods that must be defined to compose role.
	430
	431	=head2 with
	432
	433	with 'Some::Role1';
836aea1b	434
	435	with 'Some::Role1', 'Some::Role2';
	436
	437	Composes another role into the current role (or class via L<Role::Tiny::With>).
	438
	439	If you have conflicts and want to resolve them in favour of Some::Role1 you
	440	can instead write:
	441
	442	with 'Some::Role1';
5febcf4d	443	with 'Some::Role2';
5febcf4d	444
836aea1b	445	If you have conflicts and want to resolve different conflicts in favour of
836aea1b	446	different roles, please refactor your codebase.
5febcf4d	447
	448	=head2 before
	449
	450	before foo => sub { ... };
	451
	452	See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
	453	documentation.
	454
adcb6c3d	455	Note that since you are not required to use method modifiers,
	456	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	457	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	458	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	459
5febcf4d	460	=head2 around
	461
	462	around foo => sub { ... };
	463
	464	See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
	465	documentation.
	466
adcb6c3d	467	Note that since you are not required to use method modifiers,
	468	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	469	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	470	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	471
5febcf4d	472	=head2 after
	473
	474	after foo => sub { ... };
	475
	476	See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
	477	documentation.
	478
adcb6c3d	479	Note that since you are not required to use method modifiers,
	480	L<Class::Method::Modifiers> is lazily loaded and we do not declare it as
	481	a dependency. If your L<Role::Tiny> role uses modifiers you must depend on
	482	both L<Class::Method::Modifiers> and L<Role::Tiny>.
	483
ec28e16b	484	=head1 SUBROUTINES
	485
	486	=head2 does_role
	487
	488	if (Role::Tiny::does_role($foo, 'Some::Role')) {
	489	...
	490	}
	491
	492	Returns true if class has been composed with role.
	493
	494	This subroutine is also installed as ->does on any class a Role::Tiny is
	495	composed into unless that class already has an ->does method, so
	496
	497	if ($foo->does('Some::Role')) {
	498	...
	499	}
	500
fa89d582	501	will work for classes but to test a role, one must use ::does_role directly.
	502
	503	Additionally, Role::Tiny will override the standard Perl C<DOES> method
	504	for your class. However, if C<any> class in your class' inheritance
	505	heirarchy provides C<DOES>, then Role::Tiny will not override it.
ec28e16b	506
	507	=head1 METHODS
	508
	509	=head2 apply_roles_to_package
	510
	511	Role::Tiny->apply_roles_to_package(
	512	'Some::Package', 'Some::Role', 'Some::Other::Role'
	513	);
	514
	515	Composes role with package. See also L<Role::Tiny::With>.
	516
	517	=head2 apply_roles_to_object
	518
	519	Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2));
	520
	521	Composes roles in order into object directly. Object is reblessed into the
	522	resulting class.
	523
	524	=head2 create_class_with_roles
	525
	526	Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2));
	527
	528	Creates a new class based on base, with the roles composed into it in order.
	529	New class is returned.
	530
adcb6c3d	531	=head1 SEE ALSO
	532
	533	L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is
	534	a meta-protocol-less subset of the king of role systems, L<Moose::Role>.
	535
	536	If you don't want method modifiers and do want to be forcibly restricted
	537	to a single role application per class, Ovid's L<Role::Basic> exists. But
259ce3a0	538	Stevan Little (the L<Moose> author) and I don't find the additional
	539	restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices
	540	are more a guide to what you should prefer doing, to our mind, rather than
	541	something that needs to be enforced.
adcb6c3d	542
c334a5c1	543	=head1 AUTHOR
	544
	545	mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
	546
	547	=head1 CONTRIBUTORS
	548
	549	dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
	550
	551	frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
	552
	553	hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
	554
	555	jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
	556
	557	ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
	558
	559	chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
	560
	561	ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
	562
	563	doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
	564
	565	perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
	566
ec28e16b	567	Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
ec28e16b	568
91037640	569	ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
91037640	570
fa89d582	571	tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>
fa89d582	572
c334a5c1	573	=head1 COPYRIGHT
40f3e3aa	574
c334a5c1	575	Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS>
c334a5c1	576	as listed above.
40f3e3aa	577
c334a5c1	578	=head1 LICENSE
40f3e3aa	579
c334a5c1	580	This library is free software and may be distributed under the same terms
c334a5c1	581	as perl itself.
40f3e3aa	582
40f3e3aa	583	=cut