Commit | Line | Data |
ab3370e7 |
1 | package Role::Tiny; |
2 | |
119014a7 |
3 | sub _getglob { \*{$_[0]} } |
5e03b55c |
4 | sub _getstash { \%{"$_[0]::"} } |
119014a7 |
5 | |
b1eebd55 |
6 | use strict; |
7 | use warnings FATAL => 'all'; |
ab3370e7 |
8 | |
923067bb |
9 | our $VERSION = '1.002000'; # 1.2.0 |
c334a5c1 |
10 | $VERSION = eval $VERSION; |
11 | |
ab3370e7 |
12 | our %INFO; |
13 | our %APPLIED_TO; |
1947330a |
14 | our %COMPOSED; |
836aea1b |
15 | our %COMPOSITE_INFO; |
ab3370e7 |
16 | |
cf62c989 |
17 | # Module state workaround totally stolen from Zefram's Module::Runtime. |
18 | |
19 | BEGIN { |
20 | *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0}; |
21 | } |
22 | |
23 | sub Role::Tiny::__GUARD__::DESTROY { |
24 | delete $INC{$_[0]->[0]} if @{$_[0]}; |
25 | } |
5e03b55c |
26 | |
fb5074f6 |
27 | sub _load_module { |
fb5074f6 |
28 | (my $proto = $_[0]) =~ s/::/\//g; |
cf62c989 |
29 | $proto .= '.pm'; |
30 | return 1 if $INC{$proto}; |
5e03b55c |
31 | # can't just ->can('can') because a sub-package Foo::Bar::Baz |
32 | # creates a 'Baz::' key in Foo::Bar's symbol table |
33 | return 1 if grep !/::$/, keys %{_getstash($_[0])||{}}; |
cf62c989 |
34 | my $guard = _WORK_AROUND_BROKEN_MODULE_STATE |
35 | && bless([ $proto ], 'Role::Tiny::__GUARD__'); |
36 | require $proto; |
37 | pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE; |
fb5074f6 |
38 | return 1; |
39 | } |
40 | |
ab3370e7 |
41 | sub import { |
42 | my $target = caller; |
a1164a0b |
43 | my $me = shift; |
3ca7ff56 |
44 | strict->import; |
45 | warnings->import(FATAL => 'all'); |
1ba11455 |
46 | return if $INFO{$target}; # already exported into this package |
ab3370e7 |
47 | # get symbol table reference |
48 | my $stash = do { no strict 'refs'; \%{"${target}::"} }; |
49 | # install before/after/around subs |
50 | foreach my $type (qw(before after around)) { |
5a247406 |
51 | *{_getglob "${target}::${type}"} = sub { |
7568ba55 |
52 | require Class::Method::Modifiers; |
ab3370e7 |
53 | push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ]; |
ef2da711 |
54 | return; |
ab3370e7 |
55 | }; |
56 | } |
5a247406 |
57 | *{_getglob "${target}::requires"} = sub { |
ab3370e7 |
58 | push @{$INFO{$target}{requires}||=[]}, @_; |
ef2da711 |
59 | return; |
ab3370e7 |
60 | }; |
5a247406 |
61 | *{_getglob "${target}::with"} = sub { |
836aea1b |
62 | $me->apply_roles_to_package($target, @_); |
ef2da711 |
63 | return; |
96d3f07a |
64 | }; |
7b8177f8 |
65 | # grab all *non-constant* (stash slot is not a scalarref) subs present |
ab3370e7 |
66 | # in the symbol table and store their refaddrs (no need to forcibly |
67 | # inflate constant subs into real subs) - also add '' to here (this |
12f8eb0b |
68 | # is used later) with a map to the coderefs in case of copying or re-use |
69 | my @not_methods = ('', map { *$_{CODE}||() } grep !ref($_), values %$stash); |
70 | @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods; |
ab3370e7 |
71 | # a role does itself |
72 | $APPLIED_TO{$target} = { $target => undef }; |
73 | } |
74 | |
836aea1b |
75 | sub apply_single_role_to_package { |
369a4c50 |
76 | my ($me, $to, $role) = @_; |
1947330a |
77 | |
fb5074f6 |
78 | _load_module($role); |
79 | |
ab3370e7 |
80 | die "This is apply_role_to_package" if ref($to); |
1947330a |
81 | die "${role} is not a Role::Tiny" unless my $info = $INFO{$role}; |
82 | |
83 | $me->_check_requires($to, $role, @{$info->{requires}||[]}); |
84 | |
85 | $me->_install_methods($to, $role); |
86 | |
87 | $me->_install_modifiers($to, $info->{modifiers}); |
88 | |
1947330a |
89 | # copy our role list into the target's |
90 | @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = (); |
91 | } |
92 | |
93 | sub apply_roles_to_object { |
94 | my ($me, $object, @roles) = @_; |
95 | die "No roles supplied!" unless @roles; |
96 | my $class = ref($object); |
97 | bless($object, $me->create_class_with_roles($class, @roles)); |
98 | $object; |
99 | } |
100 | |
101 | sub create_class_with_roles { |
102 | my ($me, $superclass, @roles) = @_; |
103 | |
fb5074f6 |
104 | die "No roles supplied!" unless @roles; |
105 | |
f52b9821 |
106 | _load_module($superclass); |
2c580674 |
107 | { |
108 | my %seen; |
109 | $seen{$_}++ for @roles; |
110 | if (my @dupes = grep $seen{$_} > 1, @roles) { |
111 | die "Duplicated roles: ".join(', ', @dupes); |
112 | } |
113 | } |
114 | |
c69190f1 |
115 | my $new_name = join( |
116 | '__WITH__', $superclass, my $compose_name = join '__AND__', @roles |
117 | ); |
118 | |
1947330a |
119 | return $new_name if $COMPOSED{class}{$new_name}; |
120 | |
121 | foreach my $role (@roles) { |
fb5074f6 |
122 | _load_module($role); |
29dde8ba |
123 | die "${role} is not a Role::Tiny" unless $INFO{$role}; |
1947330a |
124 | } |
125 | |
786e5ba0 |
126 | if ($] >= 5.010) { |
7568ba55 |
127 | require mro; |
b1eebd55 |
128 | } else { |
7568ba55 |
129 | require MRO::Compat; |
b1eebd55 |
130 | } |
1947330a |
131 | |
471419f6 |
132 | my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}}; |
133 | if (keys %conflicts) { |
134 | my $fail = |
135 | join "\n", |
136 | map { |
137 | "Method name conflict for '$_' between roles " |
138 | ."'".join(' and ', sort values %{$conflicts{$_}})."'" |
139 | .", cannot apply these simultaneously to an object." |
140 | } keys %conflicts; |
141 | die $fail; |
142 | } |
143 | |
1947330a |
144 | my @composable = map $me->_composable_package_for($_), reverse @roles; |
145 | |
146 | *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ]; |
147 | |
29dde8ba |
148 | my @info = map $INFO{$_}, @roles; |
1947330a |
149 | |
150 | $me->_check_requires( |
151 | $new_name, $compose_name, |
152 | do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h } |
153 | ); |
1947330a |
154 | |
1947330a |
155 | @{$APPLIED_TO{$new_name}||={}}{ |
91037640 |
156 | map keys %{$APPLIED_TO{$_}}, @roles |
1947330a |
157 | } = (); |
158 | |
159 | $COMPOSED{class}{$new_name} = 1; |
160 | return $new_name; |
161 | } |
162 | |
92e1c5f8 |
163 | # preserved for compat, and apply_roles_to_package calls it to allow an |
164 | # updated Role::Tiny to use a non-updated Moo::Role |
165 | |
836aea1b |
166 | sub apply_role_to_package { shift->apply_single_role_to_package(@_) } |
167 | |
168 | sub apply_roles_to_package { |
60dfe768 |
169 | my ($me, $to, @roles) = @_; |
170 | |
92e1c5f8 |
171 | return $me->apply_role_to_package($to, $roles[0]) if @roles == 1; |
60dfe768 |
172 | |
836aea1b |
173 | my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}}; |
671b5a88 |
174 | delete $conflicts{$_} for $me->_concrete_methods_of($to); |
175 | if (keys %conflicts) { |
60dfe768 |
176 | my $fail = |
177 | join "\n", |
671b5a88 |
178 | map { |
179 | "Due to a method name conflict between roles " |
180 | ."'".join(' and ', sort values %{$conflicts{$_}})."'" |
181 | .", the method '$_' must be implemented by '${to}'" |
182 | } keys %conflicts; |
183 | die $fail; |
60dfe768 |
184 | } |
06b06c8e |
185 | |
186 | # the if guard here is essential since otherwise we accidentally create |
187 | # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because |
188 | # autovivification hates us and wants us to die() |
189 | if ($INFO{$to}) { |
190 | delete $INFO{$to}{methods}; # reset since we're about to add methods |
191 | } |
192 | |
92e1c5f8 |
193 | $me->apply_role_to_package($to, $_) for @roles; |
671b5a88 |
194 | $APPLIED_TO{$to}{join('|',@roles)} = 1; |
195 | } |
196 | |
836aea1b |
197 | sub _composite_info_for { |
671b5a88 |
198 | my ($me, @roles) = @_; |
836aea1b |
199 | $COMPOSITE_INFO{join('|', sort @roles)} ||= do { |
671b5a88 |
200 | _load_module($_) for @roles; |
201 | my %methods; |
202 | foreach my $role (@roles) { |
203 | my $this_methods = $me->_concrete_methods_of($role); |
204 | $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods; |
205 | } |
206 | delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods; |
207 | +{ conflicts => \%methods } |
208 | }; |
60dfe768 |
209 | } |
210 | |
1947330a |
211 | sub _composable_package_for { |
212 | my ($me, $role) = @_; |
213 | my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role; |
214 | return $composed_name if $COMPOSED{role}{$composed_name}; |
215 | $me->_install_methods($composed_name, $role); |
216 | my $base_name = $composed_name.'::_BASE'; |
217 | *{_getglob("${composed_name}::ISA")} = [ $base_name ]; |
218 | my $modifiers = $INFO{$role}{modifiers}||[]; |
b1eebd55 |
219 | my @mod_base; |
1947330a |
220 | foreach my $modified ( |
221 | do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h } |
222 | ) { |
b1eebd55 |
223 | push @mod_base, "sub ${modified} { shift->next::method(\@_) }"; |
1947330a |
224 | } |
385f5087 |
225 | my $e; |
59812c87 |
226 | { |
227 | local $@; |
228 | eval(my $code = join "\n", "package ${base_name};", @mod_base); |
385f5087 |
229 | $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@; |
59812c87 |
230 | } |
385f5087 |
231 | die $e if $e; |
1947330a |
232 | $me->_install_modifiers($composed_name, $modifiers); |
233 | $COMPOSED{role}{$composed_name} = 1; |
234 | return $composed_name; |
235 | } |
236 | |
237 | sub _check_requires { |
238 | my ($me, $to, $name, @requires) = @_; |
239 | if (my @requires_fail = grep !$to->can($_), @requires) { |
240 | # role -> role, add to requires, role -> class, error out |
241 | if (my $to_info = $INFO{$to}) { |
242 | push @{$to_info->{requires}||=[]}, @requires_fail; |
243 | } else { |
244 | die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail); |
245 | } |
246 | } |
247 | } |
248 | |
4db3a740 |
249 | sub _concrete_methods_of { |
250 | my ($me, $role) = @_; |
1947330a |
251 | my $info = $INFO{$role}; |
60dfe768 |
252 | # grab role symbol table |
253 | my $stash = do { no strict 'refs'; \%{"${role}::"}}; |
12f8eb0b |
254 | # reverse so our keys become the values (captured coderefs) in case |
255 | # they got copied or re-used since |
123a5a6e |
256 | my $not_methods = { reverse %{$info->{not_methods}||{}} }; |
eb8fcb2d |
257 | $info->{methods} ||= +{ |
60dfe768 |
258 | # grab all code entries that aren't in the not_methods list |
259 | map { |
260 | my $code = *{$stash->{$_}}{CODE}; |
261 | # rely on the '' key we added in import for "no code here" |
262 | exists $not_methods->{$code||''} ? () : ($_ => $code) |
263 | } grep !ref($stash->{$_}), keys %$stash |
ab3370e7 |
264 | }; |
4db3a740 |
265 | } |
266 | |
267 | sub methods_provided_by { |
268 | my ($me, $role) = @_; |
269 | die "${role} is not a Role::Tiny" unless my $info = $INFO{$role}; |
270 | (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]}); |
271 | } |
272 | |
273 | sub _install_methods { |
274 | my ($me, $to, $role) = @_; |
275 | |
276 | my $info = $INFO{$role}; |
277 | |
278 | my $methods = $me->_concrete_methods_of($role); |
1947330a |
279 | |
ab3370e7 |
280 | # grab target symbol table |
281 | my $stash = do { no strict 'refs'; \%{"${to}::"}}; |
1947330a |
282 | |
ab3370e7 |
283 | # determine already extant methods of target |
284 | my %has_methods; |
285 | @has_methods{grep |
faa9ce11 |
286 | +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}), |
ab3370e7 |
287 | keys %$stash |
288 | } = (); |
ab3370e7 |
289 | |
1947330a |
290 | foreach my $i (grep !exists $has_methods{$_}, keys %$methods) { |
ab3370e7 |
291 | no warnings 'once'; |
5a247406 |
292 | *{_getglob "${to}::${i}"} = $methods->{$i}; |
ab3370e7 |
293 | } |
fa89d582 |
294 | |
295 | $me->_install_does($to); |
1947330a |
296 | } |
ab3370e7 |
297 | |
1947330a |
298 | sub _install_modifiers { |
299 | my ($me, $to, $modifiers) = @_; |
dccea57d |
300 | if (my $info = $INFO{$to}) { |
301 | push @{$info->{modifiers}}, @{$modifiers||[]}; |
302 | } else { |
303 | foreach my $modifier (@{$modifiers||[]}) { |
304 | $me->_install_single_modifier($to, @$modifier); |
305 | } |
96d3f07a |
306 | } |
ab3370e7 |
307 | } |
308 | |
dccea57d |
309 | sub _install_single_modifier { |
310 | my ($me, @args) = @_; |
311 | Class::Method::Modifiers::install_modifier(@args); |
312 | } |
313 | |
fa89d582 |
314 | my $FALLBACK = sub { 0 }; |
315 | sub _install_does { |
316 | my ($me, $to) = @_; |
317 | |
318 | # only add does() method to classes |
319 | return if $INFO{$to}; |
320 | |
321 | # add does() only if they don't have one |
322 | *{_getglob "${to}::does"} = \&does_role unless $to->can('does'); |
323 | |
211178ea |
324 | return if ($to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') || 0)); |
fa89d582 |
325 | |
326 | my $existing = $to->can('DOES') || $to->can('isa') || $FALLBACK; |
327 | my $new_sub = sub { |
328 | my ($proto, $role) = @_; |
329 | Role::Tiny::does_role($proto, $role) or $proto->$existing($role); |
330 | }; |
331 | no warnings 'redefine'; |
332 | *{_getglob "${to}::DOES"} = $new_sub; |
333 | } |
334 | |
ab3370e7 |
335 | sub does_role { |
390ac406 |
336 | my ($proto, $role) = @_; |
91037640 |
337 | if ($] >= 5.010) { |
338 | require mro; |
339 | } else { |
340 | require MRO::Compat; |
341 | } |
342 | foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) { |
343 | return 1 if exists $APPLIED_TO{$class}{$role}; |
344 | } |
345 | return 0; |
ab3370e7 |
346 | } |
347 | |
348 | 1; |
5febcf4d |
349 | |
0b6e5fff |
350 | =head1 NAME |
351 | |
70061353 |
352 | Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose. |
5febcf4d |
353 | |
354 | =head1 SYNOPSIS |
355 | |
356 | package Some::Role; |
357 | |
358 | use Role::Tiny; |
359 | |
360 | sub foo { ... } |
361 | |
362 | sub bar { ... } |
363 | |
adcb6c3d |
364 | around baz => sub { ... } |
365 | |
5febcf4d |
366 | 1; |
367 | |
368 | else where |
369 | |
370 | package Some::Class; |
371 | |
a1164a0b |
372 | use Role::Tiny::With; |
5febcf4d |
373 | |
374 | # bar gets imported, but not foo |
a1164a0b |
375 | with 'Some::Role'; |
5febcf4d |
376 | |
377 | sub foo { ... } |
378 | |
adcb6c3d |
379 | # baz is wrapped in the around modifier by Class::Method::Modifiers |
380 | sub baz { ... } |
381 | |
5febcf4d |
382 | 1; |
383 | |
adcb6c3d |
384 | If you wanted attributes as well, look at L<Moo::Role>. |
385 | |
5febcf4d |
386 | =head1 DESCRIPTION |
387 | |
388 | C<Role::Tiny> is a minimalist role composition tool. |
389 | |
390 | =head1 ROLE COMPOSITION |
391 | |
392 | Role composition can be thought of as much more clever and meaningful multiple |
393 | inheritance. The basics of this implementation of roles is: |
394 | |
395 | =over 2 |
396 | |
397 | =item * |
398 | |
399 | If a method is already defined on a class, that method will not be composed in |
400 | from the role. |
401 | |
402 | =item * |
403 | |
404 | If a method that the role L</requires> to be implemented is not implemented, |
405 | role application will fail loudly. |
406 | |
0d39f9d3 |
407 | =back |
408 | |
5febcf4d |
409 | Unlike L<Class::C3>, where the B<last> class inherited from "wins," role |
836aea1b |
410 | composition is the other way around, where the class wins. If multiple roles |
411 | are applied in a single call (single with statement), then if any of their |
412 | provided methods clash, an exception is raised unless the class provides |
413 | a method since this conflict indicates a potential problem. |
5febcf4d |
414 | |
5febcf4d |
415 | =head1 IMPORTED SUBROUTINES |
416 | |
417 | =head2 requires |
418 | |
419 | requires qw(foo bar); |
420 | |
421 | Declares a list of methods that must be defined to compose role. |
422 | |
423 | =head2 with |
424 | |
425 | with 'Some::Role1'; |
836aea1b |
426 | |
427 | with 'Some::Role1', 'Some::Role2'; |
428 | |
429 | Composes another role into the current role (or class via L<Role::Tiny::With>). |
430 | |
431 | If you have conflicts and want to resolve them in favour of Some::Role1 you |
432 | can instead write: |
433 | |
434 | with 'Some::Role1'; |
5febcf4d |
435 | with 'Some::Role2'; |
436 | |
836aea1b |
437 | If you have conflicts and want to resolve different conflicts in favour of |
438 | different roles, please refactor your codebase. |
5febcf4d |
439 | |
440 | =head2 before |
441 | |
442 | before foo => sub { ... }; |
443 | |
444 | See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full |
445 | documentation. |
446 | |
adcb6c3d |
447 | Note that since you are not required to use method modifiers, |
448 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
449 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
450 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
451 | |
5febcf4d |
452 | =head2 around |
453 | |
454 | around foo => sub { ... }; |
455 | |
456 | See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full |
457 | documentation. |
458 | |
adcb6c3d |
459 | Note that since you are not required to use method modifiers, |
460 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
461 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
462 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
463 | |
5febcf4d |
464 | =head2 after |
465 | |
466 | after foo => sub { ... }; |
467 | |
468 | See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full |
469 | documentation. |
470 | |
adcb6c3d |
471 | Note that since you are not required to use method modifiers, |
472 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
473 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
474 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
475 | |
ec28e16b |
476 | =head1 SUBROUTINES |
477 | |
478 | =head2 does_role |
479 | |
480 | if (Role::Tiny::does_role($foo, 'Some::Role')) { |
481 | ... |
482 | } |
483 | |
484 | Returns true if class has been composed with role. |
485 | |
486 | This subroutine is also installed as ->does on any class a Role::Tiny is |
487 | composed into unless that class already has an ->does method, so |
488 | |
489 | if ($foo->does('Some::Role')) { |
490 | ... |
491 | } |
492 | |
fa89d582 |
493 | will work for classes but to test a role, one must use ::does_role directly. |
494 | |
495 | Additionally, Role::Tiny will override the standard Perl C<DOES> method |
496 | for your class. However, if C<any> class in your class' inheritance |
497 | heirarchy provides C<DOES>, then Role::Tiny will not override it. |
ec28e16b |
498 | |
499 | =head1 METHODS |
500 | |
501 | =head2 apply_roles_to_package |
502 | |
503 | Role::Tiny->apply_roles_to_package( |
504 | 'Some::Package', 'Some::Role', 'Some::Other::Role' |
505 | ); |
506 | |
507 | Composes role with package. See also L<Role::Tiny::With>. |
508 | |
509 | =head2 apply_roles_to_object |
510 | |
511 | Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2)); |
512 | |
513 | Composes roles in order into object directly. Object is reblessed into the |
514 | resulting class. |
515 | |
516 | =head2 create_class_with_roles |
517 | |
518 | Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2)); |
519 | |
520 | Creates a new class based on base, with the roles composed into it in order. |
521 | New class is returned. |
522 | |
adcb6c3d |
523 | =head1 SEE ALSO |
524 | |
525 | L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is |
526 | a meta-protocol-less subset of the king of role systems, L<Moose::Role>. |
527 | |
528 | If you don't want method modifiers and do want to be forcibly restricted |
529 | to a single role application per class, Ovid's L<Role::Basic> exists. But |
259ce3a0 |
530 | Stevan Little (the L<Moose> author) and I don't find the additional |
531 | restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices |
532 | are more a guide to what you should prefer doing, to our mind, rather than |
533 | something that needs to be enforced. |
adcb6c3d |
534 | |
c334a5c1 |
535 | =head1 AUTHOR |
536 | |
537 | mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk> |
538 | |
539 | =head1 CONTRIBUTORS |
540 | |
541 | dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx> |
542 | |
543 | frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com> |
544 | |
545 | hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org> |
546 | |
547 | jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com> |
548 | |
549 | ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org> |
550 | |
551 | chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com> |
552 | |
553 | ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org> |
554 | |
555 | doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net> |
556 | |
557 | perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org> |
558 | |
ec28e16b |
559 | Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com> |
560 | |
91037640 |
561 | ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org> |
562 | |
fa89d582 |
563 | tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org> |
564 | |
c334a5c1 |
565 | =head1 COPYRIGHT |
40f3e3aa |
566 | |
c334a5c1 |
567 | Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS> |
568 | as listed above. |
40f3e3aa |
569 | |
c334a5c1 |
570 | =head1 LICENSE |
40f3e3aa |
571 | |
c334a5c1 |
572 | This library is free software and may be distributed under the same terms |
573 | as perl itself. |
40f3e3aa |
574 | |
575 | =cut |