[scpubgit/stemmaweb.git] / lib / stemmaweb / Controller / Root.pm

package stemmaweb::Controller::Root;
use Moose;
use namespace::autoclean;
use Text::Tradition::Analysis qw/ run_analysis /;
use TryCatch;


BEGIN { extends 'Catalyst::Controller' }

#
# Sets the actions in this controller to be registered with no prefix
# so they function identically to actions created in MyApp.pm
#
__PACKAGE__->config(namespace => '');

=head1 NAME

stemmaweb::Controller::Root - Root Controller for stemmaweb

=head1 DESCRIPTION

Serves up the main container pages.

=head1 URLs

=head2 index

The root page (/).  Serves the main container page, from which the various
components will be loaded.

=cut

sub index :Path :Args(0) {
    my ( $self, $c ) = @_;

    $c->stash->{template} = 'index.tt';
}

=head1 Elements of index page

=head2 directory

 GET /directory

Serves a snippet of HTML that lists the available texts.  This returns texts belonging to the logged-in user if any, otherwise it returns all public texts.

=cut

sub directory :Local :Args(0) {
	my( $self, $c ) = @_;
    my $m = $c->model('Directory');
    # Is someone logged in?
    my %usertexts;
    if( $c->user_exists ) {
    	my $user = $c->user->get_object;
    	my @list = $m->traditionlist( $user );
    	map { $usertexts{$_->{id}} = 1 } @list;
		$c->stash->{usertexts} = \@list;
		$c->stash->{is_admin} = 1 if $user->is_admin;
	}
	# List public (i.e. readonly) texts separately from any user (i.e.
	# full access) texts that exist. Admin users therefore have nothing
	# in this list.
	my @plist = grep { !$usertexts{$_->{id}} } $m->traditionlist('public');
	$c->stash->{publictexts} = \@plist;
	$c->stash->{template} = 'directory.tt';
}

=head1 AJAX methods for traditions and their properties

=head2 newtradition

 POST /newtradition,
 	{ name: <name>,
 	  language: <language>,
 	  public: <is_public>,
 	  file: <fileupload> }
 
Creates a new tradition belonging to the logged-in user, with the given name
and the collation given in the uploaded file. The file type is indicated via
the filename extension (.csv, .txt, .xls, .xlsx, .xml). Returns the ID and 
name of the new tradition.
 
=cut

sub newtradition :Local :Args(0) {
	my( $self, $c ) = @_;
	return _json_error( $c, 403, 'Cannot save a tradition without being logged in' )
		unless $c->user_exists;

	my $user = $c->user->get_object;
	# Grab the file upload, check its name/extension, and call the
	# appropriate parser(s).
	my $upload = $c->request->upload('file');
	my $name = $c->request->param('name') || 'Uploaded tradition';
	my $lang = $c->request->param( 'language' ) || 'Default';
	my $public = $c->request->param( 'public' ) ? 1 : undef;
	my( $ext ) = $upload->filename =~ /\.(\w+)$/;
	my %newopts = (
		'name' => $name,
		'language' => $lang,
		'public' => $public,
		'file' => $upload->tempname
		);

	my $tradition;
	my $errmsg;
	if( $ext eq 'xml' ) {
		# Try the different XML parsing options to see if one works.
		foreach my $type ( qw/ CollateX CTE TEI / ) {
			try {
				$tradition = Text::Tradition->new( %newopts, 'input' => $type );
			} catch ( Text::Tradition::Error $e ) {
				$errmsg = $e->message;
			} catch {
				$errmsg = "Unexpected parsing error";
			}
			last if $tradition;
		}
	} elsif( $ext =~ /^(txt|csv|xls(x)?)$/ ) {
		# If it's Excel we need to pass excel => $ext;
		# otherwise we need to pass sep_char => [record separator].
		if( $ext =~ /xls/ ) {
			$newopts{'excel'} = $ext;
		} else {
			$newopts{'sep_char'} = $ext eq 'txt' ? "\t" : ',';
		}
		try {
			$tradition = Text::Tradition->new( 
				%newopts,
				'input' => 'Tabular',
				);
		} catch ( Text::Tradition::Error $e ) {
			$errmsg = $e->message;
		} catch {
			$errmsg = "Unexpected parsing error";
		}
	} else {
		# Error unless we have a recognized filename extension
		return _json_error( $c, 500, "Unrecognized file type extension $ext" );
	}
	
	# Save the tradition if we have it, and return its data or else the
	# error that occurred trying to make it.
	if( $errmsg ) {
		return _json_error( $c, 500, "Error parsing tradition .$ext file: $errmsg" );
	} elsif( !$tradition ) {
		return _json_error( $c, 500, "No error caught but tradition not created" );
	}

	my $m = $c->model('Directory');
	$user->add_tradition( $tradition );
	my $id = $c->model('Directory')->store( $tradition );
	$c->model('Directory')->store( $user );
	$c->stash->{'result'} = { 'id' => $id, 'name' => $tradition->name };
	$c->forward('View::JSON');
}

