[scpubgit/stemmaweb.git] / lib / stemmaweb / Controller / Stemweb.pm

package stemmaweb::Controller::Stemweb;
use Moose;
use namespace::autoclean;
use Encode qw/ decode_utf8 /;
use JSON;
use LWP::UserAgent;
use Safe::Isa;
use TryCatch;
use URI;

BEGIN { extends 'Catalyst::Controller' }

## TODO Move the /algorithms/available function to the Stemweb module
my $STEMWEB_BASE_URL = 'http://slinkola.users.cs.helsinki.fi';

=head1 NAME

stemmaweb::Controller::Stemweb - Client listener for Stemweb results

=head1 DESCRIPTION

This is a client listener for the Stemweb API as implemented by the protocol defined at
L<https://docs.google.com/document/d/1aNYGAo1v1WPDZi6LXZ30FJSMJwF8RQPYbOkKqHdCZEc/pub>.

=head1 METHODS

=head2 result

 POST stemweb/result
 Content-Type: application/json
 (On success):
 { jobid: <ID number>
   status: 0
   format: <format>
   result: <data> }
 (On failure):
 { jobid: <ID number>
   status: >1
   result: <error message> }
   
Used by the Stemweb server to notify us that one or more stemma graphs
has been calculated in response to an earlier request.

=cut

sub result :Local :Args(0) {
	my( $self, $c ) = @_;
	if( $c->request->method eq 'POST' ) {
		# TODO: Verify the sender!
		my $answer;
		if( ref( $c->request->body ) eq 'File::Temp' ) {
			# Read in the file and parse that.
			$c->log->debug( "Request body is in a temp file" );
			open( POSTDATA, $c->request->body ) 
				or return _json_error( $c, 500, "Failed to open post data file" );
			binmode( POSTDATA, ':utf8' );
			# JSON should be all one line
			my $pdata = <POSTDATA>;
			chomp $pdata;
			close POSTDATA;
			try {
				$answer = from_json( $pdata );
			} catch {
				return _json_error( $c, 400, 
					"Could not parse POST request '' $pdata '' as JSON: $@" );
			}
		} else {
			$answer = from_json( $c->request->body );
		}
		$c->log->debug( "Received push notification from Stemweb: "
			. to_json( $answer ) );
		return _process_stemweb_result( $c, $answer );
	} else {
		return _json_error( $c, 403, 'Please use POST!' );
	}
}

=head2 available

 GET algorithms/available
 
Queries the Stemweb server for available stemma generation algorithms and their 
parameters. Returns the JSON answer as obtained from Stemweb.

=cut

sub available :Local :Args(0) {
	my( $self, $c ) = @_;
	my $ua = LWP::UserAgent->new();
	my $resp = $ua->get( $STEMWEB_BASE_URL . '/algorithms/available' );
	if( $resp->is_success ) {
		$c->stash->{'result'} = decode_json( $resp->content );
	} else {
		$c->stash->{'result'} = {};
	}
	$c->forward('View::JSON');
}

=head2 query

 GET stemweb/query/<jobid>

A backup method to query the stemweb server to check a particular job status.
Returns a result as in /stemweb/result above, but status can also be -1 to 
indicate that the job is still running.

=cut

sub query :Local :Args(1) {
	my( $self, $c, $jobid ) = @_;
	my $ua = LWP::UserAgent->new();
	my $resp = $ua->get( $STEMWEB_BASE_URL . "/algorithms/jobstatus/$jobid" );
	if( $resp->is_success ) {
		# Process it
		my $response = decode_utf8( $resp->content );
		$c->log->debug( "Got a response from the server: $response" );
		my $answer;
		try {
			$answer = from_json( $response );
		} catch {
			return _json_error( $c, 500, 
				"Could not parse stemweb response '' $response '' as JSON: $@" );
		}
		return _process_stemweb_result( $c, $answer );
	} elsif( $resp->code == 500 && $resp->header('Client-Warning')
		&& $resp->header('Client-Warning') eq 'Internal response' ) {
		# The server was unavailable.
		return _json_error( $c, 503, "The Stemweb server is currently unreachable." );
	} else {
		return _json_error( $c, 500, "Stemweb error: " . $resp->code . " / "
			. $resp->content );
	}
}


