lib/Tak/MetaService.pm

   1 package Tak::MetaService;
   2
   3 use Tak::WeakClient;
   4 use Log::Contextual qw(:log);
   5 use Moo;
   6
   7 with 'Tak::Role::Service';
   8
   9 has router => (is => 'ro', required => 1, weak_ref => 1);
  10
  11 sub handle_pid {
  12   return $$;
  13 }
  14
  15 sub handle_ensure {
  16   my $self = shift;
  17   my ($name) = @_;
  18   return "Already have ${name}" if $self->router->services->{$name};
  19   $self->handle_register(@_);
  20 }
  21
  22 sub handle_register {
  23   my ($self, $name, $class, %args) = @_;
  24   (my $file = $class) =~ s/::/\//g;
  25   require "${file}.pm";
  26   my $router = $self->router;
  27   if (my $expose = delete $args{expose}) {
  28     foreach my $name (keys %$expose) {
  29       if (my ($svc, @rest) = @{$expose->{$name}}) {
  30         die "router has no service ${svc}"
  31           unless my $service = $router->services->{$svc};
  32         $args{$name} = Tak::Client->new(service => $service)
  33                                   ->curry(@rest);
  34       } else {
  35         $args{$name} = Tak::WeakClient->new(service => $router);
  36       }
  37     }
  38   }
  39   my $new = $class->new(\%args);
  40   $router->register($name => $new);
  41   return "Registered ${name}";
  42 }
  43
  44 1;