=head2 textinfo

 GET /textinfo/$textid
 POST /textinfo/$textid, 
 	{ name: $new_name, 
 	  language: $new_language,
 	  public: $is_public, 
 	  owner: $new_userid } # only admin users can update the owner
 
Returns information about a particular text.

=cut

sub textinfo :Local :Args(1) {
	my( $self, $c, $textid ) = @_;
	my $tradition = $c->model('Directory')->tradition( $textid );
	unless( $tradition ) {
		return _json_error( $c, 500, "No tradition with ID $textid" );
	}	
	my $ok = _check_permission( $c, $tradition );
	return unless $ok;
	if( $c->req->method eq 'POST' ) {
		return _json_error( $c, 403, 
			'You do not have permission to update this tradition' ) 
			unless $ok eq 'full';
		my $params = $c->request->parameters;
		# Handle changes to owner-accessible parameters
		my $m = $c->model('Directory');
		my $changed;
		# Handle scalar params
		foreach my $param ( qw/ name language / ) {
			if( exists $params->{$param} ) {
				my $newval = delete $params->{$param};
				unless( $tradition->$param eq $newval ) {
					try {
						$tradition->$param( $newval );
					} catch {
						return _json_error( $c, 500, "Error setting $param to $newval" );
					}
					$changed = 1;
				}
			}
		}
		# Handle our boolean
		if( delete $params->{'public'} ) {  # if it's any true value...
			$tradition->public( 1 );
		}
		# Handle ownership changes
		my $newuser;
		if( exists $params->{'owner'} ) {
			# Only admins can update user / owner
			my $newownerid = delete $params->{'owner'};
			unless( $tradition->has_user && $tradition->user->id eq $newownerid ) {
				unless( $c->user->get_object->is_admin ) {
					return _json_error( $c, 403, 
						"Only admin users can change tradition ownership" );
				}
				$newuser = $m->lookup_user( $params->{'owner'} );
				unless( $newuser ) {
					return _json_error( $c, 500, "No such user " . $params->{'owner'} );
				}
				$newuser->add_tradition( $tradition );
				$changed = 1;
			}
		}
		# TODO check for rogue parameters
		if( scalar keys %$params ) {
			my $rogueparams = join( ', ', keys %$params );
			return _json_error( $c, 403, "Request parameters $rogueparams not recognized" );
		}
		# If we safely got to the end, then write to the database.
		$m->save( $tradition ) if $changed;
		$m->save( $newuser ) if $newuser;		
	}

	# Now return the current textinfo, whether GET or successful POST.
	my $textinfo = {
		textid => $textid,
		name => $tradition->name,
		language => $tradition->language,
		public => $tradition->public,
		owner => $tradition->user ? $tradition->user->id : undef,
		witnesses => [ map { $_->sigil } $tradition->witnesses ],
	};
	my @stemmasvg = map { $_->as_svg({ size => [ 500, 375 ] }) } $tradition->stemmata;
	map { $_ =~ s/\n/ /mg } @stemmasvg;
	$textinfo->{stemmata} = \@stemmasvg;
	$c->stash->{'result'} = $textinfo;
	$c->forward('View::JSON');
}

=head2 variantgraph

 GET /variantgraph/$textid
 
Returns the variant graph for the text specified at $textid, in SVG form.

=cut

sub variantgraph :Local :Args(1) {
	my( $self, $c, $textid ) = @_;
	my $tradition = $c->model('Directory')->tradition( $textid );
	unless( $tradition ) {
		return _json_error( $c, 500, "No tradition with ID $textid" );
	}	
	my $ok = _check_permission( $c, $tradition );
	return unless $ok;

	my $collation = $tradition->collation;
	$c->stash->{'result'} = $collation->as_svg;
	$c->forward('View::SVG');
}
	
