Commit | Line | Data |
ab3370e7 |
1 | package Role::Tiny; |
2 | |
119014a7 |
3 | sub _getglob { \*{$_[0]} } |
5e03b55c |
4 | sub _getstash { \%{"$_[0]::"} } |
119014a7 |
5 | |
b1eebd55 |
6 | use strict; |
7 | use warnings FATAL => 'all'; |
ab3370e7 |
8 | |
b6d9324b |
9 | our $VERSION = '1.002005'; # 1.2.5 |
c334a5c1 |
10 | $VERSION = eval $VERSION; |
11 | |
ab3370e7 |
12 | our %INFO; |
13 | our %APPLIED_TO; |
1947330a |
14 | our %COMPOSED; |
836aea1b |
15 | our %COMPOSITE_INFO; |
ab3370e7 |
16 | |
cf62c989 |
17 | # Module state workaround totally stolen from Zefram's Module::Runtime. |
18 | |
19 | BEGIN { |
20 | *_WORK_AROUND_BROKEN_MODULE_STATE = "$]" < 5.009 ? sub(){1} : sub(){0}; |
21 | } |
22 | |
23 | sub Role::Tiny::__GUARD__::DESTROY { |
24 | delete $INC{$_[0]->[0]} if @{$_[0]}; |
25 | } |
5e03b55c |
26 | |
fb5074f6 |
27 | sub _load_module { |
fb5074f6 |
28 | (my $proto = $_[0]) =~ s/::/\//g; |
cf62c989 |
29 | $proto .= '.pm'; |
30 | return 1 if $INC{$proto}; |
5e03b55c |
31 | # can't just ->can('can') because a sub-package Foo::Bar::Baz |
32 | # creates a 'Baz::' key in Foo::Bar's symbol table |
33 | return 1 if grep !/::$/, keys %{_getstash($_[0])||{}}; |
cf62c989 |
34 | my $guard = _WORK_AROUND_BROKEN_MODULE_STATE |
35 | && bless([ $proto ], 'Role::Tiny::__GUARD__'); |
36 | require $proto; |
37 | pop @$guard if _WORK_AROUND_BROKEN_MODULE_STATE; |
fb5074f6 |
38 | return 1; |
39 | } |
40 | |
ab3370e7 |
41 | sub import { |
42 | my $target = caller; |
a1164a0b |
43 | my $me = shift; |
3ca7ff56 |
44 | strict->import; |
45 | warnings->import(FATAL => 'all'); |
1ba11455 |
46 | return if $INFO{$target}; # already exported into this package |
8e8b04eb |
47 | $INFO{$target}{is_role} = 1; |
ab3370e7 |
48 | # get symbol table reference |
76acfa6c |
49 | my $stash = _getstash($target); |
ab3370e7 |
50 | # install before/after/around subs |
51 | foreach my $type (qw(before after around)) { |
5a247406 |
52 | *{_getglob "${target}::${type}"} = sub { |
7568ba55 |
53 | require Class::Method::Modifiers; |
ab3370e7 |
54 | push @{$INFO{$target}{modifiers}||=[]}, [ $type => @_ ]; |
ef2da711 |
55 | return; |
ab3370e7 |
56 | }; |
57 | } |
5a247406 |
58 | *{_getglob "${target}::requires"} = sub { |
ab3370e7 |
59 | push @{$INFO{$target}{requires}||=[]}, @_; |
ef2da711 |
60 | return; |
ab3370e7 |
61 | }; |
5a247406 |
62 | *{_getglob "${target}::with"} = sub { |
836aea1b |
63 | $me->apply_roles_to_package($target, @_); |
ef2da711 |
64 | return; |
96d3f07a |
65 | }; |
7b8177f8 |
66 | # grab all *non-constant* (stash slot is not a scalarref) subs present |
ab3370e7 |
67 | # in the symbol table and store their refaddrs (no need to forcibly |
f1ce2b19 |
68 | # inflate constant subs into real subs) with a map to the coderefs in |
69 | # case of copying or re-use |
70 | my @not_methods = (map { *$_{CODE}||() } grep !ref($_), values %$stash); |
12f8eb0b |
71 | @{$INFO{$target}{not_methods}={}}{@not_methods} = @not_methods; |
ab3370e7 |
72 | # a role does itself |
73 | $APPLIED_TO{$target} = { $target => undef }; |
74 | } |
75 | |
3d203c73 |
76 | sub role_application_steps { |
77 | qw(_install_methods _install_modifiers _check_requires _copy_applied_list); |
78 | } |
79 | |
836aea1b |
80 | sub apply_single_role_to_package { |
369a4c50 |
81 | my ($me, $to, $role) = @_; |
ee81e663 |
82 | return if our $SKIP_APPLY; |
1947330a |
83 | |
fb5074f6 |
84 | _load_module($role); |
85 | |
ab3370e7 |
86 | die "This is apply_role_to_package" if ref($to); |
3d203c73 |
87 | die "${role} is not a Role::Tiny" unless $INFO{$role}; |
1947330a |
88 | |
3d203c73 |
89 | foreach my $step ($me->role_application_steps) { |
90 | $me->$step($to, $role); |
91 | } |
92 | } |
1947330a |
93 | |
3d203c73 |
94 | sub _copy_applied_list { |
95 | my ($me, $to, $role) = @_; |
1947330a |
96 | # copy our role list into the target's |
97 | @{$APPLIED_TO{$to}||={}}{keys %{$APPLIED_TO{$role}}} = (); |
98 | } |
99 | |
100 | sub apply_roles_to_object { |
101 | my ($me, $object, @roles) = @_; |
102 | die "No roles supplied!" unless @roles; |
103 | my $class = ref($object); |
104 | bless($object, $me->create_class_with_roles($class, @roles)); |
105 | $object; |
106 | } |
107 | |
108 | sub create_class_with_roles { |
109 | my ($me, $superclass, @roles) = @_; |
110 | |
fb5074f6 |
111 | die "No roles supplied!" unless @roles; |
112 | |
f52b9821 |
113 | _load_module($superclass); |
2c580674 |
114 | { |
115 | my %seen; |
116 | $seen{$_}++ for @roles; |
117 | if (my @dupes = grep $seen{$_} > 1, @roles) { |
118 | die "Duplicated roles: ".join(', ', @dupes); |
119 | } |
120 | } |
121 | |
c69190f1 |
122 | my $new_name = join( |
123 | '__WITH__', $superclass, my $compose_name = join '__AND__', @roles |
124 | ); |
125 | |
1947330a |
126 | return $new_name if $COMPOSED{class}{$new_name}; |
127 | |
128 | foreach my $role (@roles) { |
fb5074f6 |
129 | _load_module($role); |
29dde8ba |
130 | die "${role} is not a Role::Tiny" unless $INFO{$role}; |
1947330a |
131 | } |
132 | |
786e5ba0 |
133 | if ($] >= 5.010) { |
7568ba55 |
134 | require mro; |
b1eebd55 |
135 | } else { |
7568ba55 |
136 | require MRO::Compat; |
b1eebd55 |
137 | } |
1947330a |
138 | |
471419f6 |
139 | my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}}; |
140 | if (keys %conflicts) { |
141 | my $fail = |
142 | join "\n", |
143 | map { |
144 | "Method name conflict for '$_' between roles " |
145 | ."'".join(' and ', sort values %{$conflicts{$_}})."'" |
146 | .", cannot apply these simultaneously to an object." |
147 | } keys %conflicts; |
148 | die $fail; |
149 | } |
150 | |
1947330a |
151 | my @composable = map $me->_composable_package_for($_), reverse @roles; |
152 | |
153 | *{_getglob("${new_name}::ISA")} = [ @composable, $superclass ]; |
154 | |
29dde8ba |
155 | my @info = map $INFO{$_}, @roles; |
1947330a |
156 | |
157 | $me->_check_requires( |
158 | $new_name, $compose_name, |
159 | do { my %h; @h{map @{$_->{requires}||[]}, @info} = (); keys %h } |
160 | ); |
1947330a |
161 | |
1947330a |
162 | @{$APPLIED_TO{$new_name}||={}}{ |
91037640 |
163 | map keys %{$APPLIED_TO{$_}}, @roles |
1947330a |
164 | } = (); |
165 | |
166 | $COMPOSED{class}{$new_name} = 1; |
167 | return $new_name; |
168 | } |
169 | |
92e1c5f8 |
170 | # preserved for compat, and apply_roles_to_package calls it to allow an |
171 | # updated Role::Tiny to use a non-updated Moo::Role |
172 | |
836aea1b |
173 | sub apply_role_to_package { shift->apply_single_role_to_package(@_) } |
174 | |
175 | sub apply_roles_to_package { |
60dfe768 |
176 | my ($me, $to, @roles) = @_; |
177 | |
92e1c5f8 |
178 | return $me->apply_role_to_package($to, $roles[0]) if @roles == 1; |
60dfe768 |
179 | |
836aea1b |
180 | my %conflicts = %{$me->_composite_info_for(@roles)->{conflicts}}; |
8951a0b6 |
181 | delete $conflicts{$_} for keys %{ $me->_concrete_methods_of($to) }; |
671b5a88 |
182 | if (keys %conflicts) { |
60dfe768 |
183 | my $fail = |
184 | join "\n", |
671b5a88 |
185 | map { |
186 | "Due to a method name conflict between roles " |
187 | ."'".join(' and ', sort values %{$conflicts{$_}})."'" |
188 | .", the method '$_' must be implemented by '${to}'" |
189 | } keys %conflicts; |
190 | die $fail; |
60dfe768 |
191 | } |
06b06c8e |
192 | |
193 | # the if guard here is essential since otherwise we accidentally create |
194 | # a $INFO for something that isn't a Role::Tiny (or Moo::Role) because |
195 | # autovivification hates us and wants us to die() |
196 | if ($INFO{$to}) { |
197 | delete $INFO{$to}{methods}; # reset since we're about to add methods |
198 | } |
3d203c73 |
199 | foreach my $step ($me->role_application_steps) { |
200 | foreach my $role (@roles) { |
201 | $me->$step($to, $role); |
202 | } |
667f4e70 |
203 | } |
2ff0bab0 |
204 | if ($me ne __PACKAGE__ |
205 | and $me->can('apply_single_role_to_package') |
206 | != \&apply_single_role_to_package) { |
207 | # backcompat: allow subclasses to use apply_single_role_to_package |
208 | # to apply changes. set a local var so ours does nothing. |
209 | local our $SKIP_APPLY = 1; |
210 | foreach my $role (@roles) { |
211 | $me->apply_single_role_to_package($to, $role); |
212 | } |
ee81e663 |
213 | } |
671b5a88 |
214 | $APPLIED_TO{$to}{join('|',@roles)} = 1; |
215 | } |
216 | |
836aea1b |
217 | sub _composite_info_for { |
671b5a88 |
218 | my ($me, @roles) = @_; |
836aea1b |
219 | $COMPOSITE_INFO{join('|', sort @roles)} ||= do { |
667f4e70 |
220 | foreach my $role (@roles) { |
221 | _load_module($role); |
222 | } |
671b5a88 |
223 | my %methods; |
224 | foreach my $role (@roles) { |
225 | my $this_methods = $me->_concrete_methods_of($role); |
226 | $methods{$_}{$this_methods->{$_}} = $role for keys %$this_methods; |
227 | } |
228 | delete $methods{$_} for grep keys(%{$methods{$_}}) == 1, keys %methods; |
229 | +{ conflicts => \%methods } |
230 | }; |
60dfe768 |
231 | } |
232 | |
1947330a |
233 | sub _composable_package_for { |
234 | my ($me, $role) = @_; |
235 | my $composed_name = 'Role::Tiny::_COMPOSABLE::'.$role; |
236 | return $composed_name if $COMPOSED{role}{$composed_name}; |
237 | $me->_install_methods($composed_name, $role); |
238 | my $base_name = $composed_name.'::_BASE'; |
c49b0f72 |
239 | # Not using _getglob, since setting @ISA via the typeglob breaks |
240 | # inheritance on 5.10.0 if the stash has previously been accessed an |
241 | # then a method called on the class (in that order!), which |
242 | # ->_install_methods (with the help of ->_install_does) ends up doing. |
243 | { no strict 'refs'; @{"${composed_name}::ISA"} = ( $base_name ); } |
1947330a |
244 | my $modifiers = $INFO{$role}{modifiers}||[]; |
b1eebd55 |
245 | my @mod_base; |
1947330a |
246 | foreach my $modified ( |
247 | do { my %h; @h{map $_->[1], @$modifiers} = (); keys %h } |
248 | ) { |
b1eebd55 |
249 | push @mod_base, "sub ${modified} { shift->next::method(\@_) }"; |
1947330a |
250 | } |
385f5087 |
251 | my $e; |
59812c87 |
252 | { |
253 | local $@; |
254 | eval(my $code = join "\n", "package ${base_name};", @mod_base); |
385f5087 |
255 | $e = "Evaling failed: $@\nTrying to eval:\n${code}" if $@; |
59812c87 |
256 | } |
385f5087 |
257 | die $e if $e; |
3d203c73 |
258 | $me->_install_modifiers($composed_name, $role); |
1947330a |
259 | $COMPOSED{role}{$composed_name} = 1; |
260 | return $composed_name; |
261 | } |
262 | |
263 | sub _check_requires { |
3d203c73 |
264 | my ($me, $to, $name) = @_; |
265 | return unless my @requires = @{$INFO{$name}{requires}||[]}; |
1947330a |
266 | if (my @requires_fail = grep !$to->can($_), @requires) { |
267 | # role -> role, add to requires, role -> class, error out |
268 | if (my $to_info = $INFO{$to}) { |
269 | push @{$to_info->{requires}||=[]}, @requires_fail; |
270 | } else { |
271 | die "Can't apply ${name} to ${to} - missing ".join(', ', @requires_fail); |
272 | } |
273 | } |
274 | } |
275 | |
4db3a740 |
276 | sub _concrete_methods_of { |
277 | my ($me, $role) = @_; |
1947330a |
278 | my $info = $INFO{$role}; |
60dfe768 |
279 | # grab role symbol table |
76acfa6c |
280 | my $stash = _getstash($role); |
12f8eb0b |
281 | # reverse so our keys become the values (captured coderefs) in case |
282 | # they got copied or re-used since |
123a5a6e |
283 | my $not_methods = { reverse %{$info->{not_methods}||{}} }; |
eb8fcb2d |
284 | $info->{methods} ||= +{ |
60dfe768 |
285 | # grab all code entries that aren't in the not_methods list |
286 | map { |
287 | my $code = *{$stash->{$_}}{CODE}; |
f1ce2b19 |
288 | ( ! $code or exists $not_methods->{$code} ) ? () : ($_ => $code) |
60dfe768 |
289 | } grep !ref($stash->{$_}), keys %$stash |
ab3370e7 |
290 | }; |
4db3a740 |
291 | } |
292 | |
293 | sub methods_provided_by { |
294 | my ($me, $role) = @_; |
295 | die "${role} is not a Role::Tiny" unless my $info = $INFO{$role}; |
296 | (keys %{$me->_concrete_methods_of($role)}, @{$info->{requires}||[]}); |
297 | } |
298 | |
299 | sub _install_methods { |
300 | my ($me, $to, $role) = @_; |
301 | |
302 | my $info = $INFO{$role}; |
303 | |
304 | my $methods = $me->_concrete_methods_of($role); |
1947330a |
305 | |
ab3370e7 |
306 | # grab target symbol table |
76acfa6c |
307 | my $stash = _getstash($to); |
1947330a |
308 | |
ab3370e7 |
309 | # determine already extant methods of target |
310 | my %has_methods; |
311 | @has_methods{grep |
faa9ce11 |
312 | +(ref($stash->{$_}) || *{$stash->{$_}}{CODE}), |
ab3370e7 |
313 | keys %$stash |
314 | } = (); |
ab3370e7 |
315 | |
1947330a |
316 | foreach my $i (grep !exists $has_methods{$_}, keys %$methods) { |
ab3370e7 |
317 | no warnings 'once'; |
5a247406 |
318 | *{_getglob "${to}::${i}"} = $methods->{$i}; |
ab3370e7 |
319 | } |
fa89d582 |
320 | |
321 | $me->_install_does($to); |
1947330a |
322 | } |
ab3370e7 |
323 | |
1947330a |
324 | sub _install_modifiers { |
3d203c73 |
325 | my ($me, $to, $name) = @_; |
326 | return unless my $modifiers = $INFO{$name}{modifiers}; |
dccea57d |
327 | if (my $info = $INFO{$to}) { |
328 | push @{$info->{modifiers}}, @{$modifiers||[]}; |
329 | } else { |
330 | foreach my $modifier (@{$modifiers||[]}) { |
331 | $me->_install_single_modifier($to, @$modifier); |
332 | } |
96d3f07a |
333 | } |
ab3370e7 |
334 | } |
335 | |
3117a19e |
336 | my $vcheck_error; |
337 | |
dccea57d |
338 | sub _install_single_modifier { |
339 | my ($me, @args) = @_; |
3117a19e |
340 | defined($vcheck_error) or $vcheck_error = do { |
341 | local $@; |
342 | eval { Class::Method::Modifiers->VERSION(1.05); 1 } |
343 | ? 0 |
344 | : $@ |
345 | }; |
346 | $vcheck_error and die $vcheck_error; |
dccea57d |
347 | Class::Method::Modifiers::install_modifier(@args); |
348 | } |
349 | |
fa89d582 |
350 | my $FALLBACK = sub { 0 }; |
351 | sub _install_does { |
352 | my ($me, $to) = @_; |
353 | |
354 | # only add does() method to classes |
355 | return if $INFO{$to}; |
356 | |
357 | # add does() only if they don't have one |
358 | *{_getglob "${to}::does"} = \&does_role unless $to->can('does'); |
359 | |
211178ea |
360 | return if ($to->can('DOES') and $to->can('DOES') != (UNIVERSAL->can('DOES') || 0)); |
fa89d582 |
361 | |
362 | my $existing = $to->can('DOES') || $to->can('isa') || $FALLBACK; |
363 | my $new_sub = sub { |
364 | my ($proto, $role) = @_; |
365 | Role::Tiny::does_role($proto, $role) or $proto->$existing($role); |
366 | }; |
367 | no warnings 'redefine'; |
368 | *{_getglob "${to}::DOES"} = $new_sub; |
369 | } |
370 | |
ab3370e7 |
371 | sub does_role { |
390ac406 |
372 | my ($proto, $role) = @_; |
91037640 |
373 | if ($] >= 5.010) { |
374 | require mro; |
375 | } else { |
376 | require MRO::Compat; |
377 | } |
378 | foreach my $class (@{mro::get_linear_isa(ref($proto)||$proto)}) { |
379 | return 1 if exists $APPLIED_TO{$class}{$role}; |
380 | } |
381 | return 0; |
ab3370e7 |
382 | } |
383 | |
fe2e95b1 |
384 | sub is_role { |
385 | my ($me, $role) = @_; |
386 | return !!$INFO{$role}; |
387 | } |
388 | |
ab3370e7 |
389 | 1; |
5febcf4d |
390 | |
7ce64c71 |
391 | =encoding utf-8 |
392 | |
0b6e5fff |
393 | =head1 NAME |
394 | |
70061353 |
395 | Role::Tiny - Roles. Like a nouvelle cuisine portion size slice of Moose. |
5febcf4d |
396 | |
397 | =head1 SYNOPSIS |
398 | |
399 | package Some::Role; |
400 | |
401 | use Role::Tiny; |
402 | |
403 | sub foo { ... } |
404 | |
405 | sub bar { ... } |
406 | |
adcb6c3d |
407 | around baz => sub { ... } |
408 | |
5febcf4d |
409 | 1; |
410 | |
411 | else where |
412 | |
413 | package Some::Class; |
414 | |
a1164a0b |
415 | use Role::Tiny::With; |
5febcf4d |
416 | |
417 | # bar gets imported, but not foo |
a1164a0b |
418 | with 'Some::Role'; |
5febcf4d |
419 | |
420 | sub foo { ... } |
421 | |
adcb6c3d |
422 | # baz is wrapped in the around modifier by Class::Method::Modifiers |
423 | sub baz { ... } |
424 | |
5febcf4d |
425 | 1; |
426 | |
adcb6c3d |
427 | If you wanted attributes as well, look at L<Moo::Role>. |
428 | |
5febcf4d |
429 | =head1 DESCRIPTION |
430 | |
431 | C<Role::Tiny> is a minimalist role composition tool. |
432 | |
433 | =head1 ROLE COMPOSITION |
434 | |
435 | Role composition can be thought of as much more clever and meaningful multiple |
436 | inheritance. The basics of this implementation of roles is: |
437 | |
438 | =over 2 |
439 | |
440 | =item * |
441 | |
442 | If a method is already defined on a class, that method will not be composed in |
443 | from the role. |
444 | |
445 | =item * |
446 | |
447 | If a method that the role L</requires> to be implemented is not implemented, |
448 | role application will fail loudly. |
449 | |
0d39f9d3 |
450 | =back |
451 | |
5febcf4d |
452 | Unlike L<Class::C3>, where the B<last> class inherited from "wins," role |
836aea1b |
453 | composition is the other way around, where the class wins. If multiple roles |
454 | are applied in a single call (single with statement), then if any of their |
455 | provided methods clash, an exception is raised unless the class provides |
456 | a method since this conflict indicates a potential problem. |
5febcf4d |
457 | |
5febcf4d |
458 | =head1 IMPORTED SUBROUTINES |
459 | |
460 | =head2 requires |
461 | |
462 | requires qw(foo bar); |
463 | |
464 | Declares a list of methods that must be defined to compose role. |
465 | |
466 | =head2 with |
467 | |
468 | with 'Some::Role1'; |
836aea1b |
469 | |
470 | with 'Some::Role1', 'Some::Role2'; |
471 | |
472 | Composes another role into the current role (or class via L<Role::Tiny::With>). |
473 | |
474 | If you have conflicts and want to resolve them in favour of Some::Role1 you |
475 | can instead write: |
476 | |
477 | with 'Some::Role1'; |
5febcf4d |
478 | with 'Some::Role2'; |
479 | |
836aea1b |
480 | If you have conflicts and want to resolve different conflicts in favour of |
481 | different roles, please refactor your codebase. |
5febcf4d |
482 | |
483 | =head2 before |
484 | |
485 | before foo => sub { ... }; |
486 | |
487 | See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full |
488 | documentation. |
489 | |
adcb6c3d |
490 | Note that since you are not required to use method modifiers, |
491 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
492 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
493 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
494 | |
5febcf4d |
495 | =head2 around |
496 | |
497 | around foo => sub { ... }; |
498 | |
499 | See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full |
500 | documentation. |
501 | |
adcb6c3d |
502 | Note that since you are not required to use method modifiers, |
503 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
504 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
505 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
506 | |
5febcf4d |
507 | =head2 after |
508 | |
509 | after foo => sub { ... }; |
510 | |
511 | See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full |
512 | documentation. |
513 | |
adcb6c3d |
514 | Note that since you are not required to use method modifiers, |
515 | L<Class::Method::Modifiers> is lazily loaded and we do not declare it as |
516 | a dependency. If your L<Role::Tiny> role uses modifiers you must depend on |
517 | both L<Class::Method::Modifiers> and L<Role::Tiny>. |
518 | |
ec28e16b |
519 | =head1 SUBROUTINES |
520 | |
521 | =head2 does_role |
522 | |
523 | if (Role::Tiny::does_role($foo, 'Some::Role')) { |
524 | ... |
525 | } |
526 | |
527 | Returns true if class has been composed with role. |
528 | |
529 | This subroutine is also installed as ->does on any class a Role::Tiny is |
530 | composed into unless that class already has an ->does method, so |
531 | |
532 | if ($foo->does('Some::Role')) { |
533 | ... |
534 | } |
535 | |
fa89d582 |
536 | will work for classes but to test a role, one must use ::does_role directly. |
537 | |
538 | Additionally, Role::Tiny will override the standard Perl C<DOES> method |
539 | for your class. However, if C<any> class in your class' inheritance |
8159d057 |
540 | hierarchy provides C<DOES>, then Role::Tiny will not override it. |
ec28e16b |
541 | |
542 | =head1 METHODS |
543 | |
544 | =head2 apply_roles_to_package |
545 | |
546 | Role::Tiny->apply_roles_to_package( |
547 | 'Some::Package', 'Some::Role', 'Some::Other::Role' |
548 | ); |
549 | |
550 | Composes role with package. See also L<Role::Tiny::With>. |
551 | |
552 | =head2 apply_roles_to_object |
553 | |
554 | Role::Tiny->apply_roles_to_object($foo, qw(Some::Role1 Some::Role2)); |
555 | |
556 | Composes roles in order into object directly. Object is reblessed into the |
557 | resulting class. |
558 | |
559 | =head2 create_class_with_roles |
560 | |
561 | Role::Tiny->create_class_with_roles('Some::Base', qw(Some::Role1 Some::Role2)); |
562 | |
563 | Creates a new class based on base, with the roles composed into it in order. |
564 | New class is returned. |
565 | |
fe2e95b1 |
566 | =head2 is_role |
567 | |
568 | Role::Tiny->is_role('Some::Role1') |
569 | |
570 | Returns true if the given package is a role. |
571 | |
adcb6c3d |
572 | =head1 SEE ALSO |
573 | |
574 | L<Role::Tiny> is the attribute-less subset of L<Moo::Role>; L<Moo::Role> is |
575 | a meta-protocol-less subset of the king of role systems, L<Moose::Role>. |
576 | |
577 | If you don't want method modifiers and do want to be forcibly restricted |
578 | to a single role application per class, Ovid's L<Role::Basic> exists. But |
259ce3a0 |
579 | Stevan Little (the L<Moose> author) and I don't find the additional |
580 | restrictions to be amazingly helpful in most cases; L<Role::Basic>'s choices |
581 | are more a guide to what you should prefer doing, to our mind, rather than |
582 | something that needs to be enforced. |
adcb6c3d |
583 | |
c334a5c1 |
584 | =head1 AUTHOR |
585 | |
586 | mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk> |
587 | |
588 | =head1 CONTRIBUTORS |
589 | |
590 | dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx> |
591 | |
592 | frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com> |
593 | |
594 | hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org> |
595 | |
596 | jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com> |
597 | |
598 | ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org> |
599 | |
600 | chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com> |
601 | |
602 | ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org> |
603 | |
604 | doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net> |
605 | |
606 | perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org> |
607 | |
ec28e16b |
608 | Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com> |
609 | |
91037640 |
610 | ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org> |
611 | |
fa89d582 |
612 | tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org> |
613 | |
c334a5c1 |
614 | =head1 COPYRIGHT |
40f3e3aa |
615 | |
c334a5c1 |
616 | Copyright (c) 2010-2012 the Role::Tiny L</AUTHOR> and L</CONTRIBUTORS> |
617 | as listed above. |
40f3e3aa |
618 | |
c334a5c1 |
619 | =head1 LICENSE |
40f3e3aa |
620 | |
c334a5c1 |
621 | This library is free software and may be distributed under the same terms |
622 | as perl itself. |
40f3e3aa |
623 | |
624 | =cut |