lib/stemmaweb/Controller/Root.pm

   1 package stemmaweb::Controller::Root;
   2 use Moose;
   3 use namespace::autoclean;
   4 use Text::Tradition::Analysis qw/ run_analysis /;
   5 use TryCatch;
   6
   7
   8 BEGIN { extends 'Catalyst::Controller' }
   9
  10 #
  11 # Sets the actions in this controller to be registered with no prefix
  12 # so they function identically to actions created in MyApp.pm
  13 #
  14 __PACKAGE__->config(namespace => '');
  15
  16 =head1 NAME
  17
  18 stemmaweb::Controller::Root - Root Controller for stemmaweb
  19
  20 =head1 DESCRIPTION
  21
  22 Serves up the main container pages.
  23
  24 =head1 URLs
  25
  26 =head2 index
  27
  28 The root page (/).  Serves the main container page, from which the various
  29 components will be loaded.
  30
  31 =cut
  32
  33 sub index :Path :Args(0) {
  34     my ( $self, $c ) = @_;
  35
  36     $c->stash->{template} = 'index.tt';
  37 }
  38
  39 =head1 Elements of index page
  40
  41 =head2 directory
  42
  43  GET /directory
  44
  45 Serves a snippet of HTML that lists the available texts.  This returns texts belonging to the logged-in user if any, otherwise it returns all public texts.
  46
  47 =cut
  48
  49 sub directory :Local :Args(0) {
  50         my( $self, $c ) = @_;
  51     my $m = $c->model('Directory');
  52     # Is someone logged in?
  53     my %usertexts;
  54     if( $c->user_exists ) {
  55         my $user = $c->user->get_object;
  56         my @list = $m->traditionlist( $user );
  57         map { $usertexts{$_->{id}} = 1 } @list;
  58                 $c->stash->{usertexts} = \@list;
  59                 $c->stash->{is_admin} = 1 if $user->is_admin;
  60         }
  61         # List public (i.e. readonly) texts separately from any user (i.e.
  62         # full access) texts that exist. Admin users therefore have nothing
  63         # in this list.
  64         my @plist = grep { !$usertexts{$_->{id}} } $m->traditionlist('public');
  65         $c->stash->{publictexts} = \@plist;
  66         $c->stash->{template} = 'directory.tt';
  67 }
  68
  69 =head1 AJAX methods for traditions and their properties
  70
  71 =head2 newtradition
  72
  73  POST /newtradition,
  74         { name: <name>,
  75           language: <language>,
  76           public: <is_public>,
  77           file: <fileupload> }
  78
  79 Creates a new tradition belonging to the logged-in user, with the given name
  80 and the collation given in the uploaded file. The file type is indicated via
  81 the filename extension (.csv, .txt, .xls, .xlsx, .xml). Returns the ID and
  82 name of the new tradition.
  83
  84 =cut
  85
  86 sub newtradition :Local :Args(0) {
  87         my( $self, $c ) = @_;
  88         return _json_error( $c, 403, 'Cannot save a tradition without being logged in' )
  89                 unless $c->user_exists;
  90
  91         my $user = $c->user->get_object;
  92         # Grab the file upload, check its name/extension, and call the
  93         # appropriate parser(s).
  94         my $upload = $c->request->upload('file');
  95         my $name = $c->request->param('name') || 'Uploaded tradition';
  96         my $lang = $c->request->param( 'language' ) || 'Default';
  97         my $public = $c->request->param( 'public' ) ? 1 : undef;
  98         my( $ext ) = $upload->filename =~ /\.(\w+)$/;
  99         my %newopts = (
 100                 'name' => $name,
 101                 'language' => $lang,
 102                 'public' => $public,
 103                 'file' => $upload->tempname
 104                 );
 105
 106         my $tradition;
 107         my $errmsg;
 108         if( $ext eq 'xml' ) {
 109                 # Try the different XML parsing options to see if one works.
 110                 foreach my $type ( qw/ CollateX CTE TEI / ) {
 111                         try {
 112                                 $tradition = Text::Tradition->new( %newopts, 'input' => $type );
 113                         } catch ( Text::Tradition::Error $e ) {
 114                                 $errmsg = $e->message;
 115                         } catch {
 116                                 $errmsg = "Unexpected parsing error";
 117                         }
 118                         last if $tradition;
 119                 }
 120         } elsif( $ext =~ /^(txt|csv|xls(x)?)$/ ) {
 121                 # If it's Excel we need to pass excel => $ext;
 122                 # otherwise we need to pass sep_char => [record separator].
 123                 if( $ext =~ /xls/ ) {
 124                         $newopts{'excel'} = $ext;
 125                 } else {
 126                         $newopts{'sep_char'} = $ext eq 'txt' ? "\t" : ',';
 127                 }
 128                 try {
 129                         $tradition = Text::Tradition->new(
 130                                 %newopts,
 131                                 'input' => 'Tabular',
 132                                 );
 133                 } catch ( Text::Tradition::Error $e ) {
 134                         $errmsg = $e->message;
 135                 } catch {
 136                         $errmsg = "Unexpected parsing error";
 137                 }
 138         } else {
 139                 # Error unless we have a recognized filename extension
 140                 return _json_error( $c, 500, "Unrecognized file type extension $ext" );
 141         }
 142
 143         # Save the tradition if we have it, and return its data or else the
 144         # error that occurred trying to make it.
 145         if( $errmsg ) {
 146                 return _json_error( $c, 500, "Error parsing tradition .$ext file: $errmsg" );
 147         } elsif( !$tradition ) {
 148                 return _json_error( $c, 500, "No error caught but tradition not created" );
 149         }
 150
 151         my $m = $c->model('Directory');
 152         $user->add_tradition( $tradition );
 153         my $id = $c->model('Directory')->store( $tradition );
 154         $c->model('Directory')->store( $user );
 155         $c->stash->{'result'} = { 'id' => $id, 'name' => $tradition->name };
 156         $c->forward('View::JSON');
 157 }
 158
 159 =head2 textinfo
 160
 161  GET /textinfo/$textid
 162  POST /textinfo/$textid,
 163         { name: $new_name,
 164           language: $new_language,
 165           public: $is_public,
 166           owner: $new_userid } # only admin users can update the owner
 167
 168 Returns information about a particular text.
 169
 170 =cut
 171
 172 sub textinfo :Local :Args(1) {
 173         my( $self, $c, $textid ) = @_;
 174         my $tradition = $c->model('Directory')->tradition( $textid );
 175         unless( $tradition ) {
 176                 return _json_error( $c, 500, "No tradition with ID $textid" );
 177         }
 178         my $ok = _check_permission( $c, $tradition );
 179         return unless $ok;
 180         if( $c->req->method eq 'POST' ) {
 181                 return _json_error( $c, 403,
 182                         'You do not have permission to update this tradition' )
 183                         unless $ok eq 'full';
 184                 my $params = $c->request->parameters;
 185                 # Handle changes to owner-accessible parameters
 186                 my $m = $c->model('Directory');
 187                 my $changed;
 188                 # Handle name param - easy
 189                 if( exists $params->{name} ) {
 190                         my $newname = delete $params->{name};
 191                         unless( $tradition->name eq $newname ) {
 192                                 try {
 193                                         $tradition->name( $newname );
 194                                         $changed = 1;
 195                                 } catch {
 196                                         return _json_error( $c, 500, "Error setting name to $newname" );
 197                                 }
 198                         }
 199                 }
 200                 # Handle language param, making Default => null
 201                 my $langval = delete $params->{language} || 'Default';
 202                 unless( $tradition->language eq $langval ) {
 203                         try {
 204                                 $tradition->language( $langval );
 205                                 $changed = 1;
 206                         } catch {
 207                                 return _json_error( $c, 500, "Error setting language to $langval" );
 208                         }
 209                 }
 210
 211                 # Handle our boolean
 212                 my $ispublic = $tradition->public;
 213                 if( delete $params->{'public'} ) {  # if it's any true value...
 214                         $tradition->public( 1 );
 215                         $changed = 1 unless $ispublic;
 216                 } else {  # the checkbox was unchecked, ergo it should not be public
 217                         $tradition->public( 0 );
 218                         $changed = 1 if $ispublic;
 219                 }
 220
 221                 # Handle ownership change
 222                 my $newuser;
 223                 if( exists $params->{'owner'} ) {
 224                         # Only admins can update user / owner
 225                         my $newownerid = delete $params->{'owner'};
 226                         unless( $tradition->has_user && $tradition->user->id eq $newownerid ) {
 227                                 unless( $c->user->get_object->is_admin ) {
 228                                         return _json_error( $c, 403,
 229                                                 "Only admin users can change tradition ownership" );
 230                                 }
 231                                 $newuser = $m->find_user({ username => $newownerid });
 232                                 unless( $newuser ) {
 233                                         return _json_error( $c, 500, "No such user " . $newownerid );
 234                                 }
 235                                 $newuser->add_tradition( $tradition );
 236                                 $changed = 1;
 237                         }
 238                 }
 239                 # TODO check for rogue parameters
 240                 if( scalar keys %$params ) {
 241                         my $rogueparams = join( ', ', keys %$params );
 242                         return _json_error( $c, 403, "Request parameters $rogueparams not recognized" );
 243                 }
 244                 # If we safely got to the end, then write to the database.
 245                 $m->save( $tradition ) if $changed;
 246                 $m->save( $newuser ) if $newuser;
 247         }
 248
 249         # Now return the current textinfo, whether GET or successful POST.
 250         my $textinfo = {
 251                 textid => $textid,
 252                 name => $tradition->name,
 253                 language => $tradition->language,
 254                 public => $tradition->public,
 255                 owner => $tradition->user ? $tradition->user->id : undef,
 256                 witnesses => [ map { $_->sigil } $tradition->witnesses ],
 257         };
 258         my @stemmasvg = map { $_->as_svg({ size => [ 500, 375 ] }) } $tradition->stemmata;
 259         map { $_ =~ s/\n/ /mg } @stemmasvg;
 260         $textinfo->{stemmata} = \@stemmasvg;
 261         $c->stash->{'result'} = $textinfo;
 262         $c->forward('View::JSON');
 263 }
 264
 265 =head2 variantgraph
 266
 267  GET /variantgraph/$textid
 268
 269 Returns the variant graph for the text specified at $textid, in SVG form.
 270
 271 =cut
 272
 273 sub variantgraph :Local :Args(1) {
 274         my( $self, $c, $textid ) = @_;
 275         my $tradition = $c->model('Directory')->tradition( $textid );
 276         unless( $tradition ) {
 277                 return _json_error( $c, 500, "No tradition with ID $textid" );
 278         }
 279         my $ok = _check_permission( $c, $tradition );
 280         return unless $ok;
 281
 282         my $collation = $tradition->collation;
 283         $c->stash->{'result'} = $collation->as_svg;
 284         $c->forward('View::SVG');
 285 }
 286
 287 =head2 stemma
 288
 289  GET /stemma/$textid/$stemmaseq
 290  POST /stemma/$textid/$stemmaseq, { 'dot' => $dot_string }
 291
 292 Returns an SVG representation of the given stemma hypothesis for the text.
 293 If the URL is called with POST, the stemma at $stemmaseq will be altered
 294 to reflect the definition in $dot_string. If $stemmaseq is 'n', a new
 295 stemma will be added.
 296
 297 =cut
 298
 299 sub stemma :Local :Args(2) {
 300         my( $self, $c, $textid, $stemmaid ) = @_;
 301         my $m = $c->model('Directory');
 302         my $tradition = $m->tradition( $textid );
 303         unless( $tradition ) {
 304                 return _json_error( $c, 500, "No tradition with ID $textid" );
 305         }
 306         my $ok = _check_permission( $c, $tradition );
 307         return unless $ok;
 308
 309         $c->stash->{'result'} = '';
 310         my $stemma;
 311         if( $c->req->method eq 'POST' ) {
 312                 if( $ok eq 'full' ) {
 313                         my $dot = $c->request->body_params->{'dot'};
 314                         try {
 315                                 if( $stemmaid eq 'n' ) {
 316                                         # We are adding a new stemma.
 317                                         $stemma = $tradition->add_stemma( 'dot' => $dot );
 318                                         $stemmaid = $tradition->stemma_count - 1;
 319                                 } elsif( $stemmaid < $tradition->stemma_count ) {
 320                                         # We are updating an existing stemma.
 321                                         $stemma = $tradition->stemma( $stemmaid );
 322                                         $stemma->alter_graph( $dot );
 323                                 } else {
 324                                         # Unrecognized stemma ID
 325                                         return _json_error( $c, 500, "No stemma at index $stemmaid, cannot update" );
 326                                 }
 327                         } catch ( Text::Tradition::Error $e ) {
 328                                 return _json_error( $c, 500, $e->message );
 329                         }
 330                         $m->store( $tradition );
 331                 } else {
 332                         # No permissions to update the stemma
 333                         return _json_error( $c, 403,
 334                                 'You do not have permission to update stemmata for this tradition' );
 335                 }
 336         }
 337
 338         # For a GET or a successful POST request, return the SVG representation
 339         # of the stemma in question, if any.
 340         if( !$stemma && $tradition->stemma_count > $stemmaid ) {
 341                 $stemma = $tradition->stemma( $stemmaid );
 342         }
 343         my $stemma_xml = $stemma ? $stemma->as_svg( { size => [ 500, 375 ] } ) : '';
 344         # What was requested, XML or JSON?
 345         my $return_view = 'SVG';
 346         if( my $accept_header = $c->req->header('Accept') ) {
 347                 $c->log->debug( "Received Accept header: $accept_header" );
 348                 foreach my $type ( split( /,\s*/, $accept_header ) ) {
 349                         # If we were first asked for XML, return SVG
 350                         last if $type =~ /^(application|text)\/xml$/;
 351                         # If we were first asked for JSON, return JSON
 352                         if( $type eq 'application/json' ) {
 353                                 $return_view = 'JSON';
 354                                 last;
 355                         }
 356                 }
 357         }
 358         if( $return_view eq 'SVG' ) {
 359                 $c->stash->{'result'} = $stemma_xml;
 360                 $c->forward('View::SVG');
 361         } else { # JSON
 362                 $stemma_xml =~ s/\n/ /mg;
 363                 $c->stash->{'result'} = { 'stemmaid' => $stemmaid, 'stemmasvg' => $stemma_xml };
 364                 $c->forward('View::JSON');
 365         }
 366 }
 367
 368 =head2 stemmadot
 369
 370  GET /stemmadot/$textid/$stemmaseq
 371
 372 Returns the 'dot' format representation of the current stemma hypothesis.
 373
 374 =cut
 375
 376 sub stemmadot :Local :Args(2) {
 377         my( $self, $c, $textid, $stemmaid ) = @_;
 378         my $m = $c->model('Directory');
 379         my $tradition = $m->tradition( $textid );
 380         unless( $tradition ) {
 381                 return _json_error( $c, 500, "No tradition with ID $textid" );
 382         }
 383         my $ok = _check_permission( $c, $tradition );
 384         return unless $ok;
 385         my $stemma = $tradition->stemma( $stemmaid );
 386         unless( $stemma ) {
 387                 return _json_error( $c, 500, "Tradition $textid has no stemma ID $stemmaid" );
 388         }
 389         # Get the dot and transmute its line breaks to literal '|n'
 390         $c->stash->{'result'} = { 'dot' =>  $stemma->editable( { linesep => '|n' } ) };
 391         $c->forward('View::JSON');
 392 }
 393
 394 ####################
 395 ### Helper functions
 396 ####################
 397
 398 # Helper to check what permission, if any, the active user has for
 399 # the given tradition
 400 sub _check_permission {
 401         my( $c, $tradition ) = @_;
 402     my $user = $c->user_exists ? $c->user->get_object : undef;
 403     if( $user ) {
 404         return 'full' if ( $user->is_admin ||
 405                 ( $tradition->has_user && $tradition->user->id eq $user->id ) );
 406     }
 407         # Text doesn't belong to us, so maybe it's public?
 408         return 'readonly' if $tradition->public;
 409
 410         # ...nope. Forbidden!
 411         return _json_error( $c, 403, 'You do not have permission to view this tradition.' );
 412 }
 413
 414 # Helper to throw a JSON exception
 415 sub _json_error {
 416         my( $c, $code, $errmsg ) = @_;
 417         $c->response->status( $code );
 418         $c->stash->{'result'} = { 'error' => $errmsg };
 419         $c->forward('View::JSON');
 420         return 0;
 421 }
 422
 423 =head2 default
 424
 425 Standard 404 error page
 426
 427 =cut
 428
 429 sub default :Path {
 430     my ( $self, $c ) = @_;
 431     $c->response->body( 'Page not found' );
 432     $c->response->status(404);
 433 }
 434
 435 =head2 end
 436
 437 Attempt to render a view, if needed.
 438
 439 =cut
 440
 441 sub end : ActionClass('RenderView') {}
 442
 443 =head1 AUTHOR
 444
 445 Tara L Andrews
 446
 447 =head1 LICENSE
 448
 449 This library is free software. You can redistribute it and/or modify
 450 it under the same terms as Perl itself.
 451
 452 =cut
 453
 454 __PACKAGE__->meta->make_immutable;
 455
 456 1;