=head2 stemma

 GET /stemma/$textid/$stemmaseq
 POST /stemma/$textid/$stemmaseq, { 'dot' => $dot_string }

Returns an SVG representation of the given stemma hypothesis for the text.  
If the URL is called with POST, the stemma at $stemmaseq will be altered
to reflect the definition in $dot_string. If $stemmaseq is 'n', a new
stemma will be added.

=cut

sub stemma :Local :Args(2) {
	my( $self, $c, $textid, $stemmaid ) = @_;
	my $m = $c->model('Directory');
	my $tradition = $m->tradition( $textid );
	unless( $tradition ) {
		return _json_error( $c, 500, "No tradition with ID $textid" );
	}	
	my $ok = _check_permission( $c, $tradition );
	return unless $ok;

	$c->stash->{'result'} = '';
	my $stemma;
	if( $c->req->method eq 'POST' ) {
		if( $ok eq 'full' ) {
			my $dot = $c->request->body_params->{'dot'};
			try {
				if( $stemmaid eq 'n' ) {
					# We are adding a new stemma.
					$stemma = $tradition->add_stemma( 'dot' => $dot );
				} elsif( $stemmaid < $tradition->stemma_count ) {
					# We are updating an existing stemma.
					$stemma = $tradition->stemma( $stemmaid );
					$stemma->alter_graph( $dot );
				} else {
					# Unrecognized stemma ID
					return _json_error( $c, 500, "No stemma at index $stemmaid, cannot update" );
				}
			} catch ( Text::Tradition::Error $e ) {
				return _json_error( $c, 500, $e->message );
			}
			$m->store( $tradition );
		} else {
			# No permissions to update the stemma
			return _json_error( $c, 403, 
				'You do not have permission to update stemmata for this tradition' );
		}
	}
	
	# For a GET or a successful POST request, return the SVG representation
	# of the stemma in question, if any.
	$c->log->debug( "Received Accept header: " . $c->req->header('Accept') );
	if( !$stemma && $tradition->stemma_count > $stemmaid ) {
		$stemma = $tradition->stemma( $stemmaid );
	}
	$c->stash->{'result'} = $stemma 
		? $stemma->as_svg( { size => [ 500, 375 ] } ) : '';
	$c->forward('View::SVG');
}

=head2 stemmadot

 GET /stemmadot/$textid/$stemmaseq
 
Returns the 'dot' format representation of the current stemma hypothesis.

=cut

sub stemmadot :Local :Args(2) {
	my( $self, $c, $textid, $stemmaid ) = @_;
	my $m = $c->model('Directory');
	my $tradition = $m->tradition( $textid );
	unless( $tradition ) {
		return _json_error( $c, 500, "No tradition with ID $textid" );
	}	
	my $ok = _check_permission( $c, $tradition );
	return unless $ok;
	my $stemma = $tradition->stemma( $stemmaid );
	unless( $stemma ) {
		return _json_error( $c, 500, "Tradition $textid has no stemma ID $stemmaid" );
	}
	# Get the dot and transmute its line breaks to literal '|n'
	$c->stash->{'result'} = { 'dot' =>  $stemma->editable( { linesep => '|n' } ) };
	$c->forward('View::JSON');
}

####################
### Helper functions
####################

# Helper to check what permission, if any, the active user has for
# the given tradition
sub _check_permission {
	my( $c, $tradition ) = @_;
    my $user = $c->user_exists ? $c->user->get_object : undef;
    if( $user ) {
    	return 'full' if ( $user->is_admin || 
    		( $tradition->has_user && $tradition->user->id eq $user->id ) );
    }
	# Text doesn't belong to us, so maybe it's public?
	return 'readonly' if $tradition->public;

	# ...nope. Forbidden!
	return _json_error( $c, 403, 'You do not have permission to view this tradition.' );
}

# Helper to throw a JSON exception
sub _json_error {
	my( $c, $code, $errmsg ) = @_;
	$c->response->status( $code );
	$c->stash->{'result'} = { 'error' => $errmsg };
	$c->forward('View::JSON');
	return 0;
}

=head2 default

Standard 404 error page

=cut