## Helper function for parsing Stemweb result data either by push or by pull
sub _process_stemweb_result {
	my( $c, $answer ) = @_;
	# Find the specified tradition and check its job ID.
	my $m = $c->model('Directory');
	my $tradition = $m->tradition( $answer->{textid} );
	unless( $tradition ) {
		return _json_error( $c, 400, "No tradition found with ID "
			. $answer->{textid} );
	}
	if( $answer->{status} == 0 ) {
		my $stemmata;
		if( $tradition->has_stemweb_jobid 
			&& $tradition->stemweb_jobid eq $answer->{jobid} ) {
			try {
				$stemmata = $tradition->record_stemweb_result( $answer );
				$m->save( $tradition );
			} catch( Text::Tradition::Error $e ) {
				return _json_error( $c, 500, $e->message );
			} catch {
				return _json_error( $c, 500, $@ );
			}
		} else {
			# It may be that we already received a callback meanwhile.
			# Check all stemmata for the given jobid and return them.
			@$stemmata = grep { $_->came_from_jobid && $_->from_jobid eq $answer->{jobid} } $tradition->stemmata;
		}
		if( @$stemmata ) {
			# If we got here, success!
			my @steminfo = map { { 
					name => $_->identifier, 
					directed => _json_bool( !$_->is_undirected ),
					svg => $_->as_svg() } } 
				@$stemmata;
			$c->stash->{'result'} = { 
				'status' => 'success',
				'stemmata' => \@steminfo };
		} else {
			# Hm, no stemmata found on this tradition with this jobid.
			# Clear the tradition jobid so that the user can try again.
			if( $tradition->has_stemweb_jobid ) {
				$tradition->_clear_stemweb_jobid;
				$m->save( $tradition );
			}
			$c->stash->{'result'} = { status => 'notfound' };
		}
	} elsif( $answer->{status} < 1 ) {
		$c->stash->{'result'} = { 'status' => 'running' };
	} else {
		return _json_error( $c, 500,
			"Stemweb failure not handled: " . $answer->{result} );
	}
	$c->forward('View::JSON');
}

=head2 request

 GET stemweb/request/?
	tradition=<tradition ID> &
	algorithm=<algorithm ID> &
	[<algorithm parameters>]
   
Send a request for the given tradition with the given parameters to Stemweb.
Processes and returns the JSON response given by the Stemweb server.

=cut

sub request :Local :Args(0) {
	my( $self, $c ) = @_;
	# Look up the relevant tradition and check permissions.
	my $reqparams = $c->req->params;
	my $tid = delete $reqparams->{tradition};
	my $t = $c->model('Directory')->tradition( $tid );
	my $ok = _check_permission( $c, $t );
	return unless $ok;
	return( _json_error( $c, 403, 
			'You do not have permission to update stemmata for this tradition' ) )
		unless $ok eq 'full';
	
	# Form the request for Stemweb.
	my $algorithm = delete $reqparams->{algorithm};
	my $return_uri = URI->new( $c->uri_for( '/stemweb/result' ) );
	my $stemweb_request = {
		return_path => $return_uri->path,
		return_host => $return_uri->host_port,
		data => $t->collation->as_tsv({noac => 1}),
		userid => $c->user->get_object->email,
		textid => $tid,
		parameters => $reqparams };
		
	# Call to the appropriate URL with the request parameters.
	my $ua = LWP::UserAgent->new();
	$c->log->debug( 'Sending request to Stemweb: ' . to_json( $stemweb_request ) ); 
	my $resp = $ua->post( $STEMWEB_BASE_URL . "/algorithms/process/$algorithm/",
		'Content-Type' => 'application/json; charset=utf-8', 
		'Content' => encode_json( $stemweb_request ) ); 
	if( $resp->is_success ) {
		# Process it
		$c->log->debug( 'Got a response from the server: '
			. decode_utf8( $resp->content ) );
		my $stemweb_response = decode_json( $resp->content );
		try {
			$t->set_stemweb_jobid( $stemweb_response->{jobid} );
		} catch( Text::Tradition::Error $e ) {
			return _json_error( $c, 429, $e->message );
		}
		$c->model('Directory')->save( $t );
		$c->stash->{'result'} = $stemweb_response;
		$c->forward('View::JSON');
	} elsif( $resp->code == 500 && $resp->header('Client-Warning')
		&& $resp->header('Client-Warning') eq 'Internal response' ) {
		# The server was unavailable.
		return _json_error( $c, 503, "The Stemweb server is currently unreachable." );
	} else {
		return _json_error( $c, 500, "Stemweb error: " . $resp->code . " / "
			. $resp->content );
	}
}

