lib/stemmaweb/Controller/Root.pm

   1 package stemmaweb::Controller::Root;
   2 use Moose;
   3 use namespace::autoclean;
   4 use Text::Tradition::Analysis qw/ run_analysis /;
   5 use TryCatch;
   6 use XML::LibXML;
   7 use XML::LibXML::XPathContext;
   8
   9
  10 BEGIN { extends 'Catalyst::Controller' }
  11
  12 #
  13 # Sets the actions in this controller to be registered with no prefix
  14 # so they function identically to actions created in MyApp.pm
  15 #
  16 __PACKAGE__->config(namespace => '');
  17
  18 =head1 NAME
  19
  20 stemmaweb::Controller::Root - Root Controller for stemmaweb
  21
  22 =head1 DESCRIPTION
  23
  24 Serves up the main container pages.
  25
  26 =head1 URLs
  27
  28 =head2 index
  29
  30 The root page (/).  Serves the main container page, from which the various
  31 components will be loaded.
  32
  33 =cut
  34
  35 sub index :Path :Args(0) {
  36     my ( $self, $c ) = @_;
  37
  38         # Are we being asked to load a text immediately? If so
  39         if( $c->req->param('withtradition') ) {
  40                 $c->stash->{'withtradition'} = $c->req->param('withtradition');
  41         }
  42     $c->stash->{template} = 'index.tt';
  43 }
  44
  45 =head2 about
  46
  47 A general overview/documentation page for the site.
  48
  49 =cut
  50
  51 sub about :Local :Args(0) {
  52         my( $self, $c ) = @_;
  53         $c->stash->{template} = 'about.tt';
  54 }
  55
  56 =head2 help/*
  57
  58 A dispatcher for documentation of various aspects of the application.
  59
  60 =cut
  61
  62 sub help :Local :Args(1) {
  63         my( $self, $c, $topic ) = @_;
  64         $c->stash->{template} = "$topic.tt";
  65 }
  66
  67 =head1 Elements of index page
  68
  69 =head2 directory
  70
  71  GET /directory
  72
  73 Serves a snippet of HTML that lists the available texts.  This returns texts belonging to the logged-in user if any, otherwise it returns all public texts.
  74
  75 =cut
  76
  77 sub directory :Local :Args(0) {
  78         my( $self, $c ) = @_;
  79     my $m = $c->model('Directory');
  80     # Is someone logged in?
  81     my %usertexts;
  82     if( $c->user_exists ) {
  83         my $user = $c->user->get_object;
  84         my @list = $m->traditionlist( $user );
  85         map { $usertexts{$_->{id}} = 1 } @list;
  86                 $c->stash->{usertexts} = \@list;
  87                 $c->stash->{is_admin} = 1 if $user->is_admin;
  88         }
  89         # List public (i.e. readonly) texts separately from any user (i.e.
  90         # full access) texts that exist. Admin users therefore have nothing
  91         # in this list.
  92         my @plist = grep { !$usertexts{$_->{id}} } $m->traditionlist('public');
  93         $c->stash->{publictexts} = \@plist;
  94         $c->stash->{template} = 'directory.tt';
  95 }
  96
  97 =head1 AJAX methods for traditions and their properties
  98
  99 =head2 newtradition
 100
 101  POST /newtradition,
 102         { name: <name>,
 103           language: <language>,
 104           public: <is_public>,
 105           file: <fileupload> }
 106
 107 Creates a new tradition belonging to the logged-in user, with the given name
 108 and the collation given in the uploaded file. The file type is indicated via
 109 the filename extension (.csv, .txt, .xls, .xlsx, .xml). Returns the ID and
 110 name of the new tradition.
 111
 112 =cut
 113
 114 sub newtradition :Local :Args(0) {
 115         my( $self, $c ) = @_;
 116         return _json_error( $c, 403, 'Cannot save a tradition without being logged in' )
 117                 unless $c->user_exists;
 118
 119         my $user = $c->user->get_object;
 120         # Grab the file upload, check its name/extension, and call the
 121         # appropriate parser(s).
 122         my $upload = $c->request->upload('file');
 123         my $name = $c->request->param('name') || 'Uploaded tradition';
 124         my $lang = $c->request->param( 'language' ) || 'Default';
 125         my $public = $c->request->param( 'public' ) ? 1 : undef;
 126         my( $ext ) = $upload->filename =~ /\.(\w+)$/;
 127         my %newopts = (
 128                 'name' => $name,
 129                 'language' => $lang,
 130                 'public' => $public,
 131                 'file' => $upload->tempname
 132                 );
 133
 134         my $tradition;
 135         my $errmsg;
 136         if( $ext eq 'xml' ) {
 137                 my $type;
 138                 # Parse the XML to see which flavor it is.
 139                 my $parser = XML::LibXML->new();
 140                 my $doc;
 141                 try {
 142                         $doc = $parser->parse_file( $newopts{'file'} );
 143                 } catch( $err ) {
 144                         $errmsg = "XML file parsing error: $err";
 145                 }
 146                 if( $doc ) {
 147                         if( $doc->documentElement->nodeName eq 'GraphML' ) {
 148                                 $type = 'CollateX';
 149                         } elsif( $doc->documentElement->nodeName ne 'TEI' ) {
 150                                 $errmsg = 'Unrecognized XML type ' . $doc->documentElement->nodeName;
 151                         } else {
 152                                 my $xpc = XML::LibXML::XPathContext->new( $doc->documentElement );
 153                                 my $venc = $xpc->findvalue( '/TEI/teiHeader/encodingDesc/variantEncoding/attribute::method' );
 154                                 if( $venc && $venc eq 'double-end-point' ) {
 155                                         $type = 'CTE';
 156                                 } else {
 157                                         $type = 'TEI';
 158                                 }
 159                         }
 160                 }
 161                 # Try the relevant XML parsing option.
 162                 if( $type ) {
 163                         delete $newopts{'file'};
 164                         $newopts{'xmlobj'} = $doc;
 165                         try {
 166                                 $tradition = Text::Tradition->new( %newopts, 'input' => $type );
 167                         } catch ( Text::Tradition::Error $e ) {
 168                                 $errmsg = $e->message;
 169                         } catch ( $e ) {
 170                                 $errmsg = "Unexpected parsing error: $e";
 171                         }
 172                 }
 173         } elsif( $ext =~ /^(txt|csv|xls(x)?)$/ ) {
 174                 # If it's Excel we need to pass excel => $ext;
 175                 # otherwise we need to pass sep_char => [record separator].
 176                 if( $ext =~ /xls/ ) {
 177                         $newopts{'excel'} = $ext;
 178                 } else {
 179                         $newopts{'sep_char'} = $ext eq 'txt' ? "\t" : ',';
 180                 }
 181                 try {
 182                         $tradition = Text::Tradition->new(
 183                                 %newopts,
 184                                 'input' => 'Tabular',
 185                                 );
 186                 } catch ( Text::Tradition::Error $e ) {
 187                         $errmsg = $e->message;
 188                 } catch ( $e ) {
 189                         $errmsg = "Unexpected parsing error: $e";
 190                 }
 191         } else {
 192                 # Error unless we have a recognized filename extension
 193                 return _json_error( $c, 403, "Unrecognized file type extension $ext" );
 194         }
 195
 196         # Save the tradition if we have it, and return its data or else the
 197         # error that occurred trying to make it.
 198         if( $errmsg ) {
 199                 return _json_error( $c, 500, "Error parsing tradition .$ext file: $errmsg" );
 200         } elsif( !$tradition ) {
 201                 return _json_error( $c, 500, "No error caught but tradition not created" );
 202         }
 203
 204         my $m = $c->model('Directory');
 205         $user->add_tradition( $tradition );
 206         my $id = $c->model('Directory')->store( $tradition );
 207         $c->model('Directory')->store( $user );
 208         $c->stash->{'result'} = { 'id' => $id, 'name' => $tradition->name };
 209         $c->forward('View::JSON');
 210 }
 211
 212 =head2 textinfo
 213
 214  GET /textinfo/$textid
 215  POST /textinfo/$textid,
 216         { name: $new_name,
 217           language: $new_language,
 218           public: $is_public,
 219           owner: $new_userid } # only admin users can update the owner
 220
 221 Returns information about a particular text.
 222
 223 =cut
 224
 225 sub textinfo :Local :Args(1) {
 226         my( $self, $c, $textid ) = @_;
 227         my $tradition = $c->model('Directory')->tradition( $textid );
 228         ## Have to keep users in the same scope as tradition
 229         my $newuser;
 230         my $olduser;
 231         unless( $tradition ) {
 232                 return _json_error( $c, 404, "No tradition with ID $textid" );
 233         }
 234         my $ok = _check_permission( $c, $tradition );
 235         return unless $ok;
 236         if( $c->req->method eq 'POST' ) {
 237                 return _json_error( $c, 403,
 238                         'You do not have permission to update this tradition' )
 239                         unless $ok eq 'full';
 240                 my $params = $c->request->parameters;
 241                 # Handle changes to owner-accessible parameters
 242                 my $m = $c->model('Directory');
 243                 my $changed;
 244                 # Handle name param - easy
 245                 if( exists $params->{name} ) {
 246                         my $newname = delete $params->{name};
 247                         unless( $tradition->name eq $newname ) {
 248                                 try {
 249                                         $tradition->name( $newname );
 250                                         $changed = 1;
 251                                 } catch {
 252                                         return _json_error( $c, 500, "Error setting name to $newname" );
 253                                 }
 254                         }
 255                 }
 256                 # Handle language param, making Default => null
 257                 my $langval = delete $params->{language} || 'Default';
 258
 259                 unless( $tradition->language eq $langval || !$tradition->can('language') ) {
 260                         try {
 261                                 $tradition->language( $langval );
 262                                 $changed = 1;
 263                         } catch {
 264                                 return _json_error( $c, 500, "Error setting language to $langval" );
 265                         }
 266                 }
 267
 268                 # Handle our boolean
 269                 my $ispublic = $tradition->public;
 270                 if( delete $params->{'public'} ) {  # if it's any true value...
 271                         $tradition->public( 1 );
 272                         $changed = 1 unless $ispublic;
 273                 } else {  # the checkbox was unchecked, ergo it should not be public
 274                         $tradition->public( 0 );
 275                         $changed = 1 if $ispublic;
 276                 }
 277
 278                 # Handle ownership change
 279                 if( exists $params->{'owner'} ) {
 280                         # Only admins can update user / owner
 281                         my $newownerid = delete $params->{'owner'};
 282                         unless( !$newownerid ||
 283                                 ( $tradition->has_user && $tradition->user->email eq $newownerid ) ) {
 284                                 unless( $c->user->get_object->is_admin ) {
 285                                         return _json_error( $c, 403,
 286                                                 "Only admin users can change tradition ownership" );
 287                                 }
 288                                 $newuser = $m->find_user({ email => $newownerid });
 289                                 unless( $newuser ) {
 290                                         return _json_error( $c, 500, "No such user " . $newownerid );
 291                                 }
 292                                 if( $tradition->has_user ) {
 293                                         $olduser = $tradition->user;
 294                                         $olduser->remove_tradition( $tradition );
 295                                 }
 296                                 $newuser->add_tradition( $tradition );
 297                                 $changed = 1;
 298                         }
 299                 }
 300                 # TODO check for rogue parameters
 301                 if( scalar keys %$params ) {
 302                         my $rogueparams = join( ', ', keys %$params );
 303                         return _json_error( $c, 403, "Request parameters $rogueparams not recognized" );
 304                 }
 305                 # If we safely got to the end, then write to the database.
 306                 $m->save( $tradition ) if $changed;
 307                 $m->save( $newuser ) if $newuser;
 308         }
 309
 310         # Now return the current textinfo, whether GET or successful POST.
 311         my $textinfo = {
 312                 textid => $textid,
 313                 name => $tradition->name,
 314                 #language => $tradition->language,
 315                 public => $tradition->public || 0,
 316                 owner => $tradition->user ? $tradition->user->email : undef,
 317                 witnesses => [ map { $_->sigil } $tradition->witnesses ],
 318         };
 319         if( $tradition->can('language') ) {
 320                 $textinfo->{'language'} = $tradition->language;
 321         }
 322         my @stemmasvg = map { $_->as_svg() } $tradition->stemmata;
 323         map { $_ =~ s/\n/ /mg } @stemmasvg;
 324         $textinfo->{stemmata} = \@stemmasvg;
 325         $c->stash->{'result'} = $textinfo;
 326         $c->forward('View::JSON');
 327 }
 328
 329 =head2 variantgraph
 330
 331  GET /variantgraph/$textid
 332
 333 Returns the variant graph for the text specified at $textid, in SVG form.
 334
 335 =cut
 336
 337 sub variantgraph :Local :Args(1) {
 338         my( $self, $c, $textid ) = @_;
 339         my $tradition = $c->model('Directory')->tradition( $textid );
 340         unless( $tradition ) {
 341                 return _json_error( $c, 404, "No tradition with ID $textid" );
 342         }
 343         my $ok = _check_permission( $c, $tradition );
 344         return unless $ok;
 345
 346         my $collation = $tradition->collation;
 347         $c->stash->{'result'} = $collation->as_svg;
 348         $c->forward('View::SVG');
 349 }
 350
 351 =head2 stemma
 352
 353  GET /stemma/$textid/$stemmaseq
 354  POST /stemma/$textid/$stemmaseq, { 'dot' => $dot_string }
 355
 356 Returns an SVG representation of the given stemma hypothesis for the text.
 357 If the URL is called with POST, the stemma at $stemmaseq will be altered
 358 to reflect the definition in $dot_string. If $stemmaseq is 'n', a new
 359 stemma will be added.
 360
 361 =cut
 362
 363 sub stemma :Local :Args(2) {
 364         my( $self, $c, $textid, $stemmaid ) = @_;
 365         my $m = $c->model('Directory');
 366         my $tradition = $m->tradition( $textid );
 367         unless( $tradition ) {
 368                 return _json_error( $c, 404, "No tradition with ID $textid" );
 369         }
 370         my $ok = _check_permission( $c, $tradition );
 371         return unless $ok;
 372
 373         $c->stash->{'result'} = '';
 374         my $stemma;
 375         if( $c->req->method eq 'POST' ) {
 376                 if( $ok eq 'full' ) {
 377                         my $dot = $c->request->body_params->{'dot'};
 378                         # Graph::Reader::Dot does not handle bare unicode. We get around this
 379                         # by wrapping all words in double quotes, as long as they aren't already
 380                         # wrapped, and as long as they aren't the initial 'digraph stemma'.
 381                         # Horrible HACK.
 382                         $dot =~ s/(?<!")\b(?!(?:digraph|stemma)\b)(\w+)\b(?!")/"$1"/g;
 383                         try {
 384                                 if( $stemmaid eq 'n' ) {
 385                                         # We are adding a new stemma.
 386                                         $stemmaid = $tradition->stemma_count;
 387                                         $stemma = $tradition->add_stemma( 'dot' => $dot );
 388                                 } elsif( $stemmaid !~ /^\d+$/ ) {
 389                                         return _json_error( $c, 403, "Invalid stemma ID specification $stemmaid" );
 390                                 } elsif( $stemmaid < $tradition->stemma_count ) {
 391                                         # We are updating an existing stemma.
 392                                         $stemma = $tradition->stemma( $stemmaid );
 393                                         $stemma->alter_graph( $dot );
 394                                 } else {
 395                                         # Unrecognized stemma ID
 396                                         return _json_error( $c, 404, "No stemma at index $stemmaid, cannot update" );
 397                                 }
 398                         } catch ( Text::Tradition::Error $e ) {
 399                                 return _json_error( $c, 500, $e->message );
 400                         }
 401                         $m->store( $tradition );
 402                 } else {
 403                         # No permissions to update the stemma
 404                         return _json_error( $c, 403,
 405                                 'You do not have permission to update stemmata for this tradition' );
 406                 }
 407         }
 408
 409         # For a GET or a successful POST request, return the SVG representation
 410         # of the stemma in question, if any.
 411         if( !$stemma && $tradition->stemma_count > $stemmaid ) {
 412                 $stemma = $tradition->stemma( $stemmaid );
 413         }
 414         my $stemma_xml = $stemma ? $stemma->as_svg() : '';
 415         # What was requested, XML or JSON?
 416         my $return_view = 'SVG';
 417         if( my $accept_header = $c->req->header('Accept') ) {
 418                 $c->log->debug( "Received Accept header: $accept_header" );
 419                 foreach my $type ( split( /,\s*/, $accept_header ) ) {
 420                         # If we were first asked for XML, return SVG
 421                         last if $type =~ /^(application|text)\/xml$/;
 422                         # If we were first asked for JSON, return JSON
 423                         if( $type eq 'application/json' ) {
 424                                 $return_view = 'JSON';
 425                                 last;
 426                         }
 427                 }
 428         }
 429         if( $return_view eq 'SVG' ) {
 430                 $c->stash->{'result'} = $stemma_xml;
 431                 $c->forward('View::SVG');
 432         } else { # JSON
 433                 $stemma_xml =~ s/\n/ /mg;
 434                 $c->stash->{'result'} = { 'stemmaid' => $stemmaid, 'stemmasvg' => $stemma_xml };
 435                 $c->forward('View::JSON');
 436         }
 437 }
 438
 439 =head2 stemmadot
 440
 441  GET /stemmadot/$textid/$stemmaseq
 442
 443 Returns the 'dot' format representation of the current stemma hypothesis.
 444
 445 =cut
 446
 447 sub stemmadot :Local :Args(2) {
 448         my( $self, $c, $textid, $stemmaid ) = @_;
 449         my $m = $c->model('Directory');
 450         my $tradition = $m->tradition( $textid );
 451         unless( $tradition ) {
 452                 return _json_error( $c, 404, "No tradition with ID $textid" );
 453         }
 454         my $ok = _check_permission( $c, $tradition );
 455         return unless $ok;
 456         my $stemma = $tradition->stemma( $stemmaid );
 457         unless( $stemma ) {
 458                 return _json_error( $c, 404, "Tradition $textid has no stemma ID $stemmaid" );
 459         }
 460         # Get the dot and transmute its line breaks to literal '|n'
 461         $c->stash->{'result'} = { 'dot' =>  $stemma->editable( { linesep => '|n' } ) };
 462         $c->forward('View::JSON');
 463 }
 464
 465 =head2 download
 466
 467  GET /download/$textid
 468
 469 Returns the full XML definition of the tradition and its stemmata, if any.
 470
 471 =cut
 472
 473 sub download :Local :Args(1) {
 474         my( $self, $c, $textid ) = @_;
 475         my $tradition = $c->model('Directory')->tradition( $textid );
 476         unless( $tradition ) {
 477                 return _json_error( $c, 404, "No tradition with ID $textid" );
 478         }
 479         my $ok = _check_permission( $c, $tradition );
 480         return unless $ok;
 481         try {
 482                 $c->stash->{'result'} = $tradition->collation->as_graphml();
 483         } catch( Text::Tradition::Error $e ) {
 484                 return _json_error( $c, 500, $e->message );
 485         }
 486         $c->forward('View::GraphML');
 487 }
 488
 489 ####################
 490 ### Helper functions
 491 ####################
 492
 493 # Helper to check what permission, if any, the active user has for
 494 # the given tradition
 495 sub _check_permission {
 496         my( $c, $tradition ) = @_;
 497     my $user = $c->user_exists ? $c->user->get_object : undef;
 498     if( $user ) {
 499         return 'full' if ( $user->is_admin ||
 500                 ( $tradition->has_user && $tradition->user->id eq $user->id ) );
 501     }
 502         # Text doesn't belong to us, so maybe it's public?
 503         return 'readonly' if $tradition->public;
 504
 505         # ...nope. Forbidden!
 506         return _json_error( $c, 403, 'You do not have permission to view this tradition.' );
 507 }
 508
 509 # Helper to throw a JSON exception
 510 sub _json_error {
 511         my( $c, $code, $errmsg ) = @_;
 512         $c->response->status( $code );
 513         $c->stash->{'result'} = { 'error' => $errmsg };
 514         $c->forward('View::JSON');
 515         return 0;
 516 }
 517
 518 =head2 default
 519
 520 Standard 404 error page
 521
 522 =cut
 523
 524 sub default :Path {
 525     my ( $self, $c ) = @_;
 526     $c->response->body( 'Page not found' );
 527     $c->response->status(404);
 528 }
 529
 530 =head2 end
 531
 532 Attempt to render a view, if needed.
 533
 534 =cut
 535
 536 sub end : ActionClass('RenderView') {}
 537
 538 =head1 AUTHOR
 539
 540 Tara L Andrews
 541
 542 =head1 LICENSE
 543
 544 This library is free software. You can redistribute it and/or modify
 545 it under the same terms as Perl itself.
 546
 547 =cut
 548
 549 __PACKAGE__->meta->make_immutable;
 550
 551 1;