sub default :Path {
    my ( $self, $c ) = @_;
    $c->response->body( 'Page not found' );
    $c->response->status(404);
}

=head2 end

Attempt to render a view, if needed.

=cut

sub end : ActionClass('RenderView') {}

=head1 AUTHOR

Tara L Andrews

=head1 LICENSE

This library is free software. You can redistribute it and/or modify
it under the same terms as Perl itself.

=cut

__PACKAGE__->meta->make_immutable;

1;
Commit	Line	Data
b8a92065	1	package stemmaweb::Controller::Root;
	2	use Moose;
	3	use namespace::autoclean;
	4	use Text::Tradition::Analysis qw/ run_analysis /;
41279a86	5	use TryCatch;
b8a92065	6
	7
	8	BEGIN { extends 'Catalyst::Controller' }
	9
	10	#
	11	# Sets the actions in this controller to be registered with no prefix
	12	# so they function identically to actions created in MyApp.pm
	13	#
	14	__PACKAGE__->config(namespace => '');
	15
	16	=head1 NAME
	17
	18	stemmaweb::Controller::Root - Root Controller for stemmaweb
	19
	20	=head1 DESCRIPTION
	21
	22	Serves up the main container pages.
	23
	24	=head1 URLs
	25
	26	=head2 index
	27
	28	The root page (/). Serves the main container page, from which the various
	29	components will be loaded.
	30
	31	=cut
	32
	33	sub index :Path :Args(0) {
	34	my ( $self, $c ) = @_;
	35
	36	$c->stash->{template} = 'index.tt';
	37	}
	38
	39	=head1 Elements of index page
	40
	41	=head2 directory
	42
	43	GET /directory
	44
70ccaf75	45	Serves a snippet of HTML that lists the available texts. This returns texts belonging to the logged-in user if any, otherwise it returns all public texts.
b8a92065	46
b8a92065	47	=cut
70ccaf75	48
b8a92065	49	sub directory :Local :Args(0) {
	50	my( $self, $c ) = @_;
	51	my $m = $c->model('Directory');
69799996	52	# Is someone logged in?
98a45925	53	my %usertexts;
69799996	54	if( $c->user_exists ) {
69799996	55	my $user = $c->user->get_object;
98a45925	56	my @list = $m->traditionlist( $user );
	57	map { $usertexts{$_->{id}} = 1 } @list;
	58	$c->stash->{usertexts} = \@list;
69799996	59	$c->stash->{is_admin} = 1 if $user->is_admin;
69799996	60	}
98a45925	61	# List public (i.e. readonly) texts separately from any user (i.e.
	62	# full access) texts that exist. Admin users therefore have nothing
	63	# in this list.
	64	my @plist = grep { !$usertexts{$_->{id}} } $m->traditionlist('public');
	65	$c->stash->{publictexts} = \@plist;
b8a92065	66	$c->stash->{template} = 'directory.tt';
	67	}
	68
75354c3a	69	=head1 AJAX methods for traditions and their properties
fb6e49b3	70
75354c3a	71	=head2 newtradition
	72
	73	POST /newtradition,
	74	{ name: <name>,
	75	language: <language>,
	76	public: <is_public>,
	77	file: <fileupload> }