# Helper to check what permission, if any, the active user has for
# the given tradition
sub _check_permission {
	my( $c, $tradition ) = @_;
    my $user = $c->user_exists ? $c->user->get_object : undef;
    if( $user ) {
    	return 'full' if ( $user->is_admin || 
    		( $tradition->has_user && $tradition->user->id eq $user->id ) );
    }
	# Text doesn't belong to us, so maybe it's public?
	return 'readonly' if $tradition->public;

	# ...nope. Forbidden!
	return _json_error( $c, 403, 'You do not have permission to view this tradition.' );
}

# Helper to throw a JSON exception
sub _json_error {
	my( $c, $code, $errmsg ) = @_;
	$c->response->status( $code );
	$c->stash->{'result'} = { 'error' => $errmsg };
	$c->forward('View::JSON');
	return 0;
}

sub _json_bool {
	return $_[0] ? JSON::true : JSON::false;
}


1;
Commit	Line	Data
532cc23b	1	package stemmaweb::Controller::Stemweb;
	2	use Moose;
	3	use namespace::autoclean;
ed0ce314	4	use Encode qw/ decode_utf8 /;
c2b80bba	5	use JSON;
70744367	6	use LWP::UserAgent;
532cc23b	7	use Safe::Isa;
532cc23b	8	use TryCatch;
70744367	9	use URI;
532cc23b	10
	11	BEGIN { extends 'Catalyst::Controller' }
	12
70744367	13	## TODO Move the /algorithms/available function to the Stemweb module
	14	my $STEMWEB_BASE_URL = 'http://slinkola.users.cs.helsinki.fi';
	15
532cc23b	16	=head1 NAME
	17
	18	stemmaweb::Controller::Stemweb - Client listener for Stemweb results
	19
	20	=head1 DESCRIPTION
	21
	22	This is a client listener for the Stemweb API as implemented by the protocol defined at
	23	L<https://docs.google.com/document/d/1aNYGAo1v1WPDZi6LXZ30FJSMJwF8RQPYbOkKqHdCZEc/pub>.
	24
	25	=head1 METHODS
	26
	27	=head2 result
	28
	29	POST stemweb/result
	30	Content-Type: application/json
	31	(On success):
67b2a665	32	{ jobid: <ID number>
532cc23b	33	status: 0
	34	format: <format>
	35	result: <data> }
	36	(On failure):
	37	{ jobid: <ID number>
	38	status: >1
	39	result: <error message> }
	40
	41	Used by the Stemweb server to notify us that one or more stemma graphs
	42	has been calculated in response to an earlier request.
	43
	44	=cut
	45
	46	sub result :Local :Args(0) {
	47	my( $self, $c ) = @_;
	48	if( $c->request->method eq 'POST' ) {
	49	# TODO: Verify the sender!
	50	my $answer;
	51	if( ref( $c->request->body ) eq 'File::Temp' ) {
	52	# Read in the file and parse that.
67b2a665	53	$c->log->debug( "Request body is in a temp file" );
67b2a665	54	open( POSTDATA, $c->request->body )
c0292f64	55	or return _json_error( $c, 500, "Failed to open post data file" );
532cc23b	56	binmode( POSTDATA, ':utf8' );
	57	# JSON should be all one line
	58	my $pdata = <POSTDATA>;
	59	chomp $pdata;
	60	close POSTDATA;
c2b80bba	61	try {
	62	$answer = from_json( $pdata );
	63	} catch {
	64	return _json_error( $c, 400,
	65	"Could not parse POST request '' $pdata '' as JSON: $@" );
	66	}
532cc23b	67	} else {
	68	$answer = from_json( $c->request->body );
	69	}
67b2a665	70	$c->log->debug( "Received push notification from Stemweb: "
67b2a665	71	. to_json( $answer ) );
c2b80bba	72	return _process_stemweb_result( $c, $answer );
	73	} else {
	74	return _json_error( $c, 403, 'Please use POST!' );
	75	}
	76	}
	77