fb6e49b3	78
75354c3a	79	Creates a new tradition belonging to the logged-in user, with the given name
	80	and the collation given in the uploaded file. The file type is indicated via
	81	the filename extension (.csv, .txt, .xls, .xlsx, .xml). Returns the ID and
	82	name of the new tradition.
	83
	84	=cut
	85
	86	sub newtradition :Local :Args(0) {
	87	my( $self, $c ) = @_;
	88	return _json_error( $c, 403, 'Cannot save a tradition without being logged in' )
	89	unless $c->user_exists;
	90
	91	my $user = $c->user->get_object;
	92	# Grab the file upload, check its name/extension, and call the
	93	# appropriate parser(s).
	94	my $upload = $c->request->upload('file');
	95	my $name = $c->request->param('name') \|\| 'Uploaded tradition';
	96	my $lang = $c->request->param( 'language' ) \|\| 'Default';
	97	my $public = $c->request->param( 'public' ) ? 1 : undef;
	98	my( $ext ) = $upload->filename =~ /\.(\w+)$/;
	99	my %newopts = (
	100	'name' => $name,
	101	'language' => $lang,
	102	'public' => $public,
	103	'file' => $upload->tempname
	104	);
	105
	106	my $tradition;
	107	my $errmsg;
	108	if( $ext eq 'xml' ) {
	109	# Try the different XML parsing options to see if one works.
	110	foreach my $type ( qw/ CollateX CTE TEI / ) {
	111	try {
	112	$tradition = Text::Tradition->new( %newopts, 'input' => $type );
	113	} catch ( Text::Tradition::Error $e ) {
	114	$errmsg = $e->message;
	115	} catch {
	116	$errmsg = "Unexpected parsing error";
	117	}
	118	last if $tradition;
	119	}
	120	} elsif( $ext =~ /^(txt\|csv\|xls(x)?)$/ ) {
	121	# If it's Excel we need to pass excel => $ext;
	122	# otherwise we need to pass sep_char => [record separator].
	123	if( $ext =~ /xls/ ) {
	124	$newopts{'excel'} = $ext;
	125	} else {
	126	$newopts{'sep_char'} = $ext eq 'txt' ? "\t" : ',';
	127	}
	128	try {
	129	$tradition = Text::Tradition->new(
	130	%newopts,
	131	'input' => 'Tabular',
	132	);
	133	} catch ( Text::Tradition::Error $e ) {
	134	$errmsg = $e->message;
	135	} catch {
	136	$errmsg = "Unexpected parsing error";
	137	}
	138	} else {
	139	# Error unless we have a recognized filename extension
	140	return _json_error( $c, 500, "Unrecognized file type extension $ext" );
	141	}
	142
143	# Save the tradition if we have it, and return its data or else the
144	# error that occurred trying to make it.
145	if( $errmsg ) {
146	return _json_error( $c, 500, "Error parsing tradition .$ext file: $errmsg" );
147	} elsif( !$tradition ) {
148	return _json_error( $c, 500, "No error caught but tradition not created" );
149	}
150
151	my $m = $c->model('Directory');
152	$user->add_tradition( $tradition );
153	my $id = $c->model('Directory')->store( $tradition );
154	$c->model('Directory')->store( $user );
155	$c->stash->{'result'} = { 'id' => $id, 'name' => $tradition->name };
156	$c->forward('View::JSON');
157	}
158
159	=head2 textinfo
160
161	GET /textinfo/$textid
162	POST /textinfo/$textid,
163	{ name: $new_name,
164	language: $new_language,
165	public: $is_public,
166	owner: $new_userid } # only admin users can update the owner
167
168	Returns information about a particular text.
fb6e49b3	169
	170	=cut
	171
75354c3a	172	sub textinfo :Local :Args(1) {
fb6e49b3	173	my( $self, $c, $textid ) = @_;
98a45925	174	my $tradition = $c->model('Directory')->tradition( $textid );
75354c3a	175	unless( $tradition ) {
	176	return _json_error( $c, 500, "No tradition with ID $textid" );
	177	}
41279a86	178	my $ok = _check_permission( $c, $tradition );
41279a86	179	return unless $ok;
75354c3a	180	if( $c->req->method eq 'POST' ) {
	181	return _json_error( $c, 403,
	182	'You do not have permission to update this tradition' )
	183	unless $ok eq 'full';
	184	my $params = $c->request->parameters;
	185	# Handle changes to owner-accessible parameters
	186	my $m = $c->model('Directory');
	187	my $changed;
	188	# Handle scalar params
	189	foreach my $param ( qw/ name language / ) {
	190	if( exists $params->{$param} ) {
	191	my $newval = delete $params->{$param};
	192	unless( $tradition->$param eq $newval ) {
	193	try {
	194	$tradition->$param( $newval );
	195	} catch {
	196	return _json_error( $c, 500, "Error setting $param to $newval" );
	197	}
	198	$changed = 1;
	199	}
	200	}
	201	}
	202	# Handle our boolean
	203	if( delete $params->{'public'} ) { # if it's any true value...
	204	$tradition->public( 1 );
	205	}
	206	# Handle ownership changes
	207	my $newuser;
	208	if( exists $params->{'owner'} ) {
	209	# Only admins can update user / owner
	210	my $newownerid = delete $params->{'owner'};
	211	unless( $tradition->has_user && $tradition->user->id eq $newownerid ) {
	212	unless( $c->user->get_object->is_admin ) {
	213	return _json_error( $c, 403,
	214	"Only admin users can change tradition ownership" );
	215	}
	216	$newuser = $m->lookup_user( $params->{'owner'} );
	217	unless( $newuser ) {
	218	return _json_error( $c, 500, "No such user " . $params->{'owner'} );
	219	}
	220	$newuser->add_tradition( $tradition );
	221	$changed = 1;
	222	}
	223	}
	224	# TODO check for rogue parameters
	225	if( scalar keys %$params ) {
	226	my $rogueparams = join( ', ', keys %$params );
	227	return _json_error( $c, 403, "Request parameters $rogueparams not recognized" );
	228	}
	229	# If we safely got to the end, then write to the database.
	230	$m->save( $tradition ) if $changed;
	231	$m->save( $newuser ) if $newuser;
	232	}
41279a86	233
75354c3a	234	# Now return the current textinfo, whether GET or successful POST.
	235	my $textinfo = {
	236	textid => $textid,
	237	name => $tradition->name,
	238	language => $tradition->language,
	239	public => $tradition->public,
	240	owner => $tradition->user ? $tradition->user->id : undef,
	241	witnesses => [ map { $_->sigil } $tradition->witnesses ],
	242	};
	243	my @stemmasvg = map { $_->as_svg({ size => [ 500, 375 ] }) } $tradition->stemmata;
	244	map { $_ =~ s/\n/ /mg } @stemmasvg;
	245	$textinfo->{stemmata} = \@stemmasvg;
	246	$c->stash->{'result'} = $textinfo;
	247	$c->forward('View::JSON');
fb6e49b3	248	}
b8a92065	249
75354c3a	250	=head2 variantgraph
b8a92065	251
75354c3a	252	GET /variantgraph/$textid
	253
	254	Returns the variant graph for the text specified at $textid, in SVG form.
b8a92065	255
	256	=cut
	257
75354c3a	258	sub variantgraph :Local :Args(1) {
b8a92065	259	my( $self, $c, $textid ) = @_;
98a45925	260	my $tradition = $c->model('Directory')->tradition( $textid );
75354c3a	261	unless( $tradition ) {
	262	return _json_error( $c, 500, "No tradition with ID $textid" );
	263	}
41279a86	264	my $ok = _check_permission( $c, $tradition );
	265	return unless $ok;
	266
98a45925	267	my $collation = $tradition->collation;
75354c3a	268	$c->stash->{'result'} = $collation->as_svg;
75354c3a	269	$c->forward('View::SVG');
b8a92065	270	}
75354c3a	271
b8a92065	272	=head2 stemma
b8a92065	273
75354c3a	274	GET /stemma/$textid/$stemmaseq
75354c3a	275	POST /stemma/$textid/$stemmaseq, { 'dot' => $dot_string }
b8a92065	276
75354c3a	277	Returns an SVG representation of the given stemma hypothesis for the text.
	278	If the URL is called with POST, the stemma at $stemmaseq will be altered
	279	to reflect the definition in $dot_string. If $stemmaseq is 'n', a new
	280	stemma will be added.
b8a92065	281
	282	=cut
	283
75354c3a	284	sub stemma :Local :Args(2) {
41279a86	285	my( $self, $c, $textid, $stemmaid ) = @_;
b8a92065	286	my $m = $c->model('Directory');
b8a92065	287	my $tradition = $m->tradition( $textid );
75354c3a	288	unless( $tradition ) {
	289	return _json_error( $c, 500, "No tradition with ID $textid" );
	290	}
41279a86	291	my $ok = _check_permission( $c, $tradition );
	292	return unless $ok;
	293
41279a86	294	$c->stash->{'result'} = '';
75354c3a	295	my $stemma;
	296	if( $c->req->method eq 'POST' ) {
	297	if( $ok eq 'full' ) {
41279a86	298	my $dot = $c->request->body_params->{'dot'};
75354c3a	299	try {
	300	if( $stemmaid eq 'n' ) {
	301	# We are adding a new stemma.
	302	$stemma = $tradition->add_stemma( 'dot' => $dot );
	303	} elsif( $stemmaid < $tradition->stemma_count ) {
	304	# We are updating an existing stemma.
	305	$stemma = $tradition->stemma( $stemmaid );
	306	$stemma->alter_graph( $dot );
	307	} else {
	308	# Unrecognized stemma ID
	309	return _json_error( $c, 500, "No stemma at index $stemmaid, cannot update" );
	310	}
	311	} catch ( Text::Tradition::Error $e ) {
	312	return _json_error( $c, 500, $e->message );
	313	}
41279a86	314	$m->store( $tradition );
75354c3a	315	} else {
	316	# No permissions to update the stemma
	317	return _json_error( $c, 403,
	318	'You do not have permission to update stemmata for this tradition' );
41279a86	319	}
b8a92065	320	}
75354c3a	321
	322	# For a GET or a successful POST request, return the SVG representation
	323	# of the stemma in question, if any.
	324	$c->log->debug( "Received Accept header: " . $c->req->header('Accept') );
	325	if( !$stemma && $tradition->stemma_count > $stemmaid ) {
	326	$stemma = $tradition->stemma( $stemmaid );
	327	}
	328	$c->stash->{'result'} = $stemma
	329	? $stemma->as_svg( { size => [ 500, 375 ] } ) : '';
b8a92065	330	$c->forward('View::SVG');
	331	}
	332
	333	=head2 stemmadot
	334