66458003	78	=head2 available
	79
	80	GET algorithms/available
	81
	82	Queries the Stemweb server for available stemma generation algorithms and their
	83	parameters. Returns the JSON answer as obtained from Stemweb.
	84
	85	=cut
	86
	87	sub available :Local :Args(0) {
	88	my( $self, $c ) = @_;
	89	my $ua = LWP::UserAgent->new();
	90	my $resp = $ua->get( $STEMWEB_BASE_URL . '/algorithms/available' );
	91	if( $resp->is_success ) {
6aabefa3	92	$c->stash->{'result'} = decode_json( $resp->content );
66458003	93	} else {
6aabefa3	94	$c->stash->{'result'} = {};
66458003	95	}
	96	$c->forward('View::JSON');
	97	}
	98
c2b80bba	99	=head2 query
	100
	101	GET stemweb/query/<jobid>
	102
	103	A backup method to query the stemweb server to check a particular job status.
	104	Returns a result as in /stemweb/result above, but status can also be -1 to
	105	indicate that the job is still running.
	106
	107	=cut
	108
	109	sub query :Local :Args(1) {
	110	my( $self, $c, $jobid ) = @_;
	111	my $ua = LWP::UserAgent->new();
2c514a6f	112	my $resp = $ua->get( $STEMWEB_BASE_URL . "/algorithms/jobstatus/$jobid" );
c2b80bba	113	if( $resp->is_success ) {
	114	# Process it
	115	my $response = decode_utf8( $resp->content );
	116	$c->log->debug( "Got a response from the server: $response" );
	117	my $answer;
	118	try {
	119	$answer = from_json( $response );
	120	} catch {
532cc23b	121	return _json_error( $c, 500,
c2b80bba	122	"Could not parse stemweb response '' $response '' as JSON: $@" );
	123	}
	124	return _process_stemweb_result( $c, $answer );
	125	} elsif( $resp->code == 500 && $resp->header('Client-Warning')
	126	&& $resp->header('Client-Warning') eq 'Internal response' ) {
	127	# The server was unavailable.
	128	return _json_error( $c, 503, "The Stemweb server is currently unreachable." );
	129	} else {
	130	return _json_error( $c, 500, "Stemweb error: " . $resp->code . " / "
	131	. $resp->content );
	132	}
	133	}
	134
	135
	136	## Helper function for parsing Stemweb result data either by push or by pull
	137	sub _process_stemweb_result {
	138	my( $c, $answer ) = @_;
c0292f64	139	# Find the specified tradition and check its job ID.
c2b80bba	140	my $m = $c->model('Directory');
c0292f64	141	my $tradition = $m->tradition( $answer->{textid} );
	142	unless( $tradition ) {
	143	return _json_error( $c, 400, "No tradition found with ID "
	144	. $answer->{textid} );
	145	}
	146	if( $answer->{status} == 0 ) {
	147	my $stemmata;
	148	if( $tradition->has_stemweb_jobid
	149	&& $tradition->stemweb_jobid eq $answer->{jobid} ) {
c2b80bba	150	try {
	151	$stemmata = $tradition->record_stemweb_result( $answer );
	152	$m->save( $tradition );
	153	} catch( Text::Tradition::Error $e ) {
	154	return _json_error( $c, 500, $e->message );
	155	} catch {
	156	return _json_error( $c, 500, $@ );
	157	}
c0292f64	158	} else {
	159	# It may be that we already received a callback meanwhile.
	160	# Check all stemmata for the given jobid and return them.
	161	@$stemmata = grep { $_->came_from_jobid && $_->from_jobid eq $answer->{jobid} } $tradition->stemmata;
	162	}
c0292f64	163	if( @$stemmata ) {
c2b80bba	164	# If we got here, success!
	165	my @steminfo = map { {
	166	name => $_->identifier,
	167	directed => _json_bool( !$_->is_undirected ),
	168	svg => $_->as_svg() } }
2c514a6f	169	@$stemmata;
c2b80bba	170	$c->stash->{'result'} = {
	171	'status' => 'success',
	172	'stemmata' => \@steminfo };
c2b80bba	173	} else {
c0292f64	174	# Hm, no stemmata found on this tradition with this jobid.
	175	# Clear the tradition jobid so that the user can try again.
	176	if( $tradition->has_stemweb_jobid ) {
	177	$tradition->_clear_stemweb_jobid;
	178	$m->save( $tradition );
	179	}
	180	$c->stash->{'result'} = { status => 'notfound' };
c2b80bba	181	}
c0292f64	182	} elsif( $answer->{status} < 1 ) {
c0292f64	183	$c->stash->{'result'} = { 'status' => 'running' };
c2b80bba	184	} else {
c0292f64	185	return _json_error( $c, 500,
c0292f64	186	"Stemweb failure not handled: " . $answer->{result} );
532cc23b	187	}
c2b80bba	188	$c->forward('View::JSON');
532cc23b	189	}
532cc23b	190
70744367	191	=head2 request
	192
	193	GET stemweb/request/?
	194	tradition=<tradition ID> &
	195	algorithm=<algorithm ID> &
	196	[<algorithm parameters>]
	197
	198	Send a request for the given tradition with the given parameters to Stemweb.
	199	Processes and returns the JSON response given by the Stemweb server.
	200
	201	=cut
	202
	203	sub request :Local :Args(0) {
	204	my( $self, $c ) = @_;
	205	# Look up the relevant tradition and check permissions.
	206	my $reqparams = $c->req->params;
	207	my $tid = delete $reqparams->{tradition};
	208	my $t = $c->model('Directory')->tradition( $tid );
	209	my $ok = _check_permission( $c, $t );
	210	return unless $ok;
	211	return( _json_error( $c, 403,
	212	'You do not have permission to update stemmata for this tradition' ) )
	213	unless $ok eq 'full';
	214
	215	# Form the request for Stemweb.
	216	my $algorithm = delete $reqparams->{algorithm};
	217	my $return_uri = URI->new( $c->uri_for( '/stemweb/result' ) );
	218	my $stemweb_request = {
	219	return_path => $return_uri->path,
	220	return_host => $return_uri->host_port,
67b2a665	221	data => $t->collation->as_tsv({noac => 1}),
c2b80bba	222	userid => $c->user->get_object->email,
67b2a665	223	textid => $tid,
70744367	224	parameters => $reqparams };
	225
	226	# Call to the appropriate URL with the request parameters.
	227	my $ua = LWP::UserAgent->new();
c2b80bba	228	$c->log->debug( 'Sending request to Stemweb: ' . to_json( $stemweb_request ) );
70744367	229	my $resp = $ua->post( $STEMWEB_BASE_URL . "/algorithms/process/$algorithm/",
	230	'Content-Type' => 'application/json; charset=utf-8',
	231	'Content' => encode_json( $stemweb_request ) );
	232	if( $resp->is_success ) {
	233	# Process it
ed0ce314	234	$c->log->debug( 'Got a response from the server: '
c2b80bba	235	. decode_utf8( $resp->content ) );
70744367	236	my $stemweb_response = decode_json( $resp->content );
	237	try {
	238	$t->set_stemweb_jobid( $stemweb_response->{jobid} );
	239	} catch( Text::Tradition::Error $e ) {
	240	return _json_error( $c, 429, $e->message );
	241	}
	242	$c->model('Directory')->save( $t );
	243	$c->stash->{'result'} = $stemweb_response;
	244	$c->forward('View::JSON');
	245	} elsif( $resp->code == 500 && $resp->header('Client-Warning')
	246	&& $resp->header('Client-Warning') eq 'Internal response' ) {
	247	# The server was unavailable.
	248	return _json_error( $c, 503, "The Stemweb server is currently unreachable." );
	249	} else {
ed0ce314	250	return _json_error( $c, 500, "Stemweb error: " . $resp->code . " / "
70744367	251	. $resp->content );
	252	}
	253	}
	254
	255	# Helper to check what permission, if any, the active user has for
	256	# the given tradition
	257	sub _check_permission {
	258	my( $c, $tradition ) = @_;
	259	my $user = $c->user_exists ? $c->user->get_object : undef;
	260	if( $user ) {
	261	return 'full' if ( $user->is_admin \|\|
	262	( $tradition->has_user && $tradition->user->id eq $user->id ) );
	263	}
	264	# Text doesn't belong to us, so maybe it's public?
	265	return 'readonly' if $tradition->public;
	266
	267	# ...nope. Forbidden!
	268	return _json_error( $c, 403, 'You do not have permission to view this tradition.' );
	269	}
	270
532cc23b	271	# Helper to throw a JSON exception
	272	sub _json_error {
	273	my( $c, $code, $errmsg ) = @_;
	274	$c->response->status( $code );
	275	$c->stash->{'result'} = { 'error' => $errmsg };
	276	$c->forward('View::JSON');
	277	return 0;
	278	}
	279
c2b80bba	280	sub _json_bool {
	281	return $_[0] ? JSON::true : JSON::false;
	282	}
	283
	284
ed0ce314	285	1;