75354c3a	335	GET /stemmadot/$textid/$stemmaseq
b8a92065	336
	337	Returns the 'dot' format representation of the current stemma hypothesis.
	338
	339	=cut
	340
75354c3a	341	sub stemmadot :Local :Args(2) {
75354c3a	342	my( $self, $c, $textid, $stemmaid ) = @_;
b8a92065	343	my $m = $c->model('Directory');
b8a92065	344	my $tradition = $m->tradition( $textid );
75354c3a	345	unless( $tradition ) {
	346	return _json_error( $c, 500, "No tradition with ID $textid" );
	347	}
41279a86	348	my $ok = _check_permission( $c, $tradition );
41279a86	349	return unless $ok;
75354c3a	350	my $stemma = $tradition->stemma( $stemmaid );
	351	unless( $stemma ) {
	352	return _json_error( $c, 500, "Tradition $textid has no stemma ID $stemmaid" );
	353	}
	354	# Get the dot and transmute its line breaks to literal '\|n'
	355	$c->stash->{'result'} = { 'dot' => $stemma->editable( { linesep => '\|n' } ) };
41279a86	356	$c->forward('View::JSON');
	357	}
	358
75354c3a	359	####################
	360	### Helper functions
	361	####################
41279a86	362
75354c3a	363	# Helper to check what permission, if any, the active user has for
75354c3a	364	# the given tradition
41279a86	365	sub _check_permission {
	366	my( $c, $tradition ) = @_;
	367	my $user = $c->user_exists ? $c->user->get_object : undef;
	368	if( $user ) {
929ba7c8	369	return 'full' if ( $user->is_admin \|\|
929ba7c8	370	( $tradition->has_user && $tradition->user->id eq $user->id ) );
080f8a02	371	}
	372	# Text doesn't belong to us, so maybe it's public?
	373	return 'readonly' if $tradition->public;
	374
	375	# ...nope. Forbidden!
75354c3a	376	return _json_error( $c, 403, 'You do not have permission to view this tradition.' );
	377	}
	378
	379	# Helper to throw a JSON exception
	380	sub _json_error {
	381	my( $c, $code, $errmsg ) = @_;
	382	$c->response->status( $code );
	383	$c->stash->{'result'} = { 'error' => $errmsg };
	384	$c->forward('View::JSON');
929ba7c8	385	return 0;
41279a86	386	}
41279a86	387
b8a92065	388	=head2 default
	389
	390	Standard 404 error page
	391
	392	=cut
	393
	394	sub default :Path {
	395	my ( $self, $c ) = @_;
	396	$c->response->body( 'Page not found' );
	397	$c->response->status(404);
	398	}
	399
	400	=head2 end
	401
	402	Attempt to render a view, if needed.
	403
	404	=cut
	405
	406	sub end : ActionClass('RenderView') {}
	407
	408	=head1 AUTHOR
	409
	410	Tara L Andrews
	411
	412	=head1 LICENSE
	413
	414	This library is free software. You can redistribute it and/or modify
	415	it under the same terms as Perl itself.
	416
	417	=cut
	418
	419	__PACKAGE__->meta->make_immutable;
	420
	